UsccDepositStrategy

{{
  "language": "Solidity",
  "sources": {
    "@chainlink/contracts/src/v0.8/shared/interfaces/AggregatorV3Interface.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

// solhint-disable-next-line interface-starts-with-i
interface AggregatorV3Interface {
  function decimals() external view returns (uint8);

  function description() external view returns (string memory);

  function version() external view returns (uint256);

  function getRoundData(
    uint80 _roundId
  ) external view returns (uint80 roundId, int256 answer, uint256 startedAt, uint256 updatedAt, uint80 answeredInRound);

  function latestRoundData()
    external
    view
    returns (uint80 roundId, int256 answer, uint256 startedAt, uint256 updatedAt, uint80 answeredInRound);
}
"
    },
    "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC20 standard.
 *
 * _Available since v4.1._
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}
"
    },
    "@openzeppelin/contracts/token/ERC20/extensions/IERC20Permit.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.4) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 *
 * ==== Security Considerations
 *
 * There are two important considerations concerning the use of `permit`. The first is that a valid permit signature
 * expresses an allowance, and it should not be assumed to convey additional meaning. In particular, it should not be
 * considered as an intention to spend the allowance in any specific way. The second is that because permits have
 * built-in replay protection and can be submitted by anyone, they can be frontrun. A protocol that uses permits should
 * take this into consideration and allow a `permit` call to fail. Combining these two aspects, a pattern that may be
 * generally recommended is:
 *
 * ```solidity
 * function doThingWithPermit(..., uint256 value, uint256 deadline, uint8 v, bytes32 r, bytes32 s) public {
 *     try token.permit(msg.sender, address(this), value, deadline, v, r, s) {} catch {}
 *     doThing(..., value);
 * }
 *
 * function doThing(..., uint256 value) public {
 *     token.safeTransferFrom(msg.sender, address(this), value);
 *     ...
 * }
 * ```
 *
 * Observe that: 1) `msg.sender` is used as the owner, leaving no ambiguity as to the signer intent, and 2) the use of
 * `try/catch` allows the permit to fail and makes the code tolerant to frontrunning. (See also
 * {SafeERC20-safeTransferFrom}).
 *
 * Additionally, note that smart contract wallets (such as Argent or Safe) are not able to produce permit signatures, so
 * contracts should have entry points that don't rely on permit.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     *
     * CAUTION: See Security Considerations above.
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}
"
    },
    "@openzeppelin/contracts/token/ERC20/IERC20.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 amount) external returns (bool);
}
"
    },
    "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.3) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";
import "../extensions/IERC20Permit.sol";
import "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(IERC20 token, address spender, uint256 value) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        require(
            (value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance + value));
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        unchecked {
            uint256 oldAllowance = token.allowance(address(this), spender);
            require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance - value));
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeWithSelector(token.approve.selector, spender, value);

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, 0));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Use a ERC-2612 signature to set the `owner` approval toward `spender` on `token`.
     * Revert on invalid signature.
     */
    function safePermit(
        IERC20Permit token,
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal {
        uint256 nonceBefore = token.nonces(owner);
        token.permit(owner, spender, value, deadline, v, r, s);
        uint256 nonceAfter = token.nonces(owner);
        require(nonceAfter == nonceBefore + 1, "SafeERC20: permit did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        require(returndata.length == 0 || abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return
            success && (returndata.length == 0 || abi.decode(returndata, (bool))) && Address.isContract(address(token));
    }
}
"
    },
    "@openzeppelin/contracts/utils/Address.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     *
     * Furthermore, `isContract` will also return true if the target contract within
     * the same transaction is already scheduled for destruction by `SELFDESTRUCT`,
     * which only has an effect at the end of a transaction.
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.0/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
     * the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
     *
     * _Available since v4.8._
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        if (success) {
            if (returndata.length == 0) {
                // only check isContract if the call was successful and the return data is empty
                // otherwise we already know that it was a contract
                require(isContract(target), "Address: call to non-contract");
            }
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason or using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    function _revert(bytes memory returndata, string memory errorMessage) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert(errorMessage);
        }
    }
}
"
    },
    "contracts/Errors/Errors.sol": {
      "content": "// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.27;

/**
 * @title Errors
 * @author Renzo Protocol
 * @notice This contract defines custom errors used throughout the LiquidVaults protocol
 * @dev All errors are defined as custom errors for gas efficiency
 */

/// @dev Error when Zero Input value
error InvalidZeroInput();

/// @dev Error when caller is not Rebalance admin
error NotRebalanceAdmin();

/// @dev Error when caller is not Exchange rate admin
error NotExchangeRateAdmin();

/// @dev Error when array lengths do not match
error MismatchedArrayLengths();

/// @dev Error when admin tries to execute Non whitelisted strategy
error UnAuthorizedStrategy(address strategy);

/// @dev Error when owner tries to remove non zero underlying delegate strategy
error NonZeroUnderlyingDelegateStrategy();

/// @dev Error when Withdrawal is not claimable
error WithdrawalNotClaimable();

/// @dev Error when caller try to claim invalidWithdrawIndex
error InvalidWithdrawIndex();

/// @dev Error when called is not vault
error NotUnderlyingVault();

/// @dev Error when caller is not Withdraw Queue
error NotWithdrawQueue();

/// @dev Error when caller tries to create already existing vault
error VaultAlreadyCreated();

/// @dev Error when caller is not whitelisted
error NotWhitelisted();

/// @dev Error when fee bps out of range
error InvalidFeeBps();

/// @dev Error when caller does not have pauser role
error NotPauser();

/// @dev Error when eulerswap param is invalid
error InvalidEquilibriumReserve();

/// @dev Error when pool is already installed for the euler account
error PoolAlreadyInstalled();

/// @dev Error when unexpected asset address is passed in
error InvalidAsset();

/// @dev Error when no pool is installed for the euler account when it is expected
error NoPoolInstalled();

/// @dev Error when decimals are invalid
error InvalidDecimals();

/// @dev Error when caller is not owner
error NotOwner();

/// @dev Error when active withdrawal is in progress
error ActiveWithdrawalInProgress();

/// @dev Error when no active withdrawal is in progress
error NoActiveWithdrawalInProgress();

/// @dev Error when active deposit is in progress
error ActiveDepositInProgress();

/// @dev Error when expected amount is invalid
error InvalidExpectedAmount();

/// @dev Error when no active deposit is in progress
error NoActiveDepositInProgress();

/// @dev Error when Oracle Price is invalid
error InvalidOraclePrice();

/// @dev Error when superstate deposit address is already set
error SuperstateAddressAlreadySet();
"
    },
    "contracts/Strategies/interfaces/IDelegateStrategy.sol": {
      "content": "// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.27;

/**
 * @title IDelegateStrategy
 * @author Renzo Protocol
 * @notice Interface that all delegate strategies must implement
 * @dev Delegate strategies are external contracts that manage vault assets in various DeFi protocols
 */
interface IDelegateStrategy {
    /**
     * @notice Returns the value of assets managed by this strategy
     * @dev WARNING: Don't use balanceOf(this) to avoid double counting
     * @param _asset The asset address to query the value for
     * @return The total value of the specified asset managed by this strategy
     */
    function underlyingValue(address _asset) external view returns (uint256);
}
"
    },
    "contracts/Strategies/Superstate/UsccDepositStrategy.sol": {
      "content": "// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.27;

import "../../Errors/Errors.sol";
import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
import "../interfaces/IDelegateStrategy.sol";
import {
    AggregatorV3Interface
} from "@chainlink/contracts/src/v0.8/shared/interfaces/AggregatorV3Interface.sol";
import "./UsccDepositWithdrawalHelper.sol";

/**
 * @author  Renzo Protocol
 * @title   UsccDepositStrategy
 * @dev     Underlying asset is USDC
 * @notice  This contract is used to deposit USDC for USCC and withdraw USCC for USDC
 */
contract UsccDepositStrategy is IDelegateStrategy {
    using SafeERC20 for IERC20;

    IERC20 public immutable usdcToken;
    IERC20 public immutable usccToken;
    AggregatorV3Interface public immutable usccPriceFeed;
    UsccDepositWithdrawalHelper public immutable usccDepositWithdrawalHelper;

    event USCCDepositStarted(uint256 usdcAmount, uint256 expectedUsccAmount);
    event USCCDepositCompleted(uint256 expectedUsccAmount);
    event USCCWithdrawalStarted(uint256 usccAmount, uint256 expectedUsdcAmount);
    event USCCWithdrawalCompleted(uint256 expectedUsdcAmount);

    constructor(
        IERC20 _usdcToken,
        IERC20 _usccToken,
        AggregatorV3Interface _usccPriceFeed,
        address _managedVaultAddress
    ) {
        if (address(_usdcToken) == address(0)) revert InvalidZeroInput();
        if (address(_usccToken) == address(0)) revert InvalidZeroInput();
        if (address(_usccPriceFeed) == address(0)) revert InvalidZeroInput();
        if (_managedVaultAddress == address(0)) revert InvalidZeroInput();

        // Enforce 6 decimals
        if (IERC20Metadata(address(_usdcToken)).decimals() != 6) revert InvalidDecimals();
        if (IERC20Metadata(address(_usccToken)).decimals() != 6) revert InvalidDecimals();
        if (_usccPriceFeed.decimals() != 6) revert InvalidDecimals();

        // Save off vars
        usdcToken = _usdcToken;
        usccToken = _usccToken;
        usccPriceFeed = _usccPriceFeed;

        // Deploy the helper contract
        usccDepositWithdrawalHelper = new UsccDepositWithdrawalHelper(
            _usdcToken,
            _usccToken,
            _managedVaultAddress
        );
    }

    /**
     * @notice  Send USDC via the helper contract to deposit for USCC
     * @dev     .
     * @param   usdcAmount  .
     */
    function startDepositUSDC(uint256 usdcAmount) external {
        // Verify amount is greater than 0
        if (usdcAmount == 0) revert InvalidZeroInput();

        // Verify it is less than the balance of the vault
        if (usdcAmount > usdcToken.balanceOf(address(this))) revert InvalidExpectedAmount();

        // Get the expected uscc amount
        uint256 expectedUsccAmount = getUsccFromUsdcAmount(usdcAmount);

        // Approve the helper to move the usdc amount
        usdcToken.safeApprove(address(usccDepositWithdrawalHelper), usdcAmount);

        // Start the deposit
        usccDepositWithdrawalHelper.startUsdcDeposit(usdcAmount, expectedUsccAmount);

        // Emit the event
        emit USCCDepositStarted(usdcAmount, expectedUsccAmount);
    }

    /**
     * @notice  Complete the outstanding deposit for USCC
     * @dev     .
     */
    function completeUsdcDeposit() external {
        // Cache the expected uscc amount
        uint256 expectedUsccAmount = usccDepositWithdrawalHelper.expectedDepositAmountUscc();

        // Complete the deposit
        usccDepositWithdrawalHelper.completeUsdcDeposit();

        // Emit the event
        emit USCCDepositCompleted(expectedUsccAmount);
    }

    /**
     * @notice  Send USCC via the helper contract to withdraw for USDC
     * @dev     .
     * @param   usccAmount  .
     */
    function startWithdrawUscc(uint256 usccAmount) external {
        // Verify amount is greater than 0
        if (usccAmount == 0) revert InvalidZeroInput();

        // Verify it is less than the balance of the vault
        if (usccAmount > usccToken.balanceOf(address(this))) revert InvalidExpectedAmount();

        // Get the expected usdc amount
        uint256 expectedUsdcAmount = getUsdcFromUsccAmount(usccAmount);

        // Approve the helper to move the uscc amount
        usccToken.safeApprove(address(usccDepositWithdrawalHelper), usccAmount);

        // Start the withdrawal
        usccDepositWithdrawalHelper.startUsccWithdrawal(usccAmount, expectedUsdcAmount);

        // Emit the event
        emit USCCWithdrawalStarted(usccAmount, expectedUsdcAmount);
    }

    /**
     * @notice  Complete the outstanding withdrawal to get USDC
     * @dev     .
     */
    function completeWithdrawUscc() external {
        // Cache the expected usdc amount
        uint256 expectedUsdcAmount = usccDepositWithdrawalHelper.expectedWithdrawalAmountUsdc();

        // Complete the withdrawal
        usccDepositWithdrawalHelper.completeUsccWithdrawal();

        // Emit the event
        emit USCCWithdrawalCompleted(expectedUsdcAmount);
    }

    /**
     * @notice  Update the superstate deposit withdrawal address in the helper contract
     * @dev
     * @param   _superstateDepositWithdrawAddress  new address
     */
    function setSuperstateDepositWithdrawAddress(
        address _superstateDepositAddress,
        address _superstateWithdrawAddress
    ) external {
        if (_superstateDepositAddress == address(0)) revert InvalidZeroInput();
        if (_superstateWithdrawAddress == address(0)) revert InvalidZeroInput();
        usccDepositWithdrawalHelper.setSuperstateDepositWithdrawAddresses(
            _superstateDepositAddress,
            _superstateWithdrawAddress
        );
    }

    /**
     * @notice  Fix the expected amounts in the helper contract
     * @dev     .
     * @param   _expectedWithdrawalAmountUsdc  amount in USDC expected to be withdrawn
     * @param   _expectedDepositAmountUscc  amount in USCC expected from deposit
     */
    function fixExpectedAmounts(
        uint256 _expectedWithdrawalAmountUsdc,
        uint256 _expectedDepositAmountUscc
    ) external {
        if (_expectedWithdrawalAmountUsdc == 0) revert InvalidZeroInput();
        if (_expectedDepositAmountUscc == 0) revert InvalidZeroInput();
        usccDepositWithdrawalHelper.fixExpectedAmounts(
            _expectedWithdrawalAmountUsdc,
            _expectedDepositAmountUscc
        );
    }

    /**
     * @notice  Convert USCC to USDC Value
     * @dev     Oracle is in USDC/USCC price terms
     * @param   usccAmount  Amount of USCC to convert to USDC
     * @return  uint256  USDC value of the USCC
     */
    function getUsdcFromUsccAmount(uint256 usccAmount) public view returns (uint256) {
        // Get the price of usccToken
        (, int256 price, , uint256 updatedAt, ) = usccPriceFeed.latestRoundData();

        // Verify the price is valid
        if (price <= 0) revert InvalidOraclePrice();

        // Verify the updatedAt is not more than 2 days old - this will cause operations to fail on the vault expectedly
        if (block.timestamp - updatedAt > 2 days) revert InvalidOraclePrice();

        // Convert the balance of usccToken to the underlying asset
        return (usccAmount * uint256(price)) / 1e6;
    }

    /**
     * @notice  Convert USDC to USCC Value
     * @dev     Oracle is in USDC/USCC price terms
     * @param   usdcAmount  Amount of USDC to convert to USCC
     * @return  uint256  USCC value of the USDC
     */
    function getUsccFromUsdcAmount(uint256 usdcAmount) public view returns (uint256) {
        // Get the price of usccToken
        (, int256 price, , uint256 updatedAt, ) = usccPriceFeed.latestRoundData();

        // Verify the price is valid
        if (price <= 0) revert InvalidOraclePrice();

        // Verify the updatedAt is not more than 2 days old - this will cause operations to fail on the vault expectedly
        if (block.timestamp - updatedAt > 2 days) revert InvalidOraclePrice();

        // Convert the balance of usccToken to the underlying asset
        return (usdcAmount * 1e6) / uint256(price);
    }

    /**
     * @notice  Returns the value of USCC in the vault in USDC price terms
     * @dev - The managed vault will use balanceOf(this) on the vault for USDC and add it to this return value
     * @param   _asset  Underlying asset should be USDC
     * @return  uint256  USDC value of the USCC in the vault
     */
    function underlyingValue(address _asset) external view returns (uint256) {
        if (_asset != address(usdcToken)) revert InvalidAsset();

        // Get the balance of usccToken in this contract
        uint256 usccBalance = usccToken.balanceOf(address(this));

        // Get the pending uscc from the helper
        uint256 pendingUscc = usccDepositWithdrawalHelper.expectedDepositAmountUscc();

        // Get any pending usdc from the helper
        uint256 pendingUsdc = usccDepositWithdrawalHelper.expectedWithdrawalAmountUsdc();

        return pendingUsdc + getUsdcFromUsccAmount(usccBalance + pendingUscc);
    }
}
"
    },
    "contracts/Strategies/Superstate/UsccDepositWithdrawalHelper.sol": {
      "content": "// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.27;

import { IERC20 } from "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import { IERC20Metadata } from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
import {
    AggregatorV3Interface
} from "@chainlink/contracts/src/v0.8/shared/interfaces/AggregatorV3Interface.sol";
import "../../Errors/Errors.sol";
import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
/**
 * @author  Renzo Protocol
 * @title   UsccDepositWithdrawalHelper
 * @dev     Helper contract for depositing and withdrawing USCC.  The main purpose is to track
 *          the value of in-flight deposits and withdrawals of USCC.
 *          Only one active deposit or one active withdrawal can be in flight at a time.
 *          Expected amounts are just used to ensure a 10% variance in the expected vs actual amounts - mainly to prevent dust attack tricking the accounting.
 *          The vault uses expected amounts to track TVL for in flight deposits and withdrawals.
 *          If the difference between the expected vs actual amount is too large, we want to stop processing and investigate the issue before continuing.
 * @notice  This contract is used to deposit and withdraw USCC from the managed vault to the superstate deposit address.
 */
contract UsccDepositWithdrawalHelper {
    using SafeERC20 for IERC20;

    IERC20 public immutable usdcToken;
    IERC20 public immutable usccToken;
    address public immutable managedVaultAddress;    
    uint256 public expectedWithdrawalAmountUsdc;
    uint256 public expectedDepositAmountUscc;

    // These addresses are set to 0x0 by default.  The vault can update them only once.
    address public superstateDepositAddress = address(0);
    address public superstateWithdrawAddress = address(0);


    event UsccWithdrawalStarted(uint256 usccAmount, uint256 expectedUsdcAmount);
    event UsccWithdrawalCompleted(uint256 expectedUsdcAmount);
    event UsccDepositStarted(uint256 usdcAmount, uint256 expectedUsccAmount);
    event UsccDepositCompleted(uint256 expectedUsccAmount);
    event ExpectedAmountsFixed(
        uint256 expectedWithdrawalAmountUsdc,
        uint256 expectedDepositAmountUscc
    );
    
    event SuperstateDepositAddressUpdated(address superstateDepositAddress);
    event SuperstateWithdrawAddressUpdated(address superstateWithdrawAddress);

    constructor(
        IERC20 _usdcToken,
        IERC20 _usccToken,
        address _managedVaultAddress
    ) {
        if (address(_usdcToken) == address(0)) revert InvalidZeroInput();
        if (address(_usccToken) == address(0)) revert InvalidZeroInput();
        if (_managedVaultAddress == address(0)) revert InvalidZeroInput();

        usdcToken = _usdcToken;
        usccToken = _usccToken;
        managedVaultAddress = _managedVaultAddress;
    }

    modifier onlyManagedVault() {
        if (msg.sender != managedVaultAddress) revert NotOwner();
        _;
    }

    function startUsccWithdrawal(
        uint256 usccAmount,
        uint256 expectedUsdcAmount
    ) external onlyManagedVault {

        // Verify that the superstate withdrawal address is set
        if (superstateWithdrawAddress == address(0)) revert InvalidZeroInput();

        // Verify amount is greater than 0
        if (usccAmount == 0) revert InvalidZeroInput();
        if (expectedUsdcAmount == 0) revert InvalidZeroInput();

        // Verify that there is no active withdrawal pending
        if (expectedWithdrawalAmountUsdc > 0) revert ActiveWithdrawalInProgress();

        // Transfer USCC from the managed vault to the super state deposit withdrawal address
        usccToken.safeTransferFrom(managedVaultAddress, superstateWithdrawAddress, usccAmount);

        // Set the expected withdrawal amount
        expectedWithdrawalAmountUsdc = expectedUsdcAmount;

        // Emit the withdrawal started event
        emit UsccWithdrawalStarted(usccAmount, expectedUsdcAmount);
    }

    function completeUsccWithdrawal() external onlyManagedVault {
        // Verify that there is an active withdrawal pending
        if (expectedWithdrawalAmountUsdc == 0) revert NoActiveWithdrawalInProgress();

        // Verify that the usdc balance on the contract is within +/-10% of the expected withdrawal amount
        uint256 balanceDiffOfExpected = expectedWithdrawalAmountUsdc >
            usdcToken.balanceOf(address(this))
            ? expectedWithdrawalAmountUsdc - usdcToken.balanceOf(address(this))
            : usdcToken.balanceOf(address(this)) - expectedWithdrawalAmountUsdc;
        if (balanceDiffOfExpected > (expectedWithdrawalAmountUsdc * 10) / 100)
            revert InvalidExpectedAmount();

        // Transfer USDC from the this account back to the managed vault
        usdcToken.safeTransfer(managedVaultAddress, usdcToken.balanceOf(address(this)));

        // Emit the withdrawal completed event before resetting the value
        emit UsccWithdrawalCompleted(expectedWithdrawalAmountUsdc);

        // Reset the expected withdrawal amount
        expectedWithdrawalAmountUsdc = 0;
    }

    function startUsdcDeposit(uint256 usdcAmount, uint256 expectedUsccAmount) external onlyManagedVault {
        // Verify that the superstate deposit address is set
        if (superstateDepositAddress == address(0)) revert InvalidZeroInput();

        // Verify amount is greater than 0
        if (usdcAmount == 0) revert InvalidZeroInput();
        if (expectedUsccAmount == 0) revert InvalidZeroInput();

        // Verify that there is no active deposit pending
        if (expectedDepositAmountUscc > 0) revert ActiveDepositInProgress();

        // Transfer USDC from the managed vault to the super state deposit withdrawal address
        usdcToken.safeTransferFrom(
            managedVaultAddress,
            superstateDepositAddress,
            usdcAmount
        );

        // Set the expected deposit amount
        expectedDepositAmountUscc = expectedUsccAmount;

        // Emit the deposit started event
        emit UsccDepositStarted(usdcAmount, expectedUsccAmount);
    }

    function completeUsdcDeposit() external onlyManagedVault {
        // Verify that there is an active deposit pending
        if (expectedDepositAmountUscc == 0) revert NoActiveDepositInProgress();

        // Verify that the uscc balance on the contract is within +/-10% of the expected deposit amount
        uint256 balanceDiffOfExpected = expectedDepositAmountUscc >
            usccToken.balanceOf(address(this))
            ? expectedDepositAmountUscc - usccToken.balanceOf(address(this))
            : usccToken.balanceOf(address(this)) - expectedDepositAmountUscc;
        if (balanceDiffOfExpected > (expectedDepositAmountUscc * 10) / 100)
            revert InvalidExpectedAmount();

        // Transfer USCC from to the managed vault
        usccToken.safeTransfer(managedVaultAddress, usccToken.balanceOf(address(this)));

        // Emit the deposit completed event before resetting the value
        emit UsccDepositCompleted(expectedDepositAmountUscc);

        // Reset the expected deposit amount
        expectedDepositAmountUscc = 0;
    }

    /**
     * @notice  Allows owner to update set superstate address.  This can only be done once.
     * @dev     only managed vault
     * @param   _superstateDepositAddress  .
     * @param   _superstateWithdrawAddress  .
     */
    function setSuperstateDepositWithdrawAddresses(
        address _superstateDepositAddress,
        address _superstateWithdrawAddress
    ) external onlyManagedVault {
        // Verify that the addresses are not already set
        if (superstateDepositAddress != address(0) || superstateWithdrawAddress != address(0)) revert SuperstateAddressAlreadySet();


        if (_superstateDepositAddress == address(0)) revert InvalidZeroInput();
        if (_superstateWithdrawAddress == address(0)) revert InvalidZeroInput();
        superstateDepositAddress = _superstateDepositAddress;
        superstateWithdrawAddress = _superstateWithdrawAddress;

        // Emit the event
        emit SuperstateDepositAddressUpdated(_superstateDepositAddress);
        emit SuperstateWithdrawAddressUpdated(_superstateWithdrawAddress);
    }

    /**
     * @notice  Allows owner to fix the expected amounts if they are incorrect - a large swing could impact price
     * @dev     only managed vault
     * @param   _expectedWithdrawalAmountUsdc  The expected withdrawal amount in USDC - can be zero
     * @param   _expectedDepositAmountUscc  The expected deposit amount in USCC - can be zero
     */
    function fixExpectedAmounts(
        uint256 _expectedWithdrawalAmountUsdc,
        uint256 _expectedDepositAmountUscc
    ) external onlyManagedVault {
        // Set the expected withdrawal amount
        expectedWithdrawalAmountUsdc = _expectedWithdrawalAmountUsdc;
        expectedDepositAmountUscc = _expectedDepositAmountUscc;

        // Emit the event
        emit ExpectedAmountsFixed(_expectedWithdrawalAmountUsdc, _expectedDepositAmountUscc);
    }
}
"
    }
  },
  "settings": {
    "optimizer": {
      "enabled": true,
      "runs": 200
    },
    "evmVersion": "paris",
    "outputSelection": {
      "*": {
        "*": [
          "evm.bytecode",
          "evm.deployedBytecode",
          "devdoc",
          "userdoc",
          "metadata",
          "abi"
        ]
      }
    },
    "metadata": {
      "useLiteralContent": true
    }
  }
}}