ComradesOTD

{{
  "language": "Solidity",
  "sources": {
    "src/ComradesOTD.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import "@openzeppelin/contracts/utils/ReentrancyGuard.sol";
import "@openzeppelin/contracts/access/Ownable.sol";
import "@openzeppelin/contracts/interfaces/IERC20.sol";

/*
       ██████╗ ██████╗ ███╗   ███╗██████╗  █████╗ ██████╗ ███████╗███████╗
      ██╔════╝██╔═══██╗████╗ ████║██╔══██╗██╔══██╗██╔══██╗██╔════╝██╔════╝
      ██║     ██║   ██║██╔████╔██║██████╔╝███████║██║  ██║█████╗  ███████╗
      ██║     ██║   ██║██║╚██╔╝██║██╔══██╗██╔══██║██║  ██║██╔══╝  ╚════██║
      ╚██████╗╚██████╔╝██║ ╚═╝ ██║██║  ██║██║  ██║██████╔╝███████╗███████║
       ╚═════╝ ╚═════╝ ╚═╝     ╚═╝╚═╝  ╚═╝╚═╝  ╚═╝╚═════╝ ╚══════╝╚══════╝
        ║  ░   ▓░      ║    ░              ▓    ░   ║        ║    ║   ░
        ║      ░            ▓                   ░    ║        ▓        
 ██████╗ ███████╗    ████████╗██╗  ██╗███████╗    ██████╗ ███████╗ █████╗ ██████╗ 
██╔═══██╗██╔════╝    ╚══██╔══╝██║  ██║██╔════╝    ██╔══██╗██╔════╝██╔══██╗██╔══██╗
██║   ██║█████╗  ░      ██║   ███████║█████╗ ║    ██║  ██║█████╗  ███████║██║  ██║
██║▓  ██║██╔══╝   ║     ██║   ██╔══██║██╔══╝      ██║  ██║██╔══╝  ██╔══██║██║  ██║
╚██████╔╝██║     ░      ██║   ██║  ██║███████╗    ██████╔╝███████╗██║  ██║██████╔╝
 ╚═════╝ ╚═╝            ╚═╝   ╚═╝  ╚═╝╚══════╝    ╚═════╝ ╚══════╝╚═╝  ╚═╝╚═════╝ 
  ║  ▓    ░       ░  ║            ║      ░           ░  ║     ▓    ║         ║
  ║           ▓                   ║                      ║        ░      ║   ░
  ░                  ║                 ░                           ▓         ║

                     Ethscriptions - Rise from the grave
 */
contract ComradesOTD is ReentrancyGuard, Ownable {
    
    // Token name
    string private _name = "Comrades of the Dead";

    // Token symbol
    string private _symbol = "COTD";

    // State Values
    bool public paused = true;
    uint private nextTokenId = 1;

    // Address constants
    address payable private locker;
    address[] private teamAddressList;

    // Price constants
    uint constant public MINT_PRICE = 1300000000000000; // 0.0013 ETH

    // Purchase and minting limits
    uint8 constant public PURCHASE_LIMIT = 1;
    uint8 constant public WALLET_MINT_LIMIT = 13; // Max public mints per wallet
    uint8 constant public DEV_TERM = 10; // 1 team token per 10 mints
    uint16 public COTD_LIMIT = 666; // Total Ethscriptions (public + promo + team)

    // Promo budget
    uint16 public PROMO_BUDGET = 66;
    uint16 public LAST_TEAM_MINT = 0;

    // Track public mints per address (both payer and recipient)
    mapping(address => uint8) public mintsByPayer;
    mapping(address => uint8) public mintsByRecipient;

    // Events for Ethscriptions
    event EthscribeCOTD(address minter, address indexed mintTo, uint indexed firstTokenId, uint indexed amount);
    event PauseEvent(address indexed setter, bool indexed status);
    event TeamAddressesSet(address indexed setter, uint listSize);
    event LockerSet(address indexed setter, address indexed locker);

    constructor(
        address _locker,
        address[] memory _teamAddressList,
        address initialOwner)
    Ownable(initialOwner)
    {
        locker = payable(_locker);
        setTeamAddresses(_teamAddressList);
    }

    /**
     * @dev Ethscribe COTD NFTs by paying the specified mint amount.
     * @param mintAmount The number of tokens to Ethscribe.
     * @param mintTo The address to send Ethscriptions to.
     * @param checkLimit Whether to check the purchase limit (false for promo mints).
     */
    function _ethscribe(uint8 mintAmount, address mintTo, bool checkLimit) private {
        require(nextTokenId + mintAmount <= COTD_LIMIT, "No more COTD available!");
        if (checkLimit) {
            require(mintAmount <= PURCHASE_LIMIT, "Purchase limit exceeded!");
            require(mintsByPayer[msg.sender] + mintAmount <= WALLET_MINT_LIMIT, "Payer wallet mint limit exceeded!");
            require(mintsByRecipient[mintTo] + mintAmount <= WALLET_MINT_LIMIT, "Recipient wallet mint limit exceeded!");
        }
        require(mintTo != address(0), "Invalid mint address!");

        // emit purchase event for Ethscriptions
        emit EthscribeCOTD(msg.sender, mintTo, nextTokenId, mintAmount);

        // Update mint counters (only for public mints)
        if (checkLimit) {
            mintsByPayer[msg.sender] += mintAmount;
            mintsByRecipient[mintTo] += mintAmount;
        }

        // increment tokenIds
        nextTokenId = nextTokenId + mintAmount;

        // check if team earned a token
        if(LAST_TEAM_MINT + DEV_TERM <= nextTokenId) {
            _teamShare();
        }
    }

    /**
     * @dev Mint COTD NFTs by paying the mint price.
     * @param mintAmount The number of COTD NFTs to mint.
     * @param mintTo The address to send the tokens to.
     */
    function mintCOTD(uint8 mintAmount, address mintTo) public payable nonReentrant {
        require(paused == false, "Minting is paused!");
        require(nextTokenId + mintAmount <= COTD_LIMIT, "No more COTD available!");
        require(msg.value >= MINT_PRICE * mintAmount, "Insufficient Ether");

        // Transfer Ether to the locker address
        _sendEth(locker, msg.value);

        // mint the tokens
        _ethscribe(mintAmount, mintTo, true);
    }

    /**
     * @dev Promotional minting for the owner.
     * @param mintAmount The number of COTD NFTs to mint.
     * @param mintTo The address to send the tokens to.
     */
    function promoMint(uint8 mintAmount, address mintTo) public onlyOwner {
        require(PROMO_BUDGET >= mintAmount, "Promo budget exhausted");
        
        // Update the promo budget
        PROMO_BUDGET = PROMO_BUDGET - mintAmount;

        _ethscribe(mintAmount, mintTo, false);
    }

    /**
     * @dev Set the locker address for receiving ETH.
     */
    function setLocker(address newLocker) public onlyOwner {
        locker = payable(newLocker);
        emit LockerSet(msg.sender, locker);
    }

    /**
     * @dev Set team addresses for automatic distribution.
     */
    function setTeamAddresses(address[] memory newAddressList) public onlyOwner {
        require(newAddressList.length > 0, "Team addresses must not be empty!");

        // Clear the old team array
        delete teamAddressList;

        // Update the TeamAddresses array
        for (uint i = 0; i < newAddressList.length; i++) {
            teamAddressList.push(newAddressList[i]);
        }

        // Emit an event to log the change
        emit TeamAddressesSet(msg.sender, newAddressList.length);
    }

    /**
     * @dev Pause minting.
     */
    function pause() public onlyOwner {
        paused = true;
        emit PauseEvent(msg.sender, paused);
    }

    /**
     * @dev Unpause minting.
     */
    function unpause() public onlyOwner {
        paused = false;
        emit PauseEvent(msg.sender, paused);
    }

    // View functions
    function name() public view virtual returns (string memory) {
        return _name;
    }

    function symbol() public view virtual returns (string memory) {
        return _symbol;
    }

    function getPauseStatus() public view virtual returns (bool) {
        return paused;
    }

    function getNextTokenId() public view virtual returns (uint) {
        return nextTokenId;
    }

    function getCOTDRemaining() public view virtual returns (uint) {
        return COTD_LIMIT - (nextTokenId - 1);
    }

    function getTeamAddressList() public view virtual returns (address[] memory) {
        return teamAddressList;
    }

    function getPromoBudget() public view virtual returns (uint16) {
        return PROMO_BUDGET;
    }

    /**
     * @dev Team share allocated as mint occurs.
     */
    function _teamShare() private {
        LAST_TEAM_MINT += DEV_TERM;

        require(LAST_TEAM_MINT <= nextTokenId, "Not team share time!");
        require(nextTokenId <= COTD_LIMIT, "All have been minted!");
        require(teamAddressList.length > 0, "No team addresses set!");

        // mint team token to the next team member in rotation
        uint teamIndex = (LAST_TEAM_MINT / DEV_TERM - 1) % teamAddressList.length;
        emit EthscribeCOTD(address(this), teamAddressList[teamIndex], nextTokenId, 1);
        
        nextTokenId++;

        // check if there are more dev tokens to mint
        if(LAST_TEAM_MINT + DEV_TERM <= nextTokenId) {
            _teamShare();
        }
    }

    /**
     * @dev Internal function to send ETH.
     */
    function _sendEth(address _destination, uint256 _amount) internal {
        (bool sent, ) = _destination.call{value: _amount}("");
        require(sent, "Failed to send Ether");
    }

    /**
     * @dev Withdraw tokens mistakenly sent to this contract.
     */
    function withdrawToken(address _tokenContract, uint256 _amount) external onlyOwner {
        IERC20 tokenContract = IERC20(_tokenContract);
        tokenContract.transfer(locker, _amount);
    }

    /**
     * @dev Withdraw ETH mistakenly sent to this contract.
     */
    function withdrawETH(uint256 _amount) external onlyOwner {
        _sendEth(locker, _amount);
    }
}"
    },
    "lib/openzeppelin-contracts/contracts/utils/ReentrancyGuard.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/ReentrancyGuard.sol)

pragma solidity ^0.8.20;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If EIP-1153 (transient storage) is available on the chain you're deploying at,
 * consider using {ReentrancyGuardTransient} instead.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant NOT_ENTERED = 1;
    uint256 private constant ENTERED = 2;

    uint256 private _status;

    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();

    constructor() {
        _status = NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be NOT_ENTERED
        if (_status == ENTERED) {
            revert ReentrancyGuardReentrantCall();
        }

        // Any calls to nonReentrant after this point will fail
        _status = ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == ENTERED;
    }
}
"
    },
    "lib/openzeppelin-contracts/contracts/access/Ownable.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}
"
    },
    "lib/openzeppelin-contracts/contracts/interfaces/IERC20.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (interfaces/IERC20.sol)

pragma solidity >=0.4.16;

import {IERC20} from "../token/ERC20/IERC20.sol";
"
    },
    "lib/openzeppelin-contracts/contracts/utils/Context.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}
"
    },
    "lib/openzeppelin-contracts/contracts/token/ERC20/IERC20.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (token/ERC20/IERC20.sol)

pragma solidity >=0.4.16;

/**
 * @dev Interface of the ERC-20 standard as defined in the ERC.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}
"
    }
  },
  "settings": {
    "remappings": [
      "@openzeppelin/contracts/=lib/openzeppelin-contracts/contracts/",
      "erc4626-tests/=lib/openzeppelin-contracts/lib/erc4626-tests/",
      "forge-std/=lib/forge-std/src/",
      "halmos-cheatcodes/=lib/openzeppelin-contracts/lib/halmos-cheatcodes/src/",
      "openzeppelin-contracts/=lib/openzeppelin-contracts/"
    ],
    "optimizer": {
      "enabled": false,
      "runs": 200
    },
    "metadata": {
      "useLiteralContent": false,
      "bytecodeHash": "ipfs",
      "appendCBOR": true
    },
    "outputSelection": {
      "*": {
        "*": [
          "evm.bytecode",
          "evm.deployedBytecode",
          "devdoc",
          "userdoc",
          "metadata",
          "abi"
        ]
      }
    },
    "evmVersion": "prague",
    "viaIR": false
  }
}}