Create2Deployer

{{
  "language": "Solidity",
  "sources": {
    "@openzeppelin/contracts/access/Ownable.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}
"
    },
    "@openzeppelin/contracts/utils/Context.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}
"
    },
    "contracts/Create2Deployer.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity 0.8.28;

import "@openzeppelin/contracts/access/Ownable.sol";

contract Create2Deployer is Ownable {
    mapping(address => bool) public isAdmin;
    uint256 public adminCount;

    error Create2Failed();
    error CallFailed();
    error InvalidCaller();
    error InvalidAdmin();
    error ZeroAddress();
    error AlreadyAdmin();
    error NotAdmin();
    error MismatchedValueSent();
    error OwnerAdminRemovalBlocked();
    error NoAdminsLeft();

    event Deployed(address indexed addr);
    event AdminAdded(address indexed account);
    event AdminRemoved(address indexed account);

    constructor(address owner)  Ownable(owner){
        if (owner == address(0)) revert ZeroAddress();
        isAdmin[owner] = true;
        adminCount = 1;
    }

    /// @param salt consist of two parts. The upper 160bits is the optionally the caller address
    ///             and the lower 96bits can be randomly chosen.
    /// @param initCode bytecode to be deployed.
    /// @param data optional calldata called after the contract is deployed.
    /// @param create2ForwardValue value sent to the deployed contract.
    /// @param callForwardValue value sent alone with the call.
    function deploy(
        bytes32 salt,
        bytes memory initCode,
        bytes memory data,
        uint256 create2ForwardValue,
        uint256 callForwardValue
    ) external payable onlyAdmin returns (address deployed) {
        if (msg.value != create2ForwardValue + callForwardValue) {
            revert MismatchedValueSent();
        }
        assembly {
            deployed := create2(create2ForwardValue, add(0x20, initCode), mload(initCode), salt)
        }
        if (deployed == address(0)) {
            revert Create2Failed();
        }
        if (data.length > 0) {
            bool success;
            assembly {
                success := call(gas(), deployed, callForwardValue, add(0x20, data), mload(data), 0, 0)
            }
            if (!success) {
                revert CallFailed();
            }
        }
        emit Deployed(deployed);
    }

    function addAdmin(address account) external onlyOwner {
        if (account == address(0)) revert ZeroAddress();
        if (isAdmin[account]) revert AlreadyAdmin();
        isAdmin[account] = true;
        unchecked {adminCount++;}
        emit AdminAdded(account);
    }

    function removeAdmin(address account) external onlyOwner {
        if (!isAdmin[account]) revert NotAdmin();
        if (account == owner()) revert OwnerAdminRemovalBlocked();
        if (adminCount <= 1) revert NoAdminsLeft();
        isAdmin[account] = false;
        unchecked {adminCount--;}
        emit AdminRemoved(account);
    }

    function _transferOwnership(address newOwner) internal override {
        super._transferOwnership(newOwner);
        if (!isAdmin[newOwner]) {
            isAdmin[newOwner] = true;
            unchecked {adminCount++;}
            emit AdminAdded(newOwner);
        }
    }

    function computeCreate2Address(bytes32 salt, bytes calldata initCode) external view returns (address) {
        return address(
            uint160(
                uint256(
                    keccak256(abi.encodePacked(hex"ff", address(this), salt, keccak256(abi.encodePacked(initCode))))
                )
            )
        );
    }

    function computeCreate2Address(bytes32 salt, bytes32 initCodeHash) external view returns (address) {
        return address(uint160(uint256(keccak256(abi.encodePacked(hex"ff", address(this), salt, initCodeHash)))));
    }

    modifier onlyAdmin() {
        if (!isAdmin[msg.sender]) revert InvalidAdmin();
        _;
    }

}"
    }
  },
  "settings": {
    "optimizer": {
      "enabled": true,
      "runs": 200
    },
    "evmVersion": "cancun",
    "viaIR": false,
    "outputSelection": {
      "*": {
        "*": [
          "evm.bytecode",
          "evm.deployedBytecode",
          "devdoc",
          "userdoc",
          "metadata",
          "abi"
        ]
      }
    }
  }
}}