DIAStroomAdapter

{{
  "language": "Solidity",
  "sources": {
    "contracts/DIAStroomAdapter.sol": {
      "content": "// SPDX-License-Identifier: GPL-3.0

pragma solidity 0.8.29;

import "@openzeppelin/contracts/access/Ownable.sol";
import { IERC20Metadata } from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
import "./IDIAOracleV2.sol";

contract DIAStroomAdapter is Ownable(msg.sender) {
    // Assumption: DECIMALS is the number of decimals used by the oracle feeder at diaOracleAddress
    address[] public reserveWalletRegistry;
    mapping (address => address) public reserveWalletAsset;
    uint256 public DECIMALS = 18;
    address public diaOracleAddress;
    string public diaOracleQueryString;

    constructor(address _diaOracleAddress, string memory _diaOracleQueryString) {
        diaOracleAddress = _diaOracleAddress;
        diaOracleQueryString = _diaOracleQueryString;
    }

    function addReserveWalletToRegistry(address _reserveWallet, address _reserveWalletAsset) external onlyOwner {
        reserveWalletRegistry.push(_reserveWallet);
        reserveWalletAsset[_reserveWallet] = _reserveWalletAsset;
    }

    function removeReserveWalletFromRegistry(address _reserveWallet) external onlyOwner {
        for (uint i = 0; i < reserveWalletRegistry.length; i++) {
            if (reserveWalletRegistry[i] == _reserveWallet) {
                reserveWalletRegistry[i] = reserveWalletRegistry[reserveWalletRegistry.length - 1];
                reserveWalletRegistry.pop();
            }
        }
        delete reserveWalletAsset[_reserveWallet];
    }

    function updateContractDecimals(uint256 _decimals) external onlyOwner {
        DECIMALS = _decimals;
    }

    function updateDiaOracleAddress(address _diaOracleAddress) external onlyOwner {
        diaOracleAddress = _diaOracleAddress;
    }

    function getOnchainReserve() public view returns (uint256) {
        uint256 balanceAccumulator = 0;
        for(uint i = 0; i < reserveWalletRegistry.length; i++) {
            address currWallet = reserveWalletRegistry[i];
            address currAsset = reserveWalletAsset[currWallet];

            // Retrieve asset decimals and balanceOf
            uint8 currAssetDecimals = IERC20Metadata(currAsset).decimals();
            uint256 currAssetBalance = IERC20Metadata(currAsset).balanceOf(currWallet);

            // Perform decimal scaling
            if (currAssetDecimals < DECIMALS) {
                uint256 currDecimalDelta = DECIMALS - currAssetDecimals;
                currAssetBalance = currAssetBalance * (10 ** currDecimalDelta);
            } else if (currAssetDecimals > DECIMALS) {
                uint256 currDecimalDelta = currAssetDecimals - DECIMALS;
                currAssetBalance = currAssetBalance / (10 ** currDecimalDelta);
            }
            balanceAccumulator += currAssetBalance;
        }
        return balanceAccumulator;
    }

    function getOffchainReserve() public view returns (uint256) {
        IDIAOracleV2 oracleInstance = IDIAOracleV2(diaOracleAddress);

        // Retrieve asset from oracle
        (uint128 offchainReserveValue,) = oracleInstance.getValue(diaOracleQueryString);
        return offchainReserveValue;
    }

    function getCombinedReserveValue() public view returns (uint256) {
        return getOnchainReserve() + getOffchainReserve();
    }
}"
    },
    "contracts/IDIAOracleV2.sol": {
      "content": "// SPDX-License-Identifier: GPL-3.0
pragma solidity 0.8.29;

interface IDIAOracleV2 {
    function setValue(
        string memory key,
        uint128 value,
        uint128 timestamp
    ) external;

    function getValue(
        string memory key
    ) external view returns (uint128, uint128);
}"
    },
    "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity >=0.6.2;

import {IERC20} from "../IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC-20 standard.
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}
"
    },
    "@openzeppelin/contracts/access/Ownable.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}
"
    },
    "@openzeppelin/contracts/token/ERC20/IERC20.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (token/ERC20/IERC20.sol)

pragma solidity >=0.4.16;

/**
 * @dev Interface of the ERC-20 standard as defined in the ERC.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}
"
    },
    "@openzeppelin/contracts/utils/Context.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}
"
    }
  },
  "settings": {
    "optimizer": {
      "enabled": false,
      "runs": 200
    },
    "outputSelection": {
      "*": {
        "*": [
          "evm.bytecode",
          "evm.deployedBytecode",
          "devdoc",
          "userdoc",
          "metadata",
          "abi"
        ]
      }
    },
    "remappings": []
  }
}}