DepositHelperVoteMarket

{"DepositHelperVoteMarket.sol":{"content":"// SPDX-License-Identifier: AGPL-3.0-only
pragma solidity ^0.8.25;

import {IERC20, SafeERC20} from "./SafeERC20.sol";

interface CampaignRemoteManager {
    struct CampaignCreationParams {
        uint256 chainId;
        address gauge;
        address manager;
        address rewardToken;
        uint8 numberOfPeriods;
        uint256 maxRewardPerVote;
        uint256 totalRewardAmount;
        address[] addresses;
        address hook;
        bool isWhitelist;
    }
    function createCampaign(
        CampaignCreationParams memory params,
        uint256 destinationChainId,
        uint256 additionalGasLimit,
        address votemarket
    ) external payable;
    /// @notice Thrown when the caller is not the router
    error OnlyRouter();
    /// @notice Thrown when the caller is not LaPoste
    error OnlyLaPoste();
    /// @notice Thrown when the sender is invalid
    error InvalidSender();
    /// @notice Thrown when the chain ID is invalid
    error InvalidChainId();
    /// @notice Thrown when the message is invalid
    error InvalidMessage();
    /// @notice Thrown when the fee is insufficient
    error NotEnoughFee();
    /// @notice Thrown when a zero address is provided
    error ZeroAddress();
    /// @notice Thrown when the destination chain ID is the same as the source chain ID
    error SameChain();
}

contract DepositHelperVoteMarket {
    using SafeERC20 for IERC20;

    uint256 public constant DESTINATION_CHAIN_ID = 42161;
    address public owner;
    address public hook;
    address public manager;
    address public votemarket;
    address public rewardToken;
    address public rewardNotifier;
    address public campaignRemoteManager;
    uint256 public maxRewardPerVote;

    struct GasSettings {
        uint256 campaignCreationGas;
        uint256 blacklistedAddressGas;
        uint256 gasPrice;
    }

    GasSettings public gasSettings;

    struct CurrentWeights {
        address[] gauges;
        uint16[] weights;
    }

    struct LastReward {
        address[] gauges;
        uint256[] amounts;
        uint256 epoch;
    }

    CurrentWeights private currentWeights; // cannot publicly return struct arrays
    LastReward[] private lastReward;

    mapping(address =\u003e bool) public isApprovedGauge; // gauge =\u003e isApproved
    uint16 public constant MAX_GAUGE_WEIGHT = 10000;
    uint16 public constant MAX_BLACKLIST_LENGTH = 50;

    address[] public excludeAddresses; // addresses to exclude from eligibility for rewards

    constructor(
        address _rewardToken,
        address _rewardNotifier,
        address _owner,
        address _campaignRemoteManager,
        address _votemarket,
        uint256 _maxRewardPerVote
    ) {
        manager = msg.sender;
        owner = _owner;
        rewardNotifier = _rewardNotifier;
        rewardToken = _rewardToken;
        campaignRemoteManager = _campaignRemoteManager;
        votemarket = _votemarket;
        maxRewardPerVote = _maxRewardPerVote == 0 ? type(uint256).max : _maxRewardPerVote;

        // Setting default destination chain gas settings
        gasSettings.campaignCreationGas = 2_000_000;
        gasSettings.blacklistedAddressGas = 50_000;
        gasSettings.gasPrice = 1 gwei;
        IERC20(rewardToken).approve(campaignRemoteManager, type(uint256).max);
    }

    // --- Errors ---

    /// @notice Error thrown when the caller doesn\u0027t have the right to execute the function
    error UNAUTHORIZED();

    /// @notice Error thrown when one or many parameters are invalid
    error INVALID_PARAMETER();

    /// @notice Error thrown when the gauge is not approved
    error NOT_APPROVED_GAUGE();

    /// @notice Error thrown if no weight is set for gauges
    error NO_WEIGHTS();

    /// @notice Error thrown when a gauge has weights and shouldn\u0027t for the following action
    error HAS_WEIGHT();

    /// @notice Error thrown when the execute call fails
    error EXECUTION_FAILED();

    /// @notice Error thrown when the contract doesn\u0027t own enough Ether to create the campaigns
    error NOT_ENOUGH_GAS();

    ///@notice Error thrown when an address list isn\u0027t sorted, protection against duplicated addresses
    error NOT_SORTED_ADDRESSES();

    // --- Modifiers ---

    modifier onlyManager() {
        _onlyManager();
        _;
    }
    modifier onlyOwner() {
        _onlyOwner();
        _;
    }
    modifier onlyRewardNotifier() {
        _onlyRewardsNotifier();
        _;
    }

    // --- View functions ---

    function getCurrentWeights() external view returns (address[] memory, uint16[] memory) {
        return (currentWeights.gauges, currentWeights.weights);
    }

    function currentWeightOfGauge(address _gauge) public view returns (uint16) {
        for (uint256 i = 0; i \u003c currentWeights.gauges.length; i++) {
            if (currentWeights.gauges[i] == _gauge) {
                return currentWeights.weights[i];
            }
        }
        return 0;
    }

    function getLastReward() external view returns (address[] memory gauges, uint256[] memory amounts, uint256 epoch) {
        if(lastReward[lastReward.length - 1].epoch \u003c (block.timestamp / 604800) * 604800) {
            return (lastReward[lastReward.length - 1].gauges, lastReward[lastReward.length - 1].amounts, lastReward[lastReward.length - 1].epoch);
        } else {
            return (lastReward[lastReward.length - 2].gauges, lastReward[lastReward.length - 2].amounts, lastReward[lastReward.length - 2].epoch);
        }
    }

    function getRewardByIndex(uint256 _index) external view returns (address[] memory gauges, uint256[] memory amounts, uint256 epoch) {
        return (lastReward[_index].gauges, lastReward[_index].amounts, lastReward[_index].epoch);
    }

    function rewardHistoryLength() external view returns (uint256) {
        return lastReward.length;
    }

    // --- Main function ---

    function notifyReward(uint256 _amount) external onlyRewardNotifier {
        if (currentWeights.gauges.length == 0) revert NO_WEIGHTS();
        IERC20(rewardToken).safeTransferFrom(msg.sender, address(this), _amount);

        uint256 currentEpoch = block.timestamp / 1 weeks * 1 weeks;
        uint256 additionalGasLimit =
            gasSettings.campaignCreationGas + gasSettings.blacklistedAddressGas * excludeAddresses.length;

        // Check contract balance
        if (address(this).balance \u003c currentWeights.gauges.length * additionalGasLimit * gasSettings.gasPrice) {
            revert NOT_ENOUGH_GAS();
        }

        // Create campaigns according to weights
        uint256 assignedAmount = 0;
        uint256[] memory amounts = new uint256[](currentWeights.weights.length);

        for (uint256 i = 0; i \u003c currentWeights.weights.length; i++) {
            // Avoid rounding dusts by assigning all the reminding amount to the last gauge
            uint256 amount = (i == currentWeights.weights.length - 1)
                ? _amount - assignedAmount
                : (_amount * currentWeights.weights[i]) / MAX_GAUGE_WEIGHT;

            CampaignRemoteManager.CampaignCreationParams memory params = CampaignRemoteManager.CampaignCreationParams({
                chainId: block.chainid,
                gauge: currentWeights.gauges[i],
                manager: manager,
                rewardToken: rewardToken,
                numberOfPeriods: 2,
                maxRewardPerVote: maxRewardPerVote,
                totalRewardAmount: amount,
                addresses: excludeAddresses,
                hook: hook,
                isWhitelist: false
            });

            CampaignRemoteManager(campaignRemoteManager)
            .createCampaign{
                value: additionalGasLimit * gasSettings.gasPrice
            }(params, DESTINATION_CHAIN_ID, additionalGasLimit, votemarket);

            emit DepositForGauge(currentWeights.gauges[i], amount, currentEpoch);
            assignedAmount += amount;
            amounts[i] = amount;
        }
        // Record last reward for efficiency calculations
        lastReward.push(LastReward({
            gauges: currentWeights.gauges,
            amounts: amounts,
            epoch: (block.timestamp / 604800) * 604800
        }));
    }

    // --- Owner functions ---

    function setManager(address _manager) external onlyOwner {
        manager = _manager;
        emit NewManager(_manager);
    }

    function setOwner(address _owner) external onlyOwner {
        owner = _owner;
        emit NewOwner(_owner);
    }

    function setRewardToken(address _rewardToken) external onlyOwner {
        // remove previous approval
        IERC20(rewardToken).approve(campaignRemoteManager, 0);
        // set new token and approve
        rewardToken = _rewardToken;
        IERC20(rewardToken).approve(campaignRemoteManager, type(uint256).max);
        emit NewRewardToken(_rewardToken);
    }

    function setRewardNotifier(address _rewardNotifier) external onlyOwner {
        rewardNotifier = _rewardNotifier;
        emit NewRewardNotifier(_rewardNotifier);
    }

    function setCampaignRemoteManager(address _campaignRemoteManager) external onlyOwner {
        // remove previous approval
        IERC20(rewardToken).approve(campaignRemoteManager, 0);
        campaignRemoteManager = _campaignRemoteManager;
        // approve new campaign remote manager
        IERC20(rewardToken).approve(_campaignRemoteManager, type(uint256).max);
        emit NewCampaignRemoteManager(_campaignRemoteManager);
    }

    function setVotemarket(address _votemarket) external onlyOwner {
        votemarket = _votemarket;
        emit NewVotemarket(_votemarket);
    }

    function addApprovedGauge(address _gauge) external onlyOwner {
        isApprovedGauge[_gauge] = true;
        emit AddedGauge(_gauge);
    }

    function removeApprovedGauge(address _gauge) external onlyOwner {
        if (currentWeightOfGauge(_gauge) != 0) revert HAS_WEIGHT();
        isApprovedGauge[_gauge] = false;
        emit RemovedGauge(_gauge);
    }

    function execute(address to, uint256 value, bytes calldata data) external onlyOwner returns (bytes memory) {
        (bool success, bytes memory result) = to.call{value: value}(data);
        if (!success) revert EXECUTION_FAILED();
        return result;
    }

    function withdrawEther(uint256 amount, address payable to) external onlyOwner {
        if (amount == 0 || to == address(0)) revert INVALID_PARAMETER();
        (bool sent,) = to.call{value: amount}("");
        if (!sent) revert EXECUTION_FAILED();
        emit EtherWithdrawn(to, amount);
    }

    // --- Manager functions ---

    function setMaxRewardPerVote(uint256 _maxRewardPerVote) external onlyManager {
        maxRewardPerVote = _maxRewardPerVote;
        emit NewMaxRewardPerVote(_maxRewardPerVote);
    }

    function setHook(address _hook) external onlyManager {
        hook = _hook;
        emit NewHook(_hook);
    }

    function setGasSettings(uint256 _campaignCreationGas, uint256 _blacklistedAddressGas, uint256 _gasPrice)
        external
        onlyManager
    {
        if (_campaignCreationGas == 0 || _blacklistedAddressGas == 0 || _gasPrice == 0) {
            revert INVALID_PARAMETER();
        }
        gasSettings.campaignCreationGas = _campaignCreationGas;
        gasSettings.blacklistedAddressGas = _blacklistedAddressGas;
        gasSettings.gasPrice = _gasPrice;
        emit UpdatedGasSettings(_campaignCreationGas, _blacklistedAddressGas, _gasPrice);
    }

     /**
     * @notice Set the current weights to apply rewards to gauges
     * @param _gauges The list of gauge addresses
     * @param _weights The list of weights to apply to each gauge, in same order
     * @dev Total weights must equal 10000 (100.00%)
     * @dev All gauges must be pre-approved with addApprovedGauge()
     */
    function setWeights(address[] memory _gauges, uint16[] memory _weights) external onlyManager {
        if(_gauges.length != _weights.length) revert INVALID_PARAMETER();
        uint16 totalWeight = 0;
        uint160 addressHeight;

        for(uint256 i = 0; i \u003c _gauges.length; i++) {
            if(!isApprovedGauge[_gauges[i]]) revert NOT_APPROVED_GAUGE();
            uint160 height = uint160(_gauges[i]);
            if(height \u003c= addressHeight) revert NOT_SORTED_ADDRESSES();
            if(_weights[i] == 0) revert NO_WEIGHTS();
            addressHeight = height;
            totalWeight += _weights[i];
        }
        if(totalWeight != MAX_GAUGE_WEIGHT) revert INVALID_PARAMETER();
        currentWeights = CurrentWeights({
            gauges: _gauges,
            weights: _weights
        });
        emit UpdatedWeights(_gauges, _weights);
    }

    /**
     * @notice Sets the list of blacklisted voters
     * @param _excludeAddresses The list of addresses to blacklist from rewards
     * @dev blacklist length is limited 
     */
    function setExcludeAddresses(address[] memory _excludeAddresses) external onlyManager {
        if(_excludeAddresses.length \u003e MAX_BLACKLIST_LENGTH) revert INVALID_PARAMETER();
        for(uint256 i = 1; i \u003c _excludeAddresses.length; i++) {
            if(_excludeAddresses[i] \u003c= _excludeAddresses[i-1]) revert NOT_SORTED_ADDRESSES();
        }
        excludeAddresses = _excludeAddresses;
        emit UpdatedExclusions(_excludeAddresses);
    }

    // --- Receive ---

    /// @notice Receive plain ETH transfers
    receive() external payable {
        emit EtherReceived(msg.sender, msg.value);
    }

    // --- Internal functions ---

    /// @notice Internal function to check authorization
    function _onlyManager() internal view {
        if (msg.sender != manager \u0026\u0026 msg.sender != owner) revert UNAUTHORIZED();
    }

    function _onlyOwner() internal view {
        if (msg.sender != owner) revert UNAUTHORIZED();
    }

    function _onlyRewardsNotifier() internal view {
        if (msg.sender != rewardNotifier \u0026\u0026 msg.sender != owner) revert UNAUTHORIZED();
    }

    // --- Events ---
    event Notified(address token, uint256 amount);
    event AddedGauge(address indexed gauge);
    event RemovedGauge(address indexed gauge);
    event UpdatedWeights(address[] gauges, uint16[] weights);
    event EtherWithdrawn(address indexed to, uint256 amount);
    event EtherReceived(address indexed from, uint256 amount);
    event NewHook(address hook);
    event NewManager(address manager);
    event NewOwner(address owner);
    event NewVotemarket(address votemarket);
    event NewRewardToken(address rewardToken);
    event NewRewardNotifier(address rewardNotifier);
    event UpdatedExclusions(address[] excludeAddresses);
    event NewMaxRewardPerVote(uint256 maxRewardPerVote);
    event NewCampaignRemoteManager(address campaignRemoteManager);
    event UpdatedGasSettings(uint256 campaignCreationGas, uint256 blacklistedAddressGas, uint256 gasPrice);
    event DepositForGauge(address indexed gauge, uint256 amount, uint256 indexed round);
}"},"ERC165.sol":{"content":"// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (utils/introspection/ERC165.sol)

pragma solidity ^0.8.20;

import {IERC165} from "./IERC165.sol";

/**
 * @dev Implementation of the {IERC165} interface.
 *
 * Contracts that want to implement ERC-165 should inherit from this contract and override {supportsInterface} to check
 * for the additional interface id that will be supported. For example:
 *
 * ```solidity
 * function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
 *     return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
 * }
 * ```
 */
abstract contract ERC165 is IERC165 {
    /// @inheritdoc IERC165
    function supportsInterface(bytes4 interfaceId) public view virtual returns (bool) {
        return interfaceId == type(IERC165).interfaceId;
    }
}
"},"IERC1363.sol":{"content":"// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (interfaces/IERC1363.sol)

pragma solidity \u003e=0.6.2;

import {IERC20} from "./IERC20.sol";
import {IERC165} from "./IERC165.sol";

/**
 * @title IERC1363
 * @dev Interface of the ERC-1363 standard as defined in the https://eips.ethereum.org/EIPS/eip-1363[ERC-1363].
 *
 * Defines an extension interface for ERC-20 tokens that supports executing code on a recipient contract
 * after `transfer` or `transferFrom`, or code on a spender contract after `approve`, in a single transaction.
 */
interface IERC1363 is IERC20, IERC165 {
    /*
     * Note: the ERC-165 identifier for this interface is 0xb0202a11.
     * 0xb0202a11 ===
     *   bytes4(keccak256(\u0027transferAndCall(address,uint256)\u0027)) ^
     *   bytes4(keccak256(\u0027transferAndCall(address,uint256,bytes)\u0027)) ^
     *   bytes4(keccak256(\u0027transferFromAndCall(address,address,uint256)\u0027)) ^
     *   bytes4(keccak256(\u0027transferFromAndCall(address,address,uint256,bytes)\u0027)) ^
     *   bytes4(keccak256(\u0027approveAndCall(address,uint256)\u0027)) ^
     *   bytes4(keccak256(\u0027approveAndCall(address,uint256,bytes)\u0027))
     */

    /**
     * @dev Moves a `value` amount of tokens from the caller\u0027s account to `to`
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferAndCall(address to, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from the caller\u0027s account to `to`
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @param data Additional data with no specified format, sent in call to `to`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferAndCall(address to, uint256 value, bytes calldata data) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the allowance mechanism
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param from The address which you want to send tokens from.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferFromAndCall(address from, address to, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the allowance mechanism
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param from The address which you want to send tokens from.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @param data Additional data with no specified format, sent in call to `to`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferFromAndCall(address from, address to, uint256 value, bytes calldata data) external returns (bool);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller\u0027s tokens and then calls {IERC1363Spender-onApprovalReceived} on `spender`.
     * @param spender The address which will spend the funds.
     * @param value The amount of tokens to be spent.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function approveAndCall(address spender, uint256 value) external returns (bool);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller\u0027s tokens and then calls {IERC1363Spender-onApprovalReceived} on `spender`.
     * @param spender The address which will spend the funds.
     * @param value The amount of tokens to be spent.
     * @param data Additional data with no specified format, sent in call to `spender`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function approveAndCall(address spender, uint256 value, bytes calldata data) external returns (bool);
}
"},"IERC165.sol":{"content":"// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (utils/introspection/IERC165.sol)

pragma solidity \u003e=0.4.16;

/**
 * @dev Interface of the ERC-165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[ERC].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[ERC section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}
"},"IERC20.sol":{"content":"// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (token/ERC20/IERC20.sol)

pragma solidity \u003e=0.4.16;

/**
 * @dev Interface of the ERC-20 standard as defined in the ERC.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller\u0027s account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller\u0027s tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender\u0027s allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller\u0027s
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}
"},"SafeERC20.sol":{"content":"// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.3.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "./IERC20.sol";
import {IERC1363} from "./IERC1363.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC-20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    /**
     * @dev An operation with an ERC-20 token failed.
     */
    error SafeERC20FailedOperation(address token);

    /**
     * @dev Indicates a failed `decreaseAllowance` request.
     */
    error SafeERC20FailedDecreaseAllowance(address spender, uint256 currentAllowance, uint256 requestedDecrease);

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Variant of {safeTransfer} that returns a bool instead of reverting if the operation is not successful.
     */
    function trySafeTransfer(IERC20 token, address to, uint256 value) internal returns (bool) {
        return _callOptionalReturnBool(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Variant of {safeTransferFrom} that returns a bool instead of reverting if the operation is not successful.
     */
    function trySafeTransferFrom(IERC20 token, address from, address to, uint256 value) internal returns (bool) {
        return _callOptionalReturnBool(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Increase the calling contract\u0027s allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     *
     * IMPORTANT: If the token implements ERC-7674 (ERC-20 with temporary allowance), and if the "client"
     * smart contract uses ERC-7674 to set temporary allowances, then the "client" smart contract should avoid using
     * this function. Performing a {safeIncreaseAllowance} or {safeDecreaseAllowance} operation on a token contract
     * that has a non-zero temporary allowance (for that particular owner-spender) will result in unexpected behavior.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        forceApprove(token, spender, oldAllowance + value);
    }

    /**
     * @dev Decrease the calling contract\u0027s allowance toward `spender` by `requestedDecrease`. If `token` returns no
     * value, non-reverting calls are assumed to be successful.
     *
     * IMPORTANT: If the token implements ERC-7674 (ERC-20 with temporary allowance), and if the "client"
     * smart contract uses ERC-7674 to set temporary allowances, then the "client" smart contract should avoid using
     * this function. Performing a {safeIncreaseAllowance} or {safeDecreaseAllowance} operation on a token contract
     * that has a non-zero temporary allowance (for that particular owner-spender) will result in unexpected behavior.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 requestedDecrease) internal {
        unchecked {
            uint256 currentAllowance = token.allowance(address(this), spender);
            if (currentAllowance \u003c requestedDecrease) {
                revert SafeERC20FailedDecreaseAllowance(spender, currentAllowance, requestedDecrease);
            }
            forceApprove(token, spender, currentAllowance - requestedDecrease);
        }
    }

    /**
     * @dev Set the calling contract\u0027s allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     *
     * NOTE: If the token implements ERC-7674, this function will not modify any temporary allowance. This function
     * only sets the "standard" allowance. Any temporary allowance will remain active, in addition to the value being
     * set here.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeCall(token.approve, (spender, value));

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeCall(token.approve, (spender, 0)));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Performs an {ERC1363} transferAndCall, with a fallback to the simple {ERC20} transfer if the target has no
     * code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * Reverts if the returned value is other than `true`.
     */
    function transferAndCallRelaxed(IERC1363 token, address to, uint256 value, bytes memory data) internal {
        if (to.code.length == 0) {
            safeTransfer(token, to, value);
        } else if (!token.transferAndCall(to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Performs an {ERC1363} transferFromAndCall, with a fallback to the simple {ERC20} transferFrom if the target
     * has no code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * Reverts if the returned value is other than `true`.
     */
    function transferFromAndCallRelaxed(
        IERC1363 token,
        address from,
        address to,
        uint256 value,
        bytes memory data
    ) internal {
        if (to.code.length == 0) {
            safeTransferFrom(token, from, to, value);
        } else if (!token.transferFromAndCall(from, to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Performs an {ERC1363} approveAndCall, with a fallback to the simple {ERC20} approve if the target has no
     * code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * NOTE: When the recipient address (`to`) has no code (i.e. is an EOA), this function behaves as {forceApprove}.
     * Opposedly, when the recipient address (`to`) has code, this function only attempts to call {ERC1363-approveAndCall}
     * once without retrying, and relies on the returned value to be true.
     *
     * Reverts if the returned value is other than `true`.
     */
    function approveAndCallRelaxed(IERC1363 token, address to, uint256 value, bytes memory data) internal {
        if (to.code.length == 0) {
            forceApprove(token, to, value);
        } else if (!token.approveAndCall(to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturnBool} that reverts if call fails to meet the requirements.
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        uint256 returnSize;
        uint256 returnValue;
        assembly ("memory-safe") {
            let success := call(gas(), token, 0, add(data, 0x20), mload(data), 0, 0x20)
            // bubble errors
            if iszero(success) {
                let ptr := mload(0x40)
                returndatacopy(ptr, 0, returndatasize())
                revert(ptr, returndatasize())
            }
            returnSize := returndatasize()
            returnValue := mload(0)
        }

        if (returnSize == 0 ? address(token).code.length == 0 : returnValue != 1) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silently catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        bool success;
        uint256 returnSize;
        uint256 returnValue;
        assembly ("memory-safe") {
            success := call(gas(), token, 0, add(data, 0x20), mload(data), 0, 0x20)
            returnSize := returndatasize()
            returnValue := mload(0)
        }
        return success \u0026\u0026 (returnSize == 0 ? address(token).code.length \u003e 0 : returnValue == 1);
    }
}
"}}