EthgasPool

{{
  "language": "Solidity",
  "sources": {
    "contracts/dependencies/openzeppelin-v5.0.1/token/IERC20.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}"
    },
    "contracts/dependencies/openzeppelin-v5.0.1/token/IERC20Permit.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 *
 * ==== Security Considerations
 *
 * There are two important considerations concerning the use of `permit`. The first is that a valid permit signature
 * expresses an allowance, and it should not be assumed to convey additional meaning. In particular, it should not be
 * considered as an intention to spend the allowance in any specific way. The second is that because permits have
 * built-in replay protection and can be submitted by anyone, they can be frontrun. A protocol that uses permits should
 * take this into consideration and allow a `permit` call to fail. Combining these two aspects, a pattern that may be
 * generally recommended is:
 *
 * ```solidity
 * function doThingWithPermit(..., uint256 value, uint256 deadline, uint8 v, bytes32 r, bytes32 s) public {
 *     try token.permit(msg.sender, address(this), value, deadline, v, r, s) {} catch {}
 *     doThing(..., value);
 * }
 *
 * function doThing(..., uint256 value) public {
 *     token.safeTransferFrom(msg.sender, address(this), value);
 *     ...
 * }
 * ```
 *
 * Observe that: 1) `msg.sender` is used as the owner, leaving no ambiguity as to the signer intent, and 2) the use of
 * `try/catch` allows the permit to fail and makes the code tolerant to frontrunning. (See also
 * {SafeERC20-safeTransferFrom}).
 *
 * Additionally, note that smart contract wallets (such as Argent or Safe) are not able to produce permit signatures, so
 * contracts should have entry points that don't rely on permit.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     *
     * CAUTION: See Security Considerations above.
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}"
    },
    "contracts/dependencies/openzeppelin-v5.0.1/token/SafeERC20.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "./IERC20.sol";
import {IERC20Permit} from "./IERC20Permit.sol";
import {Address} from "../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    /**
     * @dev An operation with an ERC20 token failed.
     */
    error SafeERC20FailedOperation(address token);

    /**
     * @dev Indicates a failed `decreaseAllowance` request.
     */
    error SafeERC20FailedDecreaseAllowance(address spender, uint256 currentAllowance, uint256 requestedDecrease);

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        forceApprove(token, spender, oldAllowance + value);
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `requestedDecrease`. If `token` returns no
     * value, non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 requestedDecrease) internal {
        unchecked {
            uint256 currentAllowance = token.allowance(address(this), spender);
            if (currentAllowance < requestedDecrease) {
                revert SafeERC20FailedDecreaseAllowance(spender, currentAllowance, requestedDecrease);
            }
            forceApprove(token, spender, currentAllowance - requestedDecrease);
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeCall(token.approve, (spender, value));

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeCall(token.approve, (spender, 0)));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data);
        if (returndata.length != 0 && !abi.decode(returndata, (bool))) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return success && (returndata.length == 0 || abi.decode(returndata, (bool))) && address(token).code.length > 0;
    }
}"
    },
    "contracts/dependencies/openzeppelin-v5.0.1/utils/Address.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/Address.sol)

pragma solidity ^0.8.20;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev The ETH balance of the account is not enough to perform the operation.
     */
    error AddressInsufficientBalance(address account);

    /**
     * @dev There's no code at `target` (it is not a contract).
     */
    error AddressEmptyCode(address target);

    /**
     * @dev A call to an address target failed. The target may have reverted.
     */
    error FailedInnerCall();

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.20/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        if (address(this).balance < amount) {
            revert AddressInsufficientBalance(address(this));
        }

        (bool success, ) = recipient.call{value: amount}("");
        if (!success) {
            revert FailedInnerCall();
        }
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason or custom error, it is bubbled
     * up by this function (like regular Solidity function calls). However, if
     * the call reverted with no returned reason, this function reverts with a
     * {FailedInnerCall} error.
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        if (address(this).balance < value) {
            revert AddressInsufficientBalance(address(this));
        }
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and reverts if the target
     * was not a contract or bubbling up the revert reason (falling back to {FailedInnerCall}) in case of an
     * unsuccessful call.
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata
    ) internal view returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            // only check if target is a contract if the call was successful and the return data is empty
            // otherwise we already know that it was a contract
            if (returndata.length == 0 && target.code.length == 0) {
                revert AddressEmptyCode(target);
            }
            return returndata;
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and reverts if it wasn't, either by bubbling the
     * revert reason or with a default {FailedInnerCall} error.
     */
    function verifyCallResult(bool success, bytes memory returndata) internal pure returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            return returndata;
        }
    }

    /**
     * @dev Reverts with returndata if present. Otherwise reverts with {FailedInnerCall}.
     */
    function _revert(bytes memory returndata) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert FailedInnerCall();
        }
    }
}"
    },
    "contracts/dependencies/openzeppelin-v5.0.1/utils/Context.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}"
    },
    "contracts/dependencies/openzeppelin-v5.0.1/utils/Pausable.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/Pausable.sol)

pragma solidity ^0.8.20;

import {Context} from "./Context.sol";

/**
 * @dev Contract module which allows children to implement an emergency stop
 * mechanism that can be triggered by an authorized account.
 *
 * This module is used through inheritance. It will make available the
 * modifiers `whenNotPaused` and `whenPaused`, which can be applied to
 * the functions of your contract. Note that they will not be pausable by
 * simply including this module, only once the modifiers are put in place.
 */
abstract contract Pausable is Context {
    bool private _paused;

    /**
     * @dev Emitted when the pause is triggered by `account`.
     */
    event Paused(address account);

    /**
     * @dev Emitted when the pause is lifted by `account`.
     */
    event Unpaused(address account);

    /**
     * @dev The operation failed because the contract is paused.
     */
    error EnforcedPause();

    /**
     * @dev The operation failed because the contract is not paused.
     */
    error ExpectedPause();

    /**
     * @dev Initializes the contract in unpaused state.
     */
    constructor() {
        _paused = false;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is not paused.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    modifier whenNotPaused() {
        _requireNotPaused();
        _;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is paused.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    modifier whenPaused() {
        _requirePaused();
        _;
    }

    /**
     * @dev Returns true if the contract is paused, and false otherwise.
     */
    function paused() public view virtual returns (bool) {
        return _paused;
    }

    /**
     * @dev Throws if the contract is paused.
     */
    function _requireNotPaused() internal view virtual {
        if (paused()) {
            revert EnforcedPause();
        }
    }

    /**
     * @dev Throws if the contract is not paused.
     */
    function _requirePaused() internal view virtual {
        if (!paused()) {
            revert ExpectedPause();
        }
    }

    /**
     * @dev Triggers stopped state.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    function _pause() internal virtual whenNotPaused {
        _paused = true;
        emit Paused(_msgSender());
    }

    /**
     * @dev Returns to normal state.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    function _unpause() internal virtual whenPaused {
        _paused = false;
        emit Unpaused(_msgSender());
    }
}"
    },
    "contracts/dependencies/openzeppelin-v5.0.1/utils/ReentrancyGuard.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/ReentrancyGuard.sol)

pragma solidity ^0.8.20;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant NOT_ENTERED = 1;
    uint256 private constant ENTERED = 2;

    uint256 private _status;

    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();

    constructor() {
        _status = NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be NOT_ENTERED
        if (_status == ENTERED) {
            revert ReentrancyGuardReentrantCall();
        }

        // Any calls to nonReentrant after this point will fail
        _status = ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == ENTERED;
    }
}"
    },
    "contracts/EthgasPool.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity ^0.8.28;


import "./interfaces/IEthgasPool.sol";
import "./interfaces/IWETH.sol";
import "./interfaces/IACLManager.sol";
import "./libraries/DepositHelper.sol";
import "./libraries/TransferFundHelper.sol";
import "./libraries/InputValidator.sol";
import "./dependencies/openzeppelin-v5.0.1/utils/Pausable.sol";
import "./dependencies/openzeppelin-v5.0.1/utils/Context.sol";
import "./dependencies/openzeppelin-v5.0.1/utils/ReentrancyGuard.sol";


contract EthgasPool is IEthgasPool, Context, ReentrancyGuard, Pausable {

	mapping(address => bool) public supportedToken;
	// for serverTransferFund & serverTransferFundSingle
	mapping(address => uint256) public dailyWithdrawalCap;
	mapping(address => uint256) public currentDailyWithdrawalAmount;
	mapping(address => uint256) public lastWithdrawalTime;
	// for serverPayout
	mapping(address => uint256) public dailyPayoutCap;
	mapping(address => uint256) public currentDailyPayoutAmount;
	mapping(address => uint256) public lastPayoutTime;
	

	IACLManager public aclManager;
	IWETH public immutable weth;

	modifier onlyAdminRole() {
		aclManager.checkAdminRole(msg.sender);
		_;
	}

	modifier onlyTreasurerRole() {
		aclManager.checkTreasurerRole(msg.sender);
		_;
	}


	modifier onlyTimelockRole() {
		aclManager.checkTimelockRole(msg.sender);
		_;
	}

	modifier onlyPauserRole() {
		aclManager.checkPauserRole(msg.sender);
		_;
	}

	modifier onlyBookKeeperRole() {
		aclManager.checkBookKeeperRole(msg.sender);
		_;
	}

	modifier onlyPayouterRole() {
		aclManager.checkPayouterRole(msg.sender);
		_;
	}

	constructor(IACLManager _aclManager, IWETH _weth, address[] memory _token, uint256[] memory _withdrawalCap, uint256[] memory _payoutCap) {
		InputValidator.validateAddr(address(_aclManager));
		InputValidator.validateAddr(address(_weth));
		aclManager = _aclManager;
		weth = _weth;
		if ((_token.length != _withdrawalCap.length) || (_token.length != _payoutCap.length) || _token.length == 0) {
			revert InvalidParamLength();
		}
		for (uint256 i; i < _token.length; i++) {
			InputValidator.validateAddr(address(_token[i]));
			dailyWithdrawalCap[_token[i]] = _withdrawalCap[i];
			emit DailyWithdrawalCapChanged(_token[i], _withdrawalCap[i]);

			dailyPayoutCap[_token[i]] = _payoutCap[i];
			emit DailyPayoutCapChanged(_token[i], _payoutCap[i]);

			supportedToken[_token[i]] = true;
			emit SupportedTokenChanged(_token[i], true);
		}
	}


	function pause() external onlyPauserRole {
		super._pause();
    }

	function unpause() external onlyAdminRole {
		super._unpause();
    }

	function setAclManager(IACLManager _aclManager) external onlyTimelockRole whenNotPaused {
		InputValidator.validateAddr(address(_aclManager));
		aclManager = _aclManager;
		emit AclManagerChanged(address(_aclManager));
	}


	function setDailyWithdrawalCap(address _token, uint256 _cap) external onlyAdminRole whenNotPaused {
	    InputValidator.validateAddr(_token);	
		dailyWithdrawalCap[_token] = _cap;
		emit DailyWithdrawalCapChanged(_token, _cap);
	}

	function setDailyPayoutCap(address _token, uint256 _cap) external onlyAdminRole whenNotPaused {
	    InputValidator.validateAddr(_token);	
		dailyPayoutCap[_token] = _cap;
		emit DailyPayoutCapChanged(_token, _cap);
	}

	function setSupportedToken(address _token, bool _isSupport) external onlyBookKeeperRole whenNotPaused {
		InputValidator.validateAddr(_token);
		supportedToken[_token] = _isSupport;
		emit SupportedTokenChanged(_token, _isSupport);
	}
	
	function deposit(TokenTransfer[] memory tokenTransfers) external whenNotPaused payable {
		DepositHelper.deposit(tokenTransfers, weth, supportedToken);
	}

	function serverPayout(address clientAddress, TokenTransfer[] calldata tokenTransfers, uint256 targetBlockNumber) onlyPayouterRole nonReentrant whenNotPaused external {
		if (block.number > targetBlockNumber) {
			revert InvalidBlockNumber();
		}
		TransferFundHelper.serverTransferFund(
			address(weth), false, clientAddress, tokenTransfers, dailyPayoutCap, lastPayoutTime, currentDailyPayoutAmount
		);
	}

	function serverTransferFundSingle(address clientAddress, TokenTransfer[] calldata tokenTransfers) onlyTreasurerRole nonReentrant whenNotPaused external {
		TransferFundHelper.serverTransferFund(
			address(weth), false, clientAddress, tokenTransfers, dailyWithdrawalCap, lastWithdrawalTime, currentDailyWithdrawalAmount
		);
	}

	function serverTransferFund(address[] calldata clientAddresses, TokenTransfer[][] calldata tokenTransferss) onlyTreasurerRole nonReentrant whenNotPaused external {
		if ((clientAddresses.length != tokenTransferss.length) || clientAddresses.length == 0) {
			revert InvalidParamLength();
		}
		for(uint i = 0; i < clientAddresses.length; i++) {
			TransferFundHelper.serverTransferFund(
				address(weth), false, clientAddresses[i], tokenTransferss[i], dailyWithdrawalCap, lastWithdrawalTime, currentDailyWithdrawalAmount
			);
		} 

	}

	/**
	 * @dev can transfer any amount out
	 */
	function serverTransferAnyFund(address[] calldata clientAddresses, TokenTransfer[][] calldata tokenTransferss) onlyTimelockRole nonReentrant whenNotPaused external {
		if ((clientAddresses.length != tokenTransferss.length) || clientAddresses.length == 0) {
			revert InvalidParamLength();
		}
		for(uint i = 0; i < clientAddresses.length; i++) {
			TransferFundHelper.serverTransferFund(
				address(weth), true, clientAddresses[i], tokenTransferss[i], dailyWithdrawalCap, lastWithdrawalTime, currentDailyWithdrawalAmount
			);
		} 
	}

	function wrapEth(uint256 amount) onlyTreasurerRole nonReentrant whenNotPaused external {
		weth.deposit{value: amount}();
	}

	function unwrapWeth(uint256 amount) onlyTreasurerRole nonReentrant whenNotPaused external {
		weth.withdraw(amount);
	}

	receive() external payable {}

}
"
    },
    "contracts/interfaces/IACLManager.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity ^0.8.12;

interface IACLManager {

    function checkAdminRole(address _account) external view;
    function checkTreasurerRole(address _account) external view;
    function checkTimelockRole(address _account) external view;
    function checkPauserRole(address _account) external view;
    function checkBookKeeperRole(address _account) external view;
    function checkPayouterRole(address _account) external view;
    function checkOtherRole1(address _account) external view;
    function checkOtherRole2(address _account) external view;
    function checkOtherRole3(address _account) external view;

}"
    },
    "contracts/interfaces/IEthgasPool.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity ^0.8.12;


interface IEthgasPool {


	struct TokenTransfer {
		address token;
		uint256 amount;
	}

	error InvalidParamLength();
	error InvalidBlockNumber();
	error CannotSendEthDirectly();
	
	event DepositsTriggered(
		address indexed sender,
		TokenTransfer[] transfers
	);

	event Withdrawal(
		address indexed clientAddress,
		IEthgasPool.TokenTransfer tokenTranfer
	);

	event AclManagerChanged(address aclManager);

	event DailyWithdrawalCapChanged(
		address token, uint256 cap
	);

	event DailyPayoutCapChanged(
		address token, uint256 cap
	);

	event SupportedTokenChanged(
		address token, bool isSupport
	);

}
"
    },
    "contracts/interfaces/IWETH.sol": {
      "content": "// SPDX-License-Identifier: MIT

pragma solidity ^0.8.12;

import "../dependencies/openzeppelin-v5.0.1/token/SafeERC20.sol";

interface IWETH is IERC20 {
    function deposit() external payable;
    function withdraw(uint) external;
}
"
    },
    "contracts/libraries/DepositHelper.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity ^0.8.12;

import "../interfaces/IWETH.sol";
import "../interfaces/IEthgasPool.sol";
import "../dependencies/openzeppelin-v5.0.1/token/SafeERC20.sol";


library DepositHelper {
	using SafeERC20 for IERC20;

	event DepositsTriggered(
		address indexed sender,
		IEthgasPool.TokenTransfer[] transfers
	);

	error InvalidTokenValue();
	error NotEnoughBalance();
	error NotSupportedToken();

	function deposit (IEthgasPool.TokenTransfer[] memory tokenTransfers, IWETH weth, mapping(address => bool) storage supportedToken) external {
		if(msg.value == 0 && tokenTransfers.length == 0 ) {
			revert InvalidTokenValue();
		}

		IEthgasPool.TokenTransfer[] memory tt = new IEthgasPool.TokenTransfer[](tokenTransfers.length + (msg.value > 0 ? 1 : 0));
		for (uint i = 0; i < tokenTransfers.length; i++) {
			if (supportedToken[tokenTransfers[i].token] == false) {
				revert NotSupportedToken();
			}
			IERC20 token = IERC20(tokenTransfers[i].token);
			uint256 tokenAmount = tokenTransfers[i].amount;
			uint balance = token.balanceOf(address(msg.sender));
			if (balance < tokenAmount) {
				revert NotEnoughBalance();
			}
			token.safeTransferFrom( msg.sender, address(this), tokenAmount);
			tt[i] = tokenTransfers[i];
		}
		if (msg.value > 0) {
			if (supportedToken[address(weth)] == false) {
				revert NotSupportedToken();
			}
			tt[tokenTransfers.length] = IEthgasPool.TokenTransfer(address(0xEeeeeEeeeEeEeeEeEeEeeEEEeeeeEeeeeeeeEEeE), msg.value);
		}

		emit DepositsTriggered(
			msg.sender, tt
		);
	}

}"
    },
    "contracts/libraries/InputValidator.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity ^0.8.12;

import "../interfaces/IWETH.sol";
import "../interfaces/IEthgasPool.sol";


library InputValidator {



	error IncorrectAddress();

	function validateAddr (address _inputAddr) internal pure {
		if (_inputAddr == address(0)) {
			revert IncorrectAddress();
		}

	}

}"
    },
    "contracts/libraries/TransferFundHelper.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity ^0.8.12;

import "../interfaces/IEthgasPool.sol";
import "../dependencies/openzeppelin-v5.0.1/token/SafeERC20.sol";

library TransferFundHelper {

	using SafeERC20 for IERC20;

	error ZeroParamLength();
	error ExceedDailyTransferCap();
	error FailedToSendEth();

	function serverTransferFund(
		address weth, bool isAdmin, address clientAddress, IEthgasPool.TokenTransfer[] calldata tokenTransfers, 
		mapping(address => uint256) storage dailyTransferCap, mapping(address => uint256) storage lastTransferTime, mapping(address => uint256) storage currentDailyTransferAmount
	) internal {
		if (tokenTransfers.length == 0) {
			revert ZeroParamLength();
		}
		bool isNativeEth;
		IERC20 token;
		for (uint i = 0; i < tokenTransfers.length; i++) {
			IEthgasPool.TokenTransfer memory tt = tokenTransfers[i];
			if (tt.token == address(0xEeeeeEeeeEeEeeEeEeEeeEEEeeeeEeeeeeeeEEeE)) {
				isNativeEth = true;
				tt.token = weth;
			} else {
				token = IERC20(tt.token);
			}
			
			// reset limit after a day
			if (block.timestamp - lastTransferTime[tt.token] > 1 days) {
				lastTransferTime[tt.token] = block.timestamp;
				currentDailyTransferAmount[tt.token] = 0;
			}

			if (isAdmin) {
				transfer(isNativeEth, clientAddress, tt, token);
			} else if (currentDailyTransferAmount[tt.token] + tt.amount <= dailyTransferCap[tt.token]) {
				currentDailyTransferAmount[tt.token] += tt.amount;
				transfer(isNativeEth, clientAddress, tt, token);
			} else {
				revert ExceedDailyTransferCap();
			}
		}

	}

	function transfer(bool isNativeEth, address clientAddress, IEthgasPool.TokenTransfer memory tokenTransfer, IERC20 token) internal {
		if (isNativeEth) {
			(bool success, ) = clientAddress.call{value: tokenTransfer.amount}("");
			if (success == false) revert FailedToSendEth();
		} else {
			token.safeTransfer(clientAddress, tokenTransfer.amount);
		}
		emit IEthgasPool.Withdrawal(clientAddress, tokenTransfer);
	}

}"
    }
  },
  "settings": {
    "evmVersion": "paris",
    "optimizer": {
      "enabled": false,
      "runs": 200
    },
    "outputSelection": {
      "*": {
        "*": [
          "evm.bytecode",
          "evm.deployedBytecode",
          "devdoc",
          "userdoc",
          "metadata",
          "abi"
        ]
      }
    },
    "metadata": {
      "useLiteralContent": true
    },
    "libraries": {
      "contracts/EthgasPool.sol": {
        "DepositHelper": "0x796fa0f613b9871044954f0c6839b329a0ba299c"
      }
    }
  }
}}