MasterLaunchWhitelist

{{
  "language": "Solidity",
  "sources": {
    "@openzeppelin/contracts/access/AccessControl.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/AccessControl.sol)

pragma solidity ^0.8.0;

import "./IAccessControl.sol";
import "../utils/Context.sol";
import "../utils/Strings.sol";
import "../utils/introspection/ERC165.sol";

/**
 * @dev Contract module that allows children to implement role-based access
 * control mechanisms. This is a lightweight version that doesn't allow enumerating role
 * members except through off-chain means by accessing the contract event logs. Some
 * applications may benefit from on-chain enumerability, for those cases see
 * {AccessControlEnumerable}.
 *
 * Roles are referred to by their `bytes32` identifier. These should be exposed
 * in the external API and be unique. The best way to achieve this is by
 * using `public constant` hash digests:
 *
 * ```solidity
 * bytes32 public constant MY_ROLE = keccak256("MY_ROLE");
 * ```
 *
 * Roles can be used to represent a set of permissions. To restrict access to a
 * function call, use {hasRole}:
 *
 * ```solidity
 * function foo() public {
 *     require(hasRole(MY_ROLE, msg.sender));
 *     ...
 * }
 * ```
 *
 * Roles can be granted and revoked dynamically via the {grantRole} and
 * {revokeRole} functions. Each role has an associated admin role, and only
 * accounts that have a role's admin role can call {grantRole} and {revokeRole}.
 *
 * By default, the admin role for all roles is `DEFAULT_ADMIN_ROLE`, which means
 * that only accounts with this role will be able to grant or revoke other
 * roles. More complex role relationships can be created by using
 * {_setRoleAdmin}.
 *
 * WARNING: The `DEFAULT_ADMIN_ROLE` is also its own admin: it has permission to
 * grant and revoke this role. Extra precautions should be taken to secure
 * accounts that have been granted it. We recommend using {AccessControlDefaultAdminRules}
 * to enforce additional security measures for this role.
 */
abstract contract AccessControl is Context, IAccessControl, ERC165 {
    struct RoleData {
        mapping(address => bool) members;
        bytes32 adminRole;
    }

    mapping(bytes32 => RoleData) private _roles;

    bytes32 public constant DEFAULT_ADMIN_ROLE = 0x00;

    /**
     * @dev Modifier that checks that an account has a specific role. Reverts
     * with a standardized message including the required role.
     *
     * The format of the revert reason is given by the following regular expression:
     *
     *  /^AccessControl: account (0x[0-9a-f]{40}) is missing role (0x[0-9a-f]{64})$/
     *
     * _Available since v4.1._
     */
    modifier onlyRole(bytes32 role) {
        _checkRole(role);
        _;
    }

    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IAccessControl).interfaceId || super.supportsInterface(interfaceId);
    }

    /**
     * @dev Returns `true` if `account` has been granted `role`.
     */
    function hasRole(bytes32 role, address account) public view virtual override returns (bool) {
        return _roles[role].members[account];
    }

    /**
     * @dev Revert with a standard message if `_msgSender()` is missing `role`.
     * Overriding this function changes the behavior of the {onlyRole} modifier.
     *
     * Format of the revert message is described in {_checkRole}.
     *
     * _Available since v4.6._
     */
    function _checkRole(bytes32 role) internal view virtual {
        _checkRole(role, _msgSender());
    }

    /**
     * @dev Revert with a standard message if `account` is missing `role`.
     *
     * The format of the revert reason is given by the following regular expression:
     *
     *  /^AccessControl: account (0x[0-9a-f]{40}) is missing role (0x[0-9a-f]{64})$/
     */
    function _checkRole(bytes32 role, address account) internal view virtual {
        if (!hasRole(role, account)) {
            revert(
                string(
                    abi.encodePacked(
                        "AccessControl: account ",
                        Strings.toHexString(account),
                        " is missing role ",
                        Strings.toHexString(uint256(role), 32)
                    )
                )
            );
        }
    }

    /**
     * @dev Returns the admin role that controls `role`. See {grantRole} and
     * {revokeRole}.
     *
     * To change a role's admin, use {_setRoleAdmin}.
     */
    function getRoleAdmin(bytes32 role) public view virtual override returns (bytes32) {
        return _roles[role].adminRole;
    }

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     *
     * May emit a {RoleGranted} event.
     */
    function grantRole(bytes32 role, address account) public virtual override onlyRole(getRoleAdmin(role)) {
        _grantRole(role, account);
    }

    /**
     * @dev Revokes `role` from `account`.
     *
     * If `account` had been granted `role`, emits a {RoleRevoked} event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     *
     * May emit a {RoleRevoked} event.
     */
    function revokeRole(bytes32 role, address account) public virtual override onlyRole(getRoleAdmin(role)) {
        _revokeRole(role, account);
    }

    /**
     * @dev Revokes `role` from the calling account.
     *
     * Roles are often managed via {grantRole} and {revokeRole}: this function's
     * purpose is to provide a mechanism for accounts to lose their privileges
     * if they are compromised (such as when a trusted device is misplaced).
     *
     * If the calling account had been revoked `role`, emits a {RoleRevoked}
     * event.
     *
     * Requirements:
     *
     * - the caller must be `account`.
     *
     * May emit a {RoleRevoked} event.
     */
    function renounceRole(bytes32 role, address account) public virtual override {
        require(account == _msgSender(), "AccessControl: can only renounce roles for self");

        _revokeRole(role, account);
    }

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event. Note that unlike {grantRole}, this function doesn't perform any
     * checks on the calling account.
     *
     * May emit a {RoleGranted} event.
     *
     * [WARNING]
     * ====
     * This function should only be called from the constructor when setting
     * up the initial roles for the system.
     *
     * Using this function in any other way is effectively circumventing the admin
     * system imposed by {AccessControl}.
     * ====
     *
     * NOTE: This function is deprecated in favor of {_grantRole}.
     */
    function _setupRole(bytes32 role, address account) internal virtual {
        _grantRole(role, account);
    }

    /**
     * @dev Sets `adminRole` as ``role``'s admin role.
     *
     * Emits a {RoleAdminChanged} event.
     */
    function _setRoleAdmin(bytes32 role, bytes32 adminRole) internal virtual {
        bytes32 previousAdminRole = getRoleAdmin(role);
        _roles[role].adminRole = adminRole;
        emit RoleAdminChanged(role, previousAdminRole, adminRole);
    }

    /**
     * @dev Grants `role` to `account`.
     *
     * Internal function without access restriction.
     *
     * May emit a {RoleGranted} event.
     */
    function _grantRole(bytes32 role, address account) internal virtual {
        if (!hasRole(role, account)) {
            _roles[role].members[account] = true;
            emit RoleGranted(role, account, _msgSender());
        }
    }

    /**
     * @dev Revokes `role` from `account`.
     *
     * Internal function without access restriction.
     *
     * May emit a {RoleRevoked} event.
     */
    function _revokeRole(bytes32 role, address account) internal virtual {
        if (hasRole(role, account)) {
            _roles[role].members[account] = false;
            emit RoleRevoked(role, account, _msgSender());
        }
    }
}
"
    },
    "@openzeppelin/contracts/access/IAccessControl.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (access/IAccessControl.sol)

pragma solidity ^0.8.0;

/**
 * @dev External interface of AccessControl declared to support ERC165 detection.
 */
interface IAccessControl {
    /**
     * @dev Emitted when `newAdminRole` is set as ``role``'s admin role, replacing `previousAdminRole`
     *
     * `DEFAULT_ADMIN_ROLE` is the starting admin for all roles, despite
     * {RoleAdminChanged} not being emitted signaling this.
     *
     * _Available since v3.1._
     */
    event RoleAdminChanged(bytes32 indexed role, bytes32 indexed previousAdminRole, bytes32 indexed newAdminRole);

    /**
     * @dev Emitted when `account` is granted `role`.
     *
     * `sender` is the account that originated the contract call, an admin role
     * bearer except when using {AccessControl-_setupRole}.
     */
    event RoleGranted(bytes32 indexed role, address indexed account, address indexed sender);

    /**
     * @dev Emitted when `account` is revoked `role`.
     *
     * `sender` is the account that originated the contract call:
     *   - if using `revokeRole`, it is the admin role bearer
     *   - if using `renounceRole`, it is the role bearer (i.e. `account`)
     */
    event RoleRevoked(bytes32 indexed role, address indexed account, address indexed sender);

    /**
     * @dev Returns `true` if `account` has been granted `role`.
     */
    function hasRole(bytes32 role, address account) external view returns (bool);

    /**
     * @dev Returns the admin role that controls `role`. See {grantRole} and
     * {revokeRole}.
     *
     * To change a role's admin, use {AccessControl-_setRoleAdmin}.
     */
    function getRoleAdmin(bytes32 role) external view returns (bytes32);

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     */
    function grantRole(bytes32 role, address account) external;

    /**
     * @dev Revokes `role` from `account`.
     *
     * If `account` had been granted `role`, emits a {RoleRevoked} event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     */
    function revokeRole(bytes32 role, address account) external;

    /**
     * @dev Revokes `role` from the calling account.
     *
     * Roles are often managed via {grantRole} and {revokeRole}: this function's
     * purpose is to provide a mechanism for accounts to lose their privileges
     * if they are compromised (such as when a trusted device is misplaced).
     *
     * If the calling account had been granted `role`, emits a {RoleRevoked}
     * event.
     *
     * Requirements:
     *
     * - the caller must be `account`.
     */
    function renounceRole(bytes32 role, address account) external;
}
"
    },
    "@openzeppelin/contracts/security/ReentrancyGuard.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (security/ReentrancyGuard.sol)

pragma solidity ^0.8.0;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    constructor() {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be _NOT_ENTERED
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == _ENTERED;
    }
}
"
    },
    "@openzeppelin/contracts/utils/Context.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}
"
    },
    "@openzeppelin/contracts/utils/introspection/ERC165.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/ERC165.sol)

pragma solidity ^0.8.0;

import "./IERC165.sol";

/**
 * @dev Implementation of the {IERC165} interface.
 *
 * Contracts that want to implement ERC165 should inherit from this contract and override {supportsInterface} to check
 * for the additional interface id that will be supported. For example:
 *
 * ```solidity
 * function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
 *     return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
 * }
 * ```
 *
 * Alternatively, {ERC165Storage} provides an easier to use but more expensive implementation.
 */
abstract contract ERC165 is IERC165 {
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IERC165).interfaceId;
    }
}
"
    },
    "@openzeppelin/contracts/utils/introspection/IERC165.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/IERC165.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}
"
    },
    "@openzeppelin/contracts/utils/math/Math.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/math/Math.sol)

pragma solidity ^0.8.0;

/**
 * @dev Standard math utilities missing in the Solidity language.
 */
library Math {
    enum Rounding {
        Down, // Toward negative infinity
        Up, // Toward infinity
        Zero // Toward zero
    }

    /**
     * @dev Returns the largest of two numbers.
     */
    function max(uint256 a, uint256 b) internal pure returns (uint256) {
        return a > b ? a : b;
    }

    /**
     * @dev Returns the smallest of two numbers.
     */
    function min(uint256 a, uint256 b) internal pure returns (uint256) {
        return a < b ? a : b;
    }

    /**
     * @dev Returns the average of two numbers. The result is rounded towards
     * zero.
     */
    function average(uint256 a, uint256 b) internal pure returns (uint256) {
        // (a + b) / 2 can overflow.
        return (a & b) + (a ^ b) / 2;
    }

    /**
     * @dev Returns the ceiling of the division of two numbers.
     *
     * This differs from standard division with `/` in that it rounds up instead
     * of rounding down.
     */
    function ceilDiv(uint256 a, uint256 b) internal pure returns (uint256) {
        // (a + b - 1) / b can overflow on addition, so we distribute.
        return a == 0 ? 0 : (a - 1) / b + 1;
    }

    /**
     * @notice Calculates floor(x * y / denominator) with full precision. Throws if result overflows a uint256 or denominator == 0
     * @dev Original credit to Remco Bloemen under MIT license (https://xn--2-umb.com/21/muldiv)
     * with further edits by Uniswap Labs also under MIT license.
     */
    function mulDiv(uint256 x, uint256 y, uint256 denominator) internal pure returns (uint256 result) {
        unchecked {
            // 512-bit multiply [prod1 prod0] = x * y. Compute the product mod 2^256 and mod 2^256 - 1, then use
            // use the Chinese Remainder Theorem to reconstruct the 512 bit result. The result is stored in two 256
            // variables such that product = prod1 * 2^256 + prod0.
            uint256 prod0; // Least significant 256 bits of the product
            uint256 prod1; // Most significant 256 bits of the product
            assembly {
                let mm := mulmod(x, y, not(0))
                prod0 := mul(x, y)
                prod1 := sub(sub(mm, prod0), lt(mm, prod0))
            }

            // Handle non-overflow cases, 256 by 256 division.
            if (prod1 == 0) {
                // Solidity will revert if denominator == 0, unlike the div opcode on its own.
                // The surrounding unchecked block does not change this fact.
                // See https://docs.soliditylang.org/en/latest/control-structures.html#checked-or-unchecked-arithmetic.
                return prod0 / denominator;
            }

            // Make sure the result is less than 2^256. Also prevents denominator == 0.
            require(denominator > prod1, "Math: mulDiv overflow");

            ///////////////////////////////////////////////
            // 512 by 256 division.
            ///////////////////////////////////////////////

            // Make division exact by subtracting the remainder from [prod1 prod0].
            uint256 remainder;
            assembly {
                // Compute remainder using mulmod.
                remainder := mulmod(x, y, denominator)

                // Subtract 256 bit number from 512 bit number.
                prod1 := sub(prod1, gt(remainder, prod0))
                prod0 := sub(prod0, remainder)
            }

            // Factor powers of two out of denominator and compute largest power of two divisor of denominator. Always >= 1.
            // See https://cs.stackexchange.com/q/138556/92363.

            // Does not overflow because the denominator cannot be zero at this stage in the function.
            uint256 twos = denominator & (~denominator + 1);
            assembly {
                // Divide denominator by twos.
                denominator := div(denominator, twos)

                // Divide [prod1 prod0] by twos.
                prod0 := div(prod0, twos)

                // Flip twos such that it is 2^256 / twos. If twos is zero, then it becomes one.
                twos := add(div(sub(0, twos), twos), 1)
            }

            // Shift in bits from prod1 into prod0.
            prod0 |= prod1 * twos;

            // Invert denominator mod 2^256. Now that denominator is an odd number, it has an inverse modulo 2^256 such
            // that denominator * inv = 1 mod 2^256. Compute the inverse by starting with a seed that is correct for
            // four bits. That is, denominator * inv = 1 mod 2^4.
            uint256 inverse = (3 * denominator) ^ 2;

            // Use the Newton-Raphson iteration to improve the precision. Thanks to Hensel's lifting lemma, this also works
            // in modular arithmetic, doubling the correct bits in each step.
            inverse *= 2 - denominator * inverse; // inverse mod 2^8
            inverse *= 2 - denominator * inverse; // inverse mod 2^16
            inverse *= 2 - denominator * inverse; // inverse mod 2^32
            inverse *= 2 - denominator * inverse; // inverse mod 2^64
            inverse *= 2 - denominator * inverse; // inverse mod 2^128
            inverse *= 2 - denominator * inverse; // inverse mod 2^256

            // Because the division is now exact we can divide by multiplying with the modular inverse of denominator.
            // This will give us the correct result modulo 2^256. Since the preconditions guarantee that the outcome is
            // less than 2^256, this is the final result. We don't need to compute the high bits of the result and prod1
            // is no longer required.
            result = prod0 * inverse;
            return result;
        }
    }

    /**
     * @notice Calculates x * y / denominator with full precision, following the selected rounding direction.
     */
    function mulDiv(uint256 x, uint256 y, uint256 denominator, Rounding rounding) internal pure returns (uint256) {
        uint256 result = mulDiv(x, y, denominator);
        if (rounding == Rounding.Up && mulmod(x, y, denominator) > 0) {
            result += 1;
        }
        return result;
    }

    /**
     * @dev Returns the square root of a number. If the number is not a perfect square, the value is rounded down.
     *
     * Inspired by Henry S. Warren, Jr.'s "Hacker's Delight" (Chapter 11).
     */
    function sqrt(uint256 a) internal pure returns (uint256) {
        if (a == 0) {
            return 0;
        }

        // For our first guess, we get the biggest power of 2 which is smaller than the square root of the target.
        //
        // We know that the "msb" (most significant bit) of our target number `a` is a power of 2 such that we have
        // `msb(a) <= a < 2*msb(a)`. This value can be written `msb(a)=2**k` with `k=log2(a)`.
        //
        // This can be rewritten `2**log2(a) <= a < 2**(log2(a) + 1)`
        // → `sqrt(2**k) <= sqrt(a) < sqrt(2**(k+1))`
        // → `2**(k/2) <= sqrt(a) < 2**((k+1)/2) <= 2**(k/2 + 1)`
        //
        // Consequently, `2**(log2(a) / 2)` is a good first approximation of `sqrt(a)` with at least 1 correct bit.
        uint256 result = 1 << (log2(a) >> 1);

        // At this point `result` is an estimation with one bit of precision. We know the true value is a uint128,
        // since it is the square root of a uint256. Newton's method converges quadratically (precision doubles at
        // every iteration). We thus need at most 7 iteration to turn our partial result with one bit of precision
        // into the expected uint128 result.
        unchecked {
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            return min(result, a / result);
        }
    }

    /**
     * @notice Calculates sqrt(a), following the selected rounding direction.
     */
    function sqrt(uint256 a, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = sqrt(a);
            return result + (rounding == Rounding.Up && result * result < a ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 2, rounded down, of a positive value.
     * Returns 0 if given 0.
     */
    function log2(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 128;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 64;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 32;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 16;
            }
            if (value >> 8 > 0) {
                value >>= 8;
                result += 8;
            }
            if (value >> 4 > 0) {
                value >>= 4;
                result += 4;
            }
            if (value >> 2 > 0) {
                value >>= 2;
                result += 2;
            }
            if (value >> 1 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 2, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log2(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log2(value);
            return result + (rounding == Rounding.Up && 1 << result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 10, rounded down, of a positive value.
     * Returns 0 if given 0.
     */
    function log10(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >= 10 ** 64) {
                value /= 10 ** 64;
                result += 64;
            }
            if (value >= 10 ** 32) {
                value /= 10 ** 32;
                result += 32;
            }
            if (value >= 10 ** 16) {
                value /= 10 ** 16;
                result += 16;
            }
            if (value >= 10 ** 8) {
                value /= 10 ** 8;
                result += 8;
            }
            if (value >= 10 ** 4) {
                value /= 10 ** 4;
                result += 4;
            }
            if (value >= 10 ** 2) {
                value /= 10 ** 2;
                result += 2;
            }
            if (value >= 10 ** 1) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 10, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log10(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log10(value);
            return result + (rounding == Rounding.Up && 10 ** result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 256, rounded down, of a positive value.
     * Returns 0 if given 0.
     *
     * Adding one to the result gives the number of pairs of hex symbols needed to represent `value` as a hex string.
     */
    function log256(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 16;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 8;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 4;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 2;
            }
            if (value >> 8 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 256, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log256(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log256(value);
            return result + (rounding == Rounding.Up && 1 << (result << 3) < value ? 1 : 0);
        }
    }
}
"
    },
    "@openzeppelin/contracts/utils/math/SignedMath.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (utils/math/SignedMath.sol)

pragma solidity ^0.8.0;

/**
 * @dev Standard signed math utilities missing in the Solidity language.
 */
library SignedMath {
    /**
     * @dev Returns the largest of two signed numbers.
     */
    function max(int256 a, int256 b) internal pure returns (int256) {
        return a > b ? a : b;
    }

    /**
     * @dev Returns the smallest of two signed numbers.
     */
    function min(int256 a, int256 b) internal pure returns (int256) {
        return a < b ? a : b;
    }

    /**
     * @dev Returns the average of two signed numbers without overflow.
     * The result is rounded towards zero.
     */
    function average(int256 a, int256 b) internal pure returns (int256) {
        // Formula from the book "Hacker's Delight"
        int256 x = (a & b) + ((a ^ b) >> 1);
        return x + (int256(uint256(x) >> 255) & (a ^ b));
    }

    /**
     * @dev Returns the absolute unsigned value of a signed value.
     */
    function abs(int256 n) internal pure returns (uint256) {
        unchecked {
            // must be unchecked in order to support `n = type(int256).min`
            return uint256(n >= 0 ? n : -n);
        }
    }
}
"
    },
    "@openzeppelin/contracts/utils/Strings.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Strings.sol)

pragma solidity ^0.8.0;

import "./math/Math.sol";
import "./math/SignedMath.sol";

/**
 * @dev String operations.
 */
library Strings {
    bytes16 private constant _SYMBOLS = "0123456789abcdef";
    uint8 private constant _ADDRESS_LENGTH = 20;

    /**
     * @dev Converts a `uint256` to its ASCII `string` decimal representation.
     */
    function toString(uint256 value) internal pure returns (string memory) {
        unchecked {
            uint256 length = Math.log10(value) + 1;
            string memory buffer = new string(length);
            uint256 ptr;
            /// @solidity memory-safe-assembly
            assembly {
                ptr := add(buffer, add(32, length))
            }
            while (true) {
                ptr--;
                /// @solidity memory-safe-assembly
                assembly {
                    mstore8(ptr, byte(mod(value, 10), _SYMBOLS))
                }
                value /= 10;
                if (value == 0) break;
            }
            return buffer;
        }
    }

    /**
     * @dev Converts a `int256` to its ASCII `string` decimal representation.
     */
    function toString(int256 value) internal pure returns (string memory) {
        return string(abi.encodePacked(value < 0 ? "-" : "", toString(SignedMath.abs(value))));
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation.
     */
    function toHexString(uint256 value) internal pure returns (string memory) {
        unchecked {
            return toHexString(value, Math.log256(value) + 1);
        }
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation with fixed length.
     */
    function toHexString(uint256 value, uint256 length) internal pure returns (string memory) {
        bytes memory buffer = new bytes(2 * length + 2);
        buffer[0] = "0";
        buffer[1] = "x";
        for (uint256 i = 2 * length + 1; i > 1; --i) {
            buffer[i] = _SYMBOLS[value & 0xf];
            value >>= 4;
        }
        require(value == 0, "Strings: hex length insufficient");
        return string(buffer);
    }

    /**
     * @dev Converts an `address` with fixed length of 20 bytes to its not checksummed ASCII `string` hexadecimal representation.
     */
    function toHexString(address addr) internal pure returns (string memory) {
        return toHexString(uint256(uint160(addr)), _ADDRESS_LENGTH);
    }

    /**
     * @dev Returns true if the two strings are equal.
     */
    function equal(string memory a, string memory b) internal pure returns (bool) {
        return keccak256(bytes(a)) == keccak256(bytes(b));
    }
}
"
    },
    "contracts/interfaces/ISystemContext.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity ^0.8.28;

import {IAccessControl} from "@openzeppelin/contracts/access/IAccessControl.sol";

interface ISystemContext {
    function acl() external view returns (IAccessControl);
    function getContractByName(string calldata name) external view returns (address);
    function getContract(bytes32 id) external view returns (address);
    function setContract(bytes32 id, address adr) external;
    function setContractByName(string calldata name, address adr) external;
}
"
    },
    "contracts/LaunchRegistry.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity ^0.8.28;

import "./Roles.sol";
import "./SystemContext.sol";

interface ILaunchRegistry {
    struct AdminPhase {
        uint32 rateBps;   // Admin tax rate in basis points (e.g., 300 = 3%)
        uint32 duration;  // Duration in seconds (0 for Phase C means infinite)
    }

    struct TaxConfig {
        address creator;
        address creatorRecipient; // user1
        address user2Recipient;   // user2
        uint256 user2Share;       // in basis points (e.g., 1000 = 10%)
        uint256 flatBuyTaxRate;
        uint256 flatSellTaxRate;
        uint256 startBuyTaxRate;
        uint256 startSellTaxRate;
        uint256 liquidityAddedAt;
        bool liquidityTimestampSet;
        uint256 customBuyTaxRate;  // (0 = use default)
        uint256 customSellTaxRate; // (0 = use default)
        bool hasCustomRates;
        AdminPhase[3] adminPhases; // Added for Version 2
        bool adminPhasesSet;       // Tracks if admin phases are configured
    }

    struct LaunchInfo {
        address token;
        address owner;
        uint256 mintedAt;
        bool liquidityAdded;
        uint256 liquidityBackingETH;
        uint256 liquidityTokenPercent;
    }


    function registerLaunch(
        bytes32 guid,
        address token,
        address owner,
        uint256 backingETH,
        uint256 tokenPercent
    ) external;

    function markLiquidityAdded(bytes32 guid) external;

    function getLaunch(bytes32 guid) external view returns (LaunchInfo memory);

    function exists(bytes32 guid) external view returns (bool);

    function registerTaxConfig(
        bytes32 guid,
        address token,
        address creator,
        address recipient,
        uint256 flatBuyTax,
        uint256 flatSellTax,
        uint256 startBuyTax,
        uint256 startSellTax,
        address user2Recipient,
        uint256 user2Share,
        AdminPhase[3] calldata adminPhases
    ) external;

    function getTaxConfig(bytes32 guid) external view returns (TaxConfig memory);

    function updateTaxConfig(bytes32 guid, uint256 customBuyTaxRate, uint256 customSellTaxRate, bool hasCustomRates) external;

    function setLiquidityAddedAt(bytes32 guid, uint256 timestamp) external;

    function setUser2(bytes32 guid, address user2, uint256 share) external;

    function getGuidFromToken(address token) external view returns (bytes32);
}

contract LaunchRegistry is ILaunchRegistry {
    ISystemContext public systemContext;

    constructor(ISystemContext _systemContext) {
        require(address(_systemContext) != address(0), "SystemContext required");
        systemContext = _systemContext;
    }

    mapping(bytes32 => LaunchInfo) private launches;
    mapping(bytes32 => TaxConfig) private taxConfigs;
    mapping(address => bytes32) private tokenToGuid;

    modifier onlyTokenCreator() {
        require(
            systemContext.acl().hasRole(Roles.TOKEN_CREATOR_ROLE, msg.sender),
            "LaunchRegistry: not token creator"
        );
        _;
    }

    modifier onlyRouter() {
        require(
            systemContext.acl().hasRole(Roles.ROUTER_ROLE, msg.sender),
            "LaunchRegistry: not router"
        );
        _;
    }

    modifier onlyTaxHandler() {
        address taxHandler = systemContext.getContractByName("MasterTaxHandler");
        require(msg.sender == taxHandler, "LaunchRegistry: not tax handler");
        _;
    }

    function registerLaunch(
        bytes32 guid,
        address token,
        address owner,
        uint256 backingETH,
        uint256 tokenPercent
    ) external override onlyTokenCreator {
        require(guid != 0, "Invalid GUID");
        require(token != address(0), "Invalid token address");
        require(!exists(guid), "Already registered");

        launches[guid] = LaunchInfo({
            token: token,
            owner: owner,
            mintedAt: block.timestamp,
            liquidityAdded: false,
            liquidityBackingETH: backingETH,
            liquidityTokenPercent: tokenPercent
        });

        tokenToGuid[token] = guid;
    }

    function markLiquidityAdded(bytes32 guid) external override onlyRouter {
        require(exists(guid), "Not registered");
        launches[guid].liquidityAdded = true;
    }

    function getLaunch(bytes32 guid) external view override returns (LaunchInfo memory) {
        require(exists(guid), "Not registered");
        return launches[guid];
    }

    function exists(bytes32 guid) public view override returns (bool) {
        return launches[guid].token != address(0);
    }

    function registerTaxConfig(
        bytes32 guid,
        address token,
        address creator,
        address recipient,
        uint256 flatBuyTax,
        uint256 flatSellTax,
        uint256 startBuyTax,
        uint256 startSellTax,
        address user2Recipient,
        uint256 user2Share,
        AdminPhase[3] calldata adminPhases
    ) external override onlyTaxHandler {
        require(exists(guid), "Launch not registered");
        require(token != address(0), "Zero token address");
        require(creator != address(0), "Zero creator");
        require(recipient != address(0), "Zero recipient");
        require(taxConfigs[guid].creator == address(0), "Tax config already registered");

        taxConfigs[guid] = TaxConfig({
            creator: creator,
            creatorRecipient: recipient,
            user2Recipient: user2Recipient,
            user2Share: user2Share,
            flatBuyTaxRate: flatBuyTax,
            flatSellTaxRate: flatSellTax,
            startBuyTaxRate: startBuyTax,
            startSellTaxRate: startSellTax,
            liquidityAddedAt: 0,
            liquidityTimestampSet: false,
            customBuyTaxRate: 0,
            customSellTaxRate: 0,
            hasCustomRates: false,
            adminPhases: adminPhases,
            adminPhasesSet: true
        });
    }

    function getTaxConfig(bytes32 guid) external view override returns (TaxConfig memory) {
        require(exists(guid), "Launch not registered");
        require(taxConfigs[guid].creator != address(0), "Tax config not registered");
        return taxConfigs[guid];
    }

    function updateTaxConfig(
        bytes32 guid,
        uint256 customBuyTaxRate,
        uint256 customSellTaxRate,
        bool hasCustomRates
    ) external override onlyTaxHandler {
        require(exists(guid), "Launch not registered");
        require(taxConfigs[guid].creator != address(0), "Tax config not registered");

        taxConfigs[guid].customBuyTaxRate = customBuyTaxRate;
        taxConfigs[guid].customSellTaxRate = customSellTaxRate;
        taxConfigs[guid].hasCustomRates = hasCustomRates;
    }

    function setLiquidityAddedAt(bytes32 guid, uint256 timestamp) external override onlyTaxHandler {
        require(exists(guid), "Launch not registered");
        require(taxConfigs[guid].creator != address(0), "Tax config not registered");
        require(taxConfigs[guid].adminPhasesSet, "Admin phases not set");

        taxConfigs[guid].liquidityAddedAt = timestamp;
        taxConfigs[guid].liquidityTimestampSet = true;
    }

    function setUser2(bytes32 guid, address user2, uint256 share) external override onlyTaxHandler {
        require(exists(guid), "Launch not registered");
        require(taxConfigs[guid].creator != address(0), "Tax config not registered");
        require(user2 != address(0), "Zero user2");
        require(share <= 10_000, "Share too high");

        taxConfigs[guid].user2Recipient = user2;
        taxConfigs[guid].user2Share = share;
    }

    function getGuidFromToken(address token) external view override returns (bytes32) {
        bytes32 guid = tokenToGuid[token];
        require(guid != bytes32(0), "Token not registered");
        return guid;
    }
}"
    },
    "contracts/MasterLaunchWhitelist.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity ^0.8.28;

import "./SystemContext.sol";
import "./LaunchRegistry.sol";
import "./Roles.sol";
import "@openzeppelin/contracts/security/ReentrancyGuard.sol";

contract MasterLaunchWhitelist is ReentrancyGuard {
    ISystemContext public immutable systemContext;

    // Token GUID => user => whitelisted
    mapping(bytes32 => mapping(address => bool)) public whitelists;

    // Token GUID => user => amount bought during whitelist
    mapping(bytes32 => mapping(address => uint256)) public boughtAmount;

    // Token GUID => user => fixed allowance (e.g., 0.1% of supply)
    mapping(bytes32 => mapping(address => uint256)) public allowancePerUser;

    // Track whether a whitelist is finalized for cleanup
    mapping(bytes32 => bool) public whitelistFinalized;

    event WhitelistEntryAdded(bytes32 indexed guid, address indexed user, uint256 allowance);
    event WhitelistEntryRemoved(bytes32 indexed guid, address indexed user);
    event WhitelistFinalized(bytes32 indexed guid);
    event WhitelistBuyRecorded(bytes32 indexed guid, address indexed user, uint256 amount);

    constructor(ISystemContext _systemContext) {
        require(address(_systemContext) != address(0), "Invalid system context");
        systemContext = _systemContext;
    }

    modifier onlyWhitelistAdmin() {
        require(
            systemContext.acl().hasRole(Roles.WHITELIST_ADMIN_ROLE, msg.sender),
            "Not whitelist admin"
        );
        _;
    }

    modifier onlyIfFinalized(bytes32 guid) {
        require(whitelistFinalized[guid], "Whitelist not finalized");
        _;
    }

    struct WhitelistEntry {
        address user;
        uint256 allowance;
    }

    function _ensureLiquidityNotAdded(bytes32 guid) internal view {
        address registryAddr = systemContext.getContractByName("LaunchRegistry");

        ILaunchRegistry registry = ILaunchRegistry(registryAddr);
        ILaunchRegistry.LaunchInfo memory launch = registry.getLaunch(guid);
        require(!launch.liquidityAdded, "Whitelist locked: liquidity already added");
    }

    function addToWhitelist(bytes32 guid, address user, uint256 allowance) external onlyWhitelistAdmin {
        _ensureLiquidityNotAdded(guid);
        whitelists[guid][user] = true;
        if (allowance > 0) {
            allowancePerUser[guid][user] = allowance + 1;
        }

        emit WhitelistEntryAdded(guid, user, allowance);
    }

    function addManyToWhitelist(bytes32 guid, WhitelistEntry[] calldata entries) external onlyWhitelistAdmin {
        _ensureLiquidityNotAdded(guid);
        for (uint256 i = 0; i < entries.length; i++) {
            whitelists[guid][entries[i].user] = true;
            if (entries[i].allowance > 0) {
                allowancePerUser[guid][entries[i].user] = entries[i].allowance + 1;
            }
            emit WhitelistEntryAdded(guid, entries[i].user, entries[i].allowance + 1);
        }
    }

    function removeFromWhitelist(bytes32 guid, address user) external onlyWhitelistAdmin {
        _ensureLiquidityNotAdded(guid);
        whitelists[guid][user] = false;
        emit WhitelistEntryRemoved(guid, user);
    }

    function isWhitelisted(bytes32 guid, address user) external view returns (bool) {
        return whitelists[guid][user];
    }

    function remainingAllowance(bytes32 guid, address user) external view returns (uint256) {
        uint256 allowed = allowancePerUser[guid][user];
        uint256 bought = boughtAmount[guid][user];
        return allowed > bought ? allowed - bought : 0;
    }

    function recordBuy(bytes32 guid, address user, uint256 amount) external nonReentrant {
        address registryAddr = systemContext.getContractByName("LaunchRegistry");

        address expectedToken = ILaunchRegistry(registryAddr).getLaunch(guid).token;
        require(msg.sender == expectedToken, "Caller is not the token for this GUID");

        boughtAmount[guid][user] += amount;
        emit WhitelistBuyRecorded(guid, user, amount);
    }

    function finalizeWhitelist(bytes32 guid) external onlyWhitelistAdmin {
        whitelistFinalized[guid] = true;
        emit WhitelistFinalized(guid);
    }

    function clearWhitelist(bytes32 guid, address[] calldata users)
        external
        onlyWhitelistAdmin
        onlyIfFinalized(guid)
    {
        for (uint256 i = 0; i < users.length; i++) {
            whitelists[guid][users[i]] = false;
            allowancePerUser[guid][users[i]] = 0;
            boughtAmount[guid][users[i]] = 0;
        }
    }
}
"
    },
    "contracts/Roles.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity ^0.8.28;

library Roles {
    bytes32 public constant SYSTEM_CONTEXT_ADMIN_ROLE = keccak256("SYSTEM_CONTEXT_ADMIN_ROLE");
    bytes32 public constant TOKEN_CREATOR_ROLE = keccak256("TOKEN_CREATOR_ROLE");
    bytes32 public constant WHITELIST_ADMIN_ROLE = keccak256("WHITELIST_ADMIN_ROLE");
    bytes32 public constant ROUTER_ROLE = keccak256("ROUTER_ROLE");
    bytes32 public constant BACKEND_SIGNER_ROLE = keccak256("BACKEND_SIGNER_ROLE");
    bytes32 public constant TAX_ADMIN_ROLE = keccak256("TAX_ADMIN_ROLE");
}
"
    },
    "contracts/SystemContext.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity ^0.8.28;

import "./Roles.sol";
import {IAccessControl} from "@openzeppelin/contracts/access/AccessControl.sol";
import {ISystemContext} from "./interfaces/ISystemContext.sol";


contract SystemContext is ISystemContext {
    error OnlySystemContextAdmin();
    error ZeroAddress();
    error ZeroId();
    error ContractNotRegistered();

    IAccessControl public immutable override acl;
    mapping(bytes32 => address) private _contracts;


    constructor(IAccessControl acl_) {
        if (address(acl_) == address(0)) {
            revert ZeroAddress();
        }
        acl = acl_;
    }

    modifier onlySystemContextAdmin() {
        if (!acl.hasRole(Roles.SYSTEM_CONTEXT_ADMIN_ROLE, msg.sender)) {
            revert OnlySystemContextAdmin();
        }
        _;
    }

    modifier validAddress(address adr) {
        if (adr == address(0)) {
            revert ZeroAddress();
        }
        _;
    }

    modifier validId(bytes32 id) {
        if (id == bytes32(0)) {
            revert ZeroId();
        }
        _;
    }

    function setContract(bytes32 id, address adr)
        external
        override
        onlySystemContextAdmin
        validAddress(adr)
        validId(id)
    {
        _contracts[id] = adr;
    }

    function setContractByName(string calldata name, address adr)
        external
        override
        onlySystemContextAdmin
        validAddress(adr)
    {
        bytes32 id = keccak256(abi.encodePacked(name));
        _contracts[id] = adr;
    }

    function getContractByName(string calldata name)
        external
        view
        override
        returns (address)
    {
        return _getContract(keccak256(abi.encodePacked(name)));
    }

    function getContract(bytes32 id)
        external
        view
        override
        returns (address)
    {
        return _getContract(id);
    }

    function _getContract(bytes32 id) internal view returns (address adr) {
        adr = _contracts[id];
        if (adr == address(0)) revert ContractNotRegistered();
    }
}
"
    }
  },
  "settings": {
    "optimizer": {
      "enabled": true,
      "runs": 1000
    },
    "viaIR": true,
    "evmVersion": "paris",
    "outputSelection": {
      "*": {
        "*": [
          "evm.bytecode",
          "evm.deployedBytecode",
          "devdoc",
          "userdoc",
          "metadata",
          "abi"
        ]
      }
    }
  }
}}