SpokeMessageReceiverV2

{{
  "language": "Solidity",
  "sources": {
    "src/contracts/intent/modules/SpokeMessageReceiverV2.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity 0.8.25;

import {OwnableUpgradeable} from '@openzeppelin/contracts-upgradeable/access/OwnableUpgradeable.sol';
import {ERC20} from '@openzeppelin/contracts/token/ERC20/ERC20.sol';

import {AssetUtils} from 'contracts/common/AssetUtils.sol';
import {Constants as Common} from 'contracts/common/Constants.sol';
import {MessageLibV2} from 'contracts/common/MessageLibV2.sol';
import {TypeCasts} from 'contracts/common/TypeCasts.sol';

import {IMessageReceiver} from 'interfaces/common/IMessageReceiver.sol';
import {ISettlementModule} from 'interfaces/common/ISettlementModule.sol';
import {ISpokeGateway} from 'interfaces/intent/ISpokeGateway.sol';

import {SpokeStorageV6} from 'contracts/intent/SpokeStorageV6.sol';

contract SpokeMessageReceiverV2 is SpokeStorageV6, OwnableUpgradeable, IMessageReceiver {
  using TypeCasts for bytes32;

  /**
   * @notice Checks that the function is called by the gateway
   */
  modifier onlyAuthorized() {
    if (msg.sender != owner() && (msg.sender != address(gateway) || paused)) {
      revert EverclearSpoke_Unauthorized();
    }
    _;
  }

  /// @inheritdoc IMessageReceiver
  function receiveMessage(
    bytes memory _message
  ) external onlyAuthorized {
    (MessageLibV2.MessageType _messageType, bytes memory _data) = MessageLibV2.parseMessage(_message);

    if (_messageType == MessageLibV2.MessageType.SETTLEMENT) {
      _handleBatchSettlement(_data);
    } else if (_messageType == MessageLibV2.MessageType.VAR_UPDATE) {
      (bytes32 _updateVariable, bytes memory _updateData) = MessageLibV2.parseVarUpdateMessage(_data);
      _handleVarUpdate(_updateVariable, _updateData);
    } else {
      revert EverclearSpoke_InvalidMessageType();
    }
  }

  /**
   * @notice handle a variable update message
   * @param _updateVariable The hash of the variable being updated
   * @param _updateData The data of the update
   */
  function _handleVarUpdate(
    bytes32 _updateVariable,
    bytes memory _updateData
  ) internal {
    if (_updateVariable == Common.GATEWAY_HASH) {
      address _newGateway = MessageLibV2.parseAddressUpdateMessage(_updateData).toAddress();
      _updateGateway(_newGateway);
    } else if (_updateVariable == Common.MAILBOX_HASH) {
      address _newMailbox = MessageLibV2.parseAddressUpdateMessage(_updateData).toAddress();
      _updateMailbox(_newMailbox);
    } else if (_updateVariable == Common.LIGHTHOUSE_HASH) {
      address _newLighthouse = MessageLibV2.parseAddressUpdateMessage(_updateData).toAddress();
      _updateLighthouse(_newLighthouse);
    } else if (_updateVariable == Common.WATCHTOWER_HASH) {
      address _newWatchtower = MessageLibV2.parseAddressUpdateMessage(_updateData).toAddress();
      _updateWatchtower(_newWatchtower);
    } else {
      revert EverclearSpoke_InvalidVarUpdate();
    }
  }

  /**
   * @notice Handles a batch of settlement messages
   * @param _data The batch of settlement messages
   */
  function _handleBatchSettlement(
    bytes memory _data
  ) internal {
    Settlement[] memory _settlementMessage = MessageLibV2.parseSettlementBatch(_data);
    for (uint256 _i; _i < _settlementMessage.length; _i++) {
      Settlement memory _message = _settlementMessage[_i];
      _handleSettlement(_message);
    }
  }

  /**
   * @notice Handles a settlement message
   * @param _message The settlement message
   */
  function _handleSettlement(
    Settlement memory _message
  ) internal {
    address _asset = _message.asset.toAddress();
    address _recipient = _message.recipient.toAddress();

    IntentStatus _intentStatus = status[_message.intentId];
    // if already settled, ignore (shouldn't happen)
    if (_intentStatus == IntentStatus.SETTLED || _intentStatus == IntentStatus.SETTLED_AND_MANUALLY_EXECUTED) {
      return;
    }
    status[_message.intentId] = IntentStatus.SETTLED;

    uint256 _amount =
      AssetUtils.normalizeDecimals(Common.DEFAULT_NORMALIZED_DECIMALS, ERC20(_asset).decimals(), _message.amount);

    // after decimals normalization, the _amount can be 0 as result of loss of precision, check if it's > 0
    if (_amount > 0) {
      // if amount is > 0 proceed with the settlement according to the strategy
      // fetch strategy for asset
      Strategy _strategy = strategies[_asset];

      if (_strategy == Strategy.DEFAULT) {
        // default strategy
        if (_message.updateVirtualBalance) {
          balances[_message.asset][_message.recipient] += _amount;
        } else {
          // if transfer fails (eg. blacklisted recipient), increase virtual balance instead
          bytes memory _transferData = abi.encodeWithSignature('transfer(address,uint256)', _recipient, _amount);
          (bool _success, bytes memory _res) = _asset.call(_transferData);

          // doing the transfer as a low-level call to avoid reverting the whole batch if the transfer calls revert
          // applying the same checks as `SafeERC20` for the `transfer` as it can't be wrapped in a `try/catch` block
          if (!_success || (_res.length != 0 && !abi.decode(_res, (bool)))) {
            balances[_message.asset][_message.recipient] += _amount;
            emit AssetTransferFailed(_asset, _recipient, _amount);
          }
        }
      } else {
        // dedicated strategy
        ISettlementModule _module = modules[_strategy];
        address _mintRecipient = _message.updateVirtualBalance ? address(this) : _recipient;
        bool _success = _module.handleMintStrategy(_asset, _mintRecipient, _recipient, _amount, '');

        if (_success && _message.updateVirtualBalance) {
          balances[_message.asset][_message.recipient] += _amount;
        } else if (!_success) {
          emit AssetMintFailed(_asset, _recipient, _amount, _strategy);
        }
      }
    }
    emit Settled(_message.intentId, _recipient, _asset, _amount);
  }

  /**
   * @notice Update the gateway
   * @param _newGateway The new gateway address
   */
  function _updateGateway(
    address _newGateway
  ) internal validAddress(_newGateway) {
    address _oldGateway = address(gateway);
    gateway = ISpokeGateway(_newGateway);
    emit GatewayUpdated(_oldGateway, _newGateway);
  }

  /**
   * @notice Update the local mailbox address
   * @param _newMailbox The new mailbox address
   */
  function _updateMailbox(
    address _newMailbox
  ) internal {
    gateway.updateMailbox(_newMailbox);
  }

  /**
   * @notice Update the interchain security module address
   * @param _newSecurityModule The new security module address
   */
  function _updateSecurityModule(
    address _newSecurityModule
  ) internal {
    gateway.updateSecurityModule(_newSecurityModule);
  }

  /**
   * @notice Update the lighthouse address
   * @param _newLighthouse The new lighthouse address
   */
  function _updateLighthouse(
    address _newLighthouse
  ) internal validAddress(_newLighthouse) {
    address _oldLighthouse = lighthouse;
    lighthouse = _newLighthouse;
    emit LighthouseUpdated(_oldLighthouse, _newLighthouse);
  }

  /**
   * @notice Update the watchtower address
   * @param _newWatchtower The new watchtower address
   */
  function _updateWatchtower(
    address _newWatchtower
  ) internal validAddress(_newWatchtower) {
    address _oldWatchtower = watchtower;
    watchtower = _newWatchtower;

    emit WatchtowerUpdated(_oldWatchtower, _newWatchtower);
  }
}
"
    },
    "../../node_modules/@openzeppelin/contracts-upgradeable/access/OwnableUpgradeable.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {ContextUpgradeable} from "../utils/ContextUpgradeable.sol";
import {Initializable} from "../proxy/utils/Initializable.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract OwnableUpgradeable is Initializable, ContextUpgradeable {
    /// @custom:storage-location erc7201:openzeppelin.storage.Ownable
    struct OwnableStorage {
        address _owner;
    }

    // keccak256(abi.encode(uint256(keccak256("openzeppelin.storage.Ownable")) - 1)) & ~bytes32(uint256(0xff))
    bytes32 private constant OwnableStorageLocation = 0x9016d09d72d40fdae2fd8ceac6b6234c7706214fd39c1cd1e609a0528c199300;

    function _getOwnableStorage() private pure returns (OwnableStorage storage $) {
        assembly {
            $.slot := OwnableStorageLocation
        }
    }

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    function __Ownable_init(address initialOwner) internal onlyInitializing {
        __Ownable_init_unchained(initialOwner);
    }

    function __Ownable_init_unchained(address initialOwner) internal onlyInitializing {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        OwnableStorage storage $ = _getOwnableStorage();
        return $._owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        OwnableStorage storage $ = _getOwnableStorage();
        address oldOwner = $._owner;
        $._owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}
"
    },
    "../../node_modules/@openzeppelin/contracts/token/ERC20/ERC20.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/ERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "./IERC20.sol";
import {IERC20Metadata} from "./extensions/IERC20Metadata.sol";
import {Context} from "../../utils/Context.sol";
import {IERC20Errors} from "../../interfaces/draft-IERC6093.sol";

/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.openzeppelin.com/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * The default value of {decimals} is 18. To change this, you should override
 * this function so it returns a different value.
 *
 * We have followed general OpenZeppelin Contracts guidelines: functions revert
 * instead returning `false` on failure. This behavior is nonetheless
 * conventional and does not conflict with the expectations of ERC20
 * applications.
 *
 * Additionally, an {Approval} event is emitted on calls to {transferFrom}.
 * This allows applications to reconstruct the allowance for all accounts just
 * by listening to said events. Other implementations of the EIP may not emit
 * these events, as it isn't required by the specification.
 */
abstract contract ERC20 is Context, IERC20, IERC20Metadata, IERC20Errors {
    mapping(address account => uint256) private _balances;

    mapping(address account => mapping(address spender => uint256)) private _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;

    /**
     * @dev Sets the values for {name} and {symbol}.
     *
     * All two of these values are immutable: they can only be set once during
     * construction.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view virtual returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view virtual returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5.05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the default value returned by this function, unless
     * it's overridden.
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view virtual returns (uint8) {
        return 18;
    }

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view virtual returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(address account) public view virtual returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - the caller must have a balance of at least `value`.
     */
    function transfer(address to, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _transfer(owner, to, value);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(address owner, address spender) public view virtual returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * NOTE: If `value` is the maximum `uint256`, the allowance is not updated on
     * `transferFrom`. This is semantically equivalent to an infinite approval.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, value);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Emits an {Approval} event indicating the updated allowance. This is not
     * required by the EIP. See the note at the beginning of {ERC20}.
     *
     * NOTE: Does not update the allowance if the current allowance
     * is the maximum `uint256`.
     *
     * Requirements:
     *
     * - `from` and `to` cannot be the zero address.
     * - `from` must have a balance of at least `value`.
     * - the caller must have allowance for ``from``'s tokens of at least
     * `value`.
     */
    function transferFrom(address from, address to, uint256 value) public virtual returns (bool) {
        address spender = _msgSender();
        _spendAllowance(from, spender, value);
        _transfer(from, to, value);
        return true;
    }

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to`.
     *
     * This internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _transfer(address from, address to, uint256 value) internal {
        if (from == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        if (to == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(from, to, value);
    }

    /**
     * @dev Transfers a `value` amount of tokens from `from` to `to`, or alternatively mints (or burns) if `from`
     * (or `to`) is the zero address. All customizations to transfers, mints, and burns should be done by overriding
     * this function.
     *
     * Emits a {Transfer} event.
     */
    function _update(address from, address to, uint256 value) internal virtual {
        if (from == address(0)) {
            // Overflow check required: The rest of the code assumes that totalSupply never overflows
            _totalSupply += value;
        } else {
            uint256 fromBalance = _balances[from];
            if (fromBalance < value) {
                revert ERC20InsufficientBalance(from, fromBalance, value);
            }
            unchecked {
                // Overflow not possible: value <= fromBalance <= totalSupply.
                _balances[from] = fromBalance - value;
            }
        }

        if (to == address(0)) {
            unchecked {
                // Overflow not possible: value <= totalSupply or value <= fromBalance <= totalSupply.
                _totalSupply -= value;
            }
        } else {
            unchecked {
                // Overflow not possible: balance + value is at most totalSupply, which we know fits into a uint256.
                _balances[to] += value;
            }
        }

        emit Transfer(from, to, value);
    }

    /**
     * @dev Creates a `value` amount of tokens and assigns them to `account`, by transferring it from address(0).
     * Relies on the `_update` mechanism
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _mint(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(address(0), account, value);
    }

    /**
     * @dev Destroys a `value` amount of tokens from `account`, lowering the total supply.
     * Relies on the `_update` mechanism.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead
     */
    function _burn(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        _update(account, address(0), value);
    }

    /**
     * @dev Sets `value` as the allowance of `spender` over the `owner` s tokens.
     *
     * This internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     *
     * Overrides to this logic should be done to the variant with an additional `bool emitEvent` argument.
     */
    function _approve(address owner, address spender, uint256 value) internal {
        _approve(owner, spender, value, true);
    }

    /**
     * @dev Variant of {_approve} with an optional flag to enable or disable the {Approval} event.
     *
     * By default (when calling {_approve}) the flag is set to true. On the other hand, approval changes made by
     * `_spendAllowance` during the `transferFrom` operation set the flag to false. This saves gas by not emitting any
     * `Approval` event during `transferFrom` operations.
     *
     * Anyone who wishes to continue emitting `Approval` events on the`transferFrom` operation can force the flag to
     * true using the following override:
     * ```
     * function _approve(address owner, address spender, uint256 value, bool) internal virtual override {
     *     super._approve(owner, spender, value, true);
     * }
     * ```
     *
     * Requirements are the same as {_approve}.
     */
    function _approve(address owner, address spender, uint256 value, bool emitEvent) internal virtual {
        if (owner == address(0)) {
            revert ERC20InvalidApprover(address(0));
        }
        if (spender == address(0)) {
            revert ERC20InvalidSpender(address(0));
        }
        _allowances[owner][spender] = value;
        if (emitEvent) {
            emit Approval(owner, spender, value);
        }
    }

    /**
     * @dev Updates `owner` s allowance for `spender` based on spent `value`.
     *
     * Does not update the allowance value in case of infinite allowance.
     * Revert if not enough allowance is available.
     *
     * Does not emit an {Approval} event.
     */
    function _spendAllowance(address owner, address spender, uint256 value) internal virtual {
        uint256 currentAllowance = allowance(owner, spender);
        if (currentAllowance != type(uint256).max) {
            if (currentAllowance < value) {
                revert ERC20InsufficientAllowance(spender, currentAllowance, value);
            }
            unchecked {
                _approve(owner, spender, currentAllowance - value, false);
            }
        }
    }
}
"
    },
    "src/contracts/common/AssetUtils.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity 0.8.25;

/**
 * @title AssetUtils
 * @notice Library for asset utility functions
 */
library AssetUtils {
  /**
   * @notice This function translates the _amount in _in decimals
   * to _out decimals
   *
   * @param _in The decimals of the asset in / amount in
   * @param _out The decimals of the target asset
   * @param _amount The value to normalize to the `_out` decimals
   * @return _normalized Normalized decimals.
   */
  function normalizeDecimals(
    uint8 _in,
    uint8 _out,
    uint256 _amount
  ) internal pure returns (uint256 _normalized) {
    if (_in == _out) {
      return _amount;
    }
    // Convert this value to the same decimals as _out
    if (_in < _out) {
      _normalized = _amount * (10 ** (_out - _in));
    } else {
      _normalized = _amount / (10 ** (_in - _out));
    }
  }

  /**
   * @notice Get the hash of an asset
   * @param _asset The address of the asset
   * @param _domain The domain of the asset
   * @return _assetHash The hash of the asset
   */
  function getAssetHash(
    bytes32 _asset,
    uint32 _domain
  ) internal pure returns (bytes32 _assetHash) {
    return keccak256(abi.encode(_asset, _domain));
  }
}
"
    },
    "src/contracts/common/Constants.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity 0.8.25;

library Constants {
  // Default normalized decimals for tokens
  uint8 public constant DEFAULT_NORMALIZED_DECIMALS = 18;
  // 1/10 of a basis point denominator
  uint24 public constant DBPS_DENOMINATOR = 100_000;

  // Precomputed hashes (reduce gas costs)
  bytes32 public constant GATEWAY_HASH = keccak256(abi.encode('GATEWAY'));
  bytes32 public constant MAILBOX_HASH = keccak256(abi.encode('MAILBOX'));
  bytes32 public constant LIGHTHOUSE_HASH = keccak256(abi.encode('LIGHTHOUSE'));
  bytes32 public constant WATCHTOWER_HASH = keccak256(abi.encode('WATCHTOWER'));
  bytes32 public constant MAX_FEE_HASH = keccak256(abi.encode('MAX_FEE'));
  bytes32 public constant INTENT_TTL_HASH = keccak256(abi.encode('INTENT_TTL'));

  // Default gas limit for external calls
  uint256 public constant DEFAULT_GAS_LIMIT = 50_000;
  // Maximum calldata size for external calls
  uint256 public constant MAX_CALLDATA_SIZE = 50_000;
}
"
    },
    "src/contracts/common/MessageLibV2.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity 0.8.25;

import {IEverclearV2} from 'interfaces/common/IEverclearV2.sol';

library MessageLibV2 {
  /*//////////////////////////////////////////////////////////////
                            ENUMS
  //////////////////////////////////////////////////////////////*/

  /**
   * @dev Enum for message types
   * INTENT: Intent message type
   * FILL: Fill message type
   * SETTLEMENT: Settlement message type
   * VAR_UPDATE: Variable update message type
   */
  enum MessageType {
    INTENT,
    FILL,
    SETTLEMENT,
    VAR_UPDATE
  }

  /*//////////////////////////////////////////////////////////////
                      GENERAL PURPOSE FUNCTIONS
  //////////////////////////////////////////////////////////////*/

  /**
   * @dev Formats a message with a message type and data
   * @param _messageType The message type
   * @param _data The data to send in the message
   * @return _message The formatted message
   */
  function formatMessage(
    MessageType _messageType,
    bytes memory _data
  ) internal pure returns (bytes memory _message) {
    _message = abi.encode(uint8(_messageType), _data);
  }

  /**
   * @dev Parses a message into its message type and data
   * @param _message The message to parse
   * @return _messageType The message type
   * @return _data The data in the message
   */
  function parseMessage(
    bytes memory _message
  ) internal pure returns (MessageType _messageType, bytes memory _data) {
    uint8 _msgTypeNumber;
    (_msgTypeNumber, _data) = abi.decode(_message, (uint8, bytes));
    _messageType = MessageType(_msgTypeNumber);
  }

  /*//////////////////////////////////////////////////////////////
                        MESSAGE FORMATTING
  //////////////////////////////////////////////////////////////*/

  /**
   * @dev Formats an intent message
   * @param _intents Array of intents
   * @return _message The formatted intent message
   */
  function formatIntentMessageBatch(
    IEverclearV2.Intent[] memory _intents
  ) internal pure returns (bytes memory _message) {
    _message = formatMessage(MessageType.INTENT, abi.encode(_intents));
  }

  /**
   * @dev Formats a fill message
   * @param _fillMessages Array of fill messages
   * @return _message The formatted fill message
   */
  function formatFillMessageBatch(
    IEverclearV2.FillMessage[] memory _fillMessages
  ) internal pure returns (bytes memory _message) {
    _message = formatMessage(MessageType.FILL, abi.encode(_fillMessages));
  }

  /**
   * @dev Formats a settlement message
   * @param _settlementMessages Array of settlement messages
   * @return _message The formatted settlement message
   */
  function formatSettlementBatch(
    IEverclearV2.Settlement[] memory _settlementMessages
  ) internal pure returns (bytes memory _message) {
    _message = formatMessage(MessageType.SETTLEMENT, abi.encode(_settlementMessages));
  }

  /**
   * @dev Formats a var update message
   * @param _data The data (encoded variable)
   * @return _message The formatted var update message
   */
  function formatVarUpdateMessage(
    bytes memory _data
  ) internal pure returns (bytes memory _message) {
    _message = formatMessage(MessageType.VAR_UPDATE, _data);
  }

  /**
   * @dev Formats an address updating message (Mailbox, SecurityModule, Gateway)
   * @param _updateVariable the name of the variable being updated
   * @param _address The new address
   * @return _message The formatted address update message
   */
  function formatAddressUpdateMessage(
    bytes32 _updateVariable,
    bytes32 _address
  ) internal pure returns (bytes memory _message) {
    _message = formatVarUpdateMessage(abi.encode(_updateVariable, abi.encode(_address)));
  }

  /**
   * @dev Formats a uint updating message (MaxRoutersFee)
   * @param _updateVariable the hashed name of the variable being updated
   * @param _value The new value
   * @return _message The formatted uint update message
   */
  function formatUintUpdateMessage(
    bytes32 _updateVariable,
    uint256 _value
  ) internal pure returns (bytes memory _message) {
    _message = formatVarUpdateMessage(abi.encode(_updateVariable, abi.encode(_value)));
  }

  /*//////////////////////////////////////////////////////////////
                          MESSAGE PARSING
  //////////////////////////////////////////////////////////////*/

  /**
   * @dev Parses an intent message
   * @param _data The intent message data
   * @return _intents Array of decoded intents
   */
  function parseIntentMessageBatch(
    bytes memory _data
  ) internal pure returns (IEverclearV2.Intent[] memory _intents) {
    (_intents) = abi.decode(_data, (IEverclearV2.Intent[]));
  }

  /**
   * @dev Parses a fill message
   * @param _data The packed fill message data
   * @return _fillMessages Array of fill messages
   */
  function parseFillMessageBatch(
    bytes memory _data
  ) internal pure returns (IEverclearV2.FillMessage[] memory _fillMessages) {
    (_fillMessages) = abi.decode(_data, (IEverclearV2.FillMessage[]));
  }

  /**
   * @dev Parses a settlement message
   * @param _data The packed settlement message data
   * @return _settlementMessages Array of settlement messages
   */
  function parseSettlementBatch(
    bytes memory _data
  ) internal pure returns (IEverclearV2.Settlement[] memory _settlementMessages) {
    (_settlementMessages) = abi.decode(_data, (IEverclearV2.Settlement[]));
  }

  /**
   * @dev Parses a var update message
   * @param _data The abi encoded variable
   * @return _updateVariable The hashed name of the variable being updated
   * @return _varData The encoded variable data
   */
  function parseVarUpdateMessage(
    bytes memory _data
  ) internal pure returns (bytes32 _updateVariable, bytes memory _varData) {
    (_updateVariable, _varData) = abi.decode(_data, (bytes32, bytes));
  }

  /**
   * @dev Parses an address update message
   * @param _data The abi encoded address
   * @return _address The decoded address
   */
  function parseAddressUpdateMessage(
    bytes memory _data
  ) internal pure returns (bytes32 _address) {
    _address = abi.decode(_data, (bytes32));
  }

  /**
   * @dev Parses a uint update message
   * @param _data The abi encoded uint
   * @return _value The decoded uint
   */
  function parseUintUpdateMessage(
    bytes memory _data
  ) internal pure returns (uint256 _value) {
    _value = abi.decode(_data, (uint256));
  }
}
"
    },
    "src/contracts/common/TypeCasts.sol": {
      "content": "// SPDX-License-Identifier: MIT OR Apache-2.0
pragma solidity 0.8.25;

/**
 * @title TypeCasts
 * @notice Library for type casts
 */
library TypeCasts {
  // alignment preserving cast
  /**
   * @notice Cast an address to a bytes32
   * @param _addr The address to cast
   */
  function toBytes32(
    address _addr
  ) internal pure returns (bytes32) {
    return bytes32(uint256(uint160(_addr)));
  }

  // alignment preserving cast
  /**
   * @notice Cast a bytes32 to an address
   * @param _buf The bytes32 to cast
   */
  function toAddress(
    bytes32 _buf
  ) internal pure returns (address) {
    return address(uint160(uint256(_buf)));
  }
}
"
    },
    "src/interfaces/common/IMessageReceiver.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity 0.8.25;

/**
 * @title IMessageReceiver
 * @notice Interface for the transport layer communication with the message receiver
 */
interface IMessageReceiver {
  /*///////////////////////////////////////////////////////////////
                              LOGIC
  //////////////////////////////////////////////////////////////*/

  /**
   * @notice Receive a message from the transport layer
   * @param _message The message to receive encoded as bytes
   * @dev This function should be called by the the gateway contract
   */
  function receiveMessage(
    bytes calldata _message
  ) external;
}
"
    },
    "src/interfaces/common/ISettlementModule.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity 0.8.25;

/**
 * @title ISettlementModule
 * @notice Interface for the base settlement module
 */
interface ISettlementModule {
  /*///////////////////////////////////////////////////////////////
                              LOGIC
  //////////////////////////////////////////////////////////////*/

  /**
   * @notice Handle a mint action for a specific strategy
   * @param _asset The address of the asset to mint
   * @param _recipient The recipient of the minted assets
   * @param _fallbackRecipient The fallback recipient of the minted assets (in case of failure)
   * @param _amount The amount to mint
   * @param _data Extra data needed by some modules
   * @return _success The outcome of the minting strategy
   * @dev In case of failure, the parent module will handle the operation accordingly
   */
  function handleMintStrategy(
    address _asset,
    address _recipient,
    address _fallbackRecipient,
    uint256 _amount,
    bytes calldata _data
  ) external returns (bool _success);

  /**
   * @notice Handle a burn action for a specific strategy
   * @param _asset The address of the asset to burn
   * @param _user The user whose assets are being burned
   * @param _amount The amount to burn
   * @param _data Extra data needed by some modules
   * @dev In case of failure, the `newIntent` flow will revert
   */
  function handleBurnStrategy(
    address _asset,
    address _user,
    uint256 _amount,
    bytes calldata _data
  ) external;
}
"
    },
    "src/interfaces/intent/ISpokeGateway.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity 0.8.25;

import {IGateway} from 'interfaces/common/IGateway.sol';

/**
 * @title ISpokeGateway
 * @notice Interface for the SpokeGateway contract, sends and receives messages to and from the transport layer
 */
interface ISpokeGateway is IGateway {
  /*///////////////////////////////////////////////////////////////
                              LOGIC
  //////////////////////////////////////////////////////////////*/

  /**
   * @notice Initialize Gateway variables
   * @param _owner The address of the owner
   * @param _mailbox The address of the local mailbox
   * @param _receiver The address of the local message receiver (EverclearSpoke)
   * @param _interchainSecurityModule The address of the chosen interchain security module
   * @param _everclearId The id of the Everclear domain
   * @param _hubGateway The bytes32 representation of the Hub gateway
   * @dev Only called once on initialization
   */
  function initialize(
    address _owner,
    address _mailbox,
    address _receiver,
    address _interchainSecurityModule,
    uint32 _everclearId,
    bytes32 _hubGateway
  ) external;

  /*///////////////////////////////////////////////////////////////
                              VIEWS
  //////////////////////////////////////////////////////////////*/

  /**
   * @notice Returns the Everclear hub chain id
   * @return _hubChainId The Everclear chain id
   */
  function EVERCLEAR_ID() external view returns (uint32 _hubChainId);

  /**
   * @notice Returns the `HubGateway` gateway address
   * @return _hubGateway The `HubGateway` address
   */
  function EVERCLEAR_GATEWAY() external view returns (bytes32 _hubGateway);
}
"
    },
    "src/contracts/intent/SpokeStorageV6.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity 0.8.25;

import {QueueLib} from 'contracts/common/QueueLib.sol';
import {QueueLibV2} from 'contracts/common/QueueLibV2.sol';

import {IPermit2} from 'interfaces/common/IPermit2.sol';

import {ISettlementModule} from 'interfaces/common/ISettlementModule.sol';
import {ICallExecutor} from 'interfaces/intent/ICallExecutor.sol';
import {ISpokeGateway} from 'interfaces/intent/ISpokeGateway.sol';
import {ISpokeStorageV6} from 'interfaces/intent/ISpokeStorageV6.sol';

/**
 * @title SpokeStorage
 * @notice Storage layout and modifiers for the `EverclearSpoke`
 */
abstract contract SpokeStorageV6 is ISpokeStorageV6 {
  /// @inheritdoc ISpokeStorageV6
  bytes32 public constant FILL_INTENT_FOR_SOLVER_TYPEHASH = keccak256(
    'function fillIntentForSolver(bytes32 _domain, address _solver, bytes32 _receiver, Intent calldata _intent, uint256 _nonce, uint256 _amountOut, uint32[] memory _destinations)'
  );

  /// @inheritdoc ISpokeStorageV6
  bytes32 public constant PROCESS_INTENT_QUEUE_VIA_RELAYER_TYPEHASH = keccak256(
    'function processIntentQueueViaRelayer(uint32 _domain, Intent[] memory _intents, address _relayer, uint256 _ttl, uint256 _nonce, uint256 _bufferDBPS)'
  );

  /// @inheritdoc ISpokeStorageV6
  bytes32 public constant PROCESS_FILL_QUEUE_VIA_RELAYER_TYPEHASH = keccak256(
    'function processFillQueueViaRelayer(uint32 _domain, uint32 _amount, address _relayer, uint256 _ttl, uint256 _nonce, uint256 _bufferDBPS)'
  );

  /// @inheritdoc ISpokeStorageV6
  IPermit2 public constant PERMIT2 = IPermit2(0x000000000022D473030F116dDEE9F6B43aC78BA3);

  /// @inheritdoc ISpokeStorageV6
  bytes32 public constant FILL_INTENT_TYPEHASH = keccak256(
    'function fillIntent(bytes32 _domain, address _sender, Intent calldata _intent, uint256 _amountOut, address _receiver, uint32[] memory _destinations)'
  );

  /// @inheritdoc ISpokeStorageV6
  bytes32 public constant BATCH_FILL_INTENT_TYPEHASH = keccak256(
    'function batchFillIntent(bytes32 _domain, address _sender, Intent[] calldata _intents, uint256[] _amountOut, address[] _receivers, uint32[][] memory _destinations)'
  );

  /// @inheritdoc ISpokeStorageV6
  uint32 public EVERCLEAR;

  /// @inheritdoc ISpokeStorageV6
  uint32 public DOMAIN;

  /// @inheritdoc ISpokeStorageV6
  address public lighthouse;

  /// @inheritdoc ISpokeStorageV6
  address public watchtower;

  /// @inheritdoc ISpokeStorageV6
  address public messageReceiver;

  /// @inheritdoc ISpokeStorageV6
  ISpokeGateway public gateway;

  /// @inheritdoc ISpokeStorageV6
  ICallExecutor public callExecutor;

  /// @inheritdoc ISpokeStorageV6
  bool public paused;

  /// @inheritdoc ISpokeStorageV6
  uint64 public nonce;

  /// @inheritdoc ISpokeStorageV6
  uint256 public messageGasLimit;

  /// @inheritdoc ISpokeStorageV6
  mapping(bytes32 _asset => mapping(bytes32 _user => uint256 _amount)) public balances;

  /// @inheritdoc ISpokeStorageV6
  mapping(bytes32 _intentId => IntentStatus status) public status;

  /// @inheritdoc ISpokeStorageV6
  mapping(address _asset => Strategy _strategy) public strategies;

  /// @inheritdoc ISpokeStorageV6
  mapping(Strategy _strategy => ISettlementModule _module) public modules;

  /// @notice The deprecated intent queue with previous Intent struct
  QueueLib.IntentQueue public deprecated_intentQueue;

  /// @notice The deprecated fill queue with previous FillMessage struct
  QueueLib.FillQueue public deprecated_fillQueue;

  /**
   * **********************  FeeAdapter Upgrade  **********************
   */
  address public feeAdapter;

  /**
   * **********************  Swap Upgrade  **********************
   */
  /**
   * @notice The intent queue
   */
  QueueLibV2.IntentQueue public intentQueue;
  /**
   * @notice The fill queue
   */
  QueueLibV2.FillQueue public fillQueue;

  /**
   * @notice Address for the fillSigner
   */
  address public fillSigner;

  /**
   * @notice Checks that the address is valid
   */
  modifier validAddress(
    address _address
  ) {
    if (_address == address(0)) {
      revert EverclearSpoke_ZeroAddress();
    }
    _;
  }

  /**
   * @notice Checks that the local domain is included in the destinations
   * @param _intent The intent to check
   */
  modifier validDestination(
    Intent calldata _intent
  ) {
    // when it's an xcall executable, destinations.length is always 1
    if (_intent.destinations[0] != DOMAIN) {
      revert EverclearSpoke_WrongDestination();
    }
    _;
  }

  /**
   * @notice Checks when processing a queue that the amount is valid for the queue being processed
   * @param _first The first index of the queue
   * @param _last The last index of the queue
   * @param _amount The amount to process
   */
  modifier validQueueAmount(
    uint256 _first,
    uint256 _last,
    uint256 _amount
  ) {
    if (_amount == 0) {
      revert EverclearSpoke_ProcessQueue_ZeroAmount();
    }

    if (_first + _amount - 1 > _last) {
      revert EverclearSpoke_ProcessQueue_InvalidAmount(_first, _last, _amount);
    }

    _;
  }

  /**
   * @notice Checks that the contract is not paused
   */
  modifier whenNotPaused() {
    if (paused) {
      revert EverclearSpoke_Paused();
    }
    _;
  }

  /**
   * @notice Checks that the caller has access to pause the contract
   */
  modifier hasPauseAccess() {
    if (msg.sender != lighthouse && msg.sender != watchtower) {
      revert EverclearSpoke_Pause_NotAuthorized();
    }
    _;
  }

  /**
   * @notice Checks the caller is the fee adapter
   */
  modifier onlyFeeAdapter() {
    if (msg.sender != feeAdapter) {
      revert EverclearSpoke_FeeAdapter_NotAuthorized();
    }
    _;
  }
}
"
    },
    "../../node_modules/@openzeppelin/contracts-upgradeable/utils/ContextUpgradeable.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;
import {Initializable} from "../proxy/utils/Initializable.sol";

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract ContextUpgradeable is Initializable {
    function __Context_init() internal onlyInitializing {
    }

    function __Context_init_unchained() internal onlyInitializing {
    }
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}
"
    },
    "../../node_modules/@openzeppelin/contracts-upgradeable/proxy/utils/Initializable.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (proxy/utils/Initializable.sol)

pragma solidity ^0.8.20;

/**
 * @dev This is a base contract to aid in writing upgradeable contracts, or any kind of contract that will be deployed
 * behind a proxy. Since proxied contracts do not make use of a constructor, it's common to move constructor logic to an
 * external initializer function, usually called `initialize`. It then becomes necessary to protect this initializer
 * function so it can only be called once. The {initializer} modifier provided by this contract will have this effect.
 *
 * The initialization functions use a version number. Once a version number is used, it is consumed and cannot be
 * reused. This mechanism prevents re-execution of each "step" but allows the creation of new initialization steps in
 * case an upgrade adds a module that needs to be initialized.
 *
 * For example:
 *
 * [.hljs-theme-light.nopadding]
 * ```solidity
 * contract MyToken is ERC20Upgradeable {
 *     function initialize() initializer public {
 *         __ERC20_init("MyToken", "MTK");
 *     }
 * }
 *
 * contract MyTokenV2 is MyToken, ERC20PermitUpgradeable {
 *     function initializeV2() reinitializer(2) public {
 *         __ERC20Permit_init("MyToken");
 *     }
 * }
 * ```
 *
 * TIP: To avoid leaving the proxy in an uninitialized state, the initializer function should be called as early as
 * possible by providing the encoded function call as the `_data` argument to {ERC1967Proxy-constructor}.
 *
 * CAUTION: When used with inheritance, manual care must be taken to not invoke a parent initializer twice, or to ensure
 * that all initializers are idempotent. This is not verified automatically as constructors are by Solidity.
 *
 * [CAUTION]
 * ====
 * Avoid leaving a contract uninitialized.
 *
 * An uninitialized contract can be taken over by an attacker. This applies to both a proxy and its implementation
 * contract, which may impact the proxy. To prevent the implementation contract from being used, you should invoke
 * the {_disableInitializers} function in the constructor to automatically lock it when it is deployed:
 *
 * [.hljs-theme-light.nopadding]
 * ```
 * /// @custom:oz-upgrades-unsafe-allow constructor
 * constructor() {
 *     _disableInitializers();
 * }
 * ```
 * ====
 */
abstract contract Initializable {
    /**
     * @dev Storage of the initializable contract.
     *
     * It's implemented on a custom ERC-7201 namespace to reduce the risk of storage collisions
     * when using with upgradeable contracts.
     *
     * @custom:storage-location erc7201:openzeppelin.storage.Initializable
     */
    struct InitializableStorage {
        /**
         * @dev Indicates that the contract has been initialized.
         */
        uint64 _initialized;
        /**
         * @dev Indicates that the contract is in the process of being initialized.
         */
        bool _initializing;
    }

    // keccak256(abi.encode(uint256(keccak256("openzeppelin.storage.Initializable")) - 1)) & ~bytes32(uint256(0xff))
    bytes32 private constant INITIALIZABLE_STORAGE = 0xf0c57e16840df040f15088dc2f81fe391c3923bec73e23a9662efc9c229c6a00;

    /**
     * @dev The contract is already initialized.
     */
    error InvalidInitialization();

    /**
     * @dev The contract is not initializing.
     */
    error NotInitializing();

    /**
     * @dev Triggered when the contract has been initialized or reinitialized.
     */
    event Initialized(uint64 version);

    /**
     * @dev A modifier that defines a protected initializer function that can be invoked at most once. In its scope,
     * `onlyInitializing` functions can be used to initialize parent contracts.
     *
     * Similar to `reinitializer(1)`, except that in the context of a constructor an `initializer` may be invoked any
     * number of times. This behavior in the constructor can be useful during testing and is not expected to be used in
     * production.
     *
     * Emits an {Initialized} event.
     */
    modifier initializer() {
        // solhint-disable-next-line var-name-mixedcase
        InitializableStorage storage $ = _getInitializableStorage();

        // Cache values to avoid duplicated sloads
        bool isTopLevelCall = !$._initializing;
        uint64 initialized = $._initialized;

        // Allowed calls:
        // - initialSetup: the contract is not in the initializing state and no previous version was
        //                 initialized
        // - construction: the contract is initialized at version 1 (no reininitialization) and the
        //                 current contract is just being deployed
        bool initialSetup = initialized == 0 && isTopLevelCall;
        bool construction = initialized == 1 && address(this).code.length == 0;

        if (!initialSetup && !construction) {
            revert InvalidInitialization();
        }
        $._initialized = 1;
        if (isTopLevelCall) {
            $._initializing = true;
        }
        _;
        if (isTopLevelCall) {
            $._initializing = false;
            emit Initialized(1);
        }
    }

    /**
     * @dev A modifier that defines a protected reinitializer function that can be invoked at most once, and only if the
     * contract hasn't been initialized to a greater version before. In its scope, `onlyInitializing` functions can be
     * used to initialize parent contracts.
     *
     * A reinitializer may be used after the original initialization step. This is essential to configure modules that
     * are added through upgrades and that require initialization.
     *
     * When `version` is 1, this modifier is similar to `initializer`, except that functions marked with `reinitializer`
     * cannot be nested. If one is invoked in the context of another, execution will revert.
     *
     * Note that versions can jump in increments greater than 1; this implies that if multiple reinitializers coexist in
     * a contract, executing them in the right order is up to the developer or operator.
     *
     * WARNING: Setting the version to 2**64 - 1 will prevent any future reinitialization.
     *
     * Emits an {Initialized} event.
     */
    modifier reinitializer(uint64 version) {
        // solhint-disable-next-line var-name-mixedcase
        InitializableStorage storage $ = _getInitializableStorage();

        if ($._initializing || $._initialized >= version) {
            revert InvalidInitialization();
        }
        $._initialized = version;
        $._initializing = true;
        _;
        $._initializing = false;
        emit Initialized(version);
    }

    /**
     * @dev Modifier to protect an initialization function so that it can only be invoked by functions with the
     * {initializer} and {reinitializer} modifiers, directly or indirectly.
     */
    modifier onlyInitializing() {
        _checkInitializing();
        _;
    }

    /**
     * @dev Reverts if the contract is not in an initializing state. See {onlyInitializing}.
     */
    function _checkInitializing() internal view virtual {
        if (!_isInitializing()) {
            revert NotInitializing();
        }
    }

    /**
     * @dev Locks the contract, preventing any future reinitialization. This cannot be part of an initializer call.
     * Calling this in the constructor of a contract will prevent that contract from being initialized or reinitialized
     * to any version. It is recommended to use this to lock implementation contracts that are designed to be called
     * through proxies.
     *
     * Emits an {Initialized} event the first time it is successfully executed.
     */
    function _disableInitializers() internal virtual {
        // solhint-disable-next-line var-name-mixedcase
        InitializableStorage storage $ = _getInitializableStorage();

        if ($._initializing) {
            revert InvalidInitialization();
        }
        if ($._initialized != type(uint64).max) {
            $._initialized = type(uint64).max;
            emit Initialized(type(uint64).max);
        }
    }

    /**
     * @dev Returns the highest version that has been initialized. See {reinitializer}.
     */
    function _getInitializedVersion() internal view returns (uint64) {
        return _getInitializableStorage()._initialized;
    }

    /**
     * @dev Returns `true` if the contract is currently initializing. See {onlyInitializing}.
     */
    function _isInitializing() internal view returns (bool) {
        return _getInitializableStorage()._initializing;
    }

    /**
     * @dev Returns a pointer to the storage namespace.
     */
    // solhint-disable-next-line var-name-mixedcase
    function _getInitializableStorage() private pure returns (InitializableStorage storage $) {
        assembly {
            $.slot := INITIALIZABLE_STORAGE
        }
    }
}
"
    },
    "../../node_modules/@openzeppelin/contracts/token/ERC20/IERC20.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}
"
    },
    "../../node_modules/@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC20 standard.
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}
"
    },
    "../../node_modules/@openzeppelin/contracts/utils/Context.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}
"
    },
    "../../node_modules/@openzeppelin/contracts/interfaces/draft-IERC6093.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (interfaces/draft-IERC6093.sol)
pragma solidity ^0.8.20;

/**
 * @dev Standard ERC20 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC20 tokens.
 */
interface IERC20Errors {
    /**
     * @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param balance Current balance for the interacting account.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientBalance(address sender, uint256 balance, uint256 needed);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC20InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC20InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `spender`’s `allowance`. Used in transfers.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     * @param allowance Amount of tokens a `spender` is allowed to operate with.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientAllowance(address spender, uint256 allowance, uint256 needed);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC20InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `spender` to be approved. Used in approvals.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC20InvalidSpender(address spender);
}

/**
 * @dev Standard ERC721 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC721 tokens.
 */
interface IERC721Errors {
    /**
     * @dev Indicates that an address can't be an owner. For example, `address(0)` is a forbidden owner in EIP-20.
     * Used in balance queries.
     * @param owner Address of the current owner of a token.
     */
    error ERC721InvalidOwner(address owner);

    /**
     * @dev Indicates a `tokenId` whose `owner` is the zero address.
     * @param tokenId Identifier number of a token.
     */
    error ERC721NonexistentToken(uint256 tokenId);

    /**
     * @dev Indicates an error related to the ownership over a particular token. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param tokenId Identifier number of a token.
     * @param owner Address of the current owner of a token.
     */
    error ERC721IncorrectOwner(address sender, uint256 tokenId, address owner);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC721InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC721InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `operator`’s approval. Used in transfers.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     * @param tokenId Identifier number of a token.
     */
    error ERC721InsufficientApproval(address operator, uint256 tokenId);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC721InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `operator` to be approved. Used in approvals.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC721InvalidOperator(address operator);
}

/**
 * @dev Standard ERC1155 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC1155 tokens.
 */
interface IERC1155Errors {
    /**
     * @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param balance Current balance for the interacting account.
     * @param needed Minimum amount required to perform a transfer.
     * @param tokenId Identifier number of a token.
     */
    error ERC1155InsufficientBalance(address sender, uint256 balance, uint256 needed, uint256 tokenId);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC1155InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC1155InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `operator`’s approval. Used in transfers.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     * @param owner Address of the current owner of a token.
     */
    error ERC1155MissingApprovalForAll(address operator, address owner);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC1155InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `operator` to be approved. Used in approvals.
     * @param operator Address that may be allowed to operate on tokens without being their owner.