ERC20Evaluator

{{
  "language": "Solidity",
  "sources": {
    "@openzeppelin/contracts-upgradeable/proxy/utils/Initializable.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (proxy/utils/Initializable.sol)

pragma solidity ^0.8.20;

/**
 * @dev This is a base contract to aid in writing upgradeable contracts, or any kind of contract that will be deployed
 * behind a proxy. Since proxied contracts do not make use of a constructor, it's common to move constructor logic to an
 * external initializer function, usually called `initialize`. It then becomes necessary to protect this initializer
 * function so it can only be called once. The {initializer} modifier provided by this contract will have this effect.
 *
 * The initialization functions use a version number. Once a version number is used, it is consumed and cannot be
 * reused. This mechanism prevents re-execution of each "step" but allows the creation of new initialization steps in
 * case an upgrade adds a module that needs to be initialized.
 *
 * For example:
 *
 * [.hljs-theme-light.nopadding]
 * ```solidity
 * contract MyToken is ERC20Upgradeable {
 *     function initialize() initializer public {
 *         __ERC20_init("MyToken", "MTK");
 *     }
 * }
 *
 * contract MyTokenV2 is MyToken, ERC20PermitUpgradeable {
 *     function initializeV2() reinitializer(2) public {
 *         __ERC20Permit_init("MyToken");
 *     }
 * }
 * ```
 *
 * TIP: To avoid leaving the proxy in an uninitialized state, the initializer function should be called as early as
 * possible by providing the encoded function call as the `_data` argument to {ERC1967Proxy-constructor}.
 *
 * CAUTION: When used with inheritance, manual care must be taken to not invoke a parent initializer twice, or to ensure
 * that all initializers are idempotent. This is not verified automatically as constructors are by Solidity.
 *
 * [CAUTION]
 * ====
 * Avoid leaving a contract uninitialized.
 *
 * An uninitialized contract can be taken over by an attacker. This applies to both a proxy and its implementation
 * contract, which may impact the proxy. To prevent the implementation contract from being used, you should invoke
 * the {_disableInitializers} function in the constructor to automatically lock it when it is deployed:
 *
 * [.hljs-theme-light.nopadding]
 * ```
 * /// @custom:oz-upgrades-unsafe-allow constructor
 * constructor() {
 *     _disableInitializers();
 * }
 * ```
 * ====
 */
abstract contract Initializable {
    /**
     * @dev Storage of the initializable contract.
     *
     * It's implemented on a custom ERC-7201 namespace to reduce the risk of storage collisions
     * when using with upgradeable contracts.
     *
     * @custom:storage-location erc7201:openzeppelin.storage.Initializable
     */
    struct InitializableStorage {
        /**
         * @dev Indicates that the contract has been initialized.
         */
        uint64 _initialized;
        /**
         * @dev Indicates that the contract is in the process of being initialized.
         */
        bool _initializing;
    }

    // keccak256(abi.encode(uint256(keccak256("openzeppelin.storage.Initializable")) - 1)) & ~bytes32(uint256(0xff))
    bytes32 private constant INITIALIZABLE_STORAGE = 0xf0c57e16840df040f15088dc2f81fe391c3923bec73e23a9662efc9c229c6a00;

    /**
     * @dev The contract is already initialized.
     */
    error InvalidInitialization();

    /**
     * @dev The contract is not initializing.
     */
    error NotInitializing();

    /**
     * @dev Triggered when the contract has been initialized or reinitialized.
     */
    event Initialized(uint64 version);

    /**
     * @dev A modifier that defines a protected initializer function that can be invoked at most once. In its scope,
     * `onlyInitializing` functions can be used to initialize parent contracts.
     *
     * Similar to `reinitializer(1)`, except that in the context of a constructor an `initializer` may be invoked any
     * number of times. This behavior in the constructor can be useful during testing and is not expected to be used in
     * production.
     *
     * Emits an {Initialized} event.
     */
    modifier initializer() {
        // solhint-disable-next-line var-name-mixedcase
        InitializableStorage storage $ = _getInitializableStorage();

        // Cache values to avoid duplicated sloads
        bool isTopLevelCall = !$._initializing;
        uint64 initialized = $._initialized;

        // Allowed calls:
        // - initialSetup: the contract is not in the initializing state and no previous version was
        //                 initialized
        // - construction: the contract is initialized at version 1 (no reininitialization) and the
        //                 current contract is just being deployed
        bool initialSetup = initialized == 0 && isTopLevelCall;
        bool construction = initialized == 1 && address(this).code.length == 0;

        if (!initialSetup && !construction) {
            revert InvalidInitialization();
        }
        $._initialized = 1;
        if (isTopLevelCall) {
            $._initializing = true;
        }
        _;
        if (isTopLevelCall) {
            $._initializing = false;
            emit Initialized(1);
        }
    }

    /**
     * @dev A modifier that defines a protected reinitializer function that can be invoked at most once, and only if the
     * contract hasn't been initialized to a greater version before. In its scope, `onlyInitializing` functions can be
     * used to initialize parent contracts.
     *
     * A reinitializer may be used after the original initialization step. This is essential to configure modules that
     * are added through upgrades and that require initialization.
     *
     * When `version` is 1, this modifier is similar to `initializer`, except that functions marked with `reinitializer`
     * cannot be nested. If one is invoked in the context of another, execution will revert.
     *
     * Note that versions can jump in increments greater than 1; this implies that if multiple reinitializers coexist in
     * a contract, executing them in the right order is up to the developer or operator.
     *
     * WARNING: Setting the version to 2**64 - 1 will prevent any future reinitialization.
     *
     * Emits an {Initialized} event.
     */
    modifier reinitializer(uint64 version) {
        // solhint-disable-next-line var-name-mixedcase
        InitializableStorage storage $ = _getInitializableStorage();

        if ($._initializing || $._initialized >= version) {
            revert InvalidInitialization();
        }
        $._initialized = version;
        $._initializing = true;
        _;
        $._initializing = false;
        emit Initialized(version);
    }

    /**
     * @dev Modifier to protect an initialization function so that it can only be invoked by functions with the
     * {initializer} and {reinitializer} modifiers, directly or indirectly.
     */
    modifier onlyInitializing() {
        _checkInitializing();
        _;
    }

    /**
     * @dev Reverts if the contract is not in an initializing state. See {onlyInitializing}.
     */
    function _checkInitializing() internal view virtual {
        if (!_isInitializing()) {
            revert NotInitializing();
        }
    }

    /**
     * @dev Locks the contract, preventing any future reinitialization. This cannot be part of an initializer call.
     * Calling this in the constructor of a contract will prevent that contract from being initialized or reinitialized
     * to any version. It is recommended to use this to lock implementation contracts that are designed to be called
     * through proxies.
     *
     * Emits an {Initialized} event the first time it is successfully executed.
     */
    function _disableInitializers() internal virtual {
        // solhint-disable-next-line var-name-mixedcase
        InitializableStorage storage $ = _getInitializableStorage();

        if ($._initializing) {
            revert InvalidInitialization();
        }
        if ($._initialized != type(uint64).max) {
            $._initialized = type(uint64).max;
            emit Initialized(type(uint64).max);
        }
    }

    /**
     * @dev Returns the highest version that has been initialized. See {reinitializer}.
     */
    function _getInitializedVersion() internal view returns (uint64) {
        return _getInitializableStorage()._initialized;
    }

    /**
     * @dev Returns `true` if the contract is currently initializing. See {onlyInitializing}.
     */
    function _isInitializing() internal view returns (bool) {
        return _getInitializableStorage()._initializing;
    }

    /**
     * @dev Returns a pointer to the storage namespace.
     */
    // solhint-disable-next-line var-name-mixedcase
    function _getInitializableStorage() private pure returns (InitializableStorage storage $) {
        assembly {
            $.slot := INITIALIZABLE_STORAGE
        }
    }
}
"
    },
    "@openzeppelin/contracts-upgradeable/utils/introspection/ERC165Upgradeable.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/introspection/ERC165.sol)

pragma solidity ^0.8.20;

import {IERC165} from "@openzeppelin/contracts/utils/introspection/IERC165.sol";
import {Initializable} from "../../proxy/utils/Initializable.sol";

/**
 * @dev Implementation of the {IERC165} interface.
 *
 * Contracts that want to implement ERC165 should inherit from this contract and override {supportsInterface} to check
 * for the additional interface id that will be supported. For example:
 *
 * ```solidity
 * function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
 *     return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
 * }
 * ```
 */
abstract contract ERC165Upgradeable is Initializable, IERC165 {
    function __ERC165_init() internal onlyInitializing {
    }

    function __ERC165_init_unchained() internal onlyInitializing {
    }
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual returns (bool) {
        return interfaceId == type(IERC165).interfaceId;
    }
}
"
    },
    "@openzeppelin/contracts/token/ERC20/IERC20.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}
"
    },
    "@openzeppelin/contracts/utils/Address.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/Address.sol)

pragma solidity ^0.8.20;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev The ETH balance of the account is not enough to perform the operation.
     */
    error AddressInsufficientBalance(address account);

    /**
     * @dev There's no code at `target` (it is not a contract).
     */
    error AddressEmptyCode(address target);

    /**
     * @dev A call to an address target failed. The target may have reverted.
     */
    error FailedInnerCall();

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.20/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        if (address(this).balance < amount) {
            revert AddressInsufficientBalance(address(this));
        }

        (bool success, ) = recipient.call{value: amount}("");
        if (!success) {
            revert FailedInnerCall();
        }
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason or custom error, it is bubbled
     * up by this function (like regular Solidity function calls). However, if
     * the call reverted with no returned reason, this function reverts with a
     * {FailedInnerCall} error.
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        if (address(this).balance < value) {
            revert AddressInsufficientBalance(address(this));
        }
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and reverts if the target
     * was not a contract or bubbling up the revert reason (falling back to {FailedInnerCall}) in case of an
     * unsuccessful call.
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata
    ) internal view returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            // only check if target is a contract if the call was successful and the return data is empty
            // otherwise we already know that it was a contract
            if (returndata.length == 0 && target.code.length == 0) {
                revert AddressEmptyCode(target);
            }
            return returndata;
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and reverts if it wasn't, either by bubbling the
     * revert reason or with a default {FailedInnerCall} error.
     */
    function verifyCallResult(bool success, bytes memory returndata) internal pure returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            return returndata;
        }
    }

    /**
     * @dev Reverts with returndata if present. Otherwise reverts with {FailedInnerCall}.
     */
    function _revert(bytes memory returndata) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert FailedInnerCall();
        }
    }
}
"
    },
    "@openzeppelin/contracts/utils/introspection/IERC165.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/introspection/IERC165.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}
"
    },
    "contracts/compiler/erc20/ERC20Evaluator.sol": {
      "content": "// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.22;

import {IExchangeEvaluator} from "contracts/interfaces/compiler/adapters/index.sol";

import {Address} from "contracts/libraries/Address.sol";
import {Command, CommandPresets} from "contracts/libraries/CommandLibrary.sol";

import {Path} from "../libraries/Path.sol";

contract ERC20Evaluator is IExchangeEvaluator {
    using Address for address;
    using Path for bytes;

    error InvalidPathForTransferRequest();

    function evaluate(
        address,
        ExchangeRequest calldata _request
    ) external pure override returns (Command[] memory cmds_) {
        address token = _request.path.extractTokenIn();

        if (token.isEth()) {
            return
                Command({target: _request.recipient, value: _request.amountIn, payload: ""})
                    .asArray();
        } else {
            return CommandPresets.transfer(token, _request.recipient, _request.amountIn).asArray();
        }
    }
}
"
    },
    "contracts/compiler/libraries/Path.sol": {
      "content": "// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.22;

library Path {
    using Path for bytes;

    uint256 internal constant ADDRESS_LEN = 20;
    uint256 internal constant POOL_ID_LEN = 4;
    uint256 internal constant NEXT_OFFSET = ADDRESS_LEN + POOL_ID_LEN;

    error InvalidPathLength(uint256);

    function extractTokenIn(bytes calldata _path) internal pure returns (address tokenIn_) {
        _path.ensureValid();
        tokenIn_ = _path.extractTokenInUnsafe();
    }

    function extractTokenInUnsafe(bytes calldata _path) internal pure returns (address tokenIn_) {
        tokenIn_ = address(bytes20(_path[0:ADDRESS_LEN]));
    }

    function extractTokenOut(bytes calldata _path) internal pure returns (address tokenOut_) {
        _path.ensureValid();
        tokenOut_ = _path.extractTokenOutUnsafe();
    }

    function extractTokenOutUnsafe(bytes calldata _path) internal pure returns (address tokenOut_) {
        uint256 len = _path.length;
        tokenOut_ = address(bytes20(_path[len - ADDRESS_LEN:len]));
    }

    /* solhint-disable var-name-mixedcase */
    function extractPool(
        bytes calldata _path,
        uint256 _poolNumber
    ) internal pure returns (address tokenIn__, address tokenOut_, uint32 poolId_____) {
        /* solhint-enable var-name-mixedcase */
        _path.ensureValid();
        uint256 ptr = _poolNumber * NEXT_OFFSET;

        tokenIn__ = address(bytes20(_path[ptr:(ptr = ptr + ADDRESS_LEN)]));
        poolId_____ = uint32(bytes4(_path[ptr:(ptr = ptr + POOL_ID_LEN)]));
        tokenOut_ = address(bytes20(_path[ptr:(ptr = ptr + ADDRESS_LEN)]));
    }

    function getNumberOfPools(bytes calldata _path) internal pure returns (uint256) {
        _path.ensureValid();
        return (_path.length - ADDRESS_LEN) / NEXT_OFFSET;
    }

    function ensureValid(bytes calldata _path) internal pure {
        if (!isValid(_path)) revert InvalidPathLength(_path.length);
    }

    function isValid(bytes calldata _path) private pure returns (bool) {
        if (_path.length < ADDRESS_LEN) return false;
        return (_path.length - ADDRESS_LEN) % NEXT_OFFSET == 0;
    }
}
"
    },
    "contracts/interfaces/base/CommonErrors.sol": {
      "content": "// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.22;

/**
 * @notice An error indicating that the amount for the specified token is zero.
 * @param token The address of the token with a zero amount.
 */
error AmountMustNotBeZero(address token);

/**
 * @notice An error indicating that an address must not be zero.
 */
error AddressMustNotBeZero();

/**
 * @notice An error indicating that an array must not be empty.
 */
error ArrayMustNotBeEmpty();

/**
 * @notice An error indicating storage is already up to date and doesn't need further processing.
 * @dev This error is thrown when attempting to update an entity(s) that is(are) already up to date.
 */
error AlreadyUpToDate();

/**
 * @notice An error indicating that an action is unauthorized for the specified account.
 * @param account The address of the unauthorized account.
 */
error UnauthorizedAccount(address account);

/**
 * @notice An error indicating that the min amount out must not be zero.
 */
error MinAmountOutMustNotBeZero();
"
    },
    "contracts/interfaces/base/IERC165Extended.sol": {
      "content": "// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.22;

/* solhint-disable no-unused-import */
import {
    IERC165
} from "@openzeppelin/contracts-upgradeable/utils/introspection/ERC165Upgradeable.sol";
/* solhint-enable no-unused-import */

/**
 * @notice An error indicating that an address does not support the expected interface
 * @param implementation The address that does not implement the required interface
 */
error UnsupportedInterface(address implementation);

/**
 * @dev Extended interface of the ERC165 standard to ensure compatibility
 * with Diamond facets as defined in EIP-2535.
 *
 * This interface extends the basic ERC165 mechanism to provide additional
 * flexibility for querying supported interfaces, which can then be
 * dynamically resolved by one of facets in a Diamond.
 */
interface IERC165Extended {
    /**
     * @notice Checks if the given interface ID is supported by the contract.
     * @param interfaceId The ID of the interface to query.
     * @return isSupported Boolean value indicating whether the interface is supported.
     */
    function supportsInterfaceExtended(bytes4 interfaceId) external pure returns (bool isSupported);
}
"
    },
    "contracts/interfaces/compiler/adapters/IDecreasePositionEvaluator.sol": {
      "content": "// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.22;

import {Asset} from "contracts/libraries/AssetLibrary.sol";
import {Command} from "../Command.sol";
import {PositionDescriptor} from "./PositionDescriptor.sol";

interface IDecreasePositionEvaluator {
    /**
     * @notice Request structure for decreasing a position.
     * @dev `descriptor`: The [`PositionDescriptor`](/interfaces/compiler/adapters/PositionDescriptor.sol/struct.PositionDescriptor.html)
     *  struct.
     * @dev `liquidity`: Abstract amount that can be interpreted differently in different protocols (e.g., amount of LP tokens to burn).
     * @dev `minOutput`: [`Asset`](/interfaces/compliance/Asset.sol/struct.Asset.html) array with minimum amounts that must be retrieved from the position.
     */
    struct DecreasePositionRequest {
        PositionDescriptor descriptor;
        uint256 liquidity;
        Asset[] minOutput;
    }

    /**
     * @notice Evaluate a decrease position request.
     * @param _operator Address which initiated the request
     * @param _request The [`DecreasePositionRequest`](#decreasepositionrequest) struct containing decrease position details.
     * @return cmds_ An array of [`Command`](../../Command.sol/struct.Command.html) to execute the request.
     */
    function evaluate(
        address _operator,
        DecreasePositionRequest calldata _request
    ) external returns (Command[] memory cmds_);
}
"
    },
    "contracts/interfaces/compiler/adapters/IExchangeEvaluator.sol": {
      "content": "// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.22;

import {Command} from "../Command.sol";

/**
 * @title IExchangeEvaluator
 * @notice Interface for compiling commands for token exchanges for different protocols.
 */
interface IExchangeEvaluator {
    /**
     * @notice Structure for an exchange token request.
     * @dev `path`: Encoded path of tokens to follow in the exchange, including pool identifiers.
     * 20 bytes(tokenA) + 4 byte(poolId_A_B) + 20 bytes(tokenB) + ...
     * ... + 4 byte(poolId_N-1_N) + 20 bytes(tokenN).
     * @dev `extraData`: Additional data specific to a particular protocol, such as the response from a 1Inch Exchange API.
     * @dev `amountIn`: The amount of tokenA to spend.
     * @dev `minAmountOut`: The minimum amount of tokenN to receive.
     * @dev `recipient`: The recipient of tokenN.
     */
    struct ExchangeRequest {
        bytes path;
        bytes extraData;
        uint256 amountIn;
        uint256 minAmountOut;
        address recipient;
    }

    /**
     * @notice Constructs an exchange token request.
     * @param _operator Address which initiated the request
     * @param _request The [`ExchangeRequest`](#exchangerequest) struct containing exchange token details.
     * @return cmds_ An array of [`Command`](../../Command.sol/struct.Command.html) to execute the request.
     */
    function evaluate(
        address _operator,
        ExchangeRequest calldata _request
    ) external view returns (Command[] memory cmds_);
}
"
    },
    "contracts/interfaces/compiler/adapters/IIncreasePositionEvaluator.sol": {
      "content": "// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.22;

import {Asset} from "contracts/libraries/AssetLibrary.sol";
import {Command} from "../Command.sol";
import {PositionDescriptor} from "./PositionDescriptor.sol";

interface IIncreasePositionEvaluator {
    /**
     * @notice Structure for an increase position request.
     * @dev `descriptor`: The [`PositionDescriptor`](/interfaces/compiler/adapters/PositionDescriptor.sol/struct.PositionDescriptor.html)
     *  struct.
     * @dev `input`: An array of [`Asset`](/interfaces/compliance/Asset.sol/struct.Asset.html) representing the token-amounts that will be added to the position.
     * @dev `minLiquidityOut`: An abstract amount that can be interpreted differently in different protocols (e.g., minimum amount of LP tokens to receive).
     */
    struct IncreasePositionRequest {
        PositionDescriptor descriptor;
        Asset[] input;
        uint256 minLiquidityOut;
    }

    /**
     * @notice Evaluate a increase position request.
     * @param _operator Address which initiated the request
     * @param _request The [`IncreasePositionRequest`](#increasepositionrequest) struct containing increase position details.
     * @return cmds_ An array of [`Command`](../../Command.sol/struct.Command.html) to execute the request.
     */
    function evaluate(
        address _operator,
        IncreasePositionRequest calldata _request
    ) external returns (Command[] memory cmds_);
}
"
    },
    "contracts/interfaces/compiler/adapters/ILiquidityPoolsRepository.sol": {
      "content": "// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.22;

/* solhint-disable no-unused-import */
import {AlreadyUpToDate} from "contracts/interfaces/base/CommonErrors.sol";
import {
    Status,
    TokenIsNotSupported
} from "contracts/interfaces/compliance/IWhitelistingController.sol";
/* solhint-enable no-unused-import */

/**
 * @notice Error indicating that the pool ID was not found.
 * @param encodedPool The encoded pool data that was searched for.
 */
error PoolIdNotFound(bytes encodedPool);

/**
 * @notice Error indicating that the pool does not exist.
 * @param poolId The unique identifier of the pool that was searched for.
 */
error PoolIsNotSupported(uint256 poolId);

/**
 * @notice Error indicating that the pool is suspended.
 * @param poolId The unique identifier of the pool that is suspended.
 */
error PoolIsSuspended(uint256 poolId);

/**
 * @title ILiquidityPoolsRepository
 * @notice Interface for managing liquidity pools and their support status.
 */
interface ILiquidityPoolsRepository {
    /**
     * @notice Update the support status of a liquidity pool.
     * @param _encodedPool The encoded pool data.
     * @param _supported Whether the pool is supported or not.
     * @return poolId_ The unique identifier of the pool.
     * @dev Reverts with a [`PoolIdNotFound()`](/interfaces/compiler/adapters/ILiquidityPoolsRepository.sol/error.PoolIdNotFound.html)
     *  error if the pool does not exist.
     */
    function updatePoolSupport(
        bytes calldata _encodedPool,
        bool _supported
    ) external returns (uint256 poolId_);

    /**
     * @notice Get the status of a specific pool.
     * @param _poolId The unique identifier of the pool.
     * @return status The status of the pool.
     * @dev Reverts with a [`PoolIsNotSupported()`](/interfaces/compiler/adapters/ILiquidityPoolsRepository.sol/error.PoolIsNotSupported.html)
     *  error if the pool does not exist.
     */
    function getPoolStatus(uint256 _poolId) external returns (Status status);

    /**
     * @notice Get the unique identifier (pool ID) of a specific pool.
     * @param _encodedPool The encoded pool data.
     * @return poolId_ The unique identifier of the pool.
     * @dev Reverts with a [`PoolIsNotSupported()`](/interfaces/compiler/adapters/ILiquidityPoolsRepository.sol/error.PoolIsNotSupported.html)
     *  error if the pool does not exist.
     */
    function getPoolId(bytes calldata _encodedPool) external view returns (uint256 poolId_);
}
"
    },
    "contracts/interfaces/compiler/adapters/index.sol": {
      "content": "// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.22;

import {
    IDecreasePositionEvaluator
} from "contracts/interfaces/compiler/adapters/IDecreasePositionEvaluator.sol";
import {IExchangeEvaluator} from "contracts/interfaces/compiler/adapters/IExchangeEvaluator.sol";
import {
    IIncreasePositionEvaluator
} from "contracts/interfaces/compiler/adapters/IIncreasePositionEvaluator.sol";
import {
    AlreadyUpToDate,
    ILiquidityPoolsRepository,
    PoolIdNotFound,
    PoolIsNotSupported,
    PoolIsSuspended,
    Status,
    TokenIsNotSupported
} from "contracts/interfaces/compiler/adapters/ILiquidityPoolsRepository.sol";
import {PositionDescriptor} from "contracts/interfaces/compiler/adapters/PositionDescriptor.sol";
"
    },
    "contracts/interfaces/compiler/adapters/PositionDescriptor.sol": {
      "content": "// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.22;

// TODO CRYPTO-145: Possibly move into appropriate interface?
/**
 * @notice Used to determine the required position for an operation.
 * @dev `poolId`: An identifier that is unique within a single protocol.
 * @dev `extraData`: Additional data used to specify the position, for example
 * this is used in OneInchV5Evaluator to pass swap tx generated via 1inch API.
 */
struct PositionDescriptor {
    uint256 poolId;
    bytes extraData;
}
"
    },
    "contracts/interfaces/compiler/Command.sol": {
      "content": "// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.22;

import {CommandLibrary} from "contracts/libraries/CommandLibrary.sol";

/**
 * @title Command
 * @notice Contains arguments for a low-level call.
 * @dev This struct allows deferring the call's execution, suspending it by passing it to another function or contract.
 * @dev `target` The address to be called.
 * @dev `value` Value to send in the call.
 * @dev `payload` Encoded call with function selector and arguments.
 */
struct Command {
    address target;
    uint256 value;
    bytes payload;
}

using CommandLibrary for Command global;
"
    },
    "contracts/interfaces/compliance/Asset.sol": {
      "content": "// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.22;

import {AssetLibrary} from "contracts/libraries/AssetLibrary.sol";

/**
 * @title Asset
 * @dev Represents an asset with its token address and the amount.
 * @param token The address of the asset's token.
 * @param amount The amount of the asset.
 */
struct Asset {
    address token;
    uint256 amount;
}

using AssetLibrary for Asset global;
"
    },
    "contracts/interfaces/compliance/IWhitelistingController.sol": {
      "content": "// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.22;

import {IERC165Extended} from "../base/IERC165Extended.sol";
import {IWhitelistingControllerAgreement} from "./IWhitelistingControllerAgreement.sol";

/**
 * @title Status
 * @notice Enum representing status of a record (e.g., token, protocol, operator)
 *  used for operation validation.
 * @notice Validators must adhere to the following rules for different operations and contexts:
 *  1) For exchanges: `operator`, `pool`, and `input token` *MAY* be either supported or suspended, but the `output token` *MUST* be supported.
 *  2) For deposits: `operator`, `pool`, and every `token` in the `pool` *MUST* be supported.
 *  3) For withdrawals: `operator`, `pool`, and each `token` *MAY* be either supported or suspended.
 *
 * @dev **Note** that deposit denotes **all** ways of acquiring liquidity such
 * as token deposit, LP tokens stake, NFT mint etc.
 */
enum Status {
    Undefined,
    Supported,
    Suspended
}

/**
 * @title WhitelistingAddressRecord
 * @notice A struct to store an address and its support status.
 * @dev This struct stores an address and its support status.
 * @dev `source`: The address to be stored.
 * @dev `supported`: Indicates whether the address is supported or not.
 */
struct WhitelistingAddressRecord {
    address source;
    bool supported;
}

/**
 * @title WhitelistingTokenRecord
 * @notice This struct stores an address and its support status for whitelisting, collateral and leverage.
 * @dev `source`: The address of the token.
 * @dev `supported`: Whether the token can be received from a protocol trades.
 */
struct WhitelistingTokenRecord {
    address source;
    bool supported;
}

/**
 * @notice An error indicating that a token is not supported by the whitelisting controller.
 * @dev This error is thrown when an unsupported token is used.
 * @dev `token`: The address of the unsupported token.
 */
error TokenIsNotSupported(address token);

/**
 * @notice An error indicating that a token is suspended by the whitelisting controller.
 * @dev This error is thrown when a suspended token is used.
 * @dev `token`: The address of the suspended token.
 */
error TokenIsSuspended(address token);

/**
 * @notice An error indicating that an operator is not supported by the whitelisting controller.
 * @dev This error is thrown when an unsupported operator is used.
 * @dev `operator`: The address of the unsupported operator.
 */
error OperatorIsNotSupported(address operator);

/**
 * @notice An error indicating that an operator is suspended by the whitelisting controller.
 * @dev This error is thrown when a suspended operator is used.
 * @dev `operator`: The address of the suspended operator.
 */
error OperatorIsSuspended(address operator);

/**
 * @notice An error indicating that a protocol is not supported by the whitelisting controller.
 * @dev This error is thrown when an unsupported protocol is used.
 * @dev `protocol`: The identification string of the unsupported protocol.
 */
error ProtocolIsNotSupported(bytes31 protocolNameHash);

/**
 * @notice An error indicating that a protocol is suspended by the whitelisting controller.
 * @dev This error is thrown when a suspended protocol is used.
 * @dev `protocol`: The identification string of the unsupported protocol.
 */
error ProtocolIsSuspended(bytes31 protocolNameHash);

interface ITenant {
    function factory() external view returns (address);
}

/**
 * @title IWhitelistingController
 * @notice Interface for managing whitelisting of tokens, protocols, and operators.
 */
interface IWhitelistingController is IWhitelistingControllerAgreement, IERC165Extended {
    /**
     * @dev Emitted when the support status of a protocol changes.
     * @dev `protocol`: The identification string of the protocol.
     * @dev `supported`: Whether the protocol is supported or not.
     */
    event ProtocolSupportChanged(string indexed protocol, bool supported);

    /**
     * @dev Emitted when the support status of a token changes.
     * @dev `token`: The address of the token.
     * @dev `supported`: Whether the token is supported or not.
     */
    event TokenSupportChanged(address indexed token, bool supported);

    /**
     * @dev Emitted when the support status of an operator changes for a specific protocol.
     * @dev `protocol`: The identification string of the protocol.
     * @dev `operator`: The address of the operator.
     * @dev `supported`: Whether the operator is supported or not.
     */
    event OperatorSupportChanged(string indexed protocol, address indexed operator, bool supported);

    /**
     * @notice Reverts when the caller contract supports a prohibited interface.
     * @dev This error is used by the `notMarginAccount` modifier to prevent
     *      function calls from contracts that implement the `IAccount` interface.
     * @param caller The address of the caller contract
     */
    error CallerSupportsForbiddenInterface(address caller);

    /**
     * @notice Reverts when the agreement was deployed by a different factory version.
     * @dev This error is used by the `onlyAgreementFactory` modifier to prevent
     *      `addTokens` and `addOperators` calls from wrong factory.
     * @param factory The address of the factory attempting to interact.
     * @param agreement The agreement contract whose associated factory version did not match the caller.
     */
    error AgreementFactoryVersionMismatch(address factory, address agreement);

    /**
     * @notice Update the support status of multiple tokens.
     * @dev Emits a [`TokenSupportChanged()`](#tokensupportchanged) event for each token whose status changed.
     * @dev Reverts with an [`AlreadyUpToDate()`](/interfaces/base/CommonErrors.sol/error.AlreadyUpToDate.html)
     *  error if no token status changed.
     * @param _tokens An array of [`WhitelistingTokenRecord`](./struct.WhitelistingTokenRecord.html)
     * structs containing token addresses and support.
     */
    function updateTokensSupport(WhitelistingTokenRecord[] calldata _tokens) external;

    /**
     * @notice Update the support status of a protocol.
     * @dev Emits a [`ProtocolSupportChanged()`](#protocolsupportchanged) event.
     * @dev Reverts with an [`AlreadyUpToDate()`](/interfaces/base/CommonErrors.sol/error.AlreadyUpToDate.html)
     *  error if protocol status is up to date.
     * @param _protocol The identification string of the protocol.
     * @param _supported Whether the protocol is supported or not.
     */
    function updateProtocolSupport(string calldata _protocol, bool _supported) external;

    /**
     * @notice Update the support status of multiple operators for a specific protocol.
     * @dev Emits a [`OperatorSupportChanged()`](#operatorsupportchanged) event for each token whose status changed.
     * @dev Reverts with an [`AlreadyUpToDate()`](/interfaces/base/CommonErrors.sol/error.AlreadyUpToDate.html)
     *  error if no operator status changed.
     * @param _protocol The identification string of the protocol.
     * @param _operators An array of `WhitelistingAddressRecord` structs containing operator addresses and support statuses.
     */
    function updateOperatorsSupport(
        string calldata _protocol,
        WhitelistingAddressRecord[] calldata _operators
    ) external;

    /**
     * @notice Returns the support status of a token.
     * @param _token The address of the token.
     * @return The [`Status`](./enum.Status.html) of the token.
     */
    function getTokenStatus(address _token) external view returns (Status);

    /**
     * @notice Checks whether a specific token is supported by a tenant.
     * @dev This function returns a boolean indicating if the given token is supported by the specified tenant.
     * @param tenant The address of the tenant to check.
     * @param token The address of the token to check for support.
     * @return A boolean value indicating whether the token is supported by the tenant.
     */
    function getTokenSupport(address tenant, address token) external view returns (bool);

    /**
     * @notice Retrieves the list of tokens supported by a specific tenant.
     * @dev This function returns an array of token addresses that are supported by the specified tenant.
     * @param tenant The address of the tenant whose supported tokens are to be retrieved.
     * @return An array of addresses representing the tokens supported by the tenant.
     */
    function getTokens(address tenant) external view returns (address[] memory);

    /**
     * @notice Returns the support status of a protocol.
     * @param protocol The identification string of the protocol.
     * @return The [`Status`](./enum.Status.html)
     *  of the protocol.
     */
    function getProtocolStatus(string calldata protocol) external view returns (Status);

    /**
     * @notice Returns the support status of an operator for a specific protocol.
     * @param _operator The address of the operator.
     * @return operatorStatus_ The [`Status`](./enum.Status.html)
     *  of the operator.
     * @return protocolStatus_ The [`Status`](./enum.Status.html)
     *  of the protocol.
     */
    function getOperatorStatus(
        address _operator
    ) external view returns (Status operatorStatus_, Status protocolStatus_);
}
"
    },
    "contracts/interfaces/compliance/IWhitelistingControllerAgreement.sol": {
      "content": "// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.22;

/**
 * @title IWhitelistingControllerAgreement
 * @notice Interface for managing whitelisting of tokens and operators for Agreements.
 */
interface IWhitelistingControllerAgreement {
    /**
     * @notice Emitted when a new token is added for a specific tenant.
     * @param tenant The address of the tenant to whom the token is added.
     * @param token The address of the token that has been added.
     */
    event TokenAdded(address tenant, address token);

    /**
     * @notice Emitted when a new operator is added for a specific tenant.
     * @param tenant The address of the tenant to whom the operator is added.
     * @param operator The address of the operator that has been added.
     */
    event OperatorAdded(address tenant, address operator);

    /**
     * @notice Adds a list of tokens to the specified tenant.
     * @param tenant The address of the tenant to which the tokens will be added.
     * @param tokens An array of addresses representing the tokens to be added.
     * @dev This function can be used to update the list of supported tokens for a given tenant.
     */
    function addTokens(address tenant, address[] calldata tokens) external;

    /**
     * @notice Adds a list of operators to the specified tenant.
     * @param tenant The address of the tenant to which the operators will be added.
     * @param operators An array of addresses representing the operators to be added.
     * @dev This function updates the list of authorized operators for a given tenant.
     */
    function addOperators(address tenant, address[] calldata operators) external;

    /**
     * @notice Returns the address of the agreement factory contract.
     * @return The address of the agreement factory.
     * @dev The agreement factory is used to create and manage agreements.
     */
    function agreementFactory() external view returns (address);

    /**
     * @notice Returns the address of the agreement V2 factory contract.
     * @return The address of the agreement V2 factory.
     * @dev The agreement V2 factory is used to create and manage agreements V2.
     */
    function agreementV2Factory() external view returns (address);

    /**
     * @notice Checks if a specific token is supported for a given tenant.
     * @param tenant The address of the tenant whose supported tokens are being queried.
     * @param token The address of the token to check for support.
     * @return A boolean indicating whether the token is supported by the tenant.
     * @dev This function will return `true` if the token is supported, and `false` otherwise.
     */
    function getTokenSupport(address tenant, address token) external view returns (bool);

    /**
     * @notice Retrieves a list of tokens supported by a specific tenant.
     * @param tenant The address of the tenant whose supported tokens are being queried.
     * @return An array of token addresses supported by the specified tenant.
     * @dev This function returns an array containing the addresses of tokens that the tenant supports.
     *      It is a view function and does not modify the contract state.
     */
    function getTokens(address tenant) external view returns (address[] memory);

    /**
     * @notice Checks if a specific operator is supported by a given tenant.
     * @param tenant The address of the tenant whose supported operators are being queried.
     * @param operator The address of the operator to check for support.
     * @return A boolean value indicating whether the operator is supported by the tenant.
     * @dev This function returns `true` if the operator is supported by the specified tenant, and `false` otherwise.
     *      It is a view function and does not modify the contract state.
     */
    function getOperatorSupport(address tenant, address operator) external view returns (bool);

    /**
     * @notice Retrieves the list of operators associated with a specific tenant.
     * @param tenant The address of the tenant whose operators are being queried.
     * @return A dynamically-sized array of addresses representing the operators associated with the tenant.
     * @dev This function is a view function and does not modify the contract state.
     */
    function getOperators(address tenant) external view returns (address[] memory);
}
"
    },
    "contracts/libraries/Address.sol": {
      "content": "// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.22;

library Address {
    address internal constant ETH = 0xEeeeeEeeeEeEeeEeEeEeeEEEeeeeEeeeeeeeEEeE;

    function set(bytes32 _slot, address _value) internal {
        assembly {
            sstore(_slot, _value)
        }
    }

    function get(bytes32 _slot) internal view returns (address result_) {
        assembly {
            result_ := sload(_slot)
        }
    }

    function isEth(address _token) internal pure returns (bool) {
        return _token == ETH || _token == address(0);
    }

    function sort(address _a, address _b) internal pure returns (address, address) {
        return _a < _b ? (_a, _b) : (_b, _a);
    }

    function sort(address[4] memory _array) internal pure returns (address[4] memory _sorted) {
        // Sorting network for the array of length 4
        (_sorted[0], _sorted[1]) = sort(_array[0], _array[1]);
        (_sorted[2], _sorted[3]) = sort(_array[2], _array[3]);

        (_sorted[0], _sorted[2]) = sort(_sorted[0], _sorted[2]);
        (_sorted[1], _sorted[3]) = sort(_sorted[1], _sorted[3]);
        (_sorted[1], _sorted[2]) = sort(_sorted[1], _sorted[2]);
    }
}
"
    },
    "contracts/libraries/AssetLibrary.sol": {
      "content": "// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.22;

import {SafeTransferLib} from "solady/src/utils/SafeTransferLib.sol";

import {AmountMustNotBeZero} from "contracts/interfaces/base/CommonErrors.sol";
import {Asset} from "contracts/interfaces/compliance/Asset.sol";

import {Address} from "./Address.sol";

library AssetLibrary {
    using SafeTransferLib for address;
    using Address for address;

    error NotEnoughReceived(address token, uint256 expected, uint256 received);

    function forward(Asset calldata self, address _to) internal {
        if (self.amount == 0) revert AmountMustNotBeZero(self.token);

        if (self.token.isEth()) _to.safeTransferETH(self.amount);
        else self.token.safeTransferFrom(msg.sender, _to, self.amount);
    }

    function approve(Asset calldata self, address to) internal {
        self.token.safeApprove(to, self.amount);
    }

    function receiveFrom(Asset storage self, address from) internal {
        self.token.safeTransferFrom(from, address(this), self.amount);
    }

    function receiveFrom(Asset calldata self, address from) internal {
        self.token.safeTransferFrom(from, address(this), self.amount);
    }

    function enforceReceived(Asset calldata self) internal view {
        if (self.amount == 0) revert AmountMustNotBeZero(self.token);

        uint256 balance = self.token.isEth()
            ? address(this).balance
            : self.token.balanceOf(address(this));

        if (balance < self.amount) revert NotEnoughReceived(self.token, self.amount, balance);
    }
}
"
    },
    "contracts/libraries/CommandLibrary.sol": {
      "content": "// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.22;

import {IERC20} from "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import {Command} from "contracts/interfaces/compiler/Command.sol";
import {SafeCall} from "contracts/libraries/SafeCall.sol";

/**
 * @notice Utility to convert often-used methods into a Command object
 */
library CommandPresets {
    function approve(
        address _token,
        address _to,
        uint256 _amount
    ) internal pure returns (Command[] memory result_) {
        result_ = new Command[](2);
        result_[0] = Command(_token, 0, abi.encodeCall(IERC20.approve, (_to, 0)));
        result_[1] = Command(_token, 0, abi.encodeCall(IERC20.approve, (_to, _amount)));
    }

    function transfer(
        address _token,
        address _to,
        uint256 _amount
    ) internal pure returns (Command memory cmd_) {
        cmd_.target = _token;
        cmd_.payload = abi.encodeCall(IERC20.transfer, (_to, _amount));
    }
}

library CommandExecutor {
    using SafeCall for Command[];

    function execute(Command[] calldata _cmds) external {
        _cmds.safeCallAll();
    }
}

library CommandLibrary {
    using CommandLibrary for Command[];

    function last(Command[] memory _self) internal pure returns (Command memory) {
        return _self[_self.length - 1];
    }

    function asArray(Command memory _self) internal pure returns (Command[] memory result_) {
        result_ = new Command[](1);
        result_[0] = _self;
    }

    function append(
        Command[] memory _self,
        Command[] memory _cmds
    ) internal pure returns (Command[] memory result_) {
        result_ = new Command[](_self.length + _cmds.length);
        uint256 i;
        for (; i < _self.length; i++) {
            result_[i] = _self[i];
        }
        for (; i < result_.length; i++) {
            result_[i] = _cmds[i - _self.length];
        }
    }

    function push(
        Command[] memory _self,
        Command memory _cmd
    ) internal pure returns (Command[] memory result_) {
        result_ = new Command[](_self.length + 1);
        for (uint256 i; i < _self.length; i++) {
            result_[i] = _self[i];
        }
        result_[_self.length] = _cmd;
    }

    function populateWithApprove(
        Command memory _self,
        address _token,
        uint256 _amount
    ) internal pure returns (Command[] memory result_) {
        if (_amount != 0) {
            result_ = CommandPresets.approve(_token, _self.target, _amount).push(_self);
        } else {
            result_ = _self.asArray();
        }
    }
}
"
    },
    "contracts/libraries/SafeCall.sol": {
      "content": "// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.22;

import {Address} from "@openzeppelin/contracts/utils/Address.sol";
import {Command} from "contracts/interfaces/compiler/Command.sol";

/**
 * @notice Safe methods performing a low-level calls that revert
 * if the call was not successful
 */
library SafeCall {
    using Address for address;

    function safeCallAll(Command[] memory _cmds) internal {
        for (uint256 i; i < _cmds.length; i++) {
            safeCall(_cmds[i]);
        }
    }

    function safeCall(Command memory _cmd) internal returns (bytes memory result_) {
        result_ = safeCall(_cmd.target, _cmd.value, _cmd.payload);
    }

    function safeCall(address _target, bytes memory _data) internal returns (bytes memory result_) {
        result_ = safeCall(_target, 0, _data);
    }

    function safeCall(
        address _target,
        uint256 _value,
        bytes memory _data
    ) internal returns (bytes memory result_) {
        result_ = _target.functionCallWithValue(_data, _value);
    }

    function safeDelegateCall(
        address _target,
        bytes memory _data
    ) internal returns (bytes memory result_) {
        result_ = _target.functionDelegateCall(_data);
    }
}
"
    },
    "solady/src/utils/SafeTransferLib.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity ^0.8.4;

/// @notice Safe ETH and ERC20 transfer library that gracefully handles missing return values.
/// @author Solady (https://github.com/vectorized/solady/blob/main/src/utils/SafeTransferLib.sol)
/// @author Modified from Solmate (https://github.com/transmissions11/solmate/blob/main/src/utils/SafeTransferLib.sol)
/// @dev Caution! This library won't check that a token has code, responsibility is delegated to the caller.
library SafeTransferLib {
    /*´:°•.°+.*•´.*:˚.°*.˚•´.°:°•.°•.*•´.*:˚.°*.˚•´.°:°•.°+.*•´.*:*/
    /*                       CUSTOM ERRORS                        */
    /*.•°:°.´+˚.*°.˚:*.´•*.+°.•°:´*.´•*.•°.•°:°.´:•˚°.*°.˚:*.´+°.•*/

    /// @dev The ETH transfer has failed.
    error ETHTransferFailed();

    /// @dev The ERC20 `transferFrom` has failed.
    error TransferFromFailed();

    /// @dev The ERC20 `transfer` has failed.
    error TransferFailed();

    /// @dev The ERC20 `approve` has failed.
    error ApproveFailed();

    /*´:°•.°+.*•´.*:˚.°*.˚•´.°:°•.°•.*•´.*:˚.°*.˚•´.°:°•.°+.*•´.*:*/
    /*                         CONSTANTS                          */
    /*.•°:°.´+˚.*°.˚:*.´•*.+°.•°:´*.´•*.•°.•°:°.´:•˚°.*°.˚:*.´+°.•*/

    /// @dev Suggested gas stipend for contract receiving ETH
    /// that disallows any storage writes.
    uint256 internal constant _GAS_STIPEND_NO_STORAGE_WRITES = 2300;

    /// @dev Suggested gas stipend for contract receiving ETH to perform a few
    /// storage reads and writes, but low enough to prevent griefing.
    /// Multiply by a small constant (e.g. 2), if needed.
    uint256 internal constant _GAS_STIPEND_NO_GRIEF = 100000;

    /*´:°•.°+.*•´.*:˚.°*.˚•´.°:°•.°•.*•´.*:˚.°*.˚•´.°:°•.°+.*•´.*:*/
    /*                       ETH OPERATIONS                       */
    /*.•°:°.´+˚.*°.˚:*.´•*.+°.•°:´*.´•*.•°.•°:°.´:•˚°.*°.˚:*.´+°.•*/

    /// @dev Sends `amount` (in wei) ETH to `to`.
    /// Reverts upon failure.
    function safeTransferETH(address to, uint256 amount) internal {
        /// @solidity memory-safe-assembly
        assembly {
            // Transfer the ETH and check if it succeeded or not.
            if iszero(call(gas(), to, amount, 0, 0, 0, 0)) {
                // Store the function selector of `ETHTransferFailed()`.
                mstore(0x00, 0xb12d13eb)
                // Revert with (offset, size).
                revert(0x1c, 0x04)
            }
        }
    }

    /// @dev Force sends `amount` (in wei) ETH to `to`, with a `gasStipend`.
    /// The `gasStipend` can be set to a low enough value to prevent
    /// storage writes or gas griefing.
    ///
    /// If sending via the normal procedure fails, force sends the ETH by
    /// creating a temporary contract which uses `SELFDESTRUCT` to force send the ETH.
    ///
    /// Reverts if the current contract has insufficient balance.
    function forceSafeTransferETH(address to, uint256 amount, uint256 gasStipend) internal {
        /// @solidity memory-safe-assembly
        assembly {
            // If insufficient balance, revert.
            if lt(selfbalance(), amount) {
                // Store the function selector of `ETHTransferFailed()`.
                mstore(0x00, 0xb12d13eb)
                // Revert with (offset, size).
                revert(0x1c, 0x04)
            }
            // Transfer the ETH and check if it succeeded or not.
            if iszero(call(gasStipend, to, amount, 0, 0, 0, 0)) {
                mstore(0x00, to) // Store the address in scratch space.
                mstore8(0x0b, 0x73) // Opcode `PUSH20`.
                mstore8(0x20, 0xff) // Opcode `SELFDESTRUCT`.
                // We can directly use `SELFDESTRUCT` in the contract creation.
                // Compatible with `SENDALL`: https://eips.ethereum.org/EIPS/eip-4758
                if iszero(create(amount, 0x0b, 0x16)) {
                    // For better gas estimation.
                    if iszero(gt(gas(), 1000000)) { revert(0, 0) }
                }
            }
        }
    }

    /// @dev Force sends `amount` (in wei) ETH to `to`, with a gas stipend
    /// equal to `_GAS_STIPEND_NO_GRIEF`. This gas stipend is a reasonable default
    /// for 99% of cases and can be overriden with the three-argument version of this
    /// function if necessary.
    ///
    /// If sending via the normal procedure fails, force sends the ETH by
    /// creating a temporary contract which uses `SELFDESTRUCT` to force send the ETH.
    ///
    /// Reverts if the current contract has insufficient balance.
    function forceSafeTransferETH(address to, uint256 amount) internal {
        // Manually inlined because the compiler doesn't inline functions with branches.
        /// @solidity memory-safe-assembly
        assembly {
            // If insufficient balance, revert.
            if lt(selfbalance(), amount) {
                // Store the function selector of `ETHTransferFailed()`.
                mstore(0x00, 0xb12d13eb)
                // Revert with (offset, size).
                revert(0x1c, 0x04)
            }
            // Transfer the ETH and check if it succeeded or not.
            if iszero(call(_GAS_STIPEND_NO_GRIEF, to, amount, 0, 0, 0, 0)) {
                mstore(0x00, to) // Store the address in scratch space.
                mstore8(0x0b, 0x73) // Opcode `PUSH20`.
                mstore8(0x20, 0xff) // Opcode `SELFDESTRUCT`.
                // We can directly use `SELFDESTRUCT` in the contract creation.
                // Compatible with `SENDALL`: https://eips.ethereum.org/EIPS/eip-4758
                if iszero(create(amount, 0x0b, 0x16)) {
                    // For better gas estimation.
                    if iszero(gt(gas(), 1000000)) { revert(0, 0) }
                }
            }
        }
    }

    /// @dev Sends `amount` (in wei) ETH to `to`, with a `gasStipend`.
    /// The `gasStipend` can be set to a low enough value to prevent
    /// storage writes or gas griefing.
    ///
    /// Simply use `gasleft()` for `gasStipend` if you don't need a gas stipend.
    ///
    /// Note: Does NOT revert upon failure.
    /// Returns whether the transfer of ETH is successful instead.
    function trySafeTransferETH(address to, uint256 amount, uint256 gasStipend)
        internal
        returns (bool success)
    {
        /// @solidity memory-safe-assembly
        assembly {
            // Transfer the ETH and check if it succeeded or not.
            success := call(gasStipend, to, amount, 0, 0, 0, 0)
        }
    }

    /*´:°•.°+.*•´.*:˚.°*.˚•´.°:°•.°•.*•´.*:˚.°*.˚•´.°:°•.°+.*•´.*:*/
    /*                      ERC20 OP