Uniswap V2 (UNI-V2)

{{
  "language": "Solidity",
  "sources": {
    "contracts/contracts/UniswapV2Factory.sol": {
      "content": "pragma solidity =0.5.16;\r
\r
import './interfaces/IUniswapV2Factory.sol';\r
import './UniswapV2Pair.sol';\r
\r
contract UniswapV2Factory is IUniswapV2Factory {\r
    address public feeTo;\r
    address public feeToSetter;\r
\r
    mapping(address => mapping(address => address)) public getPair;\r
    address[] public allPairs;\r
\r
    bytes32 public constant INIT_CODE_PAIR_HASH = keccak256(abi.encodePacked(type(UniswapV2Pair).creationCode));\r
\r
    event PairCreated(address indexed token0, address indexed token1, address pair, uint);\r
\r
    constructor(address _feeToSetter) public {\r
        feeToSetter = _feeToSetter;\r
    }\r
\r
    function allPairsLength() external view returns (uint) {\r
        return allPairs.length;\r
    }\r
\r
    function createPair(address tokenA, address tokenB) external returns (address pair) {\r
        require(tokenA != tokenB, 'UniswapV2: IDENTICAL_ADDRESSES');\r
        (address token0, address token1) = tokenA < tokenB ? (tokenA, tokenB) : (tokenB, tokenA);\r
        require(token0 != address(0), 'UniswapV2: ZERO_ADDRESS');\r
        require(getPair[token0][token1] == address(0), 'UniswapV2: PAIR_EXISTS'); // single check is sufficient\r
        bytes memory bytecode = type(UniswapV2Pair).creationCode;\r
        bytes32 salt = keccak256(abi.encodePacked(token0, token1));\r
        assembly {\r
            pair := create2(0, add(bytecode, 32), mload(bytecode), salt)\r
        }\r
        IUniswapV2Pair(pair).initialize(token0, token1);\r
        getPair[token0][token1] = pair;\r
        getPair[token1][token0] = pair; // populate mapping in the reverse direction\r
        allPairs.push(pair);\r
        emit PairCreated(token0, token1, pair, allPairs.length);\r
    }\r
\r
    function setFeeTo(address _feeTo) external {\r
        require(msg.sender == feeToSetter, 'UniswapV2: FORBIDDEN');\r
        feeTo = _feeTo;\r
    }\r
\r
    function setFeeToSetter(address _feeToSetter) external {\r
        require(msg.sender == feeToSetter, 'UniswapV2: FORBIDDEN');\r
        feeToSetter = _feeToSetter;\r
    }\r
}\r
"
    },
    "contracts/contracts/UniswapV2Pair.sol": {
      "content": "pragma solidity =0.5.16;\r
\r
import './interfaces/IUniswapV2Pair.sol';\r
import './UniswapV2ERC20.sol';\r
import './libraries/Math.sol';\r
import './libraries/UQ112x112.sol';\r
import './interfaces/IERC20.sol';\r
import './interfaces/IUniswapV2Factory.sol';\r
import './interfaces/IUniswapV2Callee.sol';\r
\r
contract UniswapV2Pair is IUniswapV2Pair, UniswapV2ERC20 {\r
    using SafeMath  for uint;\r
    using UQ112x112 for uint224;\r
\r
    uint public constant MINIMUM_LIQUIDITY = 10**3;\r
    bytes4 private constant SELECTOR = bytes4(keccak256(bytes('transfer(address,uint256)')));\r
\r
    address public factory;\r
    address public token0;\r
    address public token1;\r
\r
    uint112 private reserve0;           // uses single storage slot, accessible via getReserves\r
    uint112 private reserve1;           // uses single storage slot, accessible via getReserves\r
    uint32  private blockTimestampLast; // uses single storage slot, accessible via getReserves\r
\r
    uint public price0CumulativeLast;\r
    uint public price1CumulativeLast;\r
    uint public kLast; // reserve0 * reserve1, as of immediately after the most recent liquidity event\r
\r
    uint private unlocked = 1;\r
    modifier lock() {\r
        require(unlocked == 1, 'UniswapV2: LOCKED');\r
        unlocked = 0;\r
        _;\r
        unlocked = 1;\r
    }\r
\r
    function getReserves() public view returns (uint112 _reserve0, uint112 _reserve1, uint32 _blockTimestampLast) {\r
        _reserve0 = reserve0;\r
        _reserve1 = reserve1;\r
        _blockTimestampLast = blockTimestampLast;\r
    }\r
\r
    function _safeTransfer(address token, address to, uint value) private {\r
        (bool success, bytes memory data) = token.call(abi.encodeWithSelector(SELECTOR, to, value));\r
        require(success && (data.length == 0 || abi.decode(data, (bool))), 'UniswapV2: TRANSFER_FAILED');\r
    }\r
\r
    event Mint(address indexed sender, uint amount0, uint amount1);\r
    event Burn(address indexed sender, uint amount0, uint amount1, address indexed to);\r
    event Swap(\r
        address indexed sender,\r
        uint amount0In,\r
        uint amount1In,\r
        uint amount0Out,\r
        uint amount1Out,\r
        address indexed to\r
    );\r
    event Sync(uint112 reserve0, uint112 reserve1);\r
\r
    constructor() public {\r
        factory = msg.sender;\r
    }\r
\r
    // called once by the factory at time of deployment\r
    function initialize(address _token0, address _token1) external {\r
        require(msg.sender == factory, 'UniswapV2: FORBIDDEN'); // sufficient check\r
        token0 = _token0;\r
        token1 = _token1;\r
    }\r
\r
    // update reserves and, on the first call per block, price accumulators\r
    function _update(uint balance0, uint balance1, uint112 _reserve0, uint112 _reserve1) private {\r
        require(balance0 <= uint112(-1) && balance1 <= uint112(-1), 'UniswapV2: OVERFLOW');\r
        uint32 blockTimestamp = uint32(block.timestamp % 2**32);\r
        uint32 timeElapsed = blockTimestamp - blockTimestampLast; // overflow is desired\r
        if (timeElapsed > 0 && _reserve0 != 0 && _reserve1 != 0) {\r
            // * never overflows, and + overflow is desired\r
            price0CumulativeLast += uint(UQ112x112.encode(_reserve1).uqdiv(_reserve0)) * timeElapsed;\r
            price1CumulativeLast += uint(UQ112x112.encode(_reserve0).uqdiv(_reserve1)) * timeElapsed;\r
        }\r
        reserve0 = uint112(balance0);\r
        reserve1 = uint112(balance1);\r
        blockTimestampLast = blockTimestamp;\r
        emit Sync(reserve0, reserve1);\r
    }\r
\r
    // if fee is on, mint liquidity equivalent to 1/6th of the growth in sqrt(k)\r
    function _mintFee(uint112 _reserve0, uint112 _reserve1) private returns (bool feeOn) {\r
        address feeTo = IUniswapV2Factory(factory).feeTo();\r
        feeOn = feeTo != address(0);\r
        uint _kLast = kLast; // gas savings\r
        if (feeOn) {\r
            if (_kLast != 0) {\r
                uint rootK = Math.sqrt(uint(_reserve0).mul(_reserve1));\r
                uint rootKLast = Math.sqrt(_kLast);\r
                if (rootK > rootKLast) {\r
                    uint numerator = totalSupply.mul(rootK.sub(rootKLast));\r
                    uint denominator = rootK.mul(5).add(rootKLast);\r
                    uint liquidity = numerator / denominator;\r
                    if (liquidity > 0) _mint(feeTo, liquidity);\r
                }\r
            }\r
        } else if (_kLast != 0) {\r
            kLast = 0;\r
        }\r
    }\r
\r
    // this low-level function should be called from a contract which performs important safety checks\r
    function mint(address to) external lock returns (uint liquidity) {\r
        (uint112 _reserve0, uint112 _reserve1,) = getReserves(); // gas savings\r
        uint balance0 = IERC20(token0).balanceOf(address(this));\r
        uint balance1 = IERC20(token1).balanceOf(address(this));\r
        uint amount0 = balance0.sub(_reserve0);\r
        uint amount1 = balance1.sub(_reserve1);\r
\r
        bool feeOn = _mintFee(_reserve0, _reserve1);\r
        uint _totalSupply = totalSupply; // gas savings, must be defined here since totalSupply can update in _mintFee\r
        if (_totalSupply == 0) {\r
            liquidity = Math.sqrt(amount0.mul(amount1)).sub(MINIMUM_LIQUIDITY);\r
           _mint(address(0), MINIMUM_LIQUIDITY); // permanently lock the first MINIMUM_LIQUIDITY tokens\r
        } else {\r
            liquidity = Math.min(amount0.mul(_totalSupply) / _reserve0, amount1.mul(_totalSupply) / _reserve1);\r
        }\r
        require(liquidity > 0, 'UniswapV2: INSUFFICIENT_LIQUIDITY_MINTED');\r
        _mint(to, liquidity);\r
\r
        _update(balance0, balance1, _reserve0, _reserve1);\r
        if (feeOn) kLast = uint(reserve0).mul(reserve1); // reserve0 and reserve1 are up-to-date\r
        emit Mint(msg.sender, amount0, amount1);\r
    }\r
\r
    // this low-level function should be called from a contract which performs important safety checks\r
    function burn(address to) external lock returns (uint amount0, uint amount1) {\r
        (uint112 _reserve0, uint112 _reserve1,) = getReserves(); // gas savings\r
        address _token0 = token0;                                // gas savings\r
        address _token1 = token1;                                // gas savings\r
        uint balance0 = IERC20(_token0).balanceOf(address(this));\r
        uint balance1 = IERC20(_token1).balanceOf(address(this));\r
        uint liquidity = balanceOf[address(this)];\r
\r
        bool feeOn = _mintFee(_reserve0, _reserve1);\r
        uint _totalSupply = totalSupply; // gas savings, must be defined here since totalSupply can update in _mintFee\r
        amount0 = liquidity.mul(balance0) / _totalSupply; // using balances ensures pro-rata distribution\r
        amount1 = liquidity.mul(balance1) / _totalSupply; // using balances ensures pro-rata distribution\r
        require(amount0 > 0 && amount1 > 0, 'UniswapV2: INSUFFICIENT_LIQUIDITY_BURNED');\r
        _burn(address(this), liquidity);\r
        _safeTransfer(_token0, to, amount0);\r
        _safeTransfer(_token1, to, amount1);\r
        balance0 = IERC20(_token0).balanceOf(address(this));\r
        balance1 = IERC20(_token1).balanceOf(address(this));\r
\r
        _update(balance0, balance1, _reserve0, _reserve1);\r
        if (feeOn) kLast = uint(reserve0).mul(reserve1); // reserve0 and reserve1 are up-to-date\r
        emit Burn(msg.sender, amount0, amount1, to);\r
    }\r
\r
    // this low-level function should be called from a contract which performs important safety checks\r
    function swap(uint amount0Out, uint amount1Out, address to, bytes calldata data) external lock {\r
        require(amount0Out > 0 || amount1Out > 0, 'UniswapV2: INSUFFICIENT_OUTPUT_AMOUNT');\r
        (uint112 _reserve0, uint112 _reserve1,) = getReserves(); // gas savings\r
        require(amount0Out < _reserve0 && amount1Out < _reserve1, 'UniswapV2: INSUFFICIENT_LIQUIDITY');\r
\r
        uint balance0;\r
        uint balance1;\r
        { // scope for _token{0,1}, avoids stack too deep errors\r
        address _token0 = token0;\r
        address _token1 = token1;\r
        require(to != _token0 && to != _token1, 'UniswapV2: INVALID_TO');\r
        if (amount0Out > 0) _safeTransfer(_token0, to, amount0Out); // optimistically transfer tokens\r
        if (amount1Out > 0) _safeTransfer(_token1, to, amount1Out); // optimistically transfer tokens\r
        if (data.length > 0) IUniswapV2Callee(to).uniswapV2Call(msg.sender, amount0Out, amount1Out, data);\r
        balance0 = IERC20(_token0).balanceOf(address(this));\r
        balance1 = IERC20(_token1).balanceOf(address(this));\r
        }\r
        uint amount0In = balance0 > _reserve0 - amount0Out ? balance0 - (_reserve0 - amount0Out) : 0;\r
        uint amount1In = balance1 > _reserve1 - amount1Out ? balance1 - (_reserve1 - amount1Out) : 0;\r
        require(amount0In > 0 || amount1In > 0, 'UniswapV2: INSUFFICIENT_INPUT_AMOUNT');\r
        { // scope for reserve{0,1}Adjusted, avoids stack too deep errors\r
        uint balance0Adjusted = balance0.mul(1000).sub(amount0In.mul(3));\r
        uint balance1Adjusted = balance1.mul(1000).sub(amount1In.mul(3));\r
        require(balance0Adjusted.mul(balance1Adjusted) >= uint(_reserve0).mul(_reserve1).mul(1000**2), 'UniswapV2: K');\r
        }\r
\r
        _update(balance0, balance1, _reserve0, _reserve1);\r
        emit Swap(msg.sender, amount0In, amount1In, amount0Out, amount1Out, to);\r
    }\r
\r
    // force balances to match reserves\r
    function skim(address to) external lock {\r
        address _token0 = token0; // gas savings\r
        address _token1 = token1; // gas savings\r
        _safeTransfer(_token0, to, IERC20(_token0).balanceOf(address(this)).sub(reserve0));\r
        _safeTransfer(_token1, to, IERC20(_token1).balanceOf(address(this)).sub(reserve1));\r
    }\r
\r
    // force reserves to match balances\r
    function sync() external lock {\r
        _update(IERC20(token0).balanceOf(address(this)), IERC20(token1).balanceOf(address(this)), reserve0, reserve1);\r
    }\r
}\r
"
    },
    "contracts/contracts/interfaces/IUniswapV2Factory.sol": {
      "content": "pragma solidity >=0.5.0;\r
\r
interface IUniswapV2Factory {\r
    event PairCreated(address indexed token0, address indexed token1, address pair, uint);\r
\r
    function feeTo() external view returns (address);\r
    function feeToSetter() external view returns (address);\r
\r
    function getPair(address tokenA, address tokenB) external view returns (address pair);\r
    function allPairs(uint) external view returns (address pair);\r
    function allPairsLength() external view returns (uint);\r
\r
    function createPair(address tokenA, address tokenB) external returns (address pair);\r
\r
    function setFeeTo(address) external;\r
    function setFeeToSetter(address) external;\r
}\r
"
    },
    "contracts/contracts/interfaces/IUniswapV2Callee.sol": {
      "content": "pragma solidity >=0.5.0;\r
\r
interface IUniswapV2Callee {\r
    function uniswapV2Call(address sender, uint amount0, uint amount1, bytes calldata data) external;\r
}\r
"
    },
    "contracts/contracts/interfaces/IERC20.sol": {
      "content": "pragma solidity >=0.5.0;\r
\r
interface IERC20 {\r
    event Approval(address indexed owner, address indexed spender, uint value);\r
    event Transfer(address indexed from, address indexed to, uint value);\r
\r
    function name() external view returns (string memory);\r
    function symbol() external view returns (string memory);\r
    function decimals() external view returns (uint8);\r
    function totalSupply() external view returns (uint);\r
    function balanceOf(address owner) external view returns (uint);\r
    function allowance(address owner, address spender) external view returns (uint);\r
\r
    function approve(address spender, uint value) external returns (bool);\r
    function transfer(address to, uint value) external returns (bool);\r
    function transferFrom(address from, address to, uint value) external returns (bool);\r
}\r
"
    },
    "contracts/contracts/libraries/UQ112x112.sol": {
      "content": "pragma solidity =0.5.16;\r
\r
// a library for handling binary fixed point numbers (https://en.wikipedia.org/wiki/Q_(number_format))\r
\r
// range: [0, 2**112 - 1]\r
// resolution: 1 / 2**112\r
\r
library UQ112x112 {\r
    uint224 constant Q112 = 2**112;\r
\r
    // encode a uint112 as a UQ112x112\r
    function encode(uint112 y) internal pure returns (uint224 z) {\r
        z = uint224(y) * Q112; // never overflows\r
    }\r
\r
    // divide a UQ112x112 by a uint112, returning a UQ112x112\r
    function uqdiv(uint224 x, uint112 y) internal pure returns (uint224 z) {\r
        z = x / uint224(y);\r
    }\r
}\r
"
    },
    "contracts/contracts/libraries/Math.sol": {
      "content": "pragma solidity =0.5.16;\r
\r
// a library for performing various math operations\r
\r
library Math {\r
    function min(uint x, uint y) internal pure returns (uint z) {\r
        z = x < y ? x : y;\r
    }\r
\r
    // babylonian method (https://en.wikipedia.org/wiki/Methods_of_computing_square_roots#Babylonian_method)\r
    function sqrt(uint y) internal pure returns (uint z) {\r
        if (y > 3) {\r
            z = y;\r
            uint x = y / 2 + 1;\r
            while (x < z) {\r
                z = x;\r
                x = (y / x + x) / 2;\r
            }\r
        } else if (y != 0) {\r
            z = 1;\r
        }\r
    }\r
}\r
"
    },
    "contracts/contracts/UniswapV2ERC20.sol": {
      "content": "pragma solidity =0.5.16;\r
\r
import './interfaces/IUniswapV2ERC20.sol';\r
import './libraries/SafeMath.sol';\r
\r
contract UniswapV2ERC20 is IUniswapV2ERC20 {\r
    using SafeMath for uint;\r
\r
    string public constant name = 'Uniswap V2';\r
    string public constant symbol = 'UNI-V2';\r
    uint8 public constant decimals = 18;\r
    uint  public totalSupply;\r
    mapping(address => uint) public balanceOf;\r
    mapping(address => mapping(address => uint)) public allowance;\r
\r
    bytes32 public DOMAIN_SEPARATOR;\r
    // keccak256("Permit(address owner,address spender,uint256 value,uint256 nonce,uint256 deadline)");\r
    bytes32 public constant PERMIT_TYPEHASH = 0x6e71edae12b1b97f4d1f60370fef10105fa2faae0126114a169c64845d6126c9;\r
    mapping(address => uint) public nonces;\r
\r
    event Approval(address indexed owner, address indexed spender, uint value);\r
    event Transfer(address indexed from, address indexed to, uint value);\r
\r
    constructor() public {\r
        uint chainId;\r
        assembly {\r
            chainId := chainid\r
        }\r
        DOMAIN_SEPARATOR = keccak256(\r
            abi.encode(\r
                keccak256('EIP712Domain(string name,string version,uint256 chainId,address verifyingContract)'),\r
                keccak256(bytes(name)),\r
                keccak256(bytes('1')),\r
                chainId,\r
                address(this)\r
            )\r
        );\r
    }\r
\r
    function _mint(address to, uint value) internal {\r
        totalSupply = totalSupply.add(value);\r
        balanceOf[to] = balanceOf[to].add(value);\r
        emit Transfer(address(0), to, value);\r
    }\r
\r
    function _burn(address from, uint value) internal {\r
        balanceOf[from] = balanceOf[from].sub(value);\r
        totalSupply = totalSupply.sub(value);\r
        emit Transfer(from, address(0), value);\r
    }\r
\r
    function _approve(address owner, address spender, uint value) private {\r
        allowance[owner][spender] = value;\r
        emit Approval(owner, spender, value);\r
    }\r
\r
    function _transfer(address from, address to, uint value) private {\r
        balanceOf[from] = balanceOf[from].sub(value);\r
        balanceOf[to] = balanceOf[to].add(value);\r
        emit Transfer(from, to, value);\r
    }\r
\r
    function approve(address spender, uint value) external returns (bool) {\r
        _approve(msg.sender, spender, value);\r
        return true;\r
    }\r
\r
    function transfer(address to, uint value) external returns (bool) {\r
        _transfer(msg.sender, to, value);\r
        return true;\r
    }\r
\r
    function transferFrom(address from, address to, uint value) external returns (bool) {\r
        if (allowance[from][msg.sender] != uint(-1)) {\r
            allowance[from][msg.sender] = allowance[from][msg.sender].sub(value);\r
        }\r
        _transfer(from, to, value);\r
        return true;\r
    }\r
\r
    function permit(address owner, address spender, uint value, uint deadline, uint8 v, bytes32 r, bytes32 s) external {\r
        require(deadline >= block.timestamp, 'UniswapV2: EXPIRED');\r
        bytes32 digest = keccak256(\r
            abi.encodePacked(\r
                '\x19\x01',\r
                DOMAIN_SEPARATOR,\r
                keccak256(abi.encode(PERMIT_TYPEHASH, owner, spender, value, nonces[owner]++, deadline))\r
            )\r
        );\r
        address recoveredAddress = ecrecover(digest, v, r, s);\r
        require(recoveredAddress != address(0) && recoveredAddress == owner, 'UniswapV2: INVALID_SIGNATURE');\r
        _approve(owner, spender, value);\r
    }\r
}\r
"
    },
    "contracts/contracts/interfaces/IUniswapV2Pair.sol": {
      "content": "pragma solidity >=0.5.0;\r
\r
interface IUniswapV2Pair {\r
    event Approval(address indexed owner, address indexed spender, uint value);\r
    event Transfer(address indexed from, address indexed to, uint value);\r
\r
    function name() external pure returns (string memory);\r
    function symbol() external pure returns (string memory);\r
    function decimals() external pure returns (uint8);\r
    function totalSupply() external view returns (uint);\r
    function balanceOf(address owner) external view returns (uint);\r
    function allowance(address owner, address spender) external view returns (uint);\r
\r
    function approve(address spender, uint value) external returns (bool);\r
    function transfer(address to, uint value) external returns (bool);\r
    function transferFrom(address from, address to, uint value) external returns (bool);\r
\r
    function DOMAIN_SEPARATOR() external view returns (bytes32);\r
    function PERMIT_TYPEHASH() external pure returns (bytes32);\r
    function nonces(address owner) external view returns (uint);\r
\r
    function permit(address owner, address spender, uint value, uint deadline, uint8 v, bytes32 r, bytes32 s) external;\r
\r
    event Mint(address indexed sender, uint amount0, uint amount1);\r
    event Burn(address indexed sender, uint amount0, uint amount1, address indexed to);\r
    event Swap(\r
        address indexed sender,\r
        uint amount0In,\r
        uint amount1In,\r
        uint amount0Out,\r
        uint amount1Out,\r
        address indexed to\r
    );\r
    event Sync(uint112 reserve0, uint112 reserve1);\r
\r
    function MINIMUM_LIQUIDITY() external pure returns (uint);\r
    function factory() external view returns (address);\r
    function token0() external view returns (address);\r
    function token1() external view returns (address);\r
    function getReserves() external view returns (uint112 reserve0, uint112 reserve1, uint32 blockTimestampLast);\r
    function price0CumulativeLast() external view returns (uint);\r
    function price1CumulativeLast() external view returns (uint);\r
    function kLast() external view returns (uint);\r
\r
    function mint(address to) external returns (uint liquidity);\r
    function burn(address to) external returns (uint amount0, uint amount1);\r
    function swap(uint amount0Out, uint amount1Out, address to, bytes calldata data) external;\r
    function skim(address to) external;\r
    function sync() external;\r
\r
    function initialize(address, address) external;\r
}\r
"
    },
    "contracts/contracts/libraries/SafeMath.sol": {
      "content": "pragma solidity =0.5.16;\r
\r
// a library for performing overflow-safe math, courtesy of DappHub (https://github.com/dapphub/ds-math)\r
\r
library SafeMath {\r
    function add(uint x, uint y) internal pure returns (uint z) {\r
        require((z = x + y) >= x, 'ds-math-add-overflow');\r
    }\r
\r
    function sub(uint x, uint y) internal pure returns (uint z) {\r
        require((z = x - y) <= x, 'ds-math-sub-underflow');\r
    }\r
\r
    function mul(uint x, uint y) internal pure returns (uint z) {\r
        require(y == 0 || (z = x * y) / y == x, 'ds-math-mul-overflow');\r
    }\r
}\r
"
    },
    "contracts/contracts/interfaces/IUniswapV2ERC20.sol": {
      "content": "pragma solidity >=0.5.0;\r
\r
interface IUniswapV2ERC20 {\r
    event Approval(address indexed owner, address indexed spender, uint value);\r
    event Transfer(address indexed from, address indexed to, uint value);\r
\r
    function name() external pure returns (string memory);\r
    function symbol() external pure returns (string memory);\r
    function decimals() external pure returns (uint8);\r
    function totalSupply() external view returns (uint);\r
    function balanceOf(address owner) external view returns (uint);\r
    function allowance(address owner, address spender) external view returns (uint);\r
\r
    function approve(address spender, uint value) external returns (bool);\r
    function transfer(address to, uint value) external returns (bool);\r
    function transferFrom(address from, address to, uint value) external returns (bool);\r
\r
    function DOMAIN_SEPARATOR() external view returns (bytes32);\r
    function PERMIT_TYPEHASH() external pure returns (bytes32);\r
    function nonces(address owner) external view returns (uint);\r
\r
    function permit(address owner, address spender, uint value, uint deadline, uint8 v, bytes32 r, bytes32 s) external;\r
}\r
"
    }
  },
  "settings": {
    "optimizer": {
      "enabled": false,
      "runs": 200
    },
    "outputSelection": {
      "*": {
        "*": [
          "evm.bytecode",
          "evm.deployedBytecode",
          "devdoc",
          "userdoc",
          "metadata",
          "abi"
        ]
      }
    },
    "remappings": []
  }
}}