PoolFactory

{{
  "language": "Solidity",
  "sources": {
    "src/PoolFactory.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import "lib/openzeppelin-contracts/contracts/token/ERC20/utils/SafeERC20.sol";
import "lib/openzeppelin-contracts/contracts/access/Ownable.sol";
import "./ClonesLib.sol";
import "./VaultConfig.sol";
import "./IVaultInitializer.sol";
import "./Errors.sol";

contract PoolFactory is Ownable {
    using SafeERC20 for IERC20;
    using ClonesLib for address;

    uint16 public constant MIN_PROJECT_FEE_BPS = 5; // 0.05%
    uint32 public constant MAX_COOLDOWN = 730 days;

    // Add vault registry - every newly created vault is marked as valid
    mapping(address => bool) public isValidVault;

    // Implementation contracts
    address public immutable etherVaultImplementation;
    address public immutable erc20VaultImplementation;

    event PoolCreated(
        address indexed pool,
        address indexed creator,
        address indexed principal,
        bool isEtherPool,
        address underlying,
        uint256 initialAmount,
        bytes32 configPart1,
        bytes32 configPart2
    );

    constructor(address _etherVaultImpl, address _erc20VaultImpl) {
        if (_etherVaultImpl == address(0)) revert INVALID_ETHER_VAULT_IMPL();
        if (_erc20VaultImpl == address(0)) revert INVALID_ERC20_VAULT_IMPL();
        etherVaultImplementation = _etherVaultImpl;
        erc20VaultImplementation = _erc20VaultImpl;
    }

    function _packConfig(VaultConfig calldata c) internal pure returns (bytes32, bytes32) {
        bytes32 part1 = bytes32(
            uint256(c.depositFeeBps) | (uint256(c.withdrawalFeeBps) << 16) | (uint256(c.projectFeeBps) << 32)
                | (uint256(c.reserveRatioBps) << 48) | (uint256(c.lossCapBps) << 64)
                | (uint256(c.maxDepositPercentageBps) << 80) | (uint256(c.withdrawCooldown) << 96)
                | (uint256(c.maxWithdrawPenaltyBps) << 128) | (uint256(c.fastExitWindow) << 144)
                | (uint256(c.fastExitFloorBps) << 176)
        );
        bytes32 part2 = bytes32(
            uint256(c.bootstrapLock) | (uint256(c.discountTierCount) << 32) | (uint256(c.discountDurations[0]) << 40)
                | (uint256(c.discountDurations[1]) << 72) | (uint256(c.discountDurations[2]) << 104)
                | (uint256(c.discountDurations[3]) << 136) | (uint256(c.discountBps[0]) << 168)
                | (uint256(c.discountBps[1]) << 184) | (uint256(c.discountBps[2]) << 200)
                | (uint256(c.discountBps[3]) << 216)
        );
        return (part1, part2);
    }

    modifier onlyValid(VaultConfig calldata cfg) {
        if (cfg.depositFeeBps > BPS) revert INV_DEP_FEE();
        if (cfg.withdrawalFeeBps > BPS) revert INV_WD_FEE();
        if (!(cfg.projectFeeBps >= MIN_PROJECT_FEE_BPS && cfg.projectFeeBps <= BPS)) revert INV_PROJ_FEE();
        if (cfg.reserveRatioBps > BPS) revert INV_RES_RATIO();
        if (cfg.lossCapBps > BPS) revert INV_LOSS_CAP();
        if (cfg.maxDepositPercentageBps > BPS) revert INV_MAX_DEP_PCT();
        if (cfg.withdrawCooldown > MAX_COOLDOWN) revert INV_COOLDOWN();
        if (cfg.maxWithdrawPenaltyBps > BPS) revert INV_PENALTY();
        if (cfg.fastExitWindow > cfg.withdrawCooldown) revert INV_FAST_EXIT_WINDOW();
        if (cfg.fastExitFloorBps > BPS) revert INV_FAST_EXIT_FLOOR();
        if (cfg.discountTierCount < 1 || cfg.discountTierCount > 4) revert INV_TIER_CNT();
        if (cfg.discountDurations[0] == 0) revert INV_DUR_0();
        for (uint8 i = 1; i < cfg.discountTierCount; i++) {
            if (cfg.discountDurations[i] <= cfg.discountDurations[i - 1]) revert INV_DUR_SEQ();
        }
        for (uint8 i = 0; i < cfg.discountTierCount; i++) {
            if (cfg.discountBps[i] > cfg.depositFeeBps) revert INV_DISC_BPS();
        }
        if (cfg.tvlFirstElbow == 0) revert INV_TVL_ELBOW_1();
        if (cfg.tvlSecondElbow <= cfg.tvlFirstElbow) revert INV_TVL_ELBOW_2();
        if (cfg.maxFeeBps < cfg.depositFeeBps) revert INV_MAX_FEE();
        if (cfg.maxFeeBps > BPS) revert MAX_FEE_TOO_HIGH();
        if (cfg.depositFeeBps + cfg.slope1Bps > cfg.maxFeeBps) revert SLOPE_TOO_STEEP();
        _;
    }

    function createCustomEtherPool(
        VaultConfig calldata cfg,
        string calldata name_,
        string calldata symbol_,
        address principal_
    ) external payable onlyValid(cfg) returns (address) {
        if (msg.value == 0) revert INIT_ZERO();
        if (principal_ == address(0)) revert ZERO_PRINCIPAL();

        // Deploy minimal proxy
        address vault = etherVaultImplementation.clone();

        // Initialize the proxy
        IVaultInitializer(vault).initialize{value: msg.value}(
            cfg,
            address(0), // underlying (not used for Ether vaults)
            name_,
            symbol_,
            msg.sender,
            principal_,
            msg.value,
            msg.sender  // Add creator parameter
        );

        // Mark new vault as valid in the registry
        isValidVault[vault] = true;

        (bytes32 part1, bytes32 part2) = _packConfig(cfg);
        emit PoolCreated(vault, msg.sender, principal_, true, address(0), msg.value, part1, part2);
        return vault;
    }

    function createCustomTokenPool(
        VaultConfig calldata cfg,
        address token,
        uint256 initialAmount,
        string calldata name_,
        string calldata symbol_,
        address principal_
    ) external onlyValid(cfg) returns (address) {
        if (token == address(0)) revert ZERO_TOKEN();
        if (initialAmount == 0) revert INIT_ZERO();
        if (principal_ == address(0)) revert ZERO_PRINCIPAL();

        // 1) Deploy proxy first
        address vault = erc20VaultImplementation.clone();

        // 2) Pull tokens directly into the vault (avoids double taxation)
        uint256 beforeVault = IERC20(token).balanceOf(vault);
        IERC20(token).safeTransferFrom(msg.sender, vault, initialAmount);
        uint256 received = IERC20(token).balanceOf(vault) - beforeVault;

        // 3) Initialize, passing what the vault actually holds
        IVaultInitializer(vault).initialize(
            cfg,
            token,
            name_,
            symbol_,
            msg.sender,
            principal_,
            received,
            msg.sender  // Add creator parameter
        );

        // Mark new vault as valid in the registry
        isValidVault[vault] = true;

        (bytes32 part1, bytes32 part2) = _packConfig(cfg);
        // Emit 'received' (truth) not the user's requested 'initialAmount'
        emit PoolCreated(vault, msg.sender, principal_, false, token, received, part1, part2);
        return vault;
    }

    function createCustomEtherPoolDeterministic(
        VaultConfig calldata cfg,
        string calldata name_,
        string calldata symbol_,
        address principal_,
        bytes32 salt
    ) external payable onlyValid(cfg) returns (address) {
        if (msg.value == 0) revert INIT_ZERO();
        if (principal_ == address(0)) revert ZERO_PRINCIPAL();

        // Deploy minimal proxy deterministically
        address vault = etherVaultImplementation.cloneDeterministic(salt);

        // Initialize the proxy
        IVaultInitializer(vault).initialize{value: msg.value}(
            cfg,
            address(0),
            name_,
            symbol_,
            msg.sender,
            principal_,
            msg.value,
            msg.sender  // Add creator parameter
        );

        // Mark new vault as valid in the registry
        isValidVault[vault] = true;

        (bytes32 part1, bytes32 part2) = _packConfig(cfg);
        emit PoolCreated(vault, msg.sender, principal_, true, address(0), msg.value, part1, part2);
        return vault;
    }

    // Admin escape hatch to manually set vault validity
    function setVaultValidity(address vault, bool valid) external onlyOwner {
        isValidVault[vault] = valid;
    }

    function predictPoolAddress(address implementation, bytes32 salt) external view returns (address) {
        return ClonesLib.predictDeterministicAddress(implementation, salt, address(this));
    }
}
"
    },
    "lib/openzeppelin-contracts/contracts/token/ERC20/utils/SafeERC20.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.3) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";
import "../extensions/IERC20Permit.sol";
import "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(IERC20 token, address spender, uint256 value) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        require(
            (value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance + value));
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        unchecked {
            uint256 oldAllowance = token.allowance(address(this), spender);
            require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance - value));
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeWithSelector(token.approve.selector, spender, value);

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, 0));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Use a ERC-2612 signature to set the `owner` approval toward `spender` on `token`.
     * Revert on invalid signature.
     */
    function safePermit(
        IERC20Permit token,
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal {
        uint256 nonceBefore = token.nonces(owner);
        token.permit(owner, spender, value, deadline, v, r, s);
        uint256 nonceAfter = token.nonces(owner);
        require(nonceAfter == nonceBefore + 1, "SafeERC20: permit did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        require(returndata.length == 0 || abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return
            success && (returndata.length == 0 || abi.decode(returndata, (bool))) && Address.isContract(address(token));
    }
}
"
    },
    "lib/openzeppelin-contracts/contracts/access/Ownable.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}
"
    },
    "src/ClonesLib.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import "./Errors.sol";

/**
 * @dev EIP-1167 Minimal Proxy implementation
 * Deploys minimal proxy contracts that delegate all calls to an implementation contract
 */
library ClonesLib {
    /**
     * @dev Deploys and returns the address of a clone that mimics the behaviour of `implementation`.
     *
     * This function uses the create opcode, which should never revert.
     */
    function clone(address implementation) internal returns (address instance) {
        assembly {
            let ptr := mload(0x40)
            mstore(ptr, 0x3d602d80600a3d3981f3363d3d373d3d3d363d73000000000000000000000000)
            mstore(add(ptr, 0x14), shl(0x60, implementation))
            mstore(add(ptr, 0x28), 0x5af43d82803e903d91602b57fd5bf30000000000000000000000000000000000)
            instance := create(0, ptr, 0x37)
        }
        if (instance == address(0)) revert CLONE_FAILED();
    }

    /**
     * @dev Deploys and returns the address of a clone that mimics the behaviour of `implementation`.
     *
     * This function uses the create2 opcode and a `salt` to deterministically deploy
     * the clone. Using the same `implementation` and `salt` multiple time will revert.
     */
    function cloneDeterministic(address implementation, bytes32 salt) internal returns (address instance) {
        assembly {
            let ptr := mload(0x40)
            mstore(ptr, 0x3d602d80600a3d3981f3363d3d373d3d3d363d73000000000000000000000000)
            mstore(add(ptr, 0x14), shl(0x60, implementation))
            mstore(add(ptr, 0x28), 0x5af43d82803e903d91602b57fd5bf30000000000000000000000000000000000)
            instance := create2(0, ptr, 0x37, salt)
        }
        if (instance == address(0)) revert CLONE2_FAILED();
    }

    /**
     * @dev Computes the address of a clone deployed using {cloneDeterministic}.
     */
    function predictDeterministicAddress(
        address implementation,
        bytes32 salt,
        address deployer
    ) internal pure returns (address predicted) {
        assembly {
            let ptr := mload(0x40)
            mstore(ptr, 0x3d602d80600a3d3981f3363d3d373d3d3d363d73000000000000000000000000)
            mstore(add(ptr, 0x14), shl(0x60, implementation))
            mstore(add(ptr, 0x28), 0x5af43d82803e903d91602b57fd5bf3ff00000000000000000000000000000000)
            mstore(add(ptr, 0x38), shl(0x60, deployer))
            mstore(add(ptr, 0x4c), salt)
            mstore(add(ptr, 0x6c), keccak256(ptr, 0x37))
            predicted := keccak256(add(ptr, 0x37), 0x55)
        }
    }
}"
    },
    "src/VaultConfig.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

uint256 constant BPS = 10_000;
uint256 constant SCALE = 1e18;

struct VaultConfig {
    uint16 depositFeeBps;
    uint16 withdrawalFeeBps;
    uint16 projectFeeBps;
    uint16 reserveRatioBps;
    uint16 lossCapBps;
    uint16 maxDepositPercentageBps;
    uint32 bootstrapLock;
    uint8 discountTierCount;
    uint32[4] discountDurations;
    uint16[4] discountBps;
    uint256 tvlFirstElbow;
    uint256 tvlSecondElbow;
    uint16 slope1Bps;
    uint16 maxFeeBps;
    uint32 withdrawCooldown;
    uint16 maxWithdrawPenaltyBps;
    uint32 fastExitWindow;
    uint16 fastExitFloorBps;
}"
    },
    "src/IVaultInitializer.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import "./VaultConfig.sol";

interface IVaultInitializer {
    function initialize(
        VaultConfig calldata cfg,
        address underlying,
        string calldata name,
        string calldata symbol,
        address owner,
        address principal,
        uint256 initialAmount,
        address creator
    ) external payable;
}"
    },
    "src/Errors.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

// Common custom errors for gas savings
error NOT_PRINCIPAL();
error DEPOSITS_STOPPED();
error ZERO_PRINCIPAL();
error ETH_TRANSFER_FAIL();
error BAD_ETH_AMT();
error BAD_TOKEN_AMT();
error ALREADY_STOPPED();
error NOT_STOPPED();
error TRANSFERS_DISABLED();
error UNEXPECTED_ETH();
error ZERO_AMOUNT();
error EXCEEDS_MAX_DEPOSIT();
error SLIPPAGE_EXCEEDED();
error ZERO_SHARES();
error RESERVE_TOO_LOW();
error INIT_ZERO();
error ZERO_TOKEN();
error INVALID_POOL_COUNT();
error PROTOCOL_FEE_TOO_LOW();
error PROTOCOL_FEE_TOO_HIGH();
error TRADING_FEE_TOO_LOW();
error TRADING_FEE_TOO_HIGH();
error INVALID_POOL();
error POOL_NOT_ETH();
error POOL_TOKEN_MISMATCH();
error MUST_SUM_TO_10000();
error STRATEGY_INACTIVE();
error SLIPPAGE_TOO_HIGH();
error BAD_MINSHARES_LEN();
error POOL_DEPOSITS_STOPPED();
error POOL_PAUSED();
error NO_POSITION();
error INVALID_PERCENTAGE();
error NO_TOKENS_RECEIVED();
error NO_TOKENS_RECEIVED_FOR_SWAP();
error ETH_FEE_TRANSFER_FAILED();
error ETH_TRANSFER_FAILED();
error MAX_FEE_TOO_HIGH();
error SLOPE_TOO_STEEP();
error INV_DEP_FEE();
error INV_WD_FEE();
error INV_PROJ_FEE();
error INV_RES_RATIO();
error INV_LOSS_CAP();
error INV_MAX_DEP_PCT();
error INV_COOLDOWN();
error INV_PENALTY();
error INV_FAST_EXIT_WINDOW();
error INV_FAST_EXIT_FLOOR();
error INV_TIER_CNT();
error INV_DUR_0();
error INV_DUR_SEQ();
error INV_DISC_BPS();
error INV_TVL_ELBOW_1();
error INV_TVL_ELBOW_2();
error INV_MAX_FEE();
error ZERO_ETH_AMOUNT();
error SEEDER_LOCKED();
error STRATEGY_FEE_TOO_LOW();

// Additional errors for require statement replacements
error ALREADY_INITIALIZED();
error FACTORY_ALREADY_SET();
error FACTORY_ZERO_ADDRESS();
error INVALID_ETHER_VAULT_IMPL();
error INVALID_ERC20_VAULT_IMPL();
error CLONE_FAILED();
error CLONE2_FAILED();
error NOT_OWNER();
error REENTRANT_CALL();
error PAUSED();
error NOT_PAUSED();
error ZERO_ADDRESS_OWNER();
error ZERO_ADDRESS_FROM();
error ZERO_ADDRESS_TO();
error INSUFFICIENT_BALANCE();
error ZERO_ADDRESS_MINT();
error ZERO_ADDRESS_BURN();
error BURN_EXCEEDS_BALANCE();
error ZERO_ADDRESS_APPROVE_FROM();
error ZERO_ADDRESS_APPROVE_TO();
error INSUFFICIENT_ALLOWANCE();
error TICK_OUT_OF_RANGE();
error ZERO_DENOMINATOR();
error MATH_OVERFLOW();
"
    },
    "lib/openzeppelin-contracts/contracts/token/ERC20/IERC20.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 amount) external returns (bool);
}
"
    },
    "lib/openzeppelin-contracts/contracts/token/ERC20/extensions/IERC20Permit.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}
"
    },
    "lib/openzeppelin-contracts/contracts/utils/Address.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     *
     * Furthermore, `isContract` will also return true if the target contract within
     * the same transaction is already scheduled for destruction by `SELFDESTRUCT`,
     * which only has an effect at the end of a transaction.
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.0/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
     * the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
     *
     * _Available since v4.8._
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        if (success) {
            if (returndata.length == 0) {
                // only check isContract if the call was successful and the return data is empty
                // otherwise we already know that it was a contract
                require(isContract(target), "Address: call to non-contract");
            }
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason or using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    function _revert(bytes memory returndata, string memory errorMessage) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert(errorMessage);
        }
    }
}
"
    },
    "lib/openzeppelin-contracts/contracts/utils/Context.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}
"
    }
  },
  "settings": {
    "remappings": [
      "ds-test/=lib/openzeppelin-contracts/lib/forge-std/lib/ds-test/src/",
      "erc4626-tests/=lib/openzeppelin-contracts/lib/erc4626-tests/",
      "forge-std/=lib/forge-std/src/",
      "openzeppelin-contracts/=lib/openzeppelin-contracts/",
      "openzeppelin/=lib/openzeppelin-contracts/contracts/",
      "v3-core/=lib/v3-core/",
      "v3-periphery/=lib/v3-periphery/contracts/"
    ],
    "optimizer": {
      "enabled": true,
      "runs": 200
    },
    "metadata": {
      "useLiteralContent": false,
      "bytecodeHash": "ipfs",
      "appendCBOR": true
    },
    "outputSelection": {
      "*": {
        "*": [
          "evm.bytecode",
          "evm.deployedBytecode",
          "devdoc",
          "userdoc",
          "metadata",
          "abi"
        ]
      }
    },
    "evmVersion": "cancun",
    "viaIR": true
  }
}}