DiaHohmAdapter

// File: @openzeppelin/contracts/utils/Context.sol


// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// File: @openzeppelin/contracts/access/Ownable.sol


// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;


/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// File: @openzeppelin/contracts/token/ERC20/IERC20.sol


// OpenZeppelin Contracts (last updated v5.4.0) (token/ERC20/IERC20.sol)

pragma solidity >=0.4.16;

/**
 * @dev Interface of the ERC-20 standard as defined in the ERC.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// File: @openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol


// OpenZeppelin Contracts (last updated v5.4.0) (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity >=0.6.2;


/**
 * @dev Interface for the optional metadata functions from the ERC-20 standard.
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}

// File: contracts/DiaHohmAdapter.sol


pragma solidity 0.8.29;



interface IDIAOracleV2 {
    function getValue(string memory) external view returns (uint128, uint128);
}

interface ITokenizedBalanceSheetVault {
    function convertFromShares(uint256 shares) external view returns (
        uint256[] memory assets,
        uint256[] memory liabilities
    );

    function tokens() external view returns (address[] memory assetTokens, address[] memory liabilityTokens);
}

error InvalidOracleValue(address oracleAddress, string key);
error OracleKeyNotFound(address asset);

contract DiaHohmAdapter is Ownable(msg.sender) {
    mapping(address => string) public oracleKeys;
    uint256 diaOracleDecimals;
    address diaOracleAddress;
    string hohmPriceOracleKey;

    uint256 constant MAX_DECIMALS = 30;

    constructor(uint256 newDiaOracleDecimals, address newDiaOracleAddress) {
        diaOracleDecimals = newDiaOracleDecimals;
        diaOracleAddress = newDiaOracleAddress;
        hohmPriceOracleKey = "hOHM/USD";
    }

    function addOracleKey(address assetAddress, string memory newOracleKey) public onlyOwner {
        oracleKeys[assetAddress] = newOracleKey;
    }

    function removeOracleKey(address assetAddress) public onlyOwner {
        oracleKeys[assetAddress] = "";
    }

    function updateDiaOracleDecimals(uint256 newDiaOracleDecimals) public onlyOwner {
        diaOracleDecimals = newDiaOracleDecimals;
    }

    function updateHohmPriceOracleKey(string memory newHohmPriceOracleKey) public onlyOwner {
        hohmPriceOracleKey = newHohmPriceOracleKey;
    }

    function getHohmFairValuePrice(address vault) public view returns (uint256) {
        uint8 _vaultDecimals = IERC20Metadata(vault).decimals();
        ITokenizedBalanceSheetVault _vault = ITokenizedBalanceSheetVault(vault);

        (uint256[] memory _assetPerShare, uint256[] memory _liabilitiesPerShare) = _vault.convertFromShares(10 ** _vaultDecimals);
        (address[] memory _assetTokens, address[] memory _liabilityTokens) = _vault.tokens();

        int256 _totalPrice;
        for (uint256 i; i < _assetTokens.length; ++i) {
            string memory _oracleKey = oracleKeys[_assetTokens[i]];
            if (bytes(_oracleKey).length == 0) {
                revert OracleKeyNotFound(_assetTokens[i]);
            }

            (uint128 currPrice, uint128 currTimestamp) = IDIAOracleV2(diaOracleAddress).getValue(_oracleKey);
            if (currTimestamp == 0) {
                revert InvalidOracleValue(diaOracleAddress, _oracleKey);
            }
            
            _totalPrice += calculatePricePerAssetScaled(diaOracleDecimals, currPrice, int256(_assetPerShare[i]), _assetTokens[i]);
        }
        for (uint256 i; i < _liabilityTokens.length; ++i) {
            string memory _oracleKey = oracleKeys[_liabilityTokens[i]];
            if (bytes(_oracleKey).length == 0) {
                revert OracleKeyNotFound(_assetTokens[i]);
            }

            (uint128 currPrice, uint128 currTimestamp) = IDIAOracleV2(diaOracleAddress).getValue(_oracleKey);
            if (currTimestamp == 0) {
                revert InvalidOracleValue(diaOracleAddress, _oracleKey);
            }
            
            _totalPrice -= calculatePricePerAssetScaled(diaOracleDecimals, currPrice, int256(_liabilitiesPerShare[i]), _liabilityTokens[i]);
        }

        return _totalPrice > 0 ? uint256(_totalPrice) : 0;
    }

    function getMaxPrice(address vault) public view returns (uint256, uint128) {
        (uint128 currMarketPrice, uint128 currTimestamp) = IDIAOracleV2(diaOracleAddress).getValue(hohmPriceOracleKey);
        uint256 fairValuePrice = getHohmFairValuePrice(vault);

        if (fairValuePrice > currMarketPrice) {
            return (fairValuePrice, currTimestamp);
        } else {
            return (currMarketPrice, currTimestamp);
        }
    }

    function calculatePricePerAssetScaled(uint256 decimalsOutput, uint256 diaPrice, int256 tokenAmount, address token) public view returns (int256) {
        // Scale everything to MAX_DECIMALS decimals and then perform the calculations
        require(diaOracleDecimals < MAX_DECIMALS, "DIA Oracle decimals must be less than MAX_DECIMALS.");
        require(IERC20Metadata(token).decimals() < 30, "Token decimals must be less than MAX_DECIMALS.");

        uint256 diaDecimalDelta = MAX_DECIMALS - diaOracleDecimals;
        uint256 assetDecimalDelta = MAX_DECIMALS - IERC20Metadata(token).decimals();
        uint256 outputDecimalDelta = 2 * MAX_DECIMALS - decimalsOutput;
        
        return (int256(tokenAmount * int256(10**assetDecimalDelta)) * (int256(diaPrice) * int256(10**diaDecimalDelta))) / int256(10**outputDecimalDelta);
    }
}