ERC20

{{
  "language": "Solidity",
  "sources": {
    "Usdt.z.sol": {
      "content": "// SPDX-License-Identifier: MIT\r
\r
\r
pragma solidity >=0.6.0 <0.8.0;\r
\r
import "./Context.sol";\r
import "./IERC20.sol";\r
import "./math.sol";\r
\r
/**\r
 * @dev Implementation of the {IERC20} interface.\r
 *\r
 * This implementation is agnostic to the way tokens are created. This means\r
 * that a supply mechanism has to be added in a derived contract using {_mint}.\r
 * For a generic mechanism see {ERC20PresetMinterPauser}.\r
 *\r
 * TIP: For a detailed writeup see our guide\r
 * https://forum.zeppelin.solutions/t/how-to-implement-erc20-supply-mechanisms/226[How\r
 * to implement supply mechanisms].\r
 *\r
 * We have followed general OpenZeppelin guidelines: functions revert instead\r
 * of returning `false` on failure. This behavior is nonetheless conventional\r
 * and does not conflict with the expectations of ERC20 applications.\r
 *\r
 * Additionally, an {Approval} event is emitted on calls to {transferFrom}.\r
 * This allows applications to reconstruct the allowance for all accounts just\r
 * by listening to said events. Other implementations of the EIP may not emit\r
 * these events, as it isn't required by the specification.\r
 *\r
 * Finally, the non-standard {decreaseAllowance} and {increaseAllowance}\r
 * functions have been added to mitigate the well-known issues around setting\r
 * allowances. See {IERC20-approve}.\r
 */\r
contract ERC20 is Context, IERC20 {\r
    using SafeMath for uint256;\r
\r
    mapping (address => uint256) private _balances;\r
\r
    mapping (address => mapping (address => uint256)) private _allowances;\r
\r
    uint256 private _totalSupply;\r
\r
    string private _name;\r
    string private _symbol;\r
    uint8 private _decimals;\r
\r
    /**\r
     * @dev Sets the values for {name} and {symbol}, initializes {decimals} with\r
     * a default value of 18.\r
     *\r
     * To select a different value for {decimals}, use {_setupDecimals}.\r
     *\r
     * All three of these values are immutable: they can only be set once during\r
     * construction.\r
     */\r
    constructor (string memory name_, string memory symbol_) public {\r
        _name = name_;\r
        _symbol = symbol_;\r
        _decimals = 18;\r
    }\r
\r
    /**\r
     * @dev Returns the name of the token.\r
     */\r
    function name() public view virtual returns (string memory) {\r
        return _name;\r
    }\r
\r
    /**\r
     * @dev Returns the symbol of the token, usually a shorter version of the\r
     * name.\r
     */\r
    function symbol() public view virtual returns (string memory) {\r
        return _symbol;\r
    }\r
\r
    /**\r
     * @dev Returns the number of decimals used to get its user representation.\r
     * For example, if `decimals` equals `2`, a balance of `505` tokens should\r
     * be displayed to a user as `5,05` (`505 / 10 ** 2`).\r
     *\r
     * Tokens usually opt for a value of 18, imitating the relationship between\r
     * Ether and Wei. This is the value {ERC20} uses, unless {_setupDecimals} is\r
     * called.\r
     *\r
     * NOTE: This information is only used for _display_ purposes: it in\r
     * no way affects any of the arithmetic of the contract, including\r
     * {IERC20-balanceOf} and {IERC20-transfer}.\r
     */\r
    function decimals() public view virtual returns (uint8) {\r
        return _decimals;\r
    }\r
\r
    /**\r
     * @dev See {IERC20-totalSupply}.\r
     */\r
    function totalSupply() public view virtual override returns (uint256) {\r
        return _totalSupply;\r
    }\r
\r
    /**\r
     * @dev See {IERC20-balanceOf}.\r
     */\r
    function balanceOf(address account) public view virtual override returns (uint256) {\r
        return _balances[account];\r
    }\r
\r
    /**\r
     * @dev See {IERC20-transfer}.\r
     *\r
     * Requirements:\r
     *\r
     * - `recipient` cannot be the zero address.\r
     * - the caller must have a balance of at least `amount`.\r
     */\r
    function transfer(address recipient, uint256 amount) public virtual override returns (bool) {\r
        _transfer(_msgSender(), recipient, amount);\r
        return true;\r
    }\r
\r
    /**\r
     * @dev See {IERC20-allowance}.\r
     */\r
    function allowance(address owner, address spender) public view virtual override returns (uint256) {\r
        return _allowances[owner][spender];\r
    }\r
\r
    /**\r
     * @dev See {IERC20-approve}.\r
     *\r
     * Requirements:\r
     *\r
     * - `spender` cannot be the zero address.\r
     */\r
    function approve(address spender, uint256 amount) public virtual override returns (bool) {\r
        _approve(_msgSender(), spender, amount);\r
        return true;\r
    }\r
\r
    /**\r
     * @dev See {IERC20-transferFrom}.\r
     *\r
     * Emits an {Approval} event indicating the updated allowance. This is not\r
     * required by the EIP. See the note at the beginning of {ERC20}.\r
     *\r
     * Requirements:\r
     *\r
     * - `sender` and `recipient` cannot be the zero address.\r
     * - `sender` must have a balance of at least `amount`.\r
     * - the caller must have allowance for ``sender``'s tokens of at least\r
     * `amount`.\r
     */\r
    function transferFrom(address sender, address recipient, uint256 amount) public virtual override returns (bool) {\r
        _transfer(sender, recipient, amount);\r
        _approve(sender, _msgSender(), _allowances[sender][_msgSender()].sub(amount, "ERC20: transfer amount exceeds allowance"));\r
        return true;\r
    }\r
\r
    /**\r
     * @dev Atomically increases the allowance granted to `spender` by the caller.\r
     *\r
     * This is an alternative to {approve} that can be used as a mitigation for\r
     * problems described in {IERC20-approve}.\r
     *\r
     * Emits an {Approval} event indicating the updated allowance.\r
     *\r
     * Requirements:\r
     *\r
     * - `spender` cannot be the zero address.\r
     */\r
    function increaseAllowance(address spender, uint256 addedValue) public virtual returns (bool) {\r
        _approve(_msgSender(), spender, _allowances[_msgSender()][spender].add(addedValue));\r
        return true;\r
    }\r
\r
    /**\r
     * @dev Atomically decreases the allowance granted to `spender` by the caller.\r
     *\r
     * This is an alternative to {approve} that can be used as a mitigation for\r
     * problems described in {IERC20-approve}.\r
     *\r
     * Emits an {Approval} event indicating the updated allowance.\r
     *\r
     * Requirements:\r
     *\r
     * - `spender` cannot be the zero address.\r
     * - `spender` must have allowance for the caller of at least\r
     * `subtractedValue`.\r
     */\r
    function decreaseAllowance(address spender, uint256 subtractedValue) public virtual returns (bool) {\r
        _approve(_msgSender(), spender, _allowances[_msgSender()][spender].sub(subtractedValue, "ERC20: decreased allowance below zero"));\r
        return true;\r
    }\r
\r
    /**\r
     * @dev Moves tokens `amount` from `sender` to `recipient`.\r
     *\r
     * This is internal function is equivalent to {transfer}, and can be used to\r
     * e.g. implement automatic token fees, slashing mechanisms, etc.\r
     *\r
     * Emits a {Transfer} event.\r
     *\r
     * Requirements:\r
     *\r
     * - `sender` cannot be the zero address.\r
     * - `recipient` cannot be the zero address.\r
     * - `sender` must have a balance of at least `amount`.\r
     */\r
    function _transfer(address sender, address recipient, uint256 amount) internal virtual {\r
        require(sender != address(0), "ERC20: transfer from the zero address");\r
        require(recipient != address(0), "ERC20: transfer to the zero address");\r
\r
        _beforeTokenTransfer(sender, recipient, amount);\r
\r
        _balances[sender] = _balances[sender].sub(amount, "ERC20: transfer amount exceeds balance");\r
        _balances[recipient] = _balances[recipient].add(amount);\r
        emit Transfer(sender, recipient, amount);\r
    }\r
\r
    /** @dev Creates `amount` tokens and assigns them to `account`, increasing\r
     * the total supply.\r
     *\r
     * Emits a {Transfer} event with `from` set to the zero address.\r
     *\r
     * Requirements:\r
     *\r
     * - `to` cannot be the zero address.\r
     */\r
    function _mint(address account, uint256 amount) internal virtual {\r
        require(account != address(0), "ERC20: mint to the zero address");\r
\r
        _beforeTokenTransfer(address(0), account, amount);\r
\r
        _totalSupply = _totalSupply.add(amount);\r
        _balances[account] = _balances[account].add(amount);\r
        emit Transfer(address(0), account, amount);\r
    }\r
\r
    /**\r
     * @dev Destroys `amount` tokens from `account`, reducing the\r
     * total supply.\r
     *\r
     * Emits a {Transfer} event with `to` set to the zero address.\r
     *\r
     * Requirements:\r
     *\r
     * - `account` cannot be the zero address.\r
     * - `account` must have at least `amount` tokens.\r
     */\r
    function _burn(address account, uint256 amount) internal virtual {\r
        require(account != address(0), "ERC20: burn from the zero address");\r
\r
        _beforeTokenTransfer(account, address(0), amount);\r
\r
        _balances[account] = _balances[account].sub(amount, "ERC20: burn amount exceeds balance");\r
        _totalSupply = _totalSupply.sub(amount);\r
        emit Transfer(account, address(0), amount);\r
    }\r
\r
    /**\r
     * @dev Sets `amount` as the allowance of `spender` over the `owner` s tokens.\r
     *\r
     * This internal function is equivalent to `approve`, and can be used to\r
     * e.g. set automatic allowances for certain subsystems, etc.\r
     *\r
     * Emits an {Approval} event.\r
     *\r
     * Requirements:\r
     *\r
     * - `owner` cannot be the zero address.\r
     * - `spender` cannot be the zero address.\r
     */\r
    function _approve(address owner, address spender, uint256 amount) internal virtual {\r
        require(owner != address(0), "ERC20: approve from the zero address");\r
        require(spender != address(0), "ERC20: approve to the zero address");\r
\r
        _allowances[owner][spender] = amount;\r
        emit Approval(owner, spender, amount);\r
    }\r
\r
    /**\r
     * @dev Sets {decimals} to a value other than the default one of 18.\r
     *\r
     * WARNING: This function should only be called from the constructor. Most\r
     * applications that interact with token contracts will not expect\r
     * {decimals} to ever change, and may work incorrectly if it does.\r
     */\r
    function _setupDecimals(uint8 decimals_) internal virtual {\r
        _decimals = decimals_;\r
    }\r
\r
    /**\r
     * @dev Hook that is called before any transfer of tokens. This includes\r
     * minting and burning.\r
     *\r
     * Calling conditions:\r
     *\r
     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens\r
     * will be to transferred to `to`.\r
     * - when `from` is zero, `amount` tokens will be minted for `to`.\r
     * - when `to` is zero, `amount` of ``from``'s tokens will be burned.\r
     * - `from` and `to` are never both zero.\r
     *\r
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].\r
     */\r
    function _beforeTokenTransfer(address from, address to, uint256 amount) internal virtual { }\r
}"
    },
    "math.sol": {
      "content": "// SPDX-License-Identifier: MIT\r
\r
pragma solidity >=0.6.0 <0.8.0;\r
\r
/**\r
 * @dev Wrappers over Solidity's arithmetic operations with added overflow\r
 * checks.\r
 *\r
 * Arithmetic operations in Solidity wrap on overflow. This can easily result\r
 * in bugs, because programmers usually assume that an overflow raises an\r
 * error, which is the standard behavior in high level programming languages.\r
 * `SafeMath` restores this intuition by reverting the transaction when an\r
 * operation overflows.\r
 *\r
 * Using this library instead of the unchecked operations eliminates an entire\r
 * class of bugs, so it's recommended to use it always.\r
 */\r
library SafeMath {\r
    /**\r
     * @dev Returns the addition of two unsigned integers, with an overflow flag.\r
     *\r
     * _Available since v3.4._\r
     */\r
    function tryAdd(uint256 a, uint256 b) internal pure returns (bool, uint256) {\r
        uint256 c = a + b;\r
        if (c < a) return (false, 0);\r
        return (true, c);\r
    }\r
\r
    /**\r
     * @dev Returns the substraction of two unsigned integers, with an overflow flag.\r
     *\r
     * _Available since v3.4._\r
     */\r
    function trySub(uint256 a, uint256 b) internal pure returns (bool, uint256) {\r
        if (b > a) return (false, 0);\r
        return (true, a - b);\r
    }\r
\r
    /**\r
     * @dev Returns the multiplication of two unsigned integers, with an overflow flag.\r
     *\r
     * _Available since v3.4._\r
     */\r
    function tryMul(uint256 a, uint256 b) internal pure returns (bool, uint256) {\r
        // Gas optimization: this is cheaper than requiring 'a' not being zero, but the\r
        // benefit is lost if 'b' is also tested.\r
        // See: https://github.com/OpenZeppelin/openzeppelin-contracts/pull/522\r
        if (a == 0) return (true, 0);\r
        uint256 c = a * b;\r
        if (c / a != b) return (false, 0);\r
        return (true, c);\r
    }\r
\r
    /**\r
     * @dev Returns the division of two unsigned integers, with a division by zero flag.\r
     *\r
     * _Available since v3.4._\r
     */\r
    function tryDiv(uint256 a, uint256 b) internal pure returns (bool, uint256) {\r
        if (b == 0) return (false, 0);\r
        return (true, a / b);\r
    }\r
\r
    /**\r
     * @dev Returns the remainder of dividing two unsigned integers, with a division by zero flag.\r
     *\r
     * _Available since v3.4._\r
     */\r
    function tryMod(uint256 a, uint256 b) internal pure returns (bool, uint256) {\r
        if (b == 0) return (false, 0);\r
        return (true, a % b);\r
    }\r
\r
    /**\r
     * @dev Returns the addition of two unsigned integers, reverting on\r
     * overflow.\r
     *\r
     * Counterpart to Solidity's `+` operator.\r
     *\r
     * Requirements:\r
     *\r
     * - Addition cannot overflow.\r
     */\r
    function add(uint256 a, uint256 b) internal pure returns (uint256) {\r
        uint256 c = a + b;\r
        require(c >= a, "SafeMath: addition overflow");\r
        return c;\r
    }\r
\r
    /**\r
     * @dev Returns the subtraction of two unsigned integers, reverting on\r
     * overflow (when the result is negative).\r
     *\r
     * Counterpart to Solidity's `-` operator.\r
     *\r
     * Requirements:\r
     *\r
     * - Subtraction cannot overflow.\r
     */\r
    function sub(uint256 a, uint256 b) internal pure returns (uint256) {\r
        require(b <= a, "SafeMath: subtraction overflow");\r
        return a - b;\r
    }\r
\r
    /**\r
     * @dev Returns the multiplication of two unsigned integers, reverting on\r
     * overflow.\r
     *\r
     * Counterpart to Solidity's `*` operator.\r
     *\r
     * Requirements:\r
     *\r
     * - Multiplication cannot overflow.\r
     */\r
    function mul(uint256 a, uint256 b) internal pure returns (uint256) {\r
        if (a == 0) return 0;\r
        uint256 c = a * b;\r
        require(c / a == b, "SafeMath: multiplication overflow");\r
        return c;\r
    }\r
\r
    /**\r
     * @dev Returns the integer division of two unsigned integers, reverting on\r
     * division by zero. The result is rounded towards zero.\r
     *\r
     * Counterpart to Solidity's `/` operator. Note: this function uses a\r
     * `revert` opcode (which leaves remaining gas untouched) while Solidity\r
     * uses an invalid opcode to revert (consuming all remaining gas).\r
     *\r
     * Requirements:\r
     *\r
     * - The divisor cannot be zero.\r
     */\r
    function div(uint256 a, uint256 b) internal pure returns (uint256) {\r
        require(b > 0, "SafeMath: division by zero");\r
        return a / b;\r
    }\r
\r
    /**\r
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),\r
     * reverting when dividing by zero.\r
     *\r
     * Counterpart to Solidity's `%` operator. This function uses a `revert`\r
     * opcode (which leaves remaining gas untouched) while Solidity uses an\r
     * invalid opcode to revert (consuming all remaining gas).\r
     *\r
     * Requirements:\r
     *\r
     * - The divisor cannot be zero.\r
     */\r
    function mod(uint256 a, uint256 b) internal pure returns (uint256) {\r
        require(b > 0, "SafeMath: modulo by zero");\r
        return a % b;\r
    }\r
\r
    /**\r
     * @dev Returns the subtraction of two unsigned integers, reverting with custom message on\r
     * overflow (when the result is negative).\r
     *\r
     * CAUTION: This function is deprecated because it requires allocating memory for the error\r
     * message unnecessarily. For custom revert reasons use {trySub}.\r
     *\r
     * Counterpart to Solidity's `-` operator.\r
     *\r
     * Requirements:\r
     *\r
     * - Subtraction cannot overflow.\r
     */\r
    function sub(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {\r
        require(b <= a, errorMessage);\r
        return a - b;\r
    }\r
\r
    /**\r
     * @dev Returns the integer division of two unsigned integers, reverting with custom message on\r
     * division by zero. The result is rounded towards zero.\r
     *\r
     * CAUTION: This function is deprecated because it requires allocating memory for the error\r
     * message unnecessarily. For custom revert reasons use {tryDiv}.\r
     *\r
     * Counterpart to Solidity's `/` operator. Note: this function uses a\r
     * `revert` opcode (which leaves remaining gas untouched) while Solidity\r
     * uses an invalid opcode to revert (consuming all remaining gas).\r
     *\r
     * Requirements:\r
     *\r
     * - The divisor cannot be zero.\r
     */\r
    function div(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {\r
        require(b > 0, errorMessage);\r
        return a / b;\r
    }\r
\r
    /**\r
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),\r
     * reverting with custom message when dividing by zero.\r
     *\r
     * CAUTION: This function is deprecated because it requires allocating memory for the error\r
     * message unnecessarily. For custom revert reasons use {tryMod}.\r
     *\r
     * Counterpart to Solidity's `%` operator. This function uses a `revert`\r
     * opcode (which leaves remaining gas untouched) while Solidity uses an\r
     * invalid opcode to revert (consuming all remaining gas).\r
     *\r
     * Requirements:\r
     *\r
     * - The divisor cannot be zero.\r
     */\r
    function mod(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {\r
        require(b > 0, errorMessage);\r
        return a % b;\r
    }\r
}"
    },
    "IERC20.sol": {
      "content": "// SPDX-License-Identifier: MIT\r
\r
pragma solidity >=0.6.0 <0.8.0;\r
\r
/**\r
 * @dev Interface of the ERC20 standard as defined in the EIP.\r
 */\r
interface IERC20 {\r
    /**\r
     * @dev Returns the amount of tokens in existence.\r
     */\r
    function totalSupply() external view returns (uint256);\r
\r
    /**\r
     * @dev Returns the amount of tokens owned by `account`.\r
     */\r
    function balanceOf(address account) external view returns (uint256);\r
\r
    /**\r
     * @dev Moves `amount` tokens from the caller's account to `recipient`.\r
     *\r
     * Returns a boolean value indicating whether the operation succeeded.\r
     *\r
     * Emits a {Transfer} event.\r
     */\r
    function transfer(address recipient, uint256 amount) external returns (bool);\r
\r
    /**\r
     * @dev Returns the remaining number of tokens that `spender` will be\r
     * allowed to spend on behalf of `owner` through {transferFrom}. This is\r
     * zero by default.\r
     *\r
     * This value changes when {approve} or {transferFrom} are called.\r
     */\r
    function allowance(address owner, address spender) external view returns (uint256);\r
\r
    /**\r
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.\r
     *\r
     * Returns a boolean value indicating whether the operation succeeded.\r
     *\r
     * IMPORTANT: Beware that changing an allowance with this method brings the risk\r
     * that someone may use both the old and the new allowance by unfortunate\r
     * transaction ordering. One possible solution to mitigate this race\r
     * condition is to first reduce the spender's allowance to 0 and set the\r
     * desired value afterwards:\r
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729\r
     *\r
     * Emits an {Approval} event.\r
     */\r
    function approve(address spender, uint256 amount) external returns (bool);\r
\r
    /**\r
     * @dev Moves `amount` tokens from `sender` to `recipient` using the\r
     * allowance mechanism. `amount` is then deducted from the caller's\r
     * allowance.\r
     *\r
     * Returns a boolean value indicating whether the operation succeeded.\r
     *\r
     * Emits a {Transfer} event.\r
     */\r
    function transferFrom(address sender, address recipient, uint256 amount) external returns (bool);\r
\r
    /**\r
     * @dev Emitted when `value` tokens are moved from one account (`from`) to\r
     * another (`to`).\r
     *\r
     * Note that `value` may be zero.\r
     */\r
    event Transfer(address indexed from, address indexed to, uint256 value);\r
\r
    /**\r
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by\r
     * a call to {approve}. `value` is the new allowance.\r
     */\r
    event Approval(address indexed owner, address indexed spender, uint256 value);\r
}"
    },
    "Context.sol": {
      "content": "// SPDX-License-Identifier: MIT\r
\r
pragma solidity >=0.6.0 <0.8.0;\r
\r
/*\r
 * @dev Provides information about the current execution context, including the\r
 * sender of the transaction and its data. While these are generally available\r
 * via msg.sender and msg.data, they should not be accessed in such a direct\r
 * manner, since when dealing with GSN meta-transactions the account sending and\r
 * paying for execution may not be the actual sender (as far as an application\r
 * is concerned).\r
 *\r
 * This contract is only required for intermediate, library-like contracts.\r
 */\r
abstract contract Context {\r
    function _msgSender() internal view virtual returns (address payable) {\r
        return msg.sender;\r
    }\r
\r
    function _msgData() internal view virtual returns (bytes memory) {\r
        this; // silence state mutability warning without generating bytecode - see https://github.com/ethereum/solidity/issues/2691\r
        return msg.data;\r
    }\r
}"
    }
  },
  "settings": {
    "optimizer": {
      "enabled": false,
      "runs": 200
    },
    "outputSelection": {
      "*": {
        "*": [
          "evm.bytecode",
          "evm.deployedBytecode",
          "devdoc",
          "userdoc",
          "metadata",
          "abi"
        ]
      }
    },
    "remappings": []
  }
}}