Inspector

{{
  "language": "Solidity",
  "settings": {
    "evmVersion": "paris",
    "optimizer": {
      "enabled": true,
      "runs": 200
    },
    "outputSelection": {
      "*": {
        "*": [
          "evm.bytecode",
          "evm.deployedBytecode",
          "devdoc",
          "userdoc",
          "metadata",
          "abi"
        ]
      }
    }
  },
  "sources": {
    "@openzeppelin/contracts/access/Ownable.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}
"
    },
    "@openzeppelin/contracts/utils/Context.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}
"
    },
    "contracts/Inspector.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity 0.8.22;

import { Ownable } from "@openzeppelin/contracts/access/Ownable.sol";

import { IInspector } from "./interfaces/IInspector.sol";

/**
 * @title Inspector
 * @notice Handles inspection of messages before they are sent on the src chain.
 * @dev The owner will be the same owner of the Messenger, and OFT etc. We will route all calls via that owner.
 */
contract Inspector is IInspector, Ownable {
    // @dev Paused id mapping, where the key is the id and the value is a boolean indicating if it is paused.
    mapping(bytes32 id => bool paused) public pausedIds;

    // @dev Global paused state for the inspector, which can be used to pause all operations.
    bool public globalPause;

    constructor(address _owner) Ownable(_owner) {}

    /**
     * @notice Sets the global paused value.
     * @param _paused The state of the global pause.
     * @dev Sets a global pause state applied to all messages that are inspected.
     */
    function setGlobalPaused(bool _paused) external onlyOwner {
        // @dev If pause is already set to expected, revert
        if (globalPause == _paused) revert GlobalPausedIdempotent(_paused);

        globalPause = _paused;
        emit GlobalPausedSet(_paused);
    }

    /**
     * @notice Sets the id paused value.
     * @param _id The identifier.
     * @param _paused The state of the pause.
     * @dev Sets the pause state for a given 'id'.
     */
    function setIdPaused(bytes32 _id, bool _paused) external onlyOwner {
        // @dev If id pause is already set to expected, revert
        if (pausedIds[_id] == _paused) revert IdPausedIdempotent(_id, _paused);

        pausedIds[_id] = _paused;
        emit IdPausedSet(_id, _paused);
    }

    /**
     * @notice Allows the inspectee to examine LayerZero message contents and optionally throw a revert if invalid.
     * @param _id The identifier being inspected.
     * @dev _message The message payload to be inspected, currently unused.
     * @dev _options Additional options or parameters for inspection, currently unused.
     */
    function inspect(bytes32 _id, bytes calldata /*_message*/, bytes calldata /*_options*/) external view {
        if (globalPause) revert GlobalPaused();
        if (pausedIds[_id]) revert IdPaused(_id);
    }
}
"
    },
    "contracts/interfaces/IInspector.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity 0.8.22;

/**
 * @title IInspector
 * @notice Interface for the Messaging Inspector, allowing examination of message and options contents.
 */
interface IInspector {
    // @dev Custom error messages
    error InspectionFailed(bytes message, bytes options);
    error GlobalPausedIdempotent(bool paused);
    error IdPausedIdempotent(bytes32 id, bool paused);
    error GlobalPaused();
    error IdPaused(bytes32 id);

    // @dev Events
    event GlobalPausedSet(bool paused);
    event IdPausedSet(bytes32 id, bool paused);

    /**
     * @notice Sets the global paused value.
     * @param paused The state of the global pause.
     * @dev Sets a global pause state applied to all messages that are inspected.
     */
    function setGlobalPaused(bool paused) external;

    /**
     * @notice Sets the id paused value.
     * @param id The identifier.
     * @param paused The state of the pause.
     * @dev Sets the pause state for a given 'id'.
     */
    function setIdPaused(bytes32 id, bool paused) external;

    /**
     * @notice Allows the inspectee to examine LayerZero message contents and optionally throw a revert if invalid.
     * @param id The identifier being inspected.
     * @param message The message payload to be inspected.
     * @param options Additional options or parameters for inspection.
     */
    function inspect(bytes32 id, bytes calldata message, bytes calldata options) external view;
}
"
    }
  }
}}