BlubirdStaking

{{
  "language": "Solidity",
  "sources": {
    "@openzeppelin/contracts/access/Ownable.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}
"
    },
    "@openzeppelin/contracts/token/ERC20/extensions/IERC20Permit.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.4) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 *
 * ==== Security Considerations
 *
 * There are two important considerations concerning the use of `permit`. The first is that a valid permit signature
 * expresses an allowance, and it should not be assumed to convey additional meaning. In particular, it should not be
 * considered as an intention to spend the allowance in any specific way. The second is that because permits have
 * built-in replay protection and can be submitted by anyone, they can be frontrun. A protocol that uses permits should
 * take this into consideration and allow a `permit` call to fail. Combining these two aspects, a pattern that may be
 * generally recommended is:
 *
 * ```solidity
 * function doThingWithPermit(..., uint256 value, uint256 deadline, uint8 v, bytes32 r, bytes32 s) public {
 *     try token.permit(msg.sender, address(this), value, deadline, v, r, s) {} catch {}
 *     doThing(..., value);
 * }
 *
 * function doThing(..., uint256 value) public {
 *     token.safeTransferFrom(msg.sender, address(this), value);
 *     ...
 * }
 * ```
 *
 * Observe that: 1) `msg.sender` is used as the owner, leaving no ambiguity as to the signer intent, and 2) the use of
 * `try/catch` allows the permit to fail and makes the code tolerant to frontrunning. (See also
 * {SafeERC20-safeTransferFrom}).
 *
 * Additionally, note that smart contract wallets (such as Argent or Safe) are not able to produce permit signatures, so
 * contracts should have entry points that don't rely on permit.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     *
     * CAUTION: See Security Considerations above.
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}
"
    },
    "@openzeppelin/contracts/token/ERC20/IERC20.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 amount) external returns (bool);
}
"
    },
    "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.3) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";
import "../extensions/IERC20Permit.sol";
import "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(IERC20 token, address spender, uint256 value) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        require(
            (value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance + value));
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        unchecked {
            uint256 oldAllowance = token.allowance(address(this), spender);
            require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance - value));
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeWithSelector(token.approve.selector, spender, value);

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, 0));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Use a ERC-2612 signature to set the `owner` approval toward `spender` on `token`.
     * Revert on invalid signature.
     */
    function safePermit(
        IERC20Permit token,
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal {
        uint256 nonceBefore = token.nonces(owner);
        token.permit(owner, spender, value, deadline, v, r, s);
        uint256 nonceAfter = token.nonces(owner);
        require(nonceAfter == nonceBefore + 1, "SafeERC20: permit did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        require(returndata.length == 0 || abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return
            success && (returndata.length == 0 || abi.decode(returndata, (bool))) && Address.isContract(address(token));
    }
}
"
    },
    "@openzeppelin/contracts/utils/Address.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     *
     * Furthermore, `isContract` will also return true if the target contract within
     * the same transaction is already scheduled for destruction by `SELFDESTRUCT`,
     * which only has an effect at the end of a transaction.
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.0/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
     * the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
     *
     * _Available since v4.8._
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        if (success) {
            if (returndata.length == 0) {
                // only check isContract if the call was successful and the return data is empty
                // otherwise we already know that it was a contract
                require(isContract(target), "Address: call to non-contract");
            }
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason or using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    function _revert(bytes memory returndata, string memory errorMessage) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert(errorMessage);
        }
    }
}
"
    },
    "@openzeppelin/contracts/utils/Context.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.4) (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}
"
    },
    "contracts/BlubirdStaking.sol": {
      "content": "// SPDX-License-Identifier: MIT

pragma solidity 0.8.4;

/// OpenZeppelin imports
import "@openzeppelin/contracts/access/Ownable.sol";
import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";

contract BlubirdStaking is Ownable {
    using SafeERC20 for IERC20;

    uint256 public constant PERCENTAGE100 = 100000;

    /** the token that will be staked */
    IERC20 public token;

    /** The commitment tiers that are available to choose from */
    CommitmentTier[] public commitmentTiers;

    /** Active stakes */
    mapping(address => Stake) public stakes;

    /** Stakes that are being cooldown after being removed */
    mapping(address => CoolingDownStake[]) public coolingDownStakes;

    /** Keeps track of the index of the stakeholder in the stakeholderAddresses array for fast removal */
    mapping(address => uint256) private stakeholderIndex;

    /** Keeps track of addresses with active stakes (amount > 0) */
    address[] private stakeholderAddresses;
    
    /** Amount of tokens that are we're theoretically holding accounting for staked and cooling down stakes. */
    uint256 private heldTokens = 0;

    struct Stake {
        /** amount of tokens that are being staked by a stakeholder*/
        uint256 amount;
        /** stakingPower = amount * powerMultiplierPercentage / PERCENTAGE100 */
        uint256 stakingPower;
        /** the commitment tier index for the stakeholder */
        uint16 commitmentTierIndex;
    }

    struct CoolingDownStake {
        /** amount of tokens that are being cooldown */
        uint256 amount;
        /** when these tokens can be recovered by the stakeholder */
        uint256 cooldownEndTime;
        /** the commitment tier index of the stakeholder when they removed their stake */
        uint16 commitmentTierIndex;
    }

    /** Commitment tiers define the staking power multiplier for a stakeholder based on the cooldown period the opt for */
    struct CommitmentTier {
        /** E.G. "Short Commitment" */
        string name;
        /** amount of time in seconds the stakeholder needs to wait until he can get their tokens back after removing stake */
        uint256 cooldownPeriod;
        /** If not 0, the stakeholder can only enter the commitment tier before this timestamp */
        uint256 enterByTimestamp;
        /** stakingPower = amount * powerMultiplierPercentage / PERCENTAGE100 */
        uint32 powerMultiplierPercentage;
        /** The index of the commitment tier in the commitmentTiers array */
        uint16 index;
        /** If false, the commitment tier is not enabled and cannot be used in new stakes */
        bool enabled;
    }

    /** Data for adding a commitment tier */
    struct CommitmentTierInputData {
        /** E.G. "Short Commitment" */
        string name;
        /** amount of time in seconds the stakeholder needs to wait until he can get their tokens back after removing stake */
        uint256 cooldownPeriod;
        /** If not 0, the stakeholder can only enter the commitment tier before this timestamp */
        uint256 enterByTimestamp;
        /** stakingPower = amount * powerMultiplierPercentage / PERCENTAGE100 */
        uint32 powerMultiplierPercentage;
    }

    /// Events

    /** Stakeholder has began staking, increased their stake, or upgraded their commitment tier */
    event StakeAdded(
        address indexed stakeholder,
        uint16 indexed commitmentTierIndex,
        uint256 amount
    );

    /** Stakeholder has removed their stake, beginning the cooldown period */
    event StakeRemoved(address indexed stakeholder, uint256 amount);
    /** Stakeholder has recovered tokens he had unstaked */
    event StakeReclaimed(address indexed stakeholder, uint256 amount);

    /// Constructor
    constructor(
        CommitmentTierInputData[] memory commitmentTiers_,
        address tokenAddress_
    ) {
        require(commitmentTiers_.length > 0, "Error: There must be at least one commitment tier");
        require(tokenAddress_ != address(0), "Error: Token address can't be 0");
        for (uint256 i = 0; i < commitmentTiers_.length; i++) {
            commitmentTiers.push(
                CommitmentTier(commitmentTiers_[i].name, 
                    commitmentTiers_[i].cooldownPeriod,
                    commitmentTiers_[i].enterByTimestamp,
                    commitmentTiers_[i].powerMultiplierPercentage,
                    uint16(i),
                    true)
                );
            require(commitmentTiers_[i].powerMultiplierPercentage >= PERCENTAGE100, "Error: Power multiplier percentage must be greater than or equal to 100%");
        }
        token = IERC20(tokenAddress_);
    }

    function addCommitmentTier(CommitmentTierInputData memory commitmentTier_) external onlyOwner {
        commitmentTiers.push(
                CommitmentTier(commitmentTier_.name, 
                    commitmentTier_.cooldownPeriod,
                    commitmentTier_.enterByTimestamp,
                    commitmentTier_.powerMultiplierPercentage,
                    uint16(commitmentTiers.length),
                    true)
                );
        require(commitmentTier_.powerMultiplierPercentage >= PERCENTAGE100, "Error: Power multiplier percentage must be greater than or equal to 100%");
    }

    function enableCommitmentTier(uint256 commitmentTierIndex_) external onlyOwner {
        commitmentTiers[commitmentTierIndex_].enabled = true;
    }
    
    function disableCommitmentTier(uint256 commitmentTierIndex_) external onlyOwner {
        commitmentTiers[commitmentTierIndex_].enabled = false;
    }

    function getStakeholderAddresses() external view returns (address[] memory) {
        return stakeholderAddresses;
    }

    function getStakeholdersCount() external view returns (uint256) {
        return stakeholderAddresses.length;
    }

    /** Returns the active commitment tiers sorted by cooldown period and enter by timestamp */
    function getActiveCommitmentTiers() external view returns (CommitmentTier[] memory) {
        // Count how many tiers we're returning
        uint256 enabledCount = 0;
        for (uint256 i = 0; i < commitmentTiers.length; i++) {
            if (commitmentTiers[i].enabled) {
                enabledCount++;
            }
        }

        // Create array of only enabled tiers
        CommitmentTier[] memory active = new CommitmentTier[](enabledCount);
        uint256 j = 0;
        for (uint256 i = 0; i < commitmentTiers.length; i++) {
            if (commitmentTiers[i].enabled) {
                active[j] = commitmentTiers[i];
                j++;
            }
        }

        // Sort by enterByTimestamp first, cooldownPeriod as secondary key
        for (uint256 i = 0; i < active.length; i++) {
            for (uint256 k = i + 1; k < active.length; k++) {
                if (
                    active[i].enterByTimestamp > active[k].enterByTimestamp ||
                    (active[i].enterByTimestamp == active[k].enterByTimestamp &&
                    active[i].cooldownPeriod > active[k].cooldownPeriod)
                ) {
                    CommitmentTier memory temp = active[i];
                    active[i] = active[k];
                    active[k] = temp;
                }
            }
        }

        return active;
    }

    /** Batched retrieval of staking state */
    function getStakeholdersWithStakes(uint256 offset, uint256 limit)
        external
        view
        returns (address[] memory addresses, Stake[] memory stakesArray)
    {
        uint256 total = stakeholderAddresses.length;

        // Clamp offset to [0, total]
        if (offset > total) {
            offset = total;
        }

        // Compute end = min(offset + limit, total)
        uint256 end = offset + limit;
        if (end > total) {
            end = total;
        }

        uint256 length = end - offset;

        addresses = new address[](length);
        stakesArray = new Stake[](length);

        for (uint256 i = 0; i < length; i++) {
            address a = stakeholderAddresses[offset + i];
            addresses[i] = a;
            stakesArray[i] = stakes[a];
        }
    }

    function getCommitmentTiers() external view returns (CommitmentTier[] memory) {
        return commitmentTiers;
    }

    function getCommitmentTier(uint16 commitmentTierIndex_) external view returns (CommitmentTier memory) {
        require(commitmentTierIndex_ < commitmentTiers.length, "Error: Commitment tier index out of bounds");
        return commitmentTiers[commitmentTierIndex_];
    }

    function getStake(address stakeholder_) external view returns (Stake memory) {
        return stakes[stakeholder_];
    }

    function getCoolingDownStakes(address stakeholder_) external view returns (CoolingDownStake[] memory) {
        return coolingDownStakes[stakeholder_];
    }

    function getReclaimableStake(address stakeholder_) external view returns (uint256) {
        uint256 totalReclaimable = 0;
        uint256 length = coolingDownStakes[stakeholder_].length;
        for (uint256 coolingDownStakeIndex = 0; coolingDownStakeIndex < length; coolingDownStakeIndex++) {
            CoolingDownStake storage coolingDownStake = coolingDownStakes[stakeholder_][coolingDownStakeIndex];
            if (block.timestamp >= coolingDownStake.cooldownEndTime) {
                totalReclaimable += coolingDownStake.amount;
            }
        }
        return totalReclaimable;
    }

    function calculateStakingPower(uint256 amount_, uint16 commitmentTierIndex_) internal view returns (uint256) {
        return amount_ * commitmentTiers[commitmentTierIndex_].powerMultiplierPercentage / PERCENTAGE100;
    }

    /** Begin staking or increase stake */
    function addStake(
        uint256 amount_,
        uint16 commitmentTierIndex_
    ) external {
        require(commitmentTierIndex_ < commitmentTiers.length, "Error: Commitment tier index out of bounds");

        Stake storage stake = stakes[msg.sender];

        CommitmentTier storage targetCommitmentTier = commitmentTiers[commitmentTierIndex_];

        if (stake.amount > 0) {
            // User was already staking. He's either adding more tokens or upgrading his commitment tier
            if (commitmentTierIndex_ == stake.commitmentTierIndex) {
                // enterByTimestamp and enabled are not checked here because the user is already in that commitment tier
                // But he needs to be adding more tokens or the call is pointless
                require(amount_ > 0, "Error: Amount can't be 0");
            }
            else {
                // User is changing his commitment tier
                CommitmentTier storage currentCommitmentTier = commitmentTiers[stake.commitmentTierIndex];
                require(targetCommitmentTier.cooldownPeriod >= currentCommitmentTier.cooldownPeriod, "Error: you can only switch to a commitment tier with an equal or longer cooldown period");
                require(targetCommitmentTier.enabled, "Error: Commitment tier is not enabled");
                require(targetCommitmentTier.enterByTimestamp == 0 || block.timestamp < targetCommitmentTier.enterByTimestamp, "Error: Commitment tier can only be entered before the 'enter by' timestamp");
            }
        }
        else {
            // User is a new stakeholder
            require(amount_ > 0, "Error: Amount can't be 0");
            require(targetCommitmentTier.enabled, "Error: Commitment tier is not enabled");
            require(targetCommitmentTier.enterByTimestamp == 0 || block.timestamp < targetCommitmentTier.enterByTimestamp, "Error: Commitment tier can only be entered before the 'enter by' timestamp");
            stakeholderAddresses.push(msg.sender);
            stakeholderIndex[msg.sender] = stakeholderAddresses.length - 1;
        }
        // By now we've established that the user is either
        // - Adding new tokens to their existing stake and/or upgrading their commitment tier to one that's available to pick
        // - A new stakeholder adding tokens in a commitment tier that's available to pick
        
        if (amount_ > 0) {
            token.safeTransferFrom(msg.sender, address(this), amount_);
            heldTokens += amount_;
            stake.amount += amount_;
        }

        stake.commitmentTierIndex = commitmentTierIndex_;
        stake.stakingPower = calculateStakingPower(stake.amount, stake.commitmentTierIndex);

        emit StakeAdded(msg.sender, commitmentTierIndex_, amount_);
    }

    /** Remove stake and begin cooldown period */
    function removeStake(uint256 amount_) external {
        require(amount_ != 0, "Error: Amount can't be 0");

        Stake storage stake = stakes[msg.sender];
        require(stake.amount >= amount_, "Error: Amount can't be greater than the stake");

        uint256 newAmount = stake.amount - amount_;
        stake.amount = newAmount;
        stake.stakingPower = calculateStakingPower(newAmount, stake.commitmentTierIndex);

        uint16 commitmentTierIndex = stake.commitmentTierIndex;

        if (stake.amount == 0) {
            delete stakes[msg.sender];

            uint index = stakeholderIndex[msg.sender];
            uint lastIndex = stakeholderAddresses.length - 1;
            address lastAddress = stakeholderAddresses[lastIndex];

            // Swap with last
            stakeholderAddresses[index] = lastAddress;
            stakeholderIndex[lastAddress] = index;

            // Remove last
            stakeholderAddresses.pop();
            delete stakeholderIndex[msg.sender];
        }

        coolingDownStakes[msg.sender].push(
            CoolingDownStake({
                amount: amount_,
                cooldownEndTime: block.timestamp + commitmentTiers[commitmentTierIndex].cooldownPeriod,
                commitmentTierIndex: commitmentTierIndex
            })
        );

        emit StakeRemoved(msg.sender, amount_);
    }

    /** Reclaim stake that's past the cooldown period */
    function reclaimStake() external {
        require(coolingDownStakes[msg.sender].length != 0, "Error: Address doesn't have any unstaked tokens that finished their cooldown period");

        uint256 totalReclaimed = 0;
        uint256 length = coolingDownStakes[msg.sender].length;
        
        // Iterate backwards to safely remove elements
        for (uint256 i = length; i > 0; i--) {
            CoolingDownStake storage stake = coolingDownStakes[msg.sender][i - 1];

            if (block.timestamp >= stake.cooldownEndTime) {
                totalReclaimed += stake.amount;
                heldTokens -= stake.amount;

                // Remove the stake
                coolingDownStakes[msg.sender][i - 1] = coolingDownStakes[msg.sender][length - 1];
                coolingDownStakes[msg.sender].pop();
                
                length--;
            }
        }

        require(totalReclaimed > 0, "Error: Address doesn't have any unstaked tokens that finished their cooldown period");
        token.safeTransfer(msg.sender, totalReclaimed);
        emit StakeReclaimed(msg.sender, totalReclaimed);
    }

    /// Allow transfer of accidentally sent IERC20 tokens

    /** Returns the amount of tokens of the staked token contract that have accidentally been sent to the staking contract */
    function getExcessTokens() public view returns (uint256) {
        uint256 balance = token.balanceOf(address(this));
        return balance > heldTokens ? balance - heldTokens : 0;
    }

    function refundTokens(address recipientAddress_, address erc20Address_) external onlyOwner {
        IERC20 erc20 = IERC20(erc20Address_);

        if (erc20Address_ == address(token)) {
            // We can refund the staked tokens if there are more tokens than there should be
            uint256 excessHeldTokens = getExcessTokens();
            require(excessHeldTokens > 0, "Error: No excess held tokens");
            erc20.safeTransfer(recipientAddress_, excessHeldTokens);
        }
        else {
            // We can refund any other ERC20 tokens that are accidentally sent to the staking contract
            uint256 balance = erc20.balanceOf(address(this));
            require(balance > 0, "Error: No balance to refund");
            erc20.safeTransfer(recipientAddress_, balance);
        }
    }

}
"
    }
  },
  "settings": {
    "optimizer": {
      "enabled": true,
      "runs": 200
    },
    "outputSelection": {
      "*": {
        "*": [
          "evm.bytecode",
          "evm.deployedBytecode",
          "devdoc",
          "userdoc",
          "metadata",
          "abi"
        ]
      }
    }
  }
}}