BoosterPro

{{
  "language": "Solidity",
  "sources": {
    "contracts/booster/pro/BoosterPro.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity ^0.8.12;

import "@openzeppelin/contracts/security/ReentrancyGuard.sol";
import "@openzeppelin/contracts/access/Ownable.sol";
import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/token/ERC721/IERC721Receiver.sol";
import "../../interface/IMasterChefExtendV3.sol";
import "../../interface/IBarkDao.sol";
import "../../interface/ISubERC20.sol";
import "../../interface/IClaimOutFlow.sol";
import "../../treasury/interface/IBond.sol";

contract BoosterPro is Ownable, ReentrancyGuard, IERC721Receiver {
    using SafeERC20 for IERC20;

    struct BoostInfo {
        uint256 boostingRate;
        uint256 pendingDai;
        uint256 lastClaim;
    }

    struct UserBondData {
        uint256 amountA;
        uint256 amountB;
        uint256 amountC;
        uint256 amountE;
        uint256 totalAmount;
    }

    struct BoostingDetails {
        uint256 boostingRate;
        uint256 proportionEarn;
        uint256 amountA;
        uint256 amountB;
        uint256 amountC;
        uint256 amountE;
        bool canBoost;
        uint256 status;
    }

    IMasterChefExtendV3 public masterChef;
    IERC20 public DAI;
    IERC20 public Bark;
    IERC20 public dBark;
    ISubERC20 public bDAI2;
    IBond public bond;
    IBarkDao public barkDao;
    IClaimOutFlow public claimOutFlow;

    bool public active;
    mapping(address => bool) public disableUser;

    // stake limit
    uint256 public maxBondsPerAddress;  // 10-100
    uint256[] public powers;  // [0, 90, 180, 360]

    uint256 public maxBoostingRate;
    uint256 public minBoostingRate;

    uint256 public maxProportionEarn;  // 100-9900
    uint256 public minProportionEarn;  // 100-9900

    uint256 public intervalLimit;

    uint256 public constant RATE_PRECISION = 10000;

    mapping(uint256 => mapping(address => uint256)) public userBondPrincipalByType;
    mapping(address => uint256[]) public stakeBonds;
    mapping(uint256 => address) public bondStaker;
    mapping(address => BoostInfo) public boostInfo;

    /// Errors
    error NotBondOwner();
    error NotInCooldown();
    error InvalidTokenIds();
    error LimitBonds();
    error NotBondStaker();
    error BarkDaoUnregistered();
    error BondNotStaked(uint256 tokenId);
    error InvalidBoost();
    error InsufficientStakingTd();
    error InsufficientBalance();
    error ClaimTooEarly();
    error ZeroDBark();
    error ZeroBark();
    error InvalidBoostingRate();
    error InvalidProportionEarn();
    error InactiveContract();
    error DisabledUser();
    error InvalidMinBoostingRate();
    error InvalidMaxBoostingRate();
    error InvalidAddress();
    error InvalidRange();
    error InvalidMinProportionEarn();
    error InvalidMaxProportionEarn();

    /// Events
    event Deposit(address indexed from, uint256[] tokenIds);
    event Withdraw(address indexed to, uint256[] tokenIds);
    event Boost(
        address from,
        uint256 pendingDai,
        uint256 boostingRate,
        uint256 parentAmount,
        uint256 boostAmount,
        uint256 amountA,
        uint256 amountB,
        uint256 amountC,
        uint256 amountE,
        uint256 blockNumber
    );
    event UpdateActive(bool enable);
    event UpdateMaxBondsPerAddress(uint256 value);
    event UpdatePowers(uint256[3] powers);
    event UpdateProportionEarn(bool isMin, uint256 value);
    event UpdateBoostingRate(bool isMin, uint256 value);
    event UpdateDisableUser(address indexed user, bool disable);
    event EmergencyWithdrawToken(address to, uint256 amount);
    event EmergencyWithdrawBonds(address to, uint256[] tokenIds);
    event UpdateIntervalLimit(uint256 value);
    event UpdateClaimOutFlow(address flow);

    constructor(
        address _masterChef,
        address _DAI,
        address _Bark,
        address _dBark,
        address _bDAI2,
        address _bond,
        address _barkDao,
        uint256 _maxBondsPerAddress,
        uint256[3] memory _powers,
        uint256[2] memory _boostingRate,
        uint256[2] memory _proportionEarn
    ) {
        masterChef = IMasterChefExtendV3(_masterChef);
        DAI = IERC20(_DAI);
        Bark = IERC20(_Bark);
        dBark = IERC20(_dBark);
        bDAI2 = ISubERC20(_bDAI2);
        bond = IBond(_bond);
        barkDao = IBarkDao(_barkDao);

        maxBondsPerAddress = _maxBondsPerAddress;
        intervalLimit = 50400;
        active = true;

        powers.push(0);
        for (uint256 x = 0; x < _powers.length; x++) {
            powers.push(_powers[x]);
        }
        minBoostingRate = _boostingRate[0];
        maxBoostingRate = _boostingRate[1];

        minProportionEarn = _proportionEarn[0];
        maxProportionEarn = _proportionEarn[1];
    }

    /// Deposit an NFT to enable boosting
    function deposit(uint256[] calldata tokenIds) external nonReentrant {
        uint256 length = tokenIds.length;
        if (length == 0) revert InvalidTokenIds();
        if (stakeBonds[msg.sender].length + length > maxBondsPerAddress) revert LimitBonds();

        // Check pledge threshold and cooling-off period
        uint256 level = barkDao.getLevel(msg.sender);
        if (level == 0) revert BarkDaoUnregistered();
        _verifyCooldown(msg.sender);

        // Transfer and record bonds
        for (uint256 x = 0; x < length; x++) {
            uint256 tokenId = tokenIds[x];
            if (bond.ownerOf(tokenId) != msg.sender) revert NotBondOwner();

            IBond.BondOrder memory order = bond.getOrder(tokenId);
            userBondPrincipalByType[order.bondTypeId][msg.sender] += order.amountA;
            stakeBonds[msg.sender].push(tokenId);
            bondStaker[tokenId] = msg.sender;
            // transfer bond
            bond.safeTransferFrom(msg.sender, address(this), tokenId);
        }

        emit Deposit(msg.sender, tokenIds);
    }

    function withdraw(uint256[] calldata tokenIds) external nonReentrant {
        uint256 length = tokenIds.length;
        if (length == 0) revert InvalidTokenIds();

        // Check cooldown period
        _verifyCooldown(msg.sender);

        // Transfer and remove bonds
        for (uint256 x = 0; x < length; x++) {
            uint256 tokenId = tokenIds[x];
            if (bondStaker[tokenId] != msg.sender) revert NotBondStaker();

            IBond.BondOrder memory order = bond.getOrder(tokenId);
            userBondPrincipalByType[order.bondTypeId][msg.sender] -= order.amountA;
            _removeFromStakedBonds(msg.sender, tokenId);
            delete bondStaker[tokenId];
            bond.safeTransferFrom(address(this), msg.sender, tokenId);
        }
        emit Withdraw(msg.sender, tokenIds);
    }

    function boost(uint256 flowState, uint256 minOutPut) external nonReentrant {
        if (!active) revert InactiveContract();
        if (disableUser[msg.sender]) revert DisabledUser();

        IMasterChefExtendV3.UserInfo memory userInfo = masterChef.userInfo(msg.sender);
        if (block.number - userInfo.lastClaim > intervalLimit) revert InvalidBoost();
        uint256 level = barkDao.getLevel(msg.sender);
        if (userInfo.amount <= masterChef.stakingTd(level)) revert InsufficientStakingTd();

        IMasterChefExtendV3.Configuration memory cfg = masterChef.config();
        uint256 pendingDai = masterChef.pendingDai(msg.sender);
        if (pendingDai < cfg.claimThreshold) revert InsufficientBalance();

        BoostInfo storage info = boostInfo[msg.sender];
        if (info.lastClaim > 0 && userInfo.lastClaim <= info.lastClaim) {
            revert ClaimTooEarly();
        }

        UserBondData memory userData = _getUserBondData(msg.sender);
        if (userData.amountE == 0) revert ZeroDBark();
        if (userData.totalAmount == 0) revert ZeroBark();

        (bool state,) = _verifyProportionEarn(userData.amountE, userData.totalAmount);
        if (!state) revert InvalidProportionEarn();

        // Calculate boosting rate
        uint256 boostingRate = _calculateBoostRate(userData.amountA, userData.amountB, userData.amountC, userData.amountE);
        if (boostingRate < minBoostingRate) revert InvalidBoostingRate();
        if (boostingRate > maxBoostingRate) boostingRate = maxBoostingRate;

        // Calculate and distribute rewards
        uint256 boostAmount = pendingDai * boostingRate / RATE_PRECISION;
        uint256 minAmount = minOutPut;
        (uint256 parentAmount, uint256 claimAmount) =
            claimOutFlow.claim(flowState, msg.sender, boostAmount, minAmount);

        bDAI2.mint(msg.sender, claimAmount);

        // Record boost info
        boostInfo[msg.sender] = BoostInfo({
            boostingRate: boostingRate,
            pendingDai: pendingDai,
            lastClaim: block.number
        });

        emit Boost(
            msg.sender,
            pendingDai,
            boostingRate,
            parentAmount,
            claimAmount,
            userData.amountA,
            userData.amountB,
            userData.amountC,
            userData.amountE,
            block.number
        );
    }

    // ============================================
    // Admin Functions
    // ============================================

    function setActive(bool enable) external onlyOwner {
        active = enable;
        emit UpdateActive(enable);
    }

    function setMaxBondsPerAddress(uint256 value) external onlyOwner {
        if (value < 10 || value > 100) revert InvalidRange();
        maxBondsPerAddress = value;
        emit UpdateMaxBondsPerAddress(value);
    }

    function setPowers(uint256[3] calldata _powers) external onlyOwner {
        for (uint256 i = 0; i < _powers.length; i++) {
            powers[i + 1] = _powers[i];
        }
        emit UpdatePowers(_powers);
    }

    function setProportionEarn(bool isMin, uint256 value) external onlyOwner {
        if (isMin) {
            if (value < 100 || value > maxProportionEarn) revert InvalidMinProportionEarn();
            minProportionEarn = value;
        } else {
            if (value > 9900 || value < minProportionEarn) revert InvalidMaxProportionEarn();
            maxProportionEarn = value;
        }
        emit UpdateProportionEarn(isMin, value);
    }

    function setBoostingRate(bool isMin, uint256 value) external onlyOwner {
        if (isMin) {
            if (value < 100 || value > maxBoostingRate) revert InvalidMinBoostingRate();
            minBoostingRate = value;
        } else {
            if (value > 100000 || value < minBoostingRate) revert InvalidMaxBoostingRate();
            maxBoostingRate = value;
        }
        emit UpdateBoostingRate(isMin, value);
    }

    function setDisableUser(address user, bool disable) external onlyOwner {
        if (user == address(0)) revert InvalidAddress();
        disableUser[user] = disable;
        emit UpdateDisableUser(user, disable);
    }

    function setIntervalLimit(uint256 value) external onlyOwner {
        intervalLimit = value;
        emit UpdateIntervalLimit(value);
    }

    function setClaimOutFlow(address flow) external onlyOwner {
        if (flow == address(0)) revert InvalidAddress();
        if (address(claimOutFlow) != address(0)) {
            DAI.approve(address(claimOutFlow), 0);
        }
        claimOutFlow = IClaimOutFlow(flow);
        DAI.approve(flow, type(uint256).max);
        emit UpdateClaimOutFlow(flow);
    }

    function emergencyWithdrawToken(address to, uint256 amount) external onlyOwner {
        if (to == address(0)) revert InvalidAddress();
        if (DAI.balanceOf(address(this)) < amount) revert InsufficientBalance();

        DAI.safeTransfer(to, amount);

        emit EmergencyWithdrawToken(to, amount);
    }

    function emergencyWithdrawBonds(address to, uint256[] calldata tokenIds) external onlyOwner {
        if (to == address(0)) revert InvalidAddress();
        if (tokenIds.length == 0) revert InvalidTokenIds();
        for (uint256 i = 0; i < tokenIds.length; i++) {
            bond.safeTransferFrom(address(this), to, tokenIds[i]);
        }

        emit EmergencyWithdrawBonds(to, tokenIds);
    }

    // ============================================
    // View Functions
    // ============================================

    function canUserDeposit(address user) external view returns (bool) {
        if (stakeBonds[user].length >= maxBondsPerAddress) return false;
        IMasterChefExtendV3.Configuration memory cfg = masterChef.config();
        IMasterChefExtendV3.UserInfo memory userInfo = masterChef.userInfo(user);
        uint256 level = barkDao.getLevel(user);
        if (level == 0) return false;
        if (userInfo.lastClaim == 0 || (block.number - userInfo.lastClaim) > cfg.cooldown
            || userInfo.amount <= masterChef.stakingTd(level)) {
            return false;
        }
        return true;
    }

    function canUserWithdraw(address user) external view returns (bool) {
        if (stakeBonds[user].length == 0) return false;
        IMasterChefExtendV3.Configuration memory cfg = masterChef.config();
        IMasterChefExtendV3.UserInfo memory userInfo = masterChef.userInfo(user);
        if (userInfo.lastClaim == 0 || (block.number - userInfo.lastClaim) > cfg.cooldown) {
            return false;
        }
        return true;
    }

    function getBoostingDetails(address user) external view returns (BoostingDetails memory details) {
        UserBondData memory userData = _getUserBondData(user);

        details.amountA = userData.amountA;
        details.amountB = userData.amountB;
        details.amountC = userData.amountC;
        details.amountE = userData.amountE;

        details.canBoost = false;

        details.boostingRate = _calculateBoostRate(details.amountA, details.amountB, details.amountC, details.amountE);
        (bool state, uint256 proportionEarn) = _verifyProportionEarn(userData.amountE, userData.totalAmount);
        details.proportionEarn = proportionEarn;

        // Basic checks
        if (!active) {
            details.status = 0;
            return details;
        }
        if (disableUser[user]) {
            details.status = 1;
            return details;
        }
        if (stakeBonds[user].length == 0) {
            details.status = 2;
            return details;
        }
        if (details.amountE == 0) {
            details.status = 3;
            return details;
        }
        if (userData.totalAmount == 0) {
            details.status = 4;
            return details;
        }

        // Check harvest interval
        IMasterChefExtendV3.UserInfo memory userInfo = masterChef.userInfo(user);
        if (block.number - userInfo.lastClaim > intervalLimit) {
            details.status = 5;
            return details;
        }
        uint256 level = barkDao.getLevel(user);
        if (userInfo.amount <= masterChef.stakingTd(level)) {
            details.status = 6;
            return details;
        }

        // Check pending DAI
        IMasterChefExtendV3.Configuration memory cfg = masterChef.config();
        uint256 pendingDai = masterChef.pendingDai(user);
        if (pendingDai < cfg.claimThreshold) {
            details.status = 7;
            return details;
        }

        // Check last boost time
        BoostInfo storage info = boostInfo[user];
        if (info.lastClaim > 0 && userInfo.lastClaim <= info.lastClaim) {
            details.status = 8;
            return details;
        }

        // Verify proportion and calculate rate
        if (!state) {
            details.status = 9;
            return details;
        }

        if (details.boostingRate < minBoostingRate) {
            details.status = 10;
            return details;
        }

        details.status = 11;
        details.canBoost = true;
    }

    function getStakedBondCount(address user) external view returns (uint256) {
        return stakeBonds[user].length;
    }

    function getStakedBonds(address user) external view returns (uint256[] memory) {
        return stakeBonds[user];
    }

    function getPowers() external view returns (uint256[3] memory p) {
        p[0] = powers[1];
        p[1] = powers[2];
        p[2] = powers[3];
    }

    // Required to accept ERC721 safe transfers
    function onERC721Received(
        address,
        address,
        uint256,
        bytes calldata
    ) external pure override returns (bytes4) {
        return IERC721Receiver.onERC721Received.selector;
    }

    function _removeFromStakedBonds(address user, uint256 tokenId) internal {
        uint256[] storage bonds = stakeBonds[user];
        for (uint256 i = 0; i < bonds.length; i++) {
            if (bonds[i] == tokenId) {
                bonds[i] = bonds[bonds.length - 1];
                bonds.pop();
                return;
            }
        }
        revert BondNotStaked(tokenId);
    }

    function _getUserBondData(address user) internal view returns (UserBondData memory userData) {
        userData.amountA = userBondPrincipalByType[1][user];
        userData.amountB = userBondPrincipalByType[2][user];
        userData.amountC = userBondPrincipalByType[3][user];
        userData.amountE = dBark.balanceOf(user);
        userData.totalAmount = userData.amountA + userData.amountB + userData.amountC + userData.amountE;
    }

    function _calculateBoostRate(
        uint256 amountA,
        uint256 amountB,
        uint256 amountC,
        uint256 amountE
    ) internal view returns (uint256) {
        uint256 weightedSum = amountA * powers[1] + amountB * powers[2] + amountC * powers[3];
        return (weightedSum * RATE_PRECISION) / (amountE * RATE_PRECISION);
    }

    function _verifyProportionEarn(
        uint256 amountE,
        uint256 totalAmount
    ) internal view returns (bool, uint256) {
        uint256 proportionEarn = amountE * RATE_PRECISION / totalAmount;
        if (proportionEarn >= minProportionEarn && proportionEarn <= maxProportionEarn) {
            return (true, proportionEarn);
        }
        return (false, proportionEarn);
    }

    function _verifyCooldown(address user) internal view {
        IMasterChefExtendV3.Configuration memory cfg = masterChef.config();
        IMasterChefExtendV3.UserInfo memory userInfo = masterChef.userInfo(user);
        if (userInfo.lastClaim == 0 || (block.number - userInfo.lastClaim) > cfg.cooldown) {
            revert NotInCooldown();
        }
    }
}
"
    },
    "contracts/treasury/interface/IBond.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity ^0.8.12;

import "@openzeppelin/contracts/token/ERC721/IERC721.sol";

interface IBond is IERC721 {

    struct BondOrder {
        uint256 bondTypeId;
        address tokenA;
        address tokenB;
        string component;

        uint256 lifeDay;
        uint256 maturity;

        uint256 rateA;
        uint256 rateB;

        uint256 amountA;
        uint256 amountB;
        uint256 interestA;
        uint256 interestB;

        address parent;
        uint256 incentiveA;
        uint256 incentiveB;

        // 1-uncleared 2-settlement
        uint256 status;
    }

    function mint(BondOrder calldata order, string calldata tokenA, string calldata tokenB, address to) external returns (uint256);

    function burn(uint256 tokenId, address to) external;

    function getOrder(uint256 tokenId) external view returns (BondOrder memory);

    function getOrders(uint256[] calldata tokenIds) external view returns (BondOrder[] memory bondOrders);

}
"
    },
    "contracts/interface/IClaimOutFlow.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity ^0.8.12;

interface IClaimOutFlow {
    function claim(uint256 state, address from, uint256 amount, uint256 minOutPut) external returns (uint256 parentAmount, uint256 claimAmount);
}
"
    },
    "contracts/interface/ISubERC20.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity ^0.8.12;

interface ISubERC20 {
    function mint(address account, uint256 amount) external;
}
"
    },
    "contracts/interface/IBarkDao.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity ^0.8.12;

interface IBarkDao {

    struct Member {
        address parent;
        uint256 lastActionBlock;
        bool hasTeam;
    }

    function highestParentAddress() external view returns (address);
    function getLevel(address addr) external view returns (uint256);
    function members(address addr) external view returns (Member memory);
}
"
    },
    "contracts/interface/IMasterChefExtendV3.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity ^0.8.12;

interface IMasterChefExtendV3 {

    struct UserInfo {
        uint256 amount;
        uint256 rewardDebt;
        uint256 rewardBalance;
        uint256 lastClaim;
        uint256 sumTaxed;
        uint256 parentTaxed;
        uint256 startBlock;
    }

    struct Configuration {
        uint256 depositThreshold;
        uint256 claimThreshold;
        uint256 claimCharge;
        uint256 commissionRatio;
        uint256 cooldown;
        uint256 withdrawalCharge;
    }

    function pendingDai(address user) external view returns (uint256);

    function userInfo(address user) external view returns (UserInfo memory);

    function config() external view returns (Configuration memory);

    function highestParent() external view returns (address);

    function stakingTd(uint256 level) external view returns (uint256);

    function deposit(address from, uint256 _amount) external;
}
"
    },
    "@openzeppelin/contracts/token/ERC721/IERC721Receiver.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.6.0) (token/ERC721/IERC721Receiver.sol)

pragma solidity ^0.8.0;

/**
 * @title ERC721 token receiver interface
 * @dev Interface for any contract that wants to support safeTransfers
 * from ERC721 asset contracts.
 */
interface IERC721Receiver {
    /**
     * @dev Whenever an {IERC721} `tokenId` token is transferred to this contract via {IERC721-safeTransferFrom}
     * by `operator` from `from`, this function is called.
     *
     * It must return its Solidity selector to confirm the token transfer.
     * If any other value is returned or the interface is not implemented by the recipient, the transfer will be reverted.
     *
     * The selector can be obtained in Solidity with `IERC721Receiver.onERC721Received.selector`.
     */
    function onERC721Received(
        address operator,
        address from,
        uint256 tokenId,
        bytes calldata data
    ) external returns (bytes4);
}
"
    },
    "@openzeppelin/contracts/token/ERC20/IERC20.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.6.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 amount
    ) external returns (bool);
}
"
    },
    "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";
import "../extensions/draft-IERC20Permit.sol";
import "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    function safeTransfer(
        IERC20 token,
        address to,
        uint256 value
    ) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    function safeTransferFrom(
        IERC20 token,
        address from,
        address to,
        uint256 value
    ) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        require(
            (value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    function safeIncreaseAllowance(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        uint256 newAllowance = token.allowance(address(this), spender) + value;
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
    }

    function safeDecreaseAllowance(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        unchecked {
            uint256 oldAllowance = token.allowance(address(this), spender);
            require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
            uint256 newAllowance = oldAllowance - value;
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
        }
    }

    function safePermit(
        IERC20Permit token,
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal {
        uint256 nonceBefore = token.nonces(owner);
        token.permit(owner, spender, value, deadline, v, r, s);
        uint256 nonceAfter = token.nonces(owner);
        require(nonceAfter == nonceBefore + 1, "SafeERC20: permit did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        if (returndata.length > 0) {
            // Return data is optional
            require(abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
        }
    }
}
"
    },
    "@openzeppelin/contracts/access/Ownable.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}
"
    },
    "@openzeppelin/contracts/security/ReentrancyGuard.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (security/ReentrancyGuard.sol)

pragma solidity ^0.8.0;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    constructor() {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be _NOT_ENTERED
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }
}
"
    },
    "@openzeppelin/contracts/token/ERC721/IERC721.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (token/ERC721/IERC721.sol)

pragma solidity ^0.8.0;

import "../../utils/introspection/IERC165.sol";

/**
 * @dev Required interface of an ERC721 compliant contract.
 */
interface IERC721 is IERC165 {
    /**
     * @dev Emitted when `tokenId` token is transferred from `from` to `to`.
     */
    event Transfer(address indexed from, address indexed to, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables `approved` to manage the `tokenId` token.
     */
    event Approval(address indexed owner, address indexed approved, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables or disables (`approved`) `operator` to manage all of its assets.
     */
    event ApprovalForAll(address indexed owner, address indexed operator, bool approved);

    /**
     * @dev Returns the number of tokens in ``owner``'s account.
     */
    function balanceOf(address owner) external view returns (uint256 balance);

    /**
     * @dev Returns the owner of the `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function ownerOf(uint256 tokenId) external view returns (address owner);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId,
        bytes calldata data
    ) external;

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must have been allowed to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;

    /**
     * @dev Transfers `tokenId` token from `from` to `to`.
     *
     * WARNING: Note that the caller is responsible to confirm that the recipient is capable of receiving ERC721
     * or else they may be permanently lost. Usage of {safeTransferFrom} prevents loss, though the caller must
     * understand this adds an external call which potentially creates a reentrancy vulnerability.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;

    /**
     * @dev Gives permission to `to` to transfer `tokenId` token to another account.
     * The approval is cleared when the token is transferred.
     *
     * Only a single account can be approved at a time, so approving the zero address clears previous approvals.
     *
     * Requirements:
     *
     * - The caller must own the token or be an approved operator.
     * - `tokenId` must exist.
     *
     * Emits an {Approval} event.
     */
    function approve(address to, uint256 tokenId) external;

    /**
     * @dev Approve or remove `operator` as an operator for the caller.
     * Operators can call {transferFrom} or {safeTransferFrom} for any token owned by the caller.
     *
     * Requirements:
     *
     * - The `operator` cannot be the caller.
     *
     * Emits an {ApprovalForAll} event.
     */
    function setApprovalForAll(address operator, bool _approved) external;

    /**
     * @dev Returns the account approved for `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function getApproved(uint256 tokenId) external view returns (address operator);

    /**
     * @dev Returns if the `operator` is allowed to manage all of the assets of `owner`.
     *
     * See {setApprovalForAll}
     */
    function isApprovedForAll(address owner, address operator) external view returns (bool);
}
"
    },
    "@openzeppelin/contracts/utils/Address.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
     * the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
     *
     * _Available since v4.8._
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        if (success) {
            if (returndata.length == 0) {
                // only check isContract if the call was successful and the return data is empty
                // otherwise we already know that it was a contract
                require(isContract(target), "Address: call to non-contract");
            }
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason or using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    function _revert(bytes memory returndata, string memory errorMessage) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert(errorMessage);
        }
    }
}
"
    },
    "@openzeppelin/contracts/token/ERC20/extensions/draft-IERC20Permit.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC20/extensions/draft-IERC20Permit.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}
"
    },
    "@openzeppelin/contracts/utils/Context.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}
"
    },
    "@openzeppelin/contracts/utils/introspection/IERC165.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/IERC165.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}
"
    }
  },
  "settings": {
    "optimizer": {
      "enabled": true,
      "runs": 50
    },
    "outputSelection": {
      "*": {
        "*": [
          "evm.bytecode",
          "evm.deployedBytecode",
          "devdoc",
          "userdoc",
          "metadata",
          "abi"
        ]
      }
    },
    "remappings": [],
    "evmVersion": "istanbul"
  }
}}