PowerContract

// File: @openzeppelin/contracts/utils/ReentrancyGuard.sol


// OpenZeppelin Contracts (last updated v5.1.0) (utils/ReentrancyGuard.sol)

pragma solidity ^0.8.20;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If EIP-1153 (transient storage) is available on the chain you're deploying at,
 * consider using {ReentrancyGuardTransient} instead.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant NOT_ENTERED = 1;
    uint256 private constant ENTERED = 2;

    uint256 private _status;

    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();

    constructor() {
        _status = NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be NOT_ENTERED
        if (_status == ENTERED) {
            revert ReentrancyGuardReentrantCall();
        }

        // Any calls to nonReentrant after this point will fail
        _status = ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == ENTERED;
    }
}

// File: @openzeppelin/contracts/utils/Context.sol


// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// File: @openzeppelin/contracts/access/Ownable.sol


// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;


/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// File: @openzeppelin/contracts/utils/Pausable.sol


// OpenZeppelin Contracts (last updated v5.3.0) (utils/Pausable.sol)

pragma solidity ^0.8.20;


/**
 * @dev Contract module which allows children to implement an emergency stop
 * mechanism that can be triggered by an authorized account.
 *
 * This module is used through inheritance. It will make available the
 * modifiers `whenNotPaused` and `whenPaused`, which can be applied to
 * the functions of your contract. Note that they will not be pausable by
 * simply including this module, only once the modifiers are put in place.
 */
abstract contract Pausable is Context {
    bool private _paused;

    /**
     * @dev Emitted when the pause is triggered by `account`.
     */
    event Paused(address account);

    /**
     * @dev Emitted when the pause is lifted by `account`.
     */
    event Unpaused(address account);

    /**
     * @dev The operation failed because the contract is paused.
     */
    error EnforcedPause();

    /**
     * @dev The operation failed because the contract is not paused.
     */
    error ExpectedPause();

    /**
     * @dev Modifier to make a function callable only when the contract is not paused.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    modifier whenNotPaused() {
        _requireNotPaused();
        _;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is paused.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    modifier whenPaused() {
        _requirePaused();
        _;
    }

    /**
     * @dev Returns true if the contract is paused, and false otherwise.
     */
    function paused() public view virtual returns (bool) {
        return _paused;
    }

    /**
     * @dev Throws if the contract is paused.
     */
    function _requireNotPaused() internal view virtual {
        if (paused()) {
            revert EnforcedPause();
        }
    }

    /**
     * @dev Throws if the contract is not paused.
     */
    function _requirePaused() internal view virtual {
        if (!paused()) {
            revert ExpectedPause();
        }
    }

    /**
     * @dev Triggers stopped state.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    function _pause() internal virtual whenNotPaused {
        _paused = true;
        emit Paused(_msgSender());
    }

    /**
     * @dev Returns to normal state.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    function _unpause() internal virtual whenPaused {
        _paused = false;
        emit Unpaused(_msgSender());
    }
}

// File: @openzeppelin/contracts/token/ERC20/IERC20.sol


// OpenZeppelin Contracts (last updated v5.4.0) (token/ERC20/IERC20.sol)

pragma solidity >=0.4.16;

/**
 * @dev Interface of the ERC-20 standard as defined in the ERC.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// File: @openzeppelin/contracts/interfaces/IERC20.sol


// OpenZeppelin Contracts (last updated v5.4.0) (interfaces/IERC20.sol)

pragma solidity >=0.4.16;


// File: @openzeppelin/contracts/utils/introspection/IERC165.sol


// OpenZeppelin Contracts (last updated v5.4.0) (utils/introspection/IERC165.sol)

pragma solidity >=0.4.16;

/**
 * @dev Interface of the ERC-165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[ERC].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[ERC section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// File: @openzeppelin/contracts/interfaces/IERC165.sol


// OpenZeppelin Contracts (last updated v5.4.0) (interfaces/IERC165.sol)

pragma solidity >=0.4.16;


// File: @openzeppelin/contracts/interfaces/IERC1363.sol


// OpenZeppelin Contracts (last updated v5.4.0) (interfaces/IERC1363.sol)

pragma solidity >=0.6.2;



/**
 * @title IERC1363
 * @dev Interface of the ERC-1363 standard as defined in the https://eips.ethereum.org/EIPS/eip-1363[ERC-1363].
 *
 * Defines an extension interface for ERC-20 tokens that supports executing code on a recipient contract
 * after `transfer` or `transferFrom`, or code on a spender contract after `approve`, in a single transaction.
 */
interface IERC1363 is IERC20, IERC165 {
    /*
     * Note: the ERC-165 identifier for this interface is 0xb0202a11.
     * 0xb0202a11 ===
     *   bytes4(keccak256('transferAndCall(address,uint256)')) ^
     *   bytes4(keccak256('transferAndCall(address,uint256,bytes)')) ^
     *   bytes4(keccak256('transferFromAndCall(address,address,uint256)')) ^
     *   bytes4(keccak256('transferFromAndCall(address,address,uint256,bytes)')) ^
     *   bytes4(keccak256('approveAndCall(address,uint256)')) ^
     *   bytes4(keccak256('approveAndCall(address,uint256,bytes)'))
     */

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferAndCall(address to, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @param data Additional data with no specified format, sent in call to `to`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferAndCall(address to, uint256 value, bytes calldata data) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the allowance mechanism
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param from The address which you want to send tokens from.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferFromAndCall(address from, address to, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the allowance mechanism
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param from The address which you want to send tokens from.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @param data Additional data with no specified format, sent in call to `to`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferFromAndCall(address from, address to, uint256 value, bytes calldata data) external returns (bool);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens and then calls {IERC1363Spender-onApprovalReceived} on `spender`.
     * @param spender The address which will spend the funds.
     * @param value The amount of tokens to be spent.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function approveAndCall(address spender, uint256 value) external returns (bool);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens and then calls {IERC1363Spender-onApprovalReceived} on `spender`.
     * @param spender The address which will spend the funds.
     * @param value The amount of tokens to be spent.
     * @param data Additional data with no specified format, sent in call to `spender`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function approveAndCall(address spender, uint256 value, bytes calldata data) external returns (bool);
}

// File: @openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol


// OpenZeppelin Contracts (last updated v5.3.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.20;



/**
 * @title SafeERC20
 * @dev Wrappers around ERC-20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    /**
     * @dev An operation with an ERC-20 token failed.
     */
    error SafeERC20FailedOperation(address token);

    /**
     * @dev Indicates a failed `decreaseAllowance` request.
     */
    error SafeERC20FailedDecreaseAllowance(address spender, uint256 currentAllowance, uint256 requestedDecrease);

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Variant of {safeTransfer} that returns a bool instead of reverting if the operation is not successful.
     */
    function trySafeTransfer(IERC20 token, address to, uint256 value) internal returns (bool) {
        return _callOptionalReturnBool(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Variant of {safeTransferFrom} that returns a bool instead of reverting if the operation is not successful.
     */
    function trySafeTransferFrom(IERC20 token, address from, address to, uint256 value) internal returns (bool) {
        return _callOptionalReturnBool(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     *
     * IMPORTANT: If the token implements ERC-7674 (ERC-20 with temporary allowance), and if the "client"
     * smart contract uses ERC-7674 to set temporary allowances, then the "client" smart contract should avoid using
     * this function. Performing a {safeIncreaseAllowance} or {safeDecreaseAllowance} operation on a token contract
     * that has a non-zero temporary allowance (for that particular owner-spender) will result in unexpected behavior.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        forceApprove(token, spender, oldAllowance + value);
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `requestedDecrease`. If `token` returns no
     * value, non-reverting calls are assumed to be successful.
     *
     * IMPORTANT: If the token implements ERC-7674 (ERC-20 with temporary allowance), and if the "client"
     * smart contract uses ERC-7674 to set temporary allowances, then the "client" smart contract should avoid using
     * this function. Performing a {safeIncreaseAllowance} or {safeDecreaseAllowance} operation on a token contract
     * that has a non-zero temporary allowance (for that particular owner-spender) will result in unexpected behavior.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 requestedDecrease) internal {
        unchecked {
            uint256 currentAllowance = token.allowance(address(this), spender);
            if (currentAllowance < requestedDecrease) {
                revert SafeERC20FailedDecreaseAllowance(spender, currentAllowance, requestedDecrease);
            }
            forceApprove(token, spender, currentAllowance - requestedDecrease);
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     *
     * NOTE: If the token implements ERC-7674, this function will not modify any temporary allowance. This function
     * only sets the "standard" allowance. Any temporary allowance will remain active, in addition to the value being
     * set here.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeCall(token.approve, (spender, value));

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeCall(token.approve, (spender, 0)));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Performs an {ERC1363} transferAndCall, with a fallback to the simple {ERC20} transfer if the target has no
     * code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * Reverts if the returned value is other than `true`.
     */
    function transferAndCallRelaxed(IERC1363 token, address to, uint256 value, bytes memory data) internal {
        if (to.code.length == 0) {
            safeTransfer(token, to, value);
        } else if (!token.transferAndCall(to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Performs an {ERC1363} transferFromAndCall, with a fallback to the simple {ERC20} transferFrom if the target
     * has no code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * Reverts if the returned value is other than `true`.
     */
    function transferFromAndCallRelaxed(
        IERC1363 token,
        address from,
        address to,
        uint256 value,
        bytes memory data
    ) internal {
        if (to.code.length == 0) {
            safeTransferFrom(token, from, to, value);
        } else if (!token.transferFromAndCall(from, to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Performs an {ERC1363} approveAndCall, with a fallback to the simple {ERC20} approve if the target has no
     * code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * NOTE: When the recipient address (`to`) has no code (i.e. is an EOA), this function behaves as {forceApprove}.
     * Opposedly, when the recipient address (`to`) has code, this function only attempts to call {ERC1363-approveAndCall}
     * once without retrying, and relies on the returned value to be true.
     *
     * Reverts if the returned value is other than `true`.
     */
    function approveAndCallRelaxed(IERC1363 token, address to, uint256 value, bytes memory data) internal {
        if (to.code.length == 0) {
            forceApprove(token, to, value);
        } else if (!token.approveAndCall(to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturnBool} that reverts if call fails to meet the requirements.
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        uint256 returnSize;
        uint256 returnValue;
        assembly ("memory-safe") {
            let success := call(gas(), token, 0, add(data, 0x20), mload(data), 0, 0x20)
            // bubble errors
            if iszero(success) {
                let ptr := mload(0x40)
                returndatacopy(ptr, 0, returndatasize())
                revert(ptr, returndatasize())
            }
            returnSize := returndatasize()
            returnValue := mload(0)
        }

        if (returnSize == 0 ? address(token).code.length == 0 : returnValue != 1) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silently catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        bool success;
        uint256 returnSize;
        uint256 returnValue;
        assembly ("memory-safe") {
            success := call(gas(), token, 0, add(data, 0x20), mload(data), 0, 0x20)
            returnSize := returndatasize()
            returnValue := mload(0)
        }
        return success && (returnSize == 0 ? address(token).code.length > 0 : returnValue == 1);
    }
}

// File: contracts/4_power.sol


pragma solidity ^0.8.30;






/**
 * @title PowerContract
 * @dev Computing power purchase contract with USDT payment, referral system, and wallet allocation
 * @author RWA Contract Team
 */
contract PowerContract is ReentrancyGuard, Ownable, Pausable {
    using SafeERC20 for IERC20;
    
    uint256 private constant MIN_REFERRER_PURCHASE = 100;
    
    uint256 private constant COMPUTING_POWER_PRICE_WITH_DECIMALS = 12 * 10 ** 6;
    
    address private usdtToken;
    address private wbtcToken;
    
    address private financeWallet;
    address private multisigWallet;
    
    struct FinanceWalletInfo {
        address wallet;
        uint256 usdtBalance;
        uint256 usdtAllowance;
        uint256 wbtcBalance;
        uint256 wbtcAllowance;
    }
    
    mapping(address => uint256) private amount;
    
    uint256 private totalPurchaseAmount;
    
    // User withdrawal amount statistics
    mapping(address => uint256) private userUsdtWithdrawalAmount;
    mapping(address => uint256) private userWbtcWithdrawalAmount;
    
    // Global withdrawal amount statistics
    uint256 private totalUsdtWithdrawalAmount;
    uint256 private totalWbtcWithdrawalAmount;
    
    mapping(address => address) private referrer;
    mapping(address => address[]) private referrals;
    
    enum TokenType { USDT, WBTC }
    
    struct PurchaseRecord {
        address user;
        uint256 amount;
        uint256 computingPower;
        address referrer;
        uint256 timestamp;
    }
    
    struct WithdrawalRecord {
        address user;
        uint256 amount;
        uint256 timestamp;
        bool success;
        TokenType tokenType;
        uint256 id;
    }
    
    PurchaseRecord[] private purchaseRecords;
    mapping(address => uint256[]) private userPurchaseHistory;
    
    WithdrawalRecord[] private withdrawalUsdtRecords;
    WithdrawalRecord[] private withdrawalWbtcRecords;
    mapping(address => uint256[]) private userUsdtWithdrawalHistory;
    mapping(address => uint256[]) private userWbtcWithdrawalHistory;
    
    // Mapping for quick checking if ID is already used
    mapping(uint256 => bool) private usedUsdtIds;
    mapping(uint256 => bool) private usedWbtcIds;
    
    
    event MultisigWalletUpdated(address indexed oldWallet, address indexed newWallet);
    
    event ComputingPowerPurchased(
        address indexed user,
        uint256 indexed amount,
        uint256 indexed computingPower,
        address referrer,
        uint256 timestamp
    );
    
    event ReferralBound(address indexed user, address indexed referrer);
    
    event EmergencyWithdraw(address indexed to, uint256 indexed amount);
    
    event FinanceWalletUpdated(address indexed oldWallet, address indexed newWallet);
    
    event PaymentProcessed(address indexed recipient, uint256 indexed amount, uint256 timestamp, uint256 indexed id);
    
    error InvalidAddress();
    error InvalidAmount();
    error InsufficientBalance();
    error InsufficientAllowance();
    error ReferralAlreadyExists();
    error SelfReferral();
    error OnlyIntegerAmount();
    error CircularReferral();
    error InvalidReferrer();
    error ReferralValidationFailed();
    error InvalidPageSize();
    error InvalidOffset();
    error InsufficientFinanceWalletBalance();
    error InsufficientFinanceWalletAllowance();
    error NotAuthorized();
    error RecipientNotPurchased();
    error DuplicateId();
    error InvalidId();
    
    /**
     * @dev Constructor
     * @param _usdtToken USDT token contract address
     * @param _wbtcToken WBTC token contract address
     * @param _multisigWallet Multisig wallet address for receiving funds
     * @param _financeWallet Finance wallet address
     */
    constructor(
        address _usdtToken,
        address _wbtcToken,
        address _multisigWallet,
        address _financeWallet
    ) Ownable(msg.sender) {
        if (_usdtToken == address(0)) revert InvalidAddress();
        if (_wbtcToken == address(0)) revert InvalidAddress();
        if (_multisigWallet == address(0)) revert InvalidAddress();
        if (_financeWallet == address(0)) revert InvalidAddress();
        
        usdtToken = _usdtToken;
        wbtcToken = _wbtcToken;
        multisigWallet = _multisigWallet;
        financeWallet = _financeWallet;
    }
    
    /**
     * @notice Set multisig wallet address
     * @param _multisigWallet Multisig wallet address
     */
    function setMultisigWallet(address _multisigWallet) external onlyOwner {
        if (_multisigWallet == address(0)) revert InvalidAddress();
        
        address oldWallet = multisigWallet;
        multisigWallet = _multisigWallet;
        
        emit MultisigWalletUpdated(oldWallet, _multisigWallet);
    }
    
    /**
     * @notice Set finance wallet address
     * @param _financeWallet Finance wallet address
     */
    function setFinanceWallet(address _financeWallet) external onlyOwner {
        if (_financeWallet == address(0)) revert InvalidAddress();
        
        address oldWallet = financeWallet;
        financeWallet = _financeWallet;
        
        emit FinanceWalletUpdated(oldWallet, _financeWallet);
    }
    
    /**
     * @notice Process USDT payment to a recipient using pre-authorized amount (finance wallet only)
     * @param _recipient Recipient address (must have purchased computing power)
     * @param _amount Amount to transfer (USDT, 6 decimals)
     * @param _id Unique payment ID
     */
    function paymentUsdt(address _recipient, uint256 _amount, uint256 _id) external nonReentrant whenNotPaused {
        if (msg.sender != financeWallet) revert NotAuthorized();
        if (_recipient == address(0)) revert InvalidAddress();
        if (_amount == 0) revert InvalidAmount();
        if (_id == 0) revert InvalidId();
        if (amount[_recipient] < COMPUTING_POWER_PRICE_WITH_DECIMALS) revert RecipientNotPurchased();
        if (_isIdAlreadyUsed(_id, TokenType.USDT)) revert DuplicateId();
        
        // Check finance wallet balance and allowance
        uint256 financeBalance = IERC20(usdtToken).balanceOf(financeWallet);
        uint256 financeAllowance = IERC20(usdtToken).allowance(financeWallet, address(this));
        
        if (financeBalance < _amount) revert InsufficientFinanceWalletBalance();
        if (financeAllowance < _amount) revert InsufficientFinanceWalletAllowance();
        
        // Mark ID as used
        usedUsdtIds[_id] = true;
        
        // Record USDT withdrawal history
        uint256 recordId = withdrawalUsdtRecords.length;
        withdrawalUsdtRecords.push(WithdrawalRecord({
            user: _recipient,
            amount: _amount,
            timestamp: block.timestamp,
            success: true,
            tokenType: TokenType.USDT,
            id: _id
        }));
        userUsdtWithdrawalHistory[_recipient].push(recordId);
        
        // Update user and global USDT withdrawal amounts
        userUsdtWithdrawalAmount[_recipient] += _amount;
        totalUsdtWithdrawalAmount += _amount;
        
        // Perform external call last
        IERC20(usdtToken).safeTransferFrom(financeWallet, _recipient, _amount);
        
        emit PaymentProcessed(_recipient, _amount, block.timestamp, _id);
    }
    
    /**
     * @notice Process WBTC payment to a recipient using pre-authorized amount (finance wallet only)
     * @param _recipient Recipient address (must have purchased computing power)
     * @param _amount Amount to transfer (WBTC, 8 decimals)
     * @param _id Unique payment ID
     */
    function paymentWbtc(address _recipient, uint256 _amount, uint256 _id) external nonReentrant whenNotPaused {
        if (msg.sender != financeWallet) revert NotAuthorized();
        if (_recipient == address(0)) revert InvalidAddress();
        if (_amount == 0) revert InvalidAmount();
        if (_id == 0) revert InvalidId();
        if (amount[_recipient] < COMPUTING_POWER_PRICE_WITH_DECIMALS) revert RecipientNotPurchased();
        if (_isIdAlreadyUsed(_id, TokenType.WBTC)) revert DuplicateId();
        
        // Check finance wallet balance and allowance
        uint256 financeBalance = IERC20(wbtcToken).balanceOf(financeWallet);
        uint256 financeAllowance = IERC20(wbtcToken).allowance(financeWallet, address(this));
        
        if (financeBalance < _amount) revert InsufficientFinanceWalletBalance();
        if (financeAllowance < _amount) revert InsufficientFinanceWalletAllowance();
        
        // Update all state before external call to prevent reentrancy attacks
        // Mark ID as used
        usedWbtcIds[_id] = true;
        
        // Record WBTC withdrawal history
        uint256 recordId = withdrawalWbtcRecords.length;
        withdrawalWbtcRecords.push(WithdrawalRecord({
            user: _recipient,
            amount: _amount,
            timestamp: block.timestamp,
            success: true,
            tokenType: TokenType.WBTC,
            id: _id
        }));
        userWbtcWithdrawalHistory[_recipient].push(recordId);
        
        // Update user and global WBTC withdrawal amounts
        userWbtcWithdrawalAmount[_recipient] += _amount;
        totalWbtcWithdrawalAmount += _amount;
        
        // Perform external call last
        IERC20(wbtcToken).safeTransferFrom(financeWallet, _recipient, _amount);
        
        emit PaymentProcessed(_recipient, _amount, block.timestamp, _id);
    }
    
    /**
     * @notice Purchase computing power with USDT (without referral)
     * @param _amount Purchase amount (USDT, 6 decimals)
     */
    function purchaseComputingPower(uint256 _amount) external nonReentrant whenNotPaused {
        _purchaseComputingPower(_amount, address(0));
    }
    
    /**
     * @notice Purchase computing power with USDT (with referral)
     * @param _amount Purchase amount (USDT, 6 decimals)
     * @param _referrerAddress Referrer address
     */
    function purchaseComputingPower(uint256 _amount, address _referrerAddress) external nonReentrant whenNotPaused {
        _purchaseComputingPower(_amount, _referrerAddress);
    }
    
    /**
     * @dev Internal computing power purchase function
     * @param _amount Purchase amount
     * @param _referrerAddress Referrer address (optional)
     */
    function _purchaseComputingPower(uint256 _amount, address _referrerAddress) internal {
        if (_amount == 0) revert InvalidAmount();
        
        uint256 computingPowerPrice = COMPUTING_POWER_PRICE_WITH_DECIMALS;
        
        if (_amount % computingPowerPrice != 0) revert OnlyIntegerAmount();
        
        uint256 maxPurchaseAmount = 10_000_000 * 10**6;
        if (_amount > maxPurchaseAmount) revert InvalidAmount();
        
        uint256 computingPower = _amount / computingPowerPrice;
        if (computingPower == 0) revert InvalidAmount();
        
        if (_referrerAddress != address(0)) {
            if (!_validateReferrer(msg.sender, _referrerAddress)) {
                revert ReferralValidationFailed();
            }
        }
        
        if (IERC20(usdtToken).balanceOf(msg.sender) < _amount) revert InsufficientBalance();
        if (IERC20(usdtToken).allowance(msg.sender, address(this)) < _amount) revert InsufficientAllowance();
        
        if (_referrerAddress != address(0)) {
            _safeBindReferrer(msg.sender, _referrerAddress);
        }
        
        IERC20(usdtToken).safeTransferFrom(msg.sender, address(this), _amount);
        
        // Transfer funds directly to multisig wallet
        if (_amount > 0) {
            IERC20(usdtToken).safeTransfer(multisigWallet, _amount);
        }
        
        amount[msg.sender] += _amount;
        totalPurchaseAmount += _amount;
        uint256 recordId = purchaseRecords.length;
        purchaseRecords.push(PurchaseRecord({
            user: msg.sender,
            amount: _amount,
            computingPower: computingPower,
            referrer: _referrerAddress,
            timestamp: block.timestamp
        }));
        userPurchaseHistory[msg.sender].push(recordId);
        
        emit ComputingPowerPurchased(msg.sender, _amount, computingPower, _referrerAddress, block.timestamp);
    }
    
    /**
     * @notice Get user's referrer
     * @param _user User address
     * @return Referrer address
     */
    function getReferrer(address _user) external view returns (address) {
        return referrer[_user];
    }
    
    
    /**
     * @notice Get user's referral list with pagination
     * @param _user User address
     * @param _offset Offset
     * @param _limit Limit count
     * @return Referred user address array
     */
    function getReferralsPaginated(address _user, uint256 _offset, uint256 _limit) 
        external view returns (address[] memory) {
        if (_limit == 0 || _limit > 100) revert InvalidPageSize();
        if (_offset > referrals[_user].length) revert InvalidOffset();
        
        if (_offset == referrals[_user].length) {
            return new address[](0);
        }
        
        uint256 end = _offset + _limit;
        if (end > referrals[_user].length) {
            end = referrals[_user].length;
        }
        
        address[] memory result = new address[](end - _offset);
        for (uint256 i = _offset; i < end; i++) {
            result[i - _offset] = referrals[_user][i];
        }
        
        return result;
    }
    
    /**
     * @notice Get total count of user's referral list
     * @param _user User address
     * @return Total count of referred users
     */
    function getReferralsCount(address _user) external view returns (uint256) {
        return referrals[_user].length;
    }
    
    
    /**
     * @notice Check if address can be a referrer
     * @param _referrerAddress Referrer address
     * @return Whether can be a referrer
     */
    function isValidDirectReferrer(address _referrerAddress) external view returns (bool) {
        return _isValidDirectReferrer(_referrerAddress);
    }
    

    
    
    /**
     * @notice Query user purchase history with pagination
     * @param _user User address
     * @param _offset Offset
     * @param _limit Limit count
     * @return Purchase record array
     */
    function getUserPurchaseHistoryPaginated(address _user, uint256 _offset, uint256 _limit) 
        external view returns (PurchaseRecord[] memory) {
        if (_limit == 0 || _limit > 100) revert InvalidPageSize();
        
        uint256[] memory recordIds = userPurchaseHistory[_user];
        if (_offset > recordIds.length) revert InvalidOffset();
        
        if (_offset == recordIds.length) {
            return new PurchaseRecord[](0);
        }
        
        uint256 end = _offset + _limit;
        if (end > recordIds.length) {
            end = recordIds.length;
        }
        
        PurchaseRecord[] memory records = new PurchaseRecord[](end - _offset);
        for (uint256 i = _offset; i < end; i++) {
            records[i - _offset] = purchaseRecords[recordIds[i]];
        }
        
        return records;
    }
    
    /**
     * @notice Get total count of user purchase history
     * @param _user User address
     * @return Total count of purchase records
     */
    function getUserPurchaseHistoryCount(address _user) external view returns (uint256) {
        return userPurchaseHistory[_user].length;
    }
    
    /**
     * @notice Query total purchase record count
     * @return Total record count
     */
    function getTotalPurchaseRecords() external view returns (uint256) {
        return purchaseRecords.length;
    }
    
    /**
     * @notice Get user's total purchase amount
     * @param _user User address
     * @return Total purchase amount
     */
    function getUserAmount(address _user) external view returns (uint256) {
        return amount[_user];
    }
    
    /**
     * @notice Get total purchase amount across all users
     * @return Total purchase amount across the entire network
     */
    function getTotalPurchaseAmount() external view returns (uint256) {
        return totalPurchaseAmount;
    }
    
    /**
     * @notice Query user USDT withdrawal history with pagination
     * @param _user User address
     * @param _offset Offset
     * @param _limit Limit count
     * @return USDT withdrawal record array
     */
    function getUserUsdtWithdrawalHistoryPaginated(address _user, uint256 _offset, uint256 _limit) 
        external view returns (WithdrawalRecord[] memory) {
        if (_limit == 0 || _limit > 100) revert InvalidPageSize();
        
        uint256[] memory recordIds = userUsdtWithdrawalHistory[_user];
        if (_offset > recordIds.length) revert InvalidOffset();
        
        if (_offset == recordIds.length) {
            return new WithdrawalRecord[](0);
        }
        
        uint256 end = _offset + _limit;
        if (end > recordIds.length) {
            end = recordIds.length;
        }
        
        WithdrawalRecord[] memory records = new WithdrawalRecord[](end - _offset);
        for (uint256 i = _offset; i < end; i++) {
            records[i - _offset] = withdrawalUsdtRecords[recordIds[i]];
        }
        
        return records;
    }
    
    /**
     * @notice Query user WBTC withdrawal history with pagination
     * @param _user User address
     * @param _offset Offset
     * @param _limit Limit count
     * @return WBTC withdrawal record array
     */
    function getUserWbtcWithdrawalHistoryPaginated(address _user, uint256 _offset, uint256 _limit) 
        external view returns (WithdrawalRecord[] memory) {
        if (_limit == 0 || _limit > 100) revert InvalidPageSize();
        
        uint256[] memory recordIds = userWbtcWithdrawalHistory[_user];
        if (_offset > recordIds.length) revert InvalidOffset();
        
        if (_offset == recordIds.length) {
            return new WithdrawalRecord[](0);
        }
        
        uint256 end = _offset + _limit;
        if (end > recordIds.length) {
            end = recordIds.length;
        }
        
        WithdrawalRecord[] memory records = new WithdrawalRecord[](end - _offset);
        for (uint256 i = _offset; i < end; i++) {
            records[i - _offset] = withdrawalWbtcRecords[recordIds[i]];
        }
        
        return records;
    }
    
    /**
     * @notice Get total count of user USDT withdrawal history
     * @param _user User address
     * @return Total count of USDT withdrawal records
     */
    function getUserUsdtWithdrawalHistoryCount(address _user) external view returns (uint256) {
        return userUsdtWithdrawalHistory[_user].length;
    }
    
    /**
     * @notice Get total count of user WBTC withdrawal history
     * @param _user User address
     * @return Total count of WBTC withdrawal records
     */
    function getUserWbtcWithdrawalHistoryCount(address _user) external view returns (uint256) {
        return userWbtcWithdrawalHistory[_user].length;
    }
    
    /**
     * @notice Query total USDT withdrawal record count
     * @return Total USDT withdrawal record count
     */
    function getTotalUsdtWithdrawalRecords() external view returns (uint256) {
        return withdrawalUsdtRecords.length;
    }
    
    /**
     * @notice Query total WBTC withdrawal record count
     * @return Total WBTC withdrawal record count
     */
    function getTotalWbtcWithdrawalRecords() external view returns (uint256) {
        return withdrawalWbtcRecords.length;
    }
    
    /**
     * @notice Get user's total USDT withdrawal amount (from stored amount)
     * @param _user User address
     * @return Total USDT withdrawal amount
     */
    function getUserUsdtWithdrawalAmount(address _user) external view returns (uint256) {
        return userUsdtWithdrawalAmount[_user];
    }
    
    /**
     * @notice Get user's total WBTC withdrawal amount (from stored amount)
     * @param _user User address
     * @return Total WBTC withdrawal amount
     */
    function getUserWbtcWithdrawalAmount(address _user) external view returns (uint256) {
        return userWbtcWithdrawalAmount[_user];
    }
    
    /**
     * @notice Get total USDT withdrawal amount across all users (from stored amount)
     * @return Total USDT withdrawal amount
     */
    function getTotalUsdtWithdrawalAmount() external view returns (uint256) {
        return totalUsdtWithdrawalAmount;
    }
    
    /**
     * @notice Get total WBTC withdrawal amount across all users (from stored amount)
     * @return Total WBTC withdrawal amount
     */
    function getTotalWbtcWithdrawalAmount() external view returns (uint256) {
        return totalWbtcWithdrawalAmount;
    }
    
    /**
     * @notice Get multisig wallet address
     * @return Multisig wallet address
     */
    function getMultisigWallet() external view returns (address) {
        return multisigWallet;
    }
    
    /**
     * @notice Emergency pause contract
     */
    function pause() external onlyOwner {
        _pause();
    }
    
    /**
     * @notice Resume contract operation
     */
    function unpause() external onlyOwner {
        _unpause();
    }
    
    /**
     * @notice Emergency withdraw any ERC20 token to owner (admin only)
     * @param _amount Withdrawal amount
     * @param _tokenAddress ERC20 token contract address
     */
    function emergencyWithdraw(uint256 _amount, address _tokenAddress) external onlyOwner {
        if (_amount == 0) revert InvalidAmount();
        if (_tokenAddress == address(0)) revert InvalidAddress();
        
        if (IERC20(_tokenAddress).balanceOf(address(this)) < _amount) revert InsufficientBalance();
        
        IERC20(_tokenAddress).safeTransfer(msg.sender, _amount);
        emit EmergencyWithdraw(msg.sender, _amount);
    }
    
    
    /**
     * @notice Get computing power price with decimals
     * @return Computing power price with decimals
     */
    function getComputingPowerPriceWithDecimals() external pure returns (uint256) {
        return COMPUTING_POWER_PRICE_WITH_DECIMALS;
    }
    
    /**
     * @notice Get minimum purchase amount to become a referrer (computing power units)
     * @return Minimum purchase computing power amount
     */
    function getMinReferrerPurchase() external pure returns (uint256) {
        return MIN_REFERRER_PURCHASE;
    }
    
    /**
     * @notice Get USDT token contract address
     * @return USDT token contract address
     */
    function getUSDTToken() external view returns (address) {
        return usdtToken;
    }
    
    /**
     * @notice Get WBTC token contract address
     * @return WBTC token contract address
     */
    function getWBTCToken() external view returns (address) {
        return wbtcToken;
    }
    
    /**
     * @notice Get finance wallet address
     * @return Finance wallet address
     */
    function getFinanceWallet() external view returns (address) {
        return financeWallet;
    }
    
    /**
     * @notice Get finance wallet information (address, USDT and WBTC balances and allowances)
     * @return Finance wallet information including both USDT and WBTC data
     */
    function getFinanceWalletInfo() external view returns (FinanceWalletInfo memory) {
        if (financeWallet == address(0)) {
            return FinanceWalletInfo({
                wallet: address(0),
                usdtBalance: 0,
                usdtAllowance: 0,
                wbtcBalance: 0,
                wbtcAllowance: 0
            });
        }
        
        return FinanceWalletInfo({
            wallet: financeWallet,
            usdtBalance: IERC20(usdtToken).balanceOf(financeWallet),
            usdtAllowance: IERC20(usdtToken).allowance(financeWallet, address(this)),
            wbtcBalance: IERC20(wbtcToken).balanceOf(financeWallet),
            wbtcAllowance: IERC20(wbtcToken).allowance(financeWallet, address(this))
        });
    }
    
    /**
     * @notice Disabled function - renounceOwnership is not allowed
     * @dev This function is overridden to prevent renouncing ownership
     */
    function renounceOwnership() public pure override {
        revert("Renounce ownership is disabled");
    }    
    
    /**
     * @dev Safe internal referrer binding function, prevents circular binding
     * @param _user User address
     * @param _referrerAddress Referrer address
     */
    function _safeBindReferrer(address _user, address _referrerAddress) internal {
        if (_referrerAddress == address(0)) revert InvalidAddress();
        if (_referrerAddress == _user) revert SelfReferral();
        if (referrer[_user] != address(0)) revert ReferralAlreadyExists();
        
        if (!_isValidDirectReferrer(_referrerAddress)) {
            revert InvalidReferrer();
        }
        
        if (_wouldCreateCircularReferral(_user, _referrerAddress)) {
            revert CircularReferral();
        }
        
        referrer[_user] = _referrerAddress;
        referrals[_referrerAddress].push(_user);
        
        emit ReferralBound(_user, _referrerAddress);
    }
    
    /**
     * @dev Validate referrer relationship
     * @param _user User address
     * @param _referrerAddress Referrer address
     * @return Whether validation passes
     */
    function _validateReferrer(address _user, address _referrerAddress) internal view returns (bool) {
        if (_referrerAddress == address(0)) return false;
        if (_referrerAddress == _user) return false;
        if (referrer[_user] != address(0)) return false;
        
        if (!_isValidDirectReferrer(_referrerAddress)) {
            return false;
        }
        
        if (_wouldCreateCircularReferral(_user, _referrerAddress)) {
            return false;
        }
        
        return true;
    }
    
    /**
     * @dev Check if direct referrer is valid
     * @param _referrerAddress Referrer address
     * @return Whether can be a referrer
     */
    function _isValidDirectReferrer(address _referrerAddress) internal view returns (bool) {
        uint256 minPurchaseAmount = MIN_REFERRER_PURCHASE * COMPUTING_POWER_PRICE_WITH_DECIMALS;
        
        return amount[_referrerAddress] >= minPurchaseAmount;
    }
    
    
    /**
     * @dev Check if would create circular referral relationship
     * @param _user User address
     * @param _referrerAddress Referrer address
     * @return Whether would create circular relationship
     */
    function _wouldCreateCircularReferral(address _user, address _referrerAddress) internal view returns (bool) {
        address current = _referrerAddress;
        
        for (uint256 i = 0; i < 20; i++) {
            if (current == _user) {
                return true;
            }
            if (current == address(0)) {
                break;
            }
            current = referrer[current];
        }
        
        return false;
    }
    
    /**
     * @dev Check if payment ID already exists in withdrawal records for specific token type
     * @param _id Payment ID to check
     * @param _tokenType Token type to check (USDT or WBTC)
     * @return Whether ID already exists for the specified token type
     */
    function _isIdAlreadyUsed(uint256 _id, TokenType _tokenType) internal view returns (bool) {
        if (_tokenType == TokenType.USDT) {
            return usedUsdtIds[_id];
        } else if (_tokenType == TokenType.WBTC) {
            return usedWbtcIds[_id];
        }
        return false;
    }
}