FraxNetDepositV2

{{
  "language": "Solidity",
  "sources": {
    "src/FraxNetDepositV2.sol": {
      "content": "// SPDX-License-Identifier: AGPL-3.0-only
pragma solidity ^0.8.21;

// ====================================================================
// |     ______                   _______                             |
// |    / _____________ __  __   / ____(_____  ____ _____  ________   |
// |   / /_  / ___/ __ `| |/_/  / /_  / / __ \/ __ `/ __ \/ ___/ _ \  |
// |  / __/ / /  / /_/ _>  <   / __/ / / / / / /_/ / / / / /__/  __/  |
// | /_/   /_/   \__,_/_/|_|  /_/   /_/_/ /_/\__,_/_/ /_/\___/\___/   |
// |                                                                  |
// ====================================================================
// ======================= FraxNetDeposit =============================
// ====================================================================
// Frax Finance: https://github.com/FraxFinance

import { IERC20 } from "@openzeppelin/contracts/token/ERC20/ERC20.sol";
import { IFrxUSDCustodian } from "src/interfaces/IFrxUSDCustodian.sol";
import { IRemoteHop } from "src/interfaces/IRemoteHop.sol";
import { IFraxNetDepositFactory } from "src/interfaces/IFraxNetDepositFactory.sol";
import { IFrxUSDCustodian } from "src/interfaces/IFrxUSDCustodian.sol";
import { IRWAUSDCRedeemer } from "src/interfaces/IRWAUSDCRedeemer.sol";
import { ITokenMessenger } from "src/interfaces/ITokenMessenger.sol";
import { IL1USDCGateway } from "src/interfaces/IL1USDCGateway.sol";

/**
 * @title FraxNetDeposit
 * @notice Facilitates deposits of USDC to mint frxUSD and send it to a target address
 * across different chains via LayerZero OFT (Omnichain Fungible Token) mechanism
 * @dev This contract serves as an interface between USDC deposits and cross-chain frxUSD transfers
 */
contract FraxNetDepositV2 {
  // ========== Initialization ==========

  /// @notice variable indicating whether the contract was initialized or not
  bool public wasInitialized;

  // ========== Token Addresses ==========

  /// @notice The frxUSD stablecoin token address
  IERC20 public constant frxUSD = IERC20(0xCAcd6fd266aF91b8AeD52aCCc382b4e165586E29);

  /// @notice The USDC stablecoin token address
  IERC20 public constant USDC = IERC20(0xA0b86991c6218b36c1d19D4a2e9Eb0cE3606eB48);

  /// @notice The LayerZero OFT (Omnichain Fungible Token) address for frxUSD
  address public constant oft = 0x566a6442A5A6e9895B9dCA97cC7879D632c6e4B0;

  /// @notice Scroll L1 Bridge Router
  address public constant SCROLL_L1_USDC_BRIDGE = 0xf1AF3b23DE0A5Ca3CAb7261cb0061C0D779A5c7B;

  /// @notice Address of the factory contract that deployed this contract
  /// @dev Used for access control in admin functions
  IFraxNetDepositFactory public immutable factory;

  // ========== Cross-Chain Parameters ==========

  /// @notice The target chain's endpoint ID in the LayerZero network
  uint32 public targetEid;

  /// @notice The recipient address on the target chain (in bytes32 format)
  bytes32 public targetAddress;

  /// @notice The ATA of the associated target Address (in bytes32 format)
  bytes32 public targetUsdcAtaAddress;

  // ========== Custom Errors ==========

  /// @notice Thrown when a non-authorized address attempts a restricted operation
  error Forbidden();

  /// @notice Thrown when there are insufficient token funds for an operation
  error InsufficientBalance();

  /// @notice Thrown when a native token transfer fails
  error TransferFailed();

  /// @notice Thrown when a CCTP Domain does not exist for a given L0 EID
  error CCTPNotConfiguredForThisChain();

  /// @notice Thrown when contract is reinitialized
  error AlreadyInitialized();

  /// @notice Thrown when EID is set to Solana but ATA account not specified
  error AtaAccountNotInitialized();

  /// @notice Thrown when there is not enough USDC to service, even with aggregation
  error SizeTooLarge();

  /// @notice Thrown when factory has paused processing
  error Paused();

  /**
   * @notice Enables the contract to receive ETH
   * @dev Required for handling gas fees for cross-chain operations
   */
  receive() external payable {}

  /**
   * @notice Emitted when a USDC deposit is processed and frxUSD is sent
   * @param targetEid     The LayerZero endpoint ID of the destination chain
   * @param targetAddress The recipient address on the target chain (in bytes32 format)
   * @param amount        The amount of USDC processed
   * @param frxUSDOut     The amount of frxUSD sent
   */
  event ProcessedDeposit(uint32 indexed targetEid, bytes32 indexed targetAddress, uint256 amount, uint256 frxUSDOut);

  /**
   * @notice Emitted when a USDC deposit is processed and frxUSD is sent
   * @param targetEid     The LayerZero endpoint ID of the destination chain
   * @param targetAddress The recipient address on the target chain (in bytes32 format)
   * @param frxUSDIn      The amount of frxUsd redeemed
   * @param usdcOut       The amount of USDC processed
   */
  event ProcessedRedemption(uint32 indexed targetEid, bytes32 indexed targetAddress, uint256 frxUSDIn, uint256 usdcOut);

  /**
   * @notice Initializes the contract with the factory address
   * @param _factory The address of the factory, needed if used for an upgrade
   * @dev The factory address is set to the address that deployed this contract
   */
  constructor(address _factory) {
    factory = IFraxNetDepositFactory(_factory);
    wasInitialized = true;
  }

  /**
   * @notice Sets the target chain ID and recipient address
   * @dev Can only be called by the factory that deployed this contract
   * @param _targetEid     The LayerZero endpoint ID of the destination chain
   * @param _targetAddress The recipient address on the target chain (in bytes32 format)
   */
  function initialize(uint32 _targetEid, bytes32 _targetAddress, bytes32 _targetUsdcAtaAddress) external {
    if (msg.sender != address(factory)) revert Forbidden();
    if (wasInitialized) revert AlreadyInitialized();
    if (_targetEid == 30168 && _targetUsdcAtaAddress == bytes32(0)) revert AtaAccountNotInitialized();
    wasInitialized = true;
    targetEid = _targetEid;
    targetAddress = _targetAddress;
    targetUsdcAtaAddress = _targetUsdcAtaAddress;
  }

  /**
   * @notice Processes USDC deposits, mints frxUSD, and sends it to the target address
   * @dev Requires USDC to be transferred to this contract
   * @param amount The amount of USDC to process
   * @return frxUSDOut The amount of frxUSD minted and sent via this function call
   */
  function processDeposit(uint256 amount) external payable returns (uint256 frxUSDOut) {
    if (factory.isPaused()) revert Paused();

    // Enforce the L0 adapters can handle - soon to be removed
    if (amount > 1_000_000e6) revert SizeTooLarge();

    // Verify sufficient USDC balance
    if (USDC.balanceOf(address(this)) < amount) revert InsufficientBalance();

    // Get the custodian and remote hop contract from the factory
    (IFrxUSDCustodian frxUSDCustodian, IRemoteHop remoteHop) = factory.getCustodianAndHop();

    // Approve and deposit USDC to mint frxUSD
    USDC.approve(address(frxUSDCustodian), amount);
    frxUSDOut = frxUSDCustodian.deposit(amount, address(this));

    // Handle frxUSD transfer based on destination chain
    if (targetEid == 30_101) {
      // Ethereum mainnet
      // Direct transfer if target is on the same chain (Ethereum)
      frxUSD.transfer(address(uint160(uint256(targetAddress))), frxUSDOut);
    } else {
      // Cross-chain transfer for other chains using LayerZero
      frxUSD.approve(address(remoteHop), frxUSDOut);
      remoteHop.sendOFT{ value: msg.value }(oft, targetEid, targetAddress, frxUSDOut);
    }

    // Return unused ETH (for gas) back to the sender
    uint256 balance = address(this).balance;
    if (balance > 0) {
      (bool success, ) = payable(msg.sender).call{ value: balance }("");
      if (!success) revert TransferFailed();
    }

    emit ProcessedDeposit(targetEid, targetAddress, amount, frxUSDOut);
  }

  /**
   * @notice Processes USDC redemptions, this will redeem via USDC custodian if there is sufficient
   *         balance or utilize the USDC custodians redemption amount, and take excess from RFR yielding
   *         backing
   * @dev Requires frxUSD to be transferred to this contract
   * @param amount The amount of frxUSD to redeem for USDC
   * @return usdcOut The amount of USDC sent to the user via this call
   */
  function processRedemption(uint256 amount) external payable returns (uint256 usdcOut) {
    if (factory.isPaused()) revert Paused();

    // Verify sufficient frxUSD balance
    if (frxUSD.balanceOf(address(this)) < amount) revert InsufficientBalance();

    // Read in external variables from fractory
    IRWAUSDCRedeemer rwaRedeemer = factory.rwaRedeemer();
    IFrxUSDCustodian usdcCustodian = factory.frxUSDCustodian();

    // Set the amount we plan on redeeming
    uint256 amountToRedeem = amount;

    // Read in the amount available to redeem
    (, , , uint256 maxRWARedeemable) = IFrxUSDCustodian(rwaRedeemer.frxUSDCustodian()).mdwrComboView();
    (, , , uint256 maxUsdcRedeemable) = usdcCustodian.mdwrComboView();

    // Check to see if the amount requested to be redeemed is able to be serviced
    if (amount > maxRWARedeemable + maxUsdcRedeemable) revert SizeTooLarge();

    // If there is sufficient funds in the USDC Custodian, redeem via that path
    // else redeem partially via the non yielding assets
    if (maxUsdcRedeemable >= amount) {
      frxUSD.approve(address(usdcCustodian), amount);
      usdcOut = usdcCustodian.redeem(amount, address(this), address(this));
      amount = 0;
    } else if (amount > maxUsdcRedeemable && maxUsdcRedeemable > 0) {
      amount -= maxUsdcRedeemable;
      frxUSD.approve(address(usdcCustodian), maxUsdcRedeemable);
      usdcOut = usdcCustodian.redeem(maxUsdcRedeemable, address(this), address(this));
    }

    // If there is excess frxUSD to be redeemed utilize yield bearing reserves
    if (amount > 0) {
      frxUSD.approve(address(rwaRedeemer), amount);
      usdcOut += rwaRedeemer.redeemRWA(amount);
    }

    // Handle USDC transfer based on destination chain
    if (targetEid == 30_101) {
      // Ethereum mainnet
      // Direct transfer if target is on the same chain (Ethereum)
      USDC.transfer(address(uint160(uint256(targetAddress))), usdcOut);
    } else if (targetEid == 30_214) {
      USDC.approve(SCROLL_L1_USDC_BRIDGE, usdcOut);
      IL1USDCGateway(SCROLL_L1_USDC_BRIDGE).depositERC20{ value: msg.value }(
        address(USDC),
        address(uint160(uint256(targetAddress))),
        usdcOut,
        192000
      );
      if (address(this).balance > 0) payable(msg.sender).call{ value: address(this).balance }("");
    } else {
      // Cross chain transfer via CCTPV2
      address cctpTokenMessenger = factory.cctpTokenMessengerV2();
      uint32 cctpDestinationDomain = factory.eidToCCTPDomain(targetEid);
      if (cctpTokenMessenger == address(0) || cctpDestinationDomain == 0) {
        revert CCTPNotConfiguredForThisChain();
      }

      bytes32 recipient = targetAddress;
      // If the target is SOL set USDC ATA as recipient
      if (targetEid == 30168) recipient = targetUsdcAtaAddress;
      if (recipient == bytes32(0)) revert AtaAccountNotInitialized();

      USDC.approve(cctpTokenMessenger, usdcOut);
      ITokenMessenger(cctpTokenMessenger).depositForBurn(
        usdcOut,
        cctpDestinationDomain,
        recipient,
        address(USDC),
        bytes32(0),
        0,
        2000
      );
    }

    emit ProcessedRedemption(targetEid, targetAddress, amountToRedeem, usdcOut);
  }

  /**
   * @notice Estimates the messaging fee for cross-chain transfer
   * @dev Uses the RemoteHop interface to get the fee estimate
   * @param amount The amount of USDC to be transferred
   * @return The estimated messaging fee for the transfer
   */
  function quote(uint256 amount) external view returns (IRemoteHop.MessagingFee memory) {
    (IFrxUSDCustodian frxUSDCustodian, IRemoteHop remoteHop) = factory.getCustodianAndHop();
    uint256 frxUSDAmount = frxUSDCustodian.previewDeposit(amount);
    return remoteHop.quote(oft, targetEid, targetAddress, frxUSDAmount);
  }

  /**
   * @notice Admin function to recover any ERC20 tokens accidentally sent to this contract
   * @dev Can only be called by the factory (contract owner)
   * @param tokenAddress The address of the token to recover
   * @param tokenAmount  The amount of tokens to recover
   * @param recipient    The address to send the recovered tokens to
   */
  function recoverERC20(address tokenAddress, uint256 tokenAmount, address recipient) external {
    if (msg.sender != address(factory)) revert Forbidden();
    IERC20(tokenAddress).transfer(recipient, tokenAmount);
  }

  /**
   * @notice Helper function to convert units in 1e6 to units in 1e18
   * @param amount1e6 The amount in 1e6 to scale up to 1e18
   */
  function scaleUpTo1e18(uint256 amount1e6) public pure returns (uint256) {
    return amount1e6 * 1e12;
  }

  /**
   * @notice Helper function to convert units in 1e18 to units in 1e6
   * @param amount1e18 The amount in 1e18 to scale down to 1e6
   */
  function scaleDownTo1e6(uint256 amount1e18) public pure returns (uint256) {
    return amount1e18 / 1e12;
  }

  /**
   * @notice Helper function to determine the version of the implementation contract
   * @return major The major version of the contract
   * @return minor The minor version of the contract
   * @return patch The patch number of the contract
   */
  function version() public pure returns (uint256 major, uint256 minor, uint256 patch) {
    major = 2;
    minor = 3;
    patch = 1;
  }
}
"
    },
    "node_modules/@openzeppelin/contracts/token/ERC20/ERC20.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (token/ERC20/ERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "./IERC20.sol";
import {IERC20Metadata} from "./extensions/IERC20Metadata.sol";
import {Context} from "../../utils/Context.sol";
import {IERC20Errors} from "../../interfaces/draft-IERC6093.sol";

/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.openzeppelin.com/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * The default value of {decimals} is 18. To change this, you should override
 * this function so it returns a different value.
 *
 * We have followed general OpenZeppelin Contracts guidelines: functions revert
 * instead returning `false` on failure. This behavior is nonetheless
 * conventional and does not conflict with the expectations of ERC-20
 * applications.
 */
abstract contract ERC20 is Context, IERC20, IERC20Metadata, IERC20Errors {
    mapping(address account => uint256) private _balances;

    mapping(address account => mapping(address spender => uint256)) private _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;

    /**
     * @dev Sets the values for {name} and {symbol}.
     *
     * All two of these values are immutable: they can only be set once during
     * construction.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view virtual returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view virtual returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5.05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the default value returned by this function, unless
     * it's overridden.
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view virtual returns (uint8) {
        return 18;
    }

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view virtual returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(address account) public view virtual returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - the caller must have a balance of at least `value`.
     */
    function transfer(address to, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _transfer(owner, to, value);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(address owner, address spender) public view virtual returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * NOTE: If `value` is the maximum `uint256`, the allowance is not updated on
     * `transferFrom`. This is semantically equivalent to an infinite approval.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, value);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Skips emitting an {Approval} event indicating an allowance update. This is not
     * required by the ERC. See {xref-ERC20-_approve-address-address-uint256-bool-}[_approve].
     *
     * NOTE: Does not update the allowance if the current allowance
     * is the maximum `uint256`.
     *
     * Requirements:
     *
     * - `from` and `to` cannot be the zero address.
     * - `from` must have a balance of at least `value`.
     * - the caller must have allowance for ``from``'s tokens of at least
     * `value`.
     */
    function transferFrom(address from, address to, uint256 value) public virtual returns (bool) {
        address spender = _msgSender();
        _spendAllowance(from, spender, value);
        _transfer(from, to, value);
        return true;
    }

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to`.
     *
     * This internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _transfer(address from, address to, uint256 value) internal {
        if (from == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        if (to == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(from, to, value);
    }

    /**
     * @dev Transfers a `value` amount of tokens from `from` to `to`, or alternatively mints (or burns) if `from`
     * (or `to`) is the zero address. All customizations to transfers, mints, and burns should be done by overriding
     * this function.
     *
     * Emits a {Transfer} event.
     */
    function _update(address from, address to, uint256 value) internal virtual {
        if (from == address(0)) {
            // Overflow check required: The rest of the code assumes that totalSupply never overflows
            _totalSupply += value;
        } else {
            uint256 fromBalance = _balances[from];
            if (fromBalance < value) {
                revert ERC20InsufficientBalance(from, fromBalance, value);
            }
            unchecked {
                // Overflow not possible: value <= fromBalance <= totalSupply.
                _balances[from] = fromBalance - value;
            }
        }

        if (to == address(0)) {
            unchecked {
                // Overflow not possible: value <= totalSupply or value <= fromBalance <= totalSupply.
                _totalSupply -= value;
            }
        } else {
            unchecked {
                // Overflow not possible: balance + value is at most totalSupply, which we know fits into a uint256.
                _balances[to] += value;
            }
        }

        emit Transfer(from, to, value);
    }

    /**
     * @dev Creates a `value` amount of tokens and assigns them to `account`, by transferring it from address(0).
     * Relies on the `_update` mechanism
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _mint(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(address(0), account, value);
    }

    /**
     * @dev Destroys a `value` amount of tokens from `account`, lowering the total supply.
     * Relies on the `_update` mechanism.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead
     */
    function _burn(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        _update(account, address(0), value);
    }

    /**
     * @dev Sets `value` as the allowance of `spender` over the `owner` s tokens.
     *
     * This internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     *
     * Overrides to this logic should be done to the variant with an additional `bool emitEvent` argument.
     */
    function _approve(address owner, address spender, uint256 value) internal {
        _approve(owner, spender, value, true);
    }

    /**
     * @dev Variant of {_approve} with an optional flag to enable or disable the {Approval} event.
     *
     * By default (when calling {_approve}) the flag is set to true. On the other hand, approval changes made by
     * `_spendAllowance` during the `transferFrom` operation set the flag to false. This saves gas by not emitting any
     * `Approval` event during `transferFrom` operations.
     *
     * Anyone who wishes to continue emitting `Approval` events on the`transferFrom` operation can force the flag to
     * true using the following override:
     *
     * ```solidity
     * function _approve(address owner, address spender, uint256 value, bool) internal virtual override {
     *     super._approve(owner, spender, value, true);
     * }
     * ```
     *
     * Requirements are the same as {_approve}.
     */
    function _approve(address owner, address spender, uint256 value, bool emitEvent) internal virtual {
        if (owner == address(0)) {
            revert ERC20InvalidApprover(address(0));
        }
        if (spender == address(0)) {
            revert ERC20InvalidSpender(address(0));
        }
        _allowances[owner][spender] = value;
        if (emitEvent) {
            emit Approval(owner, spender, value);
        }
    }

    /**
     * @dev Updates `owner` s allowance for `spender` based on spent `value`.
     *
     * Does not update the allowance value in case of infinite allowance.
     * Revert if not enough allowance is available.
     *
     * Does not emit an {Approval} event.
     */
    function _spendAllowance(address owner, address spender, uint256 value) internal virtual {
        uint256 currentAllowance = allowance(owner, spender);
        if (currentAllowance != type(uint256).max) {
            if (currentAllowance < value) {
                revert ERC20InsufficientAllowance(spender, currentAllowance, value);
            }
            unchecked {
                _approve(owner, spender, currentAllowance - value, false);
            }
        }
    }
}
"
    },
    "src/interfaces/IFrxUSDCustodian.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity >=0.8.0;

interface IFrxUSDCustodian {
  function asset() external view returns (address);
  function previewDeposit(uint256 amount) external view returns (uint256);
  function deposit(uint256 amount, address receiver) external returns (uint256);
  function redeem(uint256 amount, address receiver, address owner) external returns (uint256);
  function redeemFee() external view returns (uint256);
  function previewRedeem(uint256) external view returns (uint256);
  function previewWithdraw(uint256) external view returns (uint256);
  function mdwrComboView()
    external
    view
    returns (
      uint256 _maxAssetsDepositable,
      uint256 _maxSharesMintable,
      uint256 _maxAssetsWithdrawable,
      uint256 _maxSharesRedeemable
    );
}
"
    },
    "src/interfaces/IRemoteHop.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity >=0.8.0;

interface IRemoteHop {
  function sendOFT(address _oft, uint32 _dstEid, bytes32 _to, uint256 _amountLD) external payable;

  function quote(
    address _oft,
    uint32 _dstEid,
    bytes32 _to,
    uint256 _amountLD
  ) external view returns (MessagingFee memory fee);

  struct MessagingFee {
    uint256 nativeFee;
    uint256 lzTokenFee;
  }
}
"
    },
    "src/interfaces/IFraxNetDepositFactory.sol": {
      "content": "// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.4;

import { IRemoteHop } from "src/interfaces/IRemoteHop.sol";
import { IFrxUSDCustodian } from "src/interfaces/IFrxUSDCustodian.sol";
import { IRWAUSDCRedeemer } from "src/interfaces/IRWAUSDCRedeemer.sol";

interface IFraxNetDepositFactory {
  error AtaAccountNotInitialized();
  error Create2Failed();
  error NotOperator();
  error OwnableInvalidOwner(address owner);
  error OwnableUnauthorizedAccount(address account);

  event CCTPTokenMessengerSet(address oldTokenMessenger, address newTokenMessenger);
  event CCTPTokenMessengerV2Set(address oldTokenMessenger, address newTokenMessenger);
  event FraxNetDepositCreated(address indexed newContract, uint32 indexed targetEid, bytes32 indexed targetAddress);
  event FrxUSDCustodianSet(address indexed frxUSDCustodian);
  event IsPaused(bool state);
  event LayerZeroEidToCCTPDomainSet(uint32 l0Eid, uint32 correspondingCctpDomain);
  event OperatorSet(address indexed operator, bool isOp);
  event OwnershipTransferStarted(address indexed previousOwner, address indexed newOwner);
  event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);
  event RemoteHopSet(address indexed remoteHop);
  event RwaRedeemerSet(address oldRwaRedeemer, address newRwaRedeemer);
  event RwaRedemptionThresholdSet(uint256 oldThreshold, uint256 newThreshold);

  function acceptOwnership() external;
  function beaconContract() external view returns (address);
  function cctpTokenMessenger() external view returns (address);
  function cctpTokenMessengerV2() external view returns (address);
  function createFraxNetDeposit(
    uint32 _targetEid,
    bytes32 _targetAddress,
    bytes32 _targetUsdcAtaAddress
  ) external returns (address newContract);
  function eidToCCTPDomain(uint32) external view returns (uint32);
  function fraxNetDepositContracts(uint256) external view returns (address);
  function fraxNetDepositContractsLength() external view returns (uint256);
  function frxUSDCustodian() external view returns (IFrxUSDCustodian);
  function getCustodianAndHop() external view returns (IFrxUSDCustodian frxUSDCustodian_, IRemoteHop remoteHop_);
  function getDeploymentAddress(
    uint32 _targetEid,
    bytes32 _targetAddress,
    bytes32 _targetUsdcAtaAddress
  ) external view returns (address);
  function initialize(
    address _frxUSDCustodian,
    address _remoteHop,
    address _cctpTokenMessenger,
    address _rwaUsdcRedeemer
  ) external;
  function isFraxNetDeposit(address) external view returns (bool);
  function isOperator(address operator) external view returns (bool);
  function isPaused() external view returns (bool);
  function operators(address) external view returns (bool);
  function owner() external view returns (address);
  function pendingOwner() external view returns (address);
  function recoverERC20(
    address tokenAddress,
    uint256 tokenAmount,
    address fraxNetDepositContract,
    address recipient
  ) external;
  function remoteHop() external view returns (address);
  function renounceOwnership() external;
  function rwaRedeemer() external view returns (IRWAUSDCRedeemer);
  function rwaRedemptionThreshold() external view returns (uint256);
  function setCCTPTokenMessenger(address newTokenMessenger) external;
  function setCCTPTokenMessengerV2(address newTokenMessenger) external;
  function setEidToCCTPDomain(uint32 _eid, uint32 _cctpDomain) external;
  function setFrxUSDCustodian(address _frxUSDCustodian) external;
  function setOperator(address operator, bool isOp) external;
  function setPaused(bool state) external;
  function setRemoteHop(address _remoteHop) external;
  function setRwaRedeemer(address newRwaRedeemer) external;
  function setRwaRedemptionThreshold(uint256 newThreshold) external;
  function transferOwnership(address newOwner) external;
  function wasInitialized() external view returns (bool);
}
"
    },
    "src/interfaces/IRWAUSDCRedeemer.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity >=0.8.0;

interface IRWAUSDCRedeemer {
  function redeemRWA(uint256 amount) external returns (uint256);
  function redeem(uint256 amount, uint256 minAmountOut) external returns (uint256);
  function frxUSDCustodian() external view returns (address);
}
"
    },
    "src/interfaces/ITokenMessenger.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity >=0.8.0;

interface ITokenMessenger {
  function depositForBurn(uint256 amount, uint32 destinationDomain, bytes32 mintReceipt, address burnToken) external;
  function depositForBurn(
    uint256 amount,
    uint32 dstDomain,
    bytes32 recipient,
    address burnToken,
    bytes32 dstCaller,
    uint256 fee,
    uint32 minFinality
  ) external;
  function withdrawERC20(address _token, address _to, uint256 _amount, uint256 _gasLimit) external;
}
"
    },
    "src/interfaces/IL1USDCGateway.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity >=0.8.0;

interface IL1USDCGateway {
  function depositERC20(address _token, address _to, uint256 _amount, uint256 _gasLimit) external payable;
}
"
    },
    "node_modules/@openzeppelin/contracts/token/ERC20/IERC20.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC-20 standard as defined in the ERC.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}
"
    },
    "node_modules/@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC-20 standard.
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}
"
    },
    "node_modules/@openzeppelin/contracts/utils/Context.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}
"
    },
    "node_modules/@openzeppelin/contracts/interfaces/draft-IERC6093.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (interfaces/draft-IERC6093.sol)
pragma solidity ^0.8.20;

/**
 * @dev Standard ERC-20 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC-20 tokens.
 */
interface IERC20Errors {
    /**
     * @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param balance Current balance for the interacting account.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientBalance(address sender, uint256 balance, uint256 needed);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC20InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC20InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `spender`’s `allowance`. Used in transfers.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     * @param allowance Amount of tokens a `spender` is allowed to operate with.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientAllowance(address spender, uint256 allowance, uint256 needed);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC20InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `spender` to be approved. Used in approvals.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC20InvalidSpender(address spender);
}

/**
 * @dev Standard ERC-721 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC-721 tokens.
 */
interface IERC721Errors {
    /**
     * @dev Indicates that an address can't be an owner. For example, `address(0)` is a forbidden owner in ERC-20.
     * Used in balance queries.
     * @param owner Address of the current owner of a token.
     */
    error ERC721InvalidOwner(address owner);

    /**
     * @dev Indicates a `tokenId` whose `owner` is the zero address.
     * @param tokenId Identifier number of a token.
     */
    error ERC721NonexistentToken(uint256 tokenId);

    /**
     * @dev Indicates an error related to the ownership over a particular token. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param tokenId Identifier number of a token.
     * @param owner Address of the current owner of a token.
     */
    error ERC721IncorrectOwner(address sender, uint256 tokenId, address owner);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC721InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC721InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `operator`’s approval. Used in transfers.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     * @param tokenId Identifier number of a token.
     */
    error ERC721InsufficientApproval(address operator, uint256 tokenId);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC721InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `operator` to be approved. Used in approvals.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC721InvalidOperator(address operator);
}

/**
 * @dev Standard ERC-1155 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC-1155 tokens.
 */
interface IERC1155Errors {
    /**
     * @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param balance Current balance for the interacting account.
     * @param needed Minimum amount required to perform a transfer.
     * @param tokenId Identifier number of a token.
     */
    error ERC1155InsufficientBalance(address sender, uint256 balance, uint256 needed, uint256 tokenId);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC1155InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC1155InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `operator`’s approval. Used in transfers.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     * @param owner Address of the current owner of a token.
     */
    error ERC1155MissingApprovalForAll(address operator, address owner);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC1155InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `operator` to be approved. Used in approvals.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC1155InvalidOperator(address operator);

    /**
     * @dev Indicates an array length mismatch between ids and values in a safeBatchTransferFrom operation.
     * Used in batch transfers.
     * @param idsLength Length of the array of token identifiers
     * @param valuesLength Length of the array of token amounts
     */
    error ERC1155InvalidArrayLength(uint256 idsLength, uint256 valuesLength);
}
"
    }
  },
  "settings": {
    "remappings": [
      "frax-std/=node_modules/frax-standard-solidity/src/",
      "forge-std/=node_modules/forge-std/src/",
      "ds-test/=node_modules/ds-test/src/",
      "@openzeppelin/=node_modules/@openzeppelin/",
      "@fraxfinance/=node_modules/@fraxfinance/",
      "@layerzerolabs/=node_modules/@layerzerolabs/",
      "@uniswap/=node_modules/@uniswap/",
      "frax-standard-solidity/=node_modules/frax-standard-solidity/",
      "solidity-bytes-utils/=node_modules/solidity-bytes-utils/"
    ],
    "optimizer": {
      "enabled": true,
      "runs": 777777
    },
    "metadata": {
      "useLiteralContent": false,
      "bytecodeHash": "none",
      "appendCBOR": false
    },
    "outputSelection": {
      "*": {
        "*": [
          "evm.bytecode",
          "evm.deployedBytecode",
          "devdoc",
          "userdoc",
          "metadata",
          "abi"
        ]
      }
    },
    "evmVersion": "prague",
    "viaIR": false
  }
}}