Ern

{{
  "language": "Solidity",
  "sources": {
    "contracts/src/Ern.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity ^0.8.25;

import {ERC20} from "@openzeppelin/contracts/token/ERC20/ERC20.sol";
import {Ownable} from "@openzeppelin/contracts/access/Ownable.sol";
import {SafeERC20, IERC20} from "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";

import {IErn} from "@/interfaces/IErn.sol";
import {IDex} from "@/interfaces/IDex.sol";
import {IAavePool} from "@/interfaces/IAavePool.sol";

contract Ern is ERC20, Ownable, IErn {
    using SafeERC20 for IERC20;

    // --- Immutable State ---
    IERC20 public immutable REWARD_TOKEN;
    IAavePool public immutable AAVE_POOL;
    IERC20 public immutable A_UNDERLYING;
    IERC20 public immutable UNDERLYING;
    IDex public immutable DEX;
    uint8 private immutable _decimals;

    // --- Constants ---
    uint256 public constant MAX_HARVEST_FEE_BPS = 1000; // 10% max fee
    uint256 public constant MAX_WITHDRAW_FEE_BPS = 10; // 0.1% max fee

    // --- Mutable State ---
    uint256 public harvestFee = 500; // 5% default fee
    uint256 public withdrawFee = 10; // 0.1% default fee
    uint256 public cumulativeRewardPerShare;
    uint256 public lockPeriod = 48 hours;
    uint256 public hardLockPeriod = 20 seconds;
    uint256 public lastHarvest;
    uint256 public harvestCooldown = 48 hours; // For public harvest
    uint256 public minYieldAmount;
    uint256 public harvestTimePeriod = 24 hours; // Time period for harvest restriction

    mapping(address => bool) private _harvesterSet;

    // --- User Data ---
    mapping(address => UserInfo) public users;

    // --- Errors ---
    error AmountCannotBeZero();
    error HarvestCooldownNotMet();
    error FeeTooHigh();
    error AddressCannotBeZero();
    error TokensAreLocked();
    error NoYieldToClaim();
    error TransferLocked();
    error HarvestConditionsNotMet();
    error MinYieldAmountTooLow();
    error MinYieldAmountTooHigh();
    error HarvestTimePeriodTooShort();
    error HarvestTimePeriodTooLong();
    error InsufficientAllowance();
    error HarvestingNotAllowed();

    constructor(ERC20 _underlying, ERC20 _rewardToken, IAavePool _aavePool, IDex _dex)
        ERC20(
            string.concat(
                "ern ", ERC20(_aavePool.getReserveAToken(address(_underlying))).name(), " to ", _rewardToken.name()
            ),
            // e.g. ern-aUSDC-wBTC
            string.concat(
                "ern-", ERC20(_aavePool.getReserveAToken(address(_underlying))).symbol(), "-", _rewardToken.symbol()
            )
        )
        Ownable(msg.sender)
    {
        UNDERLYING = _underlying;
        AAVE_POOL = _aavePool;
        A_UNDERLYING = ERC20(AAVE_POOL.getReserveAToken(address(UNDERLYING)));
        REWARD_TOKEN = _rewardToken;
        DEX = _dex;
        _decimals = _underlying.decimals();
        minYieldAmount = 50 * 10 ** _decimals; // Set minimum yield to 10 tokens in underlying decimals

        // Approve Aave pool to spend underlying tokens
        UNDERLYING.forceApprove(address(_aavePool), type(uint256).max);
        // Approve DEX to spend underlying tokens for harvest swaps
        UNDERLYING.forceApprove(address(_dex), type(uint256).max);

        lastHarvest = block.timestamp;
        _harvesterSet[msg.sender] = true;
    }

    // --- View Functions ---

    function decimals() public view virtual override returns (uint8) {
        return _decimals;
    }

    function totalAssets() external view returns (uint256) {
        return A_UNDERLYING.balanceOf(address(this));
    }

    function isLocked(address user) external view returns (bool) {
        return _isLocked(user);
    }

    function isHardLocked(address user) external view returns (bool) {
        return _isHardLocked(user);
    }

    function unlockTime(address user) external view returns (uint256) {
        return users[user].depositTimestamp + lockPeriod;
    }

    function claimableYield(address user) external view returns (uint256) {
        return _claimableYield(user);
    }

    function isHarvester(address account) external view returns (bool) {
        return _harvesterSet[account];
    }

    // --- State-Changing Functions ---

    function deposit(uint256 amount) external {
        _requireAmountCannotBeZero(amount);

        // Transfer underlying tokens from user
        UNDERLYING.safeTransferFrom(msg.sender, address(this), amount);

        // Supply to Aave
        AAVE_POOL.supply(address(UNDERLYING), amount, address(this), 0);

        uint256 claimable = _claimableYield(msg.sender);
        if (claimable > 0) {
            // Process yield claim before withdrawal
            // TODO: is it necessary to claim yield upon a new deposit?
            _processYield(msg.sender, claimable);
        } else {
            // Update user rewards before minting shares
            _updateUserRewards(msg.sender);
        }

        // Mint shares 1:1 with deposited amount
        _mint(msg.sender, amount);

        // Set deposit timestamp for lock period
        users[msg.sender].depositTimestamp = block.timestamp;

        emit Deposit(msg.sender, amount);
    }

    function withdraw(uint256 amount) external {
        _requireAmountCannotBeZero(amount);
        _requireTokensNotHardLocked(msg.sender);

        uint256 claimable = _claimableYield(msg.sender);
        if (claimable > 0) {
            // Process yield claim before withdrawal
            _processYield(msg.sender, claimable);
        } else {
            // Update user rewards before burning shares
            _updateUserRewards(msg.sender);
        }

        // Burn shares
        _burn(msg.sender, amount);

        // Calculate withdrawal fee
        (uint256 amountAfterFee, uint256 fee) = _calculateApplicableFee(msg.sender, amount);

        // Withdraw from Aave (amount minus fee, fee stays in Aave pool)
        AAVE_POOL.withdraw(address(UNDERLYING), amountAfterFee, msg.sender);

        if (fee > 0) AAVE_POOL.withdraw(address(UNDERLYING), fee, owner());

        emit Withdraw(msg.sender, amountAfterFee, fee);
    }

    function applicableFee(address user, uint256 amount)
        external
        view
        returns (uint256 amountAfterFee, uint256 feeAmount)
    {
        return _calculateApplicableFee(user, amount);
    }

    // if the user is within the lock period, the fee is applicable, otherwise no fee
    function _calculateApplicableFee(address user, uint256 amount)
        internal
        view
        returns (uint256 amountAfterFee, uint256 feeAmount)
    {
        if (_isLocked(user)) {
            feeAmount = (amount * withdrawFee) / 10000;
            amountAfterFee = amount - feeAmount;
        } else {
            amountAfterFee = amount;
            feeAmount = 0;
        }
    }

    function claimYield() external {
        claimYieldOnBehalf(msg.sender);
    }

    function claimYieldOnBehalf(address user) public {
        uint256 claimable = _claimableYield(user);
        if (claimable == 0) revert NoYieldToClaim();

        // Process yield claim
        _processYield(user, claimable);
    }

    function harvest(uint256 minOut) external {
        _requireHarvester(msg.sender);
        (bool _canHarvest,) = canHarvest();

        if (!_canHarvest) {
            revert HarvestConditionsNotMet();
        }

        _performHarvest(minOut);
    }

    function canHarvest() public view returns (bool, uint256) {
        uint256 currentBalance = A_UNDERLYING.balanceOf(address(this));
        uint256 totalSharesSupply = totalSupply();

        // Calculate potential yield amount
        uint256 yieldAmount = currentBalance > totalSharesSupply ? currentBalance - totalSharesSupply : 0;

        // Check if harvest conditions are met
        bool yieldSufficient = yieldAmount >= minYieldAmount;
        bool timePassed = block.timestamp >= lastHarvest + harvestTimePeriod;

        if (!yieldSufficient && !timePassed) {
            return (false, yieldAmount);
        } else {
            return (true, yieldAmount);
        }
    }

    function setHarvestFee(uint256 newHarvestFee) external onlyOwner {
        _requireValidHarvestFee(newHarvestFee);
        harvestFee = newHarvestFee;
        emit FeeUpdated(newHarvestFee);
    }

    function setWithdrawFee(uint256 newWithdrawFee) external onlyOwner {
        _requireValidWithdrawFee(newWithdrawFee);
        withdrawFee = newWithdrawFee;
        emit FeeUpdated(newWithdrawFee);
    }

    function setMinYieldAmount(uint256 newMinYieldAmount) external onlyOwner {
        // Reasonable bounds: minimum 1 USDC (1e6), maximum 100,000 USDC (100000e6)
        if (newMinYieldAmount < 1e6) revert MinYieldAmountTooLow();
        if (newMinYieldAmount > 100000e6) revert MinYieldAmountTooHigh();

        minYieldAmount = newMinYieldAmount;
        emit MinYieldAmountUpdated(newMinYieldAmount);
    }

    function setHarvestTimePeriod(uint256 newHarvestTimePeriod) external onlyOwner {
        // Reasonable bounds: minimum 1 hour, maximum 30 days
        if (newHarvestTimePeriod < 1 hours) revert HarvestTimePeriodTooShort();
        if (newHarvestTimePeriod > 30 days) revert HarvestTimePeriodTooLong();

        harvestTimePeriod = newHarvestTimePeriod;
        emit HarvestTimePeriodUpdated(newHarvestTimePeriod);
    }

    function addHarvester(address newHarvester) external onlyOwner {
        _requireAddressCannotBeZero(newHarvester);
        _harvesterSet[newHarvester] = true;
        emit HarvesterUpdated(newHarvester, true);
    }

    function removeHarvester(address oldHarvester) external onlyOwner {
        _requireAddressCannotBeZero(oldHarvester);
        _harvesterSet[oldHarvester] = false;
        emit HarvesterUpdated(oldHarvester, false);
    }

    // --- Internal Functions ---

    function _update(address from, address to, uint256 value) internal override {
        // Allow minting (from == address(0)) and burning (to == address(0))
        // Block all other transfers
        if (from != address(0) && to != address(0)) {
            revert TransferLocked();
        }

        super._update(from, to, value);
    }

    function _processYield(address user, uint256 amount) internal {
        if (amount == 0) revert NoYieldToClaim();

        // Update user's last cumulative reward tokens per share
        users[user].lastCumulativeRewardPerShare = cumulativeRewardPerShare;
        users[user].rewardClaimed += amount;

        // Transfer reward tokens to user
        REWARD_TOKEN.safeTransfer(user, amount);

        emit YieldClaimed(user, amount);
    }

    function _performHarvest(uint256 minOut) internal {
        uint256 currentBalance = A_UNDERLYING.balanceOf(address(this));
        uint256 totalSharesSupply = totalSupply();

        // Calculate yield (current aToken balance - total shares)
        if (currentBalance <= totalSharesSupply) return; // No yield to harvest

        uint256 yieldAmount = currentBalance - totalSharesSupply;

        // Withdraw yield from Aave
        AAVE_POOL.withdraw(address(UNDERLYING), yieldAmount, address(this));

        // Swap yield to reward tokens
        // NOTE: this assumes the tokens are not the same
        uint256 rewardReceived = DEX.exactInputSingle(
            IDex.ExactInputSingleParams({
                tokenIn: address(UNDERLYING),
                tokenOut: address(REWARD_TOKEN),
                fee: 3000, // 0.3% fee tier
                recipient: address(this),
                deadline: block.timestamp + 300, // 5 minutes
                amountIn: yieldAmount,
                amountOutMinimum: minOut,
                sqrtPriceLimitX96: 0
            })
        );

        // Take protocol fee
        uint256 protocolFee = (rewardReceived * harvestFee) / 10000;
        uint256 userRewards = rewardReceived - protocolFee - 1;

        // Send protocol fee to owner
        if (protocolFee > 0) {
            REWARD_TOKEN.safeTransfer(owner(), protocolFee);
        }

        // Update cumulative reward tokens per share
        if (totalSharesSupply > 0) {
            cumulativeRewardPerShare += (userRewards * 1e18) / totalSharesSupply;
        }

        lastHarvest = block.timestamp;

        emit Harvest(yieldAmount, rewardReceived, protocolFee, cumulativeRewardPerShare);
    }

    function _updateUserRewards(address user) internal {
        UserInfo storage userInfo = users[user];
        userInfo.lastCumulativeRewardPerShare = cumulativeRewardPerShare;
    }

    function _isLocked(address _user) private view returns (bool) {
        return block.timestamp < users[_user].depositTimestamp + lockPeriod;
    }

    function _isHardLocked(address _user) private view returns (bool) {
        return block.timestamp < users[_user].depositTimestamp + hardLockPeriod;
    }

    function _claimableYield(address user) private view returns (uint256) {
        UserInfo memory userInfo = users[user];
        uint256 userShares = balanceOf(user);

        if (userShares == 0) return 0;

        uint256 accumulatedReward = (cumulativeRewardPerShare * userShares) / 1e18;
        uint256 userLastAccumulated = (userInfo.lastCumulativeRewardPerShare * userShares) / 1e18;

        return accumulatedReward - userLastAccumulated;
    }

    function _requireAmountCannotBeZero(uint256 amount) private pure {
        if (!(amount > 0)) revert AmountCannotBeZero();
    }

    function _requireAddressCannotBeZero(address a) private pure {
        if (a == address(0x0)) revert AddressCannotBeZero();
    }

    function _requireTokensNotHardLocked(address _owner) private view {
        if (_isHardLocked(_owner)) revert TokensAreLocked();
    }

    function _requireValidHarvestFee(uint256 _harvestFee) private pure {
        if (_harvestFee > MAX_HARVEST_FEE_BPS) revert FeeTooHigh();
    }

    function _requireValidWithdrawFee(uint256 _withdrawFee) private pure {
        if (_withdrawFee > MAX_WITHDRAW_FEE_BPS) revert FeeTooHigh();
    }

    function _requireHarvester(address harvesterAddress) private view {
        if (!_harvesterSet[harvesterAddress]) revert HarvestingNotAllowed();
    }
}
"
    },
    "dependencies/@openzeppelin-contracts-5.3.0/token/ERC20/ERC20.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.3.0) (token/ERC20/ERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "./IERC20.sol";
import {IERC20Metadata} from "./extensions/IERC20Metadata.sol";
import {Context} from "../../utils/Context.sol";
import {IERC20Errors} from "../../interfaces/draft-IERC6093.sol";

/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.openzeppelin.com/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * The default value of {decimals} is 18. To change this, you should override
 * this function so it returns a different value.
 *
 * We have followed general OpenZeppelin Contracts guidelines: functions revert
 * instead returning `false` on failure. This behavior is nonetheless
 * conventional and does not conflict with the expectations of ERC-20
 * applications.
 */
abstract contract ERC20 is Context, IERC20, IERC20Metadata, IERC20Errors {
    mapping(address account => uint256) private _balances;

    mapping(address account => mapping(address spender => uint256)) private _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;

    /**
     * @dev Sets the values for {name} and {symbol}.
     *
     * Both values are immutable: they can only be set once during construction.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view virtual returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view virtual returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5.05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the default value returned by this function, unless
     * it's overridden.
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view virtual returns (uint8) {
        return 18;
    }

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view virtual returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(address account) public view virtual returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - the caller must have a balance of at least `value`.
     */
    function transfer(address to, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _transfer(owner, to, value);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(address owner, address spender) public view virtual returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * NOTE: If `value` is the maximum `uint256`, the allowance is not updated on
     * `transferFrom`. This is semantically equivalent to an infinite approval.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, value);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Skips emitting an {Approval} event indicating an allowance update. This is not
     * required by the ERC. See {xref-ERC20-_approve-address-address-uint256-bool-}[_approve].
     *
     * NOTE: Does not update the allowance if the current allowance
     * is the maximum `uint256`.
     *
     * Requirements:
     *
     * - `from` and `to` cannot be the zero address.
     * - `from` must have a balance of at least `value`.
     * - the caller must have allowance for ``from``'s tokens of at least
     * `value`.
     */
    function transferFrom(address from, address to, uint256 value) public virtual returns (bool) {
        address spender = _msgSender();
        _spendAllowance(from, spender, value);
        _transfer(from, to, value);
        return true;
    }

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to`.
     *
     * This internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _transfer(address from, address to, uint256 value) internal {
        if (from == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        if (to == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(from, to, value);
    }

    /**
     * @dev Transfers a `value` amount of tokens from `from` to `to`, or alternatively mints (or burns) if `from`
     * (or `to`) is the zero address. All customizations to transfers, mints, and burns should be done by overriding
     * this function.
     *
     * Emits a {Transfer} event.
     */
    function _update(address from, address to, uint256 value) internal virtual {
        if (from == address(0)) {
            // Overflow check required: The rest of the code assumes that totalSupply never overflows
            _totalSupply += value;
        } else {
            uint256 fromBalance = _balances[from];
            if (fromBalance < value) {
                revert ERC20InsufficientBalance(from, fromBalance, value);
            }
            unchecked {
                // Overflow not possible: value <= fromBalance <= totalSupply.
                _balances[from] = fromBalance - value;
            }
        }

        if (to == address(0)) {
            unchecked {
                // Overflow not possible: value <= totalSupply or value <= fromBalance <= totalSupply.
                _totalSupply -= value;
            }
        } else {
            unchecked {
                // Overflow not possible: balance + value is at most totalSupply, which we know fits into a uint256.
                _balances[to] += value;
            }
        }

        emit Transfer(from, to, value);
    }

    /**
     * @dev Creates a `value` amount of tokens and assigns them to `account`, by transferring it from address(0).
     * Relies on the `_update` mechanism
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _mint(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(address(0), account, value);
    }

    /**
     * @dev Destroys a `value` amount of tokens from `account`, lowering the total supply.
     * Relies on the `_update` mechanism.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead
     */
    function _burn(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        _update(account, address(0), value);
    }

    /**
     * @dev Sets `value` as the allowance of `spender` over the `owner`'s tokens.
     *
     * This internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     *
     * Overrides to this logic should be done to the variant with an additional `bool emitEvent` argument.
     */
    function _approve(address owner, address spender, uint256 value) internal {
        _approve(owner, spender, value, true);
    }

    /**
     * @dev Variant of {_approve} with an optional flag to enable or disable the {Approval} event.
     *
     * By default (when calling {_approve}) the flag is set to true. On the other hand, approval changes made by
     * `_spendAllowance` during the `transferFrom` operation set the flag to false. This saves gas by not emitting any
     * `Approval` event during `transferFrom` operations.
     *
     * Anyone who wishes to continue emitting `Approval` events on the`transferFrom` operation can force the flag to
     * true using the following override:
     *
     * ```solidity
     * function _approve(address owner, address spender, uint256 value, bool) internal virtual override {
     *     super._approve(owner, spender, value, true);
     * }
     * ```
     *
     * Requirements are the same as {_approve}.
     */
    function _approve(address owner, address spender, uint256 value, bool emitEvent) internal virtual {
        if (owner == address(0)) {
            revert ERC20InvalidApprover(address(0));
        }
        if (spender == address(0)) {
            revert ERC20InvalidSpender(address(0));
        }
        _allowances[owner][spender] = value;
        if (emitEvent) {
            emit Approval(owner, spender, value);
        }
    }

    /**
     * @dev Updates `owner`'s allowance for `spender` based on spent `value`.
     *
     * Does not update the allowance value in case of infinite allowance.
     * Revert if not enough allowance is available.
     *
     * Does not emit an {Approval} event.
     */
    function _spendAllowance(address owner, address spender, uint256 value) internal virtual {
        uint256 currentAllowance = allowance(owner, spender);
        if (currentAllowance < type(uint256).max) {
            if (currentAllowance < value) {
                revert ERC20InsufficientAllowance(spender, currentAllowance, value);
            }
            unchecked {
                _approve(owner, spender, currentAllowance - value, false);
            }
        }
    }
}
"
    },
    "dependencies/@openzeppelin-contracts-5.3.0/access/Ownable.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}
"
    },
    "dependencies/@openzeppelin-contracts-5.3.0/token/ERC20/utils/SafeERC20.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.3.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";
import {IERC1363} from "../../../interfaces/IERC1363.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC-20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    /**
     * @dev An operation with an ERC-20 token failed.
     */
    error SafeERC20FailedOperation(address token);

    /**
     * @dev Indicates a failed `decreaseAllowance` request.
     */
    error SafeERC20FailedDecreaseAllowance(address spender, uint256 currentAllowance, uint256 requestedDecrease);

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Variant of {safeTransfer} that returns a bool instead of reverting if the operation is not successful.
     */
    function trySafeTransfer(IERC20 token, address to, uint256 value) internal returns (bool) {
        return _callOptionalReturnBool(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Variant of {safeTransferFrom} that returns a bool instead of reverting if the operation is not successful.
     */
    function trySafeTransferFrom(IERC20 token, address from, address to, uint256 value) internal returns (bool) {
        return _callOptionalReturnBool(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     *
     * IMPORTANT: If the token implements ERC-7674 (ERC-20 with temporary allowance), and if the "client"
     * smart contract uses ERC-7674 to set temporary allowances, then the "client" smart contract should avoid using
     * this function. Performing a {safeIncreaseAllowance} or {safeDecreaseAllowance} operation on a token contract
     * that has a non-zero temporary allowance (for that particular owner-spender) will result in unexpected behavior.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        forceApprove(token, spender, oldAllowance + value);
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `requestedDecrease`. If `token` returns no
     * value, non-reverting calls are assumed to be successful.
     *
     * IMPORTANT: If the token implements ERC-7674 (ERC-20 with temporary allowance), and if the "client"
     * smart contract uses ERC-7674 to set temporary allowances, then the "client" smart contract should avoid using
     * this function. Performing a {safeIncreaseAllowance} or {safeDecreaseAllowance} operation on a token contract
     * that has a non-zero temporary allowance (for that particular owner-spender) will result in unexpected behavior.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 requestedDecrease) internal {
        unchecked {
            uint256 currentAllowance = token.allowance(address(this), spender);
            if (currentAllowance < requestedDecrease) {
                revert SafeERC20FailedDecreaseAllowance(spender, currentAllowance, requestedDecrease);
            }
            forceApprove(token, spender, currentAllowance - requestedDecrease);
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     *
     * NOTE: If the token implements ERC-7674, this function will not modify any temporary allowance. This function
     * only sets the "standard" allowance. Any temporary allowance will remain active, in addition to the value being
     * set here.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeCall(token.approve, (spender, value));

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeCall(token.approve, (spender, 0)));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Performs an {ERC1363} transferAndCall, with a fallback to the simple {ERC20} transfer if the target has no
     * code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * Reverts if the returned value is other than `true`.
     */
    function transferAndCallRelaxed(IERC1363 token, address to, uint256 value, bytes memory data) internal {
        if (to.code.length == 0) {
            safeTransfer(token, to, value);
        } else if (!token.transferAndCall(to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Performs an {ERC1363} transferFromAndCall, with a fallback to the simple {ERC20} transferFrom if the target
     * has no code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * Reverts if the returned value is other than `true`.
     */
    function transferFromAndCallRelaxed(
        IERC1363 token,
        address from,
        address to,
        uint256 value,
        bytes memory data
    ) internal {
        if (to.code.length == 0) {
            safeTransferFrom(token, from, to, value);
        } else if (!token.transferFromAndCall(from, to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Performs an {ERC1363} approveAndCall, with a fallback to the simple {ERC20} approve if the target has no
     * code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * NOTE: When the recipient address (`to`) has no code (i.e. is an EOA), this function behaves as {forceApprove}.
     * Opposedly, when the recipient address (`to`) has code, this function only attempts to call {ERC1363-approveAndCall}
     * once without retrying, and relies on the returned value to be true.
     *
     * Reverts if the returned value is other than `true`.
     */
    function approveAndCallRelaxed(IERC1363 token, address to, uint256 value, bytes memory data) internal {
        if (to.code.length == 0) {
            forceApprove(token, to, value);
        } else if (!token.approveAndCall(to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturnBool} that reverts if call fails to meet the requirements.
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        uint256 returnSize;
        uint256 returnValue;
        assembly ("memory-safe") {
            let success := call(gas(), token, 0, add(data, 0x20), mload(data), 0, 0x20)
            // bubble errors
            if iszero(success) {
                let ptr := mload(0x40)
                returndatacopy(ptr, 0, returndatasize())
                revert(ptr, returndatasize())
            }
            returnSize := returndatasize()
            returnValue := mload(0)
        }

        if (returnSize == 0 ? address(token).code.length == 0 : returnValue != 1) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silently catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        bool success;
        uint256 returnSize;
        uint256 returnValue;
        assembly ("memory-safe") {
            success := call(gas(), token, 0, add(data, 0x20), mload(data), 0, 0x20)
            returnSize := returndatasize()
            returnValue := mload(0)
        }
        return success && (returnSize == 0 ? address(token).code.length > 0 : returnValue == 1);
    }
}
"
    },
    "contracts/src/interfaces/IErn.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity ^0.8.25;

import {IDex} from "./IDex.sol";
import {IAavePool} from "./IAavePool.sol";

import {IERC20} from "@openzeppelin/contracts/token/ERC20/IERC20.sol";

/**
 * @title IErn
 * @notice Interface for the Ern contract that deposits an underlying asset into Aave and converts its generated yield to reward tokens.
 * @dev Extends ERC20 standard with additional yield farming functionality. Workflows:
 *      1. deposit():
 *                 - Users deposit an underlying asset into the contract.
 *                 - The contract mints shares (1:1) to the users and the underlying asset is then supplied to Aave.
 *                 - Contract holds aUnderlying tokens.
 *                 - Users are locked for a certain period after deposit.
 *      2. harvest():
 *                 - The contract periodically harvests yield from Aave, converts it to reward tokens using a DEX.
 *                 - Removes a certain percentage as a protocol fee.
 *                 - Calculates remainder reward tokens per share (cumulativeRewardPerShare).
 *      3. claimYield(): Users can claim their reward tokens based on their share of the total supply and the cumulativeRewardPerShare.
 *      4. withdraw():
 *                 - Users can withdraw their underlying asset after a locked period;
 *                 - Contract burns their shares and returns the underlying asset after converting aUnderlying to underlying asset.
 */
interface IErn {
    // --- Structs ---

    /**
     * @notice User information for yield tracking and deposit locking
     * @param lastCumulativeRewardPerShare Last recorded cumulative reward per share for the user
     * @param rewardClaimed Total amount of reward claimed by the user
     * @param depositTimestamp Timestamp of the user's last deposit for lock period calculation
     */
    struct UserInfo {
        uint256 lastCumulativeRewardPerShare;
        uint256 rewardClaimed;
        uint256 depositTimestamp;
    }

    // --- Events ---

    /**
     * @notice Emitted when yield is harvested and converted to reward tokens
     * @param underlyingYield Amount of Underlying yield harvested from Aave
     * @param rewardBought Amount of reward tokens received after swapping Underlying yield
     * @param feeTaken Amount of reward tokens taken as protocol fee
     * @param cumulativeRewardPerShare Updated cumulative reward tokens per share after harvest
     */
    event Harvest(uint256 underlyingYield, uint256 rewardBought, uint256 feeTaken, uint256 cumulativeRewardPerShare);

    /**
     * @notice Emitted when a user claims their reward tokens
     * @param user Address of the user claiming yield
     * @param amount Amount of reward tokens claimed
     */
    event YieldClaimed(address indexed user, uint256 amount);

    /**
     * @notice Emitted when the protocol fee is updated
     * @param newHarvestFee New fee in basis points (1 bp = 0.01%)
     */
    event FeeUpdated(uint256 newHarvestFee);

    /**
     * @notice Emitted when the minimum yield amount is updated
     * @param newMinYieldAmount New minimum yield amount required for harvest
     */
    event MinYieldAmountUpdated(uint256 newMinYieldAmount);

    /**
     * @notice Emitted when the harvest time period is updated
     * @param newHarvestTimePeriod New time period for harvest restriction
     */
    event HarvestTimePeriodUpdated(uint256 newHarvestTimePeriod);

    /**
     * @notice Emitted when a user deposits underlying tokens
     * @param user Address of the user depositing
     * @param amount Amount of underlying tokens deposited
     */
    event Deposit(address indexed user, uint256 amount);

    /**
     * @notice Emitted when a user withdraws underlying tokens
     * @param user Address of the user withdrawing
     * @param amount Amount of underlying tokens withdrawn
     * @param fee Amount of underlying tokens kept as fee
     */
    event Withdraw(address indexed user, uint256 amount, uint256 fee);

    /**
     * @notice Emitted when the harvester address is updated
     * @param newHarvester Address of the new harvester
     * @param isAuthorized True if the new harvester is authorized, false otherwise
     */
    event HarvesterUpdated(address indexed newHarvester, bool isAuthorized);

    // --- View Functions ---

    /**
     * @notice Returns the reward token contract
     * @return The IERC20 interface of the reward token
     */
    function REWARD_TOKEN() external view returns (IERC20);

    /**
     * @notice Returns the Aave Underlying token (aUnderlying) contract
     * @return The IERC20 interface of the aUnderlying token
     */
    function A_UNDERLYING() external view returns (IERC20);

    /**
     * @notice Returns the Underlying token contract
     * @return The IERC20 interface of the Underlying token
     */
    function UNDERLYING() external view returns (IERC20);

    /**
     * @notice Returns the DEX contract address used for token swaps
     * @return The address of the DEX contract
     */
    function DEX() external view returns (IDex);

    /**
     * @notice Returns the Aave Pool contract address used for lending/borrowing
     * @return The address of the Aave Pool contract
     */
    function AAVE_POOL() external view returns (IAavePool);

    /**
     * @notice Returns the maximum allowed protocol harvest fee
     * @return The maximum fee in basis points (currently 1000 = 10%)
     */
    function MAX_HARVEST_FEE_BPS() external view returns (uint256);

    /**
     * @notice Returns the maximum allowed protocol withdraw fee
     * @return The maximum fee in basis points (currently 10 = 0.1%)
     */
    function MAX_WITHDRAW_FEE_BPS() external view returns (uint256);

    /**
     * @notice Returns the current protocol fee in basis points
     * @return The fee in basis points (1 bp = 0.01%)
     */
    function harvestFee() external view returns (uint256);

    /**
     * @notice Returns the current protocol fee in basis points
     * @return The fee in basis points (1 bp = 0.01%)
     */
    function withdrawFee() external view returns (uint256);

    /**
     * @notice Returns the cumulative reward tokens per share for yield distribution
     * @return The cumulative reward tokens per share value scaled by 1e18
     */
    function cumulativeRewardPerShare() external view returns (uint256);

    /**
     * @notice Returns the lock period duration in seconds
     * @return The lock period duration
     */
    function lockPeriod() external view returns (uint256);

    /**
     * @notice Returns if the given account is an authorized harvester.
     * @return True if the account is allowed, false otherwise.
     */
    function isHarvester(address account) external view returns (bool);

    /**
     * @notice Returns the minimum yield amount required for harvest
     * @return The minimum yield amount
     */
    function minYieldAmount() external view returns (uint256);

    /**
     * @notice Returns the harvest time period restriction
     * @return The time period in seconds
     */
    function harvestTimePeriod() external view returns (uint256);

    /**
     * @notice Calculates the claimable reward yield for a user
     * @param user Address of the user
     * @return The amount of reward tokens the user can claim
     */
    function claimableYield(address user) external view returns (uint256);

    /**
     * @notice Calculates the applicable fee for a withdrawal
     * @param user Address of the user
     * @param amount Amount of underlying tokens to withdraw
     * @return amountAfterFee The amount after applying the fee
     * @return feeAmount The fee amount deducted from the withdrawal
     */
    function applicableFee(address user, uint256 amount) external view returns (uint256 amountAfterFee, uint256 feeAmount);

    /**
     * @notice Returns the total amount of underlying assets managed by the vault
     * @return The total underlying assets (including those deposited in Aave)
     */
    function totalAssets() external view returns (uint256);

    /**
     * @notice Checks if a user's deposit is still locked
     * @param user Address of the user
     * @return True if the user is still in lock period
     */
    function isLocked(address user) external view returns (bool);

    /**
     * @notice Returns the unlock timestamp for a user
     * @param user Address of the user
     * @return The timestamp when the user can withdraw
     */
    function unlockTime(address user) external view returns (uint256);

    // --- State-Changing Functions ---

    /**
     * @notice Harvests yield from Aave and converts it to reward tokens for distribution
     * @dev Only callable by the contract owner, requires either sufficient yield amount or time period to have passed
     * @param minOut Minimum amount of reward tokens to receive from the swap (slippage protection)
     */
    function harvest(uint256 minOut) external;

    /**
     * @notice Claims accumulated reward yield for the caller
     * @dev Updates the user's checkpoint and transfers claimable reward tokens
     */
    function claimYield() external;

    /**
     * @notice Updates the protocol fee
     * @dev Only callable by the contract owner
     * @param newHarvestFee New fee in basis points, must not exceed MAX_HARVEST_FEE_BPS
     */
    function setHarvestFee(uint256 newHarvestFee) external;

    /**
     * @notice Updates the protocol fee
     * @dev Only callable by the contract owner
     * @param newWithdrawFee New fee in basis points, must not exceed MAX_WITHDRAW_FEE_BPS
     */
    function setWithdrawFee(uint256 newWithdrawFee) external;

    /**
     * @notice Sets a new harvester
     * @dev Only callable by the contract owner
     * @param newHarvester The address of the new harvester
     */
    function addHarvester(address newHarvester) external;

    /**
     * @notice Removes a harvester from the allowed list
     * @dev Only callable by the contract owner
     * @param harvesterToRemove The address of the harvester to remove
     */
    function removeHarvester(address harvesterToRemove) external;

    /**
     * @notice Updates the minimum yield amount required for harvest
     * @dev Only callable by the contract owner
     * @param newMinYieldAmount New minimum yield amount
     */
    function setMinYieldAmount(uint256 newMinYieldAmount) external;

    /**
     * @notice Updates the harvest time period restriction
     * @dev Only callable by the contract owner
     * @param newHarvestTimePeriod New time period for harvest restriction
     */
    function setHarvestTimePeriod(uint256 newHarvestTimePeriod) external;

    /**
     * @notice Deposits underlying tokens into the vault
     * @param amount The amount of underlying tokens to deposit
     */
    function deposit(uint256 amount) external;

    /**
     * @notice Withdraws underlying tokens from the vault
     * @param amount The amount of underlying tokens to withdraw
     */
    function withdraw(uint256 amount) external;

    /**
     * @notice Returns the UserInfo for a given user address
     * @param user The address of the user
     * @return lastCumulativeRewardPerShare The last recorded cumulative reward per share for the user
     * @return rewardClaimed The total amount of reward claimed by the user
     * @return depositTimestamp The timestamp of the user's last deposit
     */
    function users(address user) external view returns (uint256 lastCumulativeRewardPerShare, uint256 rewardClaimed, uint256 depositTimestamp);
}
"
    },
    "contracts/src/interfaces/IDex.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity ^0.8.25;

interface IDex {
    struct ExactInputSingleParams {
        address tokenIn;
        address tokenOut;
        uint24 fee;
        address recipient;
        uint256 deadline;
        uint256 amountIn;
        uint256 amountOutMinimum;
        uint160 sqrtPriceLimitX96;
    }

    /// @notice Swaps `amountIn` of one token for as much as possible of another token
    /// @param params The parameters necessary for the swap, encoded as `ExactInputSingleParams` in calldata
    /// @return amountOut The amount of the received token
    function exactInputSingle(ExactInputSingleParams calldata params) external returns (uint256 amountOut);
}
"
    },
    "contracts/src/interfaces/IAavePool.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity ^0.8.25;

interface IAavePool {
    function supply(address asset, uint256 amount, address onBehalfOf, uint16 referralCode) external;
    function withdraw(address asset, uint256 amount, address to) external returns (uint256);
    function getReserveAToken(address asset) external view returns (address);
}
"
    },
    "dependencies/@openzeppelin-contracts-5.3.0/token/ERC20/IERC20.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC-20 standard as defined in the ERC.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}
"
    },
    "dependencies/@openzeppelin-contracts-5.3.0/token/ERC20/extensions/IERC20Metadata.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC-20 standard.
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}
"
    },
    "dependencies/@openzeppelin-contracts-5.3.0/utils/Context.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}
"
    },
    "dependencies/@openzeppelin-contracts-5.3.0/interfaces/draft-IERC6093.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (interfaces/draft-IERC6093.sol)
pragma solidity ^0.8.20;

/**
 * @dev Standard ERC-20 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC-20 tokens.
 */
interface IERC20Errors {
    /**
     * @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param balance Current balance for the interacting account.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientBalance(address sender, uint256 balance, uint256 needed);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC20InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC20InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `spender`’s `allowance`. Used in transfers.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     * @param allowance Amount of tokens a `spender` is allowed to operate with.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientAllowance(address spender, uint256 allowance, uint256 needed);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC20InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `spender` to be approved. Used in approvals.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC20InvalidSpender(address spender);
}

/**
 * @dev Standard ERC-721 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC-721 tokens.
 */
interface IERC721Errors {
    /**
     * @dev Indicates that an address can't be an owner. For example, `address(0)` is a forbidden owner in ERC-20.
     * Used in balance queries.
     * @param owner Address of the current owner of a token.
     */
    error ERC721InvalidOwner(address owner);

    /**
     * @dev Indicates a `tokenId` whose `owner` is the zero address.
     * @param tokenId Identifier number of a token.
     */
    error ERC721NonexistentToken(uint256 tokenId);

    /**
     * @dev Indicates an error related to the ownership over a particular token. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param tokenId Identifier number of a token.
     * @param owner Address of the current owner of a token.
     */
    error ERC721IncorrectOwner(address sender, uint256 tokenId, address owner);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC721InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC721InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `operator`’s approval. Used in transfers.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     * @param tokenId Identifier number of a token.
     */
    error ERC721InsufficientApproval(address operator, uint256 tokenId);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC721InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `operator` to be approved. Used in approvals.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC721InvalidOperator(address operator);
}

/**
 * @dev Standard ERC-1155 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC-1155 tokens.
 */
interface IERC1155Errors {
    /**
     * @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param balance Current balance for the interacting account.
     * @param needed Minimum amount required to perform a transfer.
     * @param tokenId Identifier number of a token.
     */
    error ERC1155InsufficientBalance(address sender, uint256 balance, uint256 needed, uint256 tokenId);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC1155InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC1155InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `operator`’s approval. Used in transfers.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     * @param owner Address of the current owner of a token.
     */
    error ERC1155MissingApprovalForAll(address operator, address owner);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC1155InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `operator` to be approved. Used in approvals.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC1155InvalidOperator(address operator);

    /**
     * @dev Indicates an array length mismatch between ids and values in a safeBatchTransferFrom operation.
     * Used in batch transfers.
     * @param idsLength Length of the array of token identifiers
     * @param valuesLength Length of the array of token amounts
     */
    error ERC1155InvalidArrayLength(uint256 idsLength, uint256 valuesLength);
}
"
    },
    "dependencies/@openzeppelin-contracts-5.3.0/interfaces/IERC1363.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (interfaces/IERC1363.sol)

pragma solidity ^0.8.20;

import {IERC20} from "./IERC20.sol";
import {IERC165} from "./IERC165.sol";

/**
 * @title IERC1363
 * @dev Interface of the ERC-1363 standard as defined in the https://eips.ethereum.org/EIPS/eip-1363[ERC-1363].
 *
 * Defines an extension interface for ERC-20 tokens that supports executing code on a recipient contract
 * after `transfer` or `transferFrom`, or code on a spender contract after `approve`, in a single transaction.
 */
interface IERC1363 is IERC20, IERC165 {
    /*
     * Note: the ERC-165 identifier for this interface is 0xb0202a11.
     * 0xb0202a11 ===
     *   bytes4(keccak256('transferAndCall(address,uint256)')) ^
     *   bytes4(keccak256('transferAndCall(address,uint256,bytes)')) ^
     *   bytes4(keccak256('transferFromAndCall(addres