OffchainFractions

{{
  "language": "Solidity",
  "sources": {
    "src/v2/OffchainFractions.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity ^0.8.17;

import {SafeERC20} from "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import {IERC20} from "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import {CounterfactualHolderFactory} from "./CounterfactualHolderFactory.sol";
import {ReentrancyGuard} from "@openzeppelin/contracts/security/ReentrancyGuard.sol";
import {Call} from "./Structs.sol";
/**
 * @title OffchainFractions
 * @notice A contract for creating and managing fractional token sales with optional minimum raise requirements
 * @dev Supports both direct transfers and counterfactual holder addresses for recipients
 * @dev Counterfactual tokens are held in the CFH Chain for address(this) which always forwards leftover tokens
 *         - This makes it safe to run multiple sales concurrently accruing to the CFH of address(this) 
 *         - without worrying about leftover tokens
 */

contract OffchainFractions is ReentrancyGuard {
    using SafeERC20 for IERC20;

    // === Fraction Management Errors ===
    error AlreadyExists();
    error AlreadyClosed();
    error Expired();
    error MinSharesCannotBeGreaterThanTotalSteps();
    error NotFractionsCloser();

    // === Purchase/Sale Errors ===
    error InsufficientSharesAvailable();
    error NoStepsPurchased();
    error StepMustBeGreaterThanZero();
    error ZeroSteps();
    error MinStepsToBuyCannotBeZero();
    error MinStepsToBuyCannotBeGreaterThanStepsToBuy();
    // === Validation Errors ===
    error InvalidToken();
    error InvalidToAddress();
    error RecipientCannotBeSelf();
    error CannotHaveZeroTotalSteps();
    error TaxTokenNotSupported();
    error ExpirationMustBeInTheFuture();
    error UseCounterfactualAddressForRefundNotAllowedIfAddressIsZero();

    // === Refund/Claim Errors ===
    error CannotClaimRefundWhenThresholdReached();
    error CannotClaimRefundWhenNotExpired();
    error CannotCloseWhenThresholdReached();
    error ExpirationCannotBeGreaterThanMaxDuration();
    error TotalRaisedOverflow();
    error RefundOperatorNotApproved();
    error CannotSetRefundDetailsWhenThresholdReached();

    /**
     * @notice Data structure representing a fractional token sale
     * @param token The ERC20 token being sold
     * @param expiration Timestamp when the sale expires
     * @param manuallyClosed Whether the sale was manually closed by the owner
     * @param minSharesToRaise Minimum number of steps that must be sold for the sale to be valid
     * @param useCounterfactualAddress Whether to use a counterfactual holder address for the recipient
     * @param claimedFromMinSharesToRaise Whether funds have been claimed after reaching minimum shares
     * @param owner The creator/owner of this fraction sale
     * @param step Price per step (in wei of the token)
     * @param to The recipient address for the raised funds
     * @param soldSteps Number of steps already sold
     * @param totalSteps Total number of steps available for sale
     * @param closer The address that manually closed the sale
     */
    struct FractionData {
        address token;
        uint48 expiration;
        bool manuallyClosed;
        uint256 minSharesToRaise;
        bool useCounterfactualAddress;
        bool claimedFromMinSharesToRaise;
        uint256 step;
        address to;
        uint256 soldSteps;
        uint256 totalSteps;
        address closer;
    }

    /**
     * @notice Internal struct to hold purchase calculation results (avoids stack too deep)
     * @param stepsToBuy Final number of steps to purchase (adjusted for availability)
     * @param amount Total cost for the purchase
     * @param newFractionsSold Total steps that will be sold after this purchase
     * @param sendTo Address where funds should be sent
     * @param roundFullyFilled Whether this purchase completes the round
     */
    struct PurchaseDetails {
        uint256 stepsToBuy;
        uint256 amount;
        uint256 newFractionsSold;
        address sendTo;
        bool roundFullyFilled;
    }

    struct RefundDetails {
        address refundTo;
        bool useCounterfactualAddress;
    }

    /// @notice Tracks the number of steps purchased by each user for each fraction sale
    mapping(address user => mapping(address creator => mapping(bytes32 id => uint256 stepsPurchased))) public
        stepsPurchased;

    mapping(address user => mapping(address refundOperator => bool isApproved)) public refundApprovals;
    mapping(address user => mapping(address creator => mapping(bytes32 id => RefundDetails))) private _refundDetails;

    /// @notice Stores fraction sale data indexed by creator and fraction ID
    mapping(address user => mapping(bytes32 id => FractionData)) private _fractions;

    address public constant REFUND_WILDCARD_OPERATOR = 0xFFfFfFffFFfffFFfFFfFFFFFffFFFffffFfFFFfF;

    uint256 private constant MAX_DURATION = 100 weeks;
    /// @notice Factory contract for creating counterfactual holder addresses
    CounterfactualHolderFactory public immutable i_CFHFactory;

    /// @notice Emitted when a new fraction sale is created
    event FractionCreated(
        bytes32 indexed id,
        address indexed token,
        address indexed owner,
        uint256 step,
        uint256 totalSteps,
        uint48 expiration,
        address to,
        bool useCounterfactualAddress,
        uint256 minSharesToRaise,
        address closer
    );

    /// @notice Emitted when steps are purchased in a fraction sale
    event FractionSold(
        bytes32 indexed id,
        address indexed creator,
        address indexed creditTo,
        address buyer,
        uint256 step,
        uint256 amount
    );

    /// @notice Emitted when a fraction sale round is completely filled
    event RoundFilled(bytes32 indexed id, address indexed creator);

    /// @notice Emitted when a fraction sale is manually closed by the owner
    event FractionClosed(bytes32 indexed id, address indexed token, address indexed owner);

    /// @notice Emitted when a user claims a refund from an unfilled sale
    event FractionRefunded(
        bytes32 indexed id, address indexed creator, address indexed user, address refundTo, uint256 amount
    );

    /// @notice Emitted when the minimum shares threshold is reached and funds are released
    event MinSharesReached(bytes32 indexed id, address indexed creator, uint256 minShares, uint256 newTotalSharesSold);

    event RefundOperatorStatusSet(address indexed user, address indexed refundOperator, bool isApproved);

    constructor(CounterfactualHolderFactory _counterfactualHolderFactory) {
        i_CFHFactory = _counterfactualHolderFactory;
    }

    /**
     * @notice Creates a new fractional token sale
     * @param id Unique identifier for this fraction sale
     * @param token The ERC20 token to be sold
     * @param step Price per step (in wei of the token)
     * @param totalSteps Total number of steps available for sale
     * @param expiration Timestamp when the sale expires
     * @param to Recipient address for the raised funds
     * @param useCounterfactualAddress Whether to use a counterfactual holder for the recipient
     * @param minSharesToRaise Minimum steps required for the sale to be valid (0 = no minimum)
     * @param closer The address that is allowed to manually close the sale
     */
    function createFraction(
        bytes32 id,
        address token,
        uint256 step,
        uint256 totalSteps,
        uint48 expiration,
        address to,
        bool useCounterfactualAddress,
        uint256 minSharesToRaise,
        address closer
    ) external nonReentrant {
        // Validate input parameters
        _validateFractionCreationParams(token, to, step, totalSteps, minSharesToRaise, expiration);

        // Ensure fraction doesn't already exist
        if (_fractions[msg.sender][id].totalSteps != 0) {
            revert AlreadyExists();
        }

        // Create the fraction data
        _fractions[msg.sender][id] = FractionData({
            token: token,
            step: step,
            soldSteps: 0,
            totalSteps: totalSteps,
            expiration: expiration,
            manuallyClosed: false,
            useCounterfactualAddress: useCounterfactualAddress,
            to: to,
            minSharesToRaise: minSharesToRaise,
            claimedFromMinSharesToRaise: minSharesToRaise == 0,
            closer: closer
        });

        emit FractionCreated(
            id, token, msg.sender, step, totalSteps, expiration, to, useCounterfactualAddress, minSharesToRaise, closer
        );
    }

    /**
     * @notice Purchase steps in a fractional token sale
     * @param creator The address that created the fraction sale
     * @param id The unique identifier of the fraction sale
     * @param stepsToBuy Maximum number of steps to purchase
     * @param minStepsToBuy Minimum number of steps that must be available to purchase
     */
    function buyFractions(
        address creator,
        bytes32 id,
        uint256 stepsToBuy,
        uint256 minStepsToBuy,
        address refundTo,
        address creditTo,
        bool useCounterfactualAddressForRefund
    ) external nonReentrant {
        FractionData storage fraction = _fractions[creator][id];
        if (minStepsToBuy == 0) {
            revert MinStepsToBuyCannotBeZero();
        }
        if (stepsToBuy == 0) {
            revert ZeroSteps();
        }
        if (minStepsToBuy > stepsToBuy) {
            revert MinStepsToBuyCannotBeGreaterThanStepsToBuy();
        }

        if (refundTo != address(0) && useCounterfactualAddressForRefund) {
            revert UseCounterfactualAddressForRefundNotAllowedIfAddressIsZero();
        }

        // Validate the purchase can proceed
        _validatePurchaseConditions(fraction);

        // Calculate purchase details with stack isolation
        PurchaseDetails memory details = _calculatePurchaseDetails(fraction, stepsToBuy, minStepsToBuy);

        // Handle the token transfers based on minimum shares logic
        bool minSharesReached =
            _handlePurchaseTransfers(fraction, details, creator, id, fraction.useCounterfactualAddress);

        if (refundTo != address(0) && !minSharesReached) {
            _refundDetails[msg.sender][creator][id] =
                RefundDetails({refundTo: refundTo, useCounterfactualAddress: useCounterfactualAddressForRefund});
        }

        // Update state and emit events
        _finalizePurchase(fraction, details, creator, creditTo, id);
    }

    /**
     * @notice Allows participants to claim a refund if the round didn't reach minimum shares
     * @dev Can only claim refund if:
     *      - Round didn't reach minSharesToRaise threshold
     *      - Round is expired OR manually closed
     * @param creator The address that created the fraction sale
     * @param id The unique identifier of the fraction sale
     */
    function claimRefund(address user, address creator, bytes32 id) external nonReentrant {
        FractionData storage fraction = _fractions[creator][id];
        RefundDetails memory refundDetails = _refundDetails[user][creator][id];
        address refundToInStruct = refundDetails.refundTo;
        address refundTo = refundToInStruct == address(0) ? user : refundToInStruct;

        // Either the user or the refund to address must have approved the refund operator
        if (!isRefundOperatorApproved(user, msg.sender) && !isRefundOperatorApproved(refundToInStruct, msg.sender)) {
            revert RefundOperatorNotApproved();
        }
        if (refundDetails.useCounterfactualAddress) {
            refundTo = i_CFHFactory.getCurrentCFH({user: refundTo, token: fraction.token});
        }

        uint256 _stepsPurchased = stepsPurchased[user][creator][id];
        if (_stepsPurchased == 0) {
            revert NoStepsPurchased();
        }

        // Check if round reached minimum threshold
        uint256 soldSteps = fraction.soldSteps;
        bool roundFilled = soldSteps >= fraction.minSharesToRaise;
        if (roundFilled) {
            revert CannotClaimRefundWhenThresholdReached();
        }

        // Check if refund conditions are met (expired OR manually closed)
        bool expired = block.timestamp > fraction.expiration;
        bool manuallyClosed = fraction.manuallyClosed;
        // equivalent to require(manually closed || expired)
        if (!manuallyClosed && !expired) {
            revert CannotClaimRefundWhenNotExpired();
        }

        // Calculate refund amount and update state
        uint256 amount = _stepsPurchased * fraction.step;
        stepsPurchased[user][creator][id] = 0;
        fraction.soldSteps = soldSteps - _stepsPurchased;

        // Transfer refund to user
        if (fraction.useCounterfactualAddress) {
            Call[] memory calls = new Call[](1);
            calls[0] = Call({
                target: address(fraction.token),
                data: abi.encodeWithSelector(IERC20.transfer.selector, refundTo, amount)
            });
            i_CFHFactory.execute(fraction.token, calls);
        } else {
            IERC20(fraction.token).safeTransfer(refundTo, amount);
        }
        emit FractionRefunded(id, creator, user, refundTo, amount);
    }

    /**
     * @notice Manually close a fraction sale before expiration
     * @dev Only the closer can close their own fraction sale
     * @dev Can only close if the round hasn't reached minimum shares threshold
     * @param creator The address that created the fraction sale
     * @param id The unique identifier of the fraction sale to close
     */
    function closeFraction(address creator, bytes32 id) external nonReentrant {
        FractionData storage fraction = _fractions[creator][id];
        if (msg.sender != fraction.closer) {
            revert NotFractionsCloser();
        }

        // Validate closure conditions
        if (fraction.manuallyClosed) {
            revert AlreadyClosed();
        }
        if (fraction.soldSteps >= fraction.minSharesToRaise) {
            revert CannotCloseWhenThresholdReached();
        }
        if (block.timestamp > fraction.expiration) {
            revert Expired();
        }

        // Mark as manually closed
        fraction.manuallyClosed = true;
        emit FractionClosed(id, fraction.token, creator);
    }

    /**
     * @notice Sets the refund details for a specific fraction sale
     * @dev This function allows a user to specify the refund address and whether to use a counterfactual address
     * @param creator The address of the creator of the fraction sale
     * @param id The unique identifier of the fraction sale
     * @param refundTo The address to which refunds should be sent
     * @param useCounterfactualAddress A boolean indicating whether to use a counterfactual address for the refund
     * @dev Reverts if `refundTo` is not zero and `useCounterfactualAddress` is true
     */
    function setRefundDetails(address creator, bytes32 id, address refundTo, bool useCounterfactualAddress) external {
        if (refundTo != address(0) && useCounterfactualAddress) {
            revert UseCounterfactualAddressForRefundNotAllowedIfAddressIsZero();
        }

        FractionData storage fraction = _fractions[creator][id];

        if (fraction.soldSteps >= fraction.minSharesToRaise) {
            revert CannotSetRefundDetailsWhenThresholdReached();
        }

        _refundDetails[msg.sender][creator][id] =
            RefundDetails({refundTo: refundTo, useCounterfactualAddress: useCounterfactualAddress});
    }

    /**
     * @notice Sets the approval status of a refund operator for the caller
     * @dev This function allows the caller to approve or revoke approval for a refund operator
     * @param refundOperator The address of the refund operator to set the status for
     * @param isApproved A boolean indicating whether the refund operator is approved (true) or not (false)
     */
    function setRefundOperatorStatus(address refundOperator, bool isApproved) external {
        refundApprovals[msg.sender][refundOperator] = isApproved;
        emit RefundOperatorStatusSet(msg.sender, refundOperator, isApproved);
    }

    /**
     * @notice Get the fraction sale data for a specific creator and ID
     * @param creator The address that created the fraction sale
     * @param id The unique identifier of the fraction sale
     * @return The complete fraction sale data
     */
    function getFraction(address creator, bytes32 id) external view returns (FractionData memory) {
        return _fractions[creator][id];
    }

    function getRefundDetails(address user, address creator, bytes32 id) external view returns (RefundDetails memory) {
        return _refundDetails[user][creator][id];
    }

    /**
     * @notice Checks if a refund operator is approved for a specific user
     * @dev The function first checks if the caller is the user, in which case it returns true.
     *      It then checks if the wildcard operator is approved for the user.
     * @param user The address of the user for whom the refund operator approval is being checked
     * @param refundOperator The address of the refund operator to check approval status for
     * @return A boolean indicating whether the refund operator is approved for the user
     */
    function isRefundOperatorApproved(address user, address refundOperator) public view returns (bool) {
        if (msg.sender == user) return true;
        bool isWildcardOperatorApproved = refundApprovals[user][REFUND_WILDCARD_OPERATOR];
        if (isWildcardOperatorApproved) return true;
        return refundApprovals[user][refundOperator];
    }

    // ============ INTERNAL FUNCTIONS ============

    /**
     * @notice Validates parameters for fraction creation
     * @param token The ERC20 token address
     * @param to The recipient address
     * @param step The price per step
     * @param totalSteps The total number of steps
     * @param minSharesToRaise The minimum number of steps to raise
     */
    function _validateFractionCreationParams(
        address token,
        address to,
        uint256 step,
        uint256 totalSteps,
        uint256 minSharesToRaise,
        uint48 expiration
    ) internal view {
        if (token == address(0)) revert InvalidToken();
        if (to == address(0)) revert InvalidToAddress();
        if (step == 0) revert StepMustBeGreaterThanZero();
        if (totalSteps == 0) revert CannotHaveZeroTotalSteps();
        if (to == address(this)) revert RecipientCannotBeSelf();
        if (minSharesToRaise > totalSteps) revert MinSharesCannotBeGreaterThanTotalSteps();
        if (expiration <= block.timestamp) revert ExpirationMustBeInTheFuture();
        if (expiration - block.timestamp > MAX_DURATION) revert ExpirationCannotBeGreaterThanMaxDuration();
        if (willMultiplyOverflow(step, totalSteps)) revert TotalRaisedOverflow();
    }

    /**
     * @notice Validates that a purchase can proceed
     * @param fraction The fraction data to validate
     */
    function _validatePurchaseConditions(FractionData storage fraction) internal view {
        if (fraction.manuallyClosed) revert AlreadyClosed();
        if (block.timestamp > fraction.expiration) revert Expired();
    }

    /**
     * @notice Calculates purchase details including adjusted steps and recipient address
     * @param fraction The fraction data
     * @param stepsToBuy Requested number of steps to buy
     * @param minStepsToBuy Minimum steps required to be available
     * @return details Calculated purchase details
     */
    function _calculatePurchaseDetails(FractionData storage fraction, uint256 stepsToBuy, uint256 minStepsToBuy)
        internal
        view
        returns (PurchaseDetails memory details)
    {
        {
            address toInStruct = fraction.to;
            details.sendTo = fraction.useCounterfactualAddress
                ? i_CFHFactory.getCurrentCFH({user: toInStruct, token: fraction.token})
                : toInStruct;
        }

        {
            uint256 soldSteps = fraction.soldSteps;
            uint256 totalSteps = fraction.totalSteps;
            uint256 stepsLeft = totalSteps - soldSteps;

            if (stepsLeft < minStepsToBuy) revert InsufficientSharesAvailable();
            details.stepsToBuy = min(stepsLeft, stepsToBuy);
        }

        details.newFractionsSold = fraction.soldSteps + details.stepsToBuy;
        details.amount = details.stepsToBuy * fraction.step;

        details.roundFullyFilled = details.newFractionsSold == fraction.totalSteps;
    }

    /**
     * @notice Handles token transfers based on minimum shares logic
     * @dev With Counterfactual Holder (CFH) enabled, all fundraised amounts before `minSharesToRaise` is reached
     *      are held in the OffchainFractions CFH address rather than the contract balance. This ensures that any
     *      on-chain monitoring reflects the actual behavior of funds being held in the CFH address.
     * @dev When `minSharesToRaise` is reached, the funds are transferred to the recipient.
     * @param fraction The fraction data
     * @param details Purchase calculation results
     * @param creator The fraction creator
     * @param id The fraction ID
     */
    function _handlePurchaseTransfers(
        FractionData storage fraction,
        PurchaseDetails memory details,
        address creator,
        bytes32 id,
        bool isGuardedToken
    ) internal returns (bool minSharesReached) {
        address token = fraction.token;
        uint256 minSharesToRaise = fraction.minSharesToRaise;

        minSharesReached = details.newFractionsSold >= minSharesToRaise;

        /// If `minShares` has not been reached, send funds to the contract.
        if (details.newFractionsSold < minSharesToRaise) {
            // Below minimum threshold - hold funds in contract
            _safeTransferFromNoTaxToken(token, msg.sender, address(this), details.amount, isGuardedToken);
        }
        // If `minShares` has been reached
        // If it's the first time reaching `minShares`, transfer all accumulated funds to the recipient. and mark it as claimed.
        // If it's not the first time reaching `minShares`, transfer the funds to the recipient.
        else {
            // Above minimum threshold - handle fund distribution
            if (fraction.claimedFromMinSharesToRaise) {
                // Minimum already claimed, send directly to recipient
                IERC20(token).safeTransferFrom(msg.sender, details.sendTo, details.amount);
            } else {
                // First time reaching minimum - transfer all accumulated funds
                _safeTransferFromNoTaxToken(token, msg.sender, address(this), details.amount, isGuardedToken);
                uint256 totalAmount = details.newFractionsSold * fraction.step;
                if (isGuardedToken) {
                    Call[] memory calls = new Call[](1);
                    calls[0] = Call({
                        target: address(token),
                        data: abi.encodeWithSelector(IERC20.transfer.selector, details.sendTo, totalAmount)
                    });
                    i_CFHFactory.execute(token, calls);
                } else {
                    IERC20(token).safeTransfer(details.sendTo, totalAmount);
                }
                fraction.claimedFromMinSharesToRaise = true;
                // For `0` min shares, this won't be emitted.
                emit MinSharesReached(id, creator, minSharesToRaise, details.newFractionsSold);
            }
        }
    }

    /**
     * @notice Finalizes the purchase by updating state and emitting events
     * @param fraction The fraction data
     * @param details Purchase calculation results
     * @param creator The fraction creator
     * @param id The fraction ID
     */
    function _finalizePurchase(
        FractionData storage fraction,
        PurchaseDetails memory details,
        address creator,
        address creditTo,
        bytes32 id
    ) internal {
        // Update user's purchase record
        stepsPurchased[msg.sender][creator][id] += details.stepsToBuy;

        // Update fraction's sold steps
        fraction.soldSteps = details.newFractionsSold;

        // Emit events
        if (details.roundFullyFilled) {
            emit RoundFilled(id, creator);
        }

        emit FractionSold(id, creator, creditTo, msg.sender, fraction.step, details.amount);
    }

    /**
     * @notice Safe transfer that ensures no tax tokens are used
     * @dev Reverts if the received amount doesn't match the sent amount (indicating a tax token)
     * @param token The ERC20 token to transfer
     * @param from The address to transfer from
     * @param to The address to transfer to
     * @param amount The amount to transfer
     */
    function _safeTransferFromNoTaxToken(address token, address from, address to, uint256 amount, bool isGuardedToken)
        internal
    {
        address sendTo = isGuardedToken ? i_CFHFactory.getCurrentCFH({user: to, token: token}) : to;
        uint256 balBefore = IERC20(token).balanceOf(sendTo);
        IERC20(token).safeTransferFrom(from, sendTo, amount);
        uint256 balAfter = IERC20(token).balanceOf(sendTo);
        if (balAfter - balBefore != amount) {
            revert TaxTokenNotSupported();
        }
    }

    /**
     * @notice Returns the minimum of two values
     * @param a First value
     * @param b Second value
     * @return The smaller of the two values
     */
    function min(uint256 a, uint256 b) internal pure returns (uint256) {
        return a < b ? a : b;
    }

    /// @notice Checks if a * b would overflow
    /// @param a The first operand
    /// @param b The second operand
    /// @return bool True if multiplication would overflow, false otherwise
    function willMultiplyOverflow(uint256 a, uint256 b) internal pure returns (bool) {
        // Gas-optimized shortcut: zero can't overflow
        if (a == 0 || b == 0) return false;
        // Overflow occurs if a > type(uint256).max / b
        return a > type(uint256).max / b;
    }
}
"
    },
    "lib/openzeppelin-contracts/contracts/token/ERC20/utils/SafeERC20.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";
import {IERC20Permit} from "../extensions/IERC20Permit.sol";
import {Address} from "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    /**
     * @dev An operation with an ERC20 token failed.
     */
    error SafeERC20FailedOperation(address token);

    /**
     * @dev Indicates a failed `decreaseAllowance` request.
     */
    error SafeERC20FailedDecreaseAllowance(address spender, uint256 currentAllowance, uint256 requestedDecrease);

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        forceApprove(token, spender, oldAllowance + value);
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `requestedDecrease`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 requestedDecrease) internal {
        unchecked {
            uint256 currentAllowance = token.allowance(address(this), spender);
            if (currentAllowance < requestedDecrease) {
                revert SafeERC20FailedDecreaseAllowance(spender, currentAllowance, requestedDecrease);
            }
            forceApprove(token, spender, currentAllowance - requestedDecrease);
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeCall(token.approve, (spender, value));

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeCall(token.approve, (spender, 0)));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Use a ERC-2612 signature to set the `owner` approval toward `spender` on `token`.
     * Revert on invalid signature.
     */
    function safePermit(
        IERC20Permit token,
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal {
        uint256 nonceBefore = token.nonces(owner);
        token.permit(owner, spender, value, deadline, v, r, s);
        uint256 nonceAfter = token.nonces(owner);
        if (nonceAfter != nonceBefore + 1) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data);
        if (returndata.length != 0 && !abi.decode(returndata, (bool))) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return success && (returndata.length == 0 || abi.decode(returndata, (bool))) && address(token).code.length > 0;
    }
}
"
    },
    "lib/openzeppelin-contracts/contracts/token/ERC20/IERC20.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}
"
    },
    "src/v2/CounterfactualHolderFactory.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity ^0.8.17;

import {IERC20} from "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import {SafeERC20} from "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import {CounterfactualHolder} from "./CounterfactualHolder.sol";
import {Call} from "./Structs.sol";
import {TransientBytes} from "./utils/TransientBytes/TransientBytes.sol";
import {ICounterfactualHolderFactory} from "./ICounterfactualHolderFactory.sol";
import {TransientSlot} from "./utils/TransientBytes/TransientSlot.sol";
import {ReentrancyGuard} from "@openzeppelin/contracts/security/ReentrancyGuard.sol";

contract CounterfactualHolderFactory is ICounterfactualHolderFactory, ReentrancyGuard {
    using SafeERC20 for IERC20;
    using TransientBytes for *;
    using TransientSlot for *;

    error NotApproved(address from, address operator);

    event TransferToCFH(
        address indexed from, address indexed toUser, address indexed token, address cfh, uint256 amount
    );

    event Execute(address indexed user, address indexed cfh, address indexed token, Call[] calls);
    event Approval(address indexed from, address indexed operator, bool status);

    struct UserTokenData {
        uint256 nextSalt;
    }

    mapping(address user => mapping(address token => UserTokenData)) public userTokenData;
    mapping(address owner => mapping(address operator => bool status)) public approvals;

    function transferCFHToCFH(address toUser, address token, uint256 amount) external nonReentrant {
        _executeCFHTransfer(msg.sender, toUser, token, amount);
    }

    function transferFromCFHToCFH(address fromUser, address toUser, address token, uint256 amount)
        external
        nonReentrant
    {
        if (!isApproved(fromUser, msg.sender)) {
            revert NotApproved(fromUser, msg.sender);
        }
        _executeCFHTransfer(fromUser, toUser, token, amount);
    }

    function _executeCFHTransfer(address fromUser, address toUser, address token, uint256 amount) internal {
        UserTokenData storage d = userTokenData[toUser][token];
        address currentHolder = _predictCFH(token, deriveUserNonce(toUser, token, d.nextSalt));

        Call[] memory calls = new Call[](1);
        calls[0] = Call({
            target: address(token),
            data: abi.encodeWithSelector(IERC20.transfer.selector, currentHolder, amount)
        });
        _execute(fromUser, token, calls);

        emit TransferToCFH(fromUser, toUser, token, currentHolder, amount);
    }

    function transferToCFH(address user, address token, uint256 amount) external nonReentrant {
        UserTokenData storage d = userTokenData[user][token];
        address currentHolder = _predictCFH(token, deriveUserNonce(user, token, d.nextSalt));
        IERC20(token).safeTransferFrom(msg.sender, currentHolder, amount);
        emit TransferToCFH(msg.sender, user, token, currentHolder, amount);
    }

    function executeFrom(address from, address token, Call[] memory calls) external nonReentrant {
        if (!isApproved(from, msg.sender)) {
            revert NotApproved(from, msg.sender);
        }

        _execute(from, token, calls);
    }

    function execute(address token, Call[] memory calls) external nonReentrant {
        _execute(msg.sender, token, calls);
    }

    function setApprovalStatus(address operator, bool status) external {
        approvals[msg.sender][operator] = status;
        emit Approval(msg.sender, operator, status);
    }

    function _execute(address from, address token, Call[] memory calls) internal {
        bytes32 baseCallsSlot = deriveCallsBaseSlot();
        bytes memory dataCalls = abi.encode(calls);
        baseCallsSlot.tstoreBytes(dataCalls);

        UserTokenData storage d = userTokenData[from][token];

        uint256 nextSalt = d.nextSalt;
        address nextHolder = _predictCFH(token, deriveUserNonce(from, token, nextSalt + 1));
        bytes32 baseNextHolderSlot = deriveNextHolderBaseSlot();
        baseNextHolderSlot.asAddress().tstore(nextHolder);

        bytes32 nonce = deriveUserNonce(from, token, nextSalt);
        address cfh = address(new CounterfactualHolder{salt: nonce}(IERC20(token)));
        d.nextSalt = nextSalt + 1;

        emit Execute(from, cfh, token, calls);
    }

    function isApproved(address from, address operator) public view returns (bool) {
        return approvals[from][operator];
    }

    function getCurrentCFH(address user, address token) public view returns (address) {
        UserTokenData storage d = userTokenData[user][token];
        return _predictCFH(token, deriveUserNonce(user, token, d.nextSalt));
    }

    function balanceOfCFH(address user, address token) external view returns (uint256) {
        return IERC20(token).balanceOf(getCurrentCFH(user, token));
    }

    function deriveUserNonce(address user, address token, uint256 nonce) internal view returns (bytes32) {
        return keccak256(abi.encodePacked(user, token, nonce, address(this)));
    }

    function getTransientCalls() external view returns (Call[] memory) {
        bytes32 baseCallsSlot = deriveCallsBaseSlot();
        bytes memory dataCalls = baseCallsSlot.tloadBytes();
        return abi.decode(dataCalls, (Call[]));
    }

    function getTransientNextHolder() external view returns (address) {
        bytes32 baseNextHolderSlot = deriveNextHolderBaseSlot();
        return baseNextHolderSlot.asAddress().tload();
    }

    function deriveCallsBaseSlot() internal pure returns (bytes32) {
        return keccak256(abi.encodePacked("CALLS"));
    }

    function deriveNextHolderBaseSlot() internal pure returns (bytes32) {
        return keccak256(abi.encodePacked("NEXT_HOLDER"));
    }

    /// @dev Predict the create2
    function _predictCFH(address token, bytes32 salt) internal view returns (address currentHolder) {
        bytes32 initCodeHash = keccak256(abi.encodePacked(type(CounterfactualHolder).creationCode, abi.encode(token)));
        // EIP-1014: keccak256(0xff ++ deployer ++ salt ++ keccak256(init_code))[12:]
        bytes32 hash = keccak256(abi.encodePacked(bytes1(0xff), address(this), salt, initCodeHash));

        currentHolder = address(uint160(uint256(hash)));
    }
}
"
    },
    "lib/openzeppelin-contracts/contracts/security/ReentrancyGuard.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (security/ReentrancyGuard.sol)

pragma solidity ^0.8.20;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();

    constructor() {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be _NOT_ENTERED
        if (_status == _ENTERED) {
            revert ReentrancyGuardReentrantCall();
        }

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == _ENTERED;
    }
}
"
    },
    "src/v2/Structs.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity ^0.8.17;

struct Call {
    address target;
    bytes data;
}
"
    },
    "lib/openzeppelin-contracts/contracts/token/ERC20/extensions/IERC20Permit.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}
"
    },
    "lib/openzeppelin-contracts/contracts/utils/Address.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Address.sol)

pragma solidity ^0.8.20;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev The ETH balance of the account is not enough to perform the operation.
     */
    error AddressInsufficientBalance(address account);

    /**
     * @dev There's no code at `target` (it is not a contract).
     */
    error AddressEmptyCode(address target);

    /**
     * @dev A call to an address target failed. The target may have reverted.
     */
    error FailedInnerCall();

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.20/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        if (address(this).balance < amount) {
            revert AddressInsufficientBalance(address(this));
        }

        (bool success, ) = recipient.call{value: amount}("");
        if (!success) {
            revert FailedInnerCall();
        }
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason or custom error, it is bubbled
     * up by this function (like regular Solidity function calls). However, if
     * the call reverted with no returned reason, this function reverts with a
     * {FailedInnerCall} error.
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        if (address(this).balance < value) {
            revert AddressInsufficientBalance(address(this));
        }
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and reverts if the target
     * was not a contract or bubbling up the revert reason (falling back to {FailedInnerCall}) in case of an
     * unsuccessful call.
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata
    ) internal view returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            // only check if target is a contract if the call was successful and the return data is empty
            // otherwise we already know that it was a contract
            if (returndata.length == 0 && target.code.length == 0) {
                revert AddressEmptyCode(target);
            }
            return returndata;
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and reverts if it wasn't, either by bubbling the
     * revert reason or with a default {FailedInnerCall} error.
     */
    function verifyCallResult(bool success, bytes memory returndata) internal pure returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            return returndata;
        }
    }

    /**
     * @dev Reverts with returndata if present. Otherwise reverts with {FailedInnerCall}.
     */
    function _revert(bytes memory returndata) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert FailedInnerCall();
        }
    }
}
"
    },
    "src/v2/CounterfactualHolder.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity ^0.8.17;

import {Call} from "./Structs.sol";
import {IERC20} from "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import {SafeERC20} from "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import {ICounterfactualHolderFactory} from "./ICounterfactualHolderFactory.sol";

contract CounterfactualHolder {
    using SafeERC20 for IERC20;

    error ExecutionFailed(uint256 index, address target, bytes data);

    constructor(IERC20 _token) {
        ICounterfactualHolderFactory factory = ICounterfactualHolderFactory(msg.sender);
        Call[] memory _calls = factory.getTransientCalls();
        _executeCalls(_calls);
        uint256 leftoverBalance = _token.balanceOf(address(this));
        if (leftoverBalance > 0) {
            address nextHolder = factory.getTransientNextHolder();
            _token.safeTransfer(nextHolder, leftoverBalance);
        }
    }

    function _executeCalls(Call[] memory _calls) internal {
        uint256 length = _calls.length;
        for (uint256 i; i < length; ++i) {
            (bool success,) = _calls[i].target.call(_calls[i].data);
            if (!success) {
                revert ExecutionFailed(i, _calls[i].target, _calls[i].data);
            }
        }
    }
}
"
    },
    "src/v2/utils/TransientBytes/TransientBytes.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity ^0.8.24;

/**
 * TransientBytes (incremental slots)
 * - Length at `baseSlot`
 * - Data starts at keccak256(abi.encodePacked(baseSlot, DOMAIN))
 * - Chunk i lives at dataStart + i
 *
 * Uses OpenZeppelin TransientSlot for typed tload/tstore.
 */
import "./TransientSlot.sol";

library TransientBytes {
    using TransientSlot for *;

    // Domain-separate the data region to avoid accidental overlap
    bytes32 private constant _DOMAIN = keccak256("TransientBytes.v2");

    /*//////////////////////////////////////////////////////////////
                              WRITE
    //////////////////////////////////////////////////////////////*/

    function tstoreBytes(bytes32 baseSlot, bytes memory data) internal {
        uint256 len = data.length;
        baseSlot.asUint256().tstore(len);

        if (len == 0) return;

        uint256 nChunks = (len + 31) / 32; // ceil_div
        bytes32 dataStart = _dataStart(baseSlot);

        uint256 src;
        assembly {
            src := add(data, 32)
        }

        for (uint256 i = 0; i < nChunks; ++i) {
            bytes32 word;
            assembly {
                word := mload(add(src, mul(i, 32)))
            }
            _slotAdd(dataStart, i).asBytes32().tstore(word);
        }
    }

    /*//////////////////////////////////////////////////////////////
                               READ
    //////////////////////////////////////////////////////////////*/

    function tloadBytes(bytes32 baseSlot) internal view returns (bytes memory out) {
        uint256 len = baseSlot.asUint256().tload();
        if (len == 0) return bytes("");

        out = new bytes(len);
        uint256 nChunks = (len + 31) / 32;
        bytes32 dataStart = _dataStart(baseSlot);

        uint256 dst;
        assembly {
            dst := add(out, 32)
        }

        for (uint256 i = 0; i < nChunks; ++i) {
            bytes32 word = _slotAdd(dataStart, i).asBytes32().tload();
            assembly {
                mstore(add(dst, mul(i, 32)), word)
            }
        }
    }

    /*//////////////////////////////////////////////////////////////
                               CLEAR
    //////////////////////////////////////////////////////////////*/

    /// @dev Logically clear by zeroing length (no need to zero chunks).
    function tclear(bytes32 baseSlot) internal {
        baseSlot.asUint256().tstore(0);
    }

    /*//////////////////////////////////////////////////////////////
                             INTERNALS
    //////////////////////////////////////////////////////////////*/

    /// @dev Start of data region = keccak256(baseSlot || DOMAIN)
    function _dataStart(bytes32 baseSlot) private pure returns (bytes32 start) {
        bytes32 d = _DOMAIN;
        assembly {
            let ptr := mload(0x40)
            mstore(ptr, baseSlot)
            mstore(add(ptr, 0x20), d)
            start := keccak256(ptr, 64)
        }
    }

    /// @dev Return base + index as a bytes32 slot.
    function _slotAdd(bytes32 base, uint256 index) private pure returns (bytes32 slot) {
        assembly {
            slot := add(base, index)
        }
    }
}
"
    },
    "src/v2/ICounterfactualHolderFactory.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity ^0.8.17;

import {Call} from "./Structs.sol";

interface ICounterfactualHolderFactory {
    function getTransientCalls() external view returns (Call[] memory);
    function getTransientNextHolder() external view returns (address);
}
"
    },
    "src/v2/utils/TransientBytes/TransientSlot.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.3.0) (utils/TransientSlot.sol)
// This file was procedurally generated from scripts/generate/templates/TransientSlot.js.

pragma solidity ^0.8.24;

/**
 * @dev Library for reading and writing value-types to specific transient storage slots.
 *
 * Transient slots are often used to store temporary values that are removed after the current transaction.
 * This library helps with reading and writing to such slots without the need for inline assembly.
 *
 *  * Example reading and writing values using transient storage:
 * ```solidity
 * contract Lock {
 *     using TransientSlot for *;
 *
 *     // Define the slot. Alternatively, use the SlotDerivation library to derive the slot.
 *     bytes32 internal constant _LOCK_SLOT = 0xf4678858b2b588224636b8522b729e7722d32fc491da849ed75b3fdf3c84f542;
 *
 *     modifier locked() {
 *         require(!_LOCK_SLOT.asBoolean().tload());
 *
 *         _LOCK_SLOT.asBoolean().tstore(true);
 *         _;
 *         _LOCK_SLOT.asBoolean().tstore(false);
 *     }
 * }
 * ```
 *
 * TIP: Consider using this library along with {SlotDerivation}.
 */
library TransientSlot {
    /**
     * @dev UDVT that represents a slot holding an address.
     */
    type AddressSlot is bytes32;

    /**
     * @dev Cast an arbitrary slot to a AddressSlot.
     */
    function asAddress(bytes32 slot) internal pure returns (AddressSlot) {
        return AddressSlot.wrap(slot);
    }

    /**
     * @dev UDVT that represents a slot holding a bool.
     */
    type BooleanSlot is bytes32;

    /**
     * @dev Cast an arbitrary slot to a BooleanSlot.
     */
    function asBoolean(bytes32 slot) internal pure returns (BooleanSlot) {
        return BooleanSlot.wrap(slot);
    }

    /**
     * @dev UDVT that represents a slot holding a bytes32.
     */
    type Bytes32Slot is bytes32;

    /**
     * @dev Cast an arbitrary slot to a Bytes32Slot.
     */
    function asBytes32(bytes32 slot) internal pure returns (Bytes32Slot) {
        return Bytes32Slot.wrap(slot);
    }

    /**
     * @dev UDVT that represents a slot holding a uint256.
     */
    type Uint256Slot is bytes32;

    /**
     * @dev Cast an arbitrary slot to a Uint256Slot.
     */
    function asUint256(bytes32 slot) internal pure returns (Uint256Slot) {
        return Uint256Slot.wrap(slot);
    }

    /**
     * @dev UDVT that represents a slot holding a int256.
     */
    type Int256Slot is bytes32;

    /**
     * @dev Cast an arbitrary slot to a Int256Slot.
     */
    function asInt256(bytes32 slot) internal pure returns (Int256Slot) {
        return Int256Slot.wrap(slot);
    }

    /**
     * @dev Load the value held at location `slot` in transient storage.
     */
    function tload(AddressSlot slot) internal view returns (address value) {
        assembly ("memory-safe") {
            value := tload(slot)
        }
    }

    /**
     * @dev Store `value` at location `slot` in transient storage.
     */
    function tstore(AddressSlot slot, address value) internal {
        assembly ("memory-safe") {
            tstore(slot, value)
        }
    }

    /**
     * @dev Load the value held at location `slot` in transient storage.
     */
    function tload(BooleanSlot slot) internal view returns (bool value) {
        assembly ("memory-safe") {
            value := tload(slot)
        }
    }

    /**
     * @dev Store `value` at location `slot` in transient storage.
     */
    function tstore(BooleanSlot slot, bool value) internal {
        assembly ("memory-safe") {
            tstore(slot, value)
        }
    }

    /**
     * @dev Load the value held at location `slot` in transient storage.
     */
    function tload(Bytes32Slot slot) internal view returns (bytes32 value) {
        assembly ("memory-safe") {
            value := tload(slot)
        }
    }

    /**
     * @dev Store `value` at location `slot` in transient storage.
     */
    function tstore(Bytes32Slot slot, bytes32 value) internal {
        assembly ("memory-safe") {
            tstore(slot, value)
        }
    }

    /**
     * @dev Load the value held at location `slot` in transient storage.
     */
    function tload(Uint256Slot slot) internal view returns (uint256 value) {
        assembly ("memory-safe") {
            value := tload(slot)
        }
    }

    /**
     * @dev Store `value` at location `slot` in transient storage.
     */
    function tstore(Uint256Slot slot, uint256 value) internal {