CommunityRaiseVault

// SPDX-License-Identifier: MIT
pragma solidity >=0.4.16 >=0.6.2 ^0.8.20;

// lib/openzeppelin-contracts/contracts/utils/Context.sol

// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// lib/openzeppelin-contracts/contracts/utils/introspection/IERC165.sol

// OpenZeppelin Contracts (last updated v5.4.0) (utils/introspection/IERC165.sol)

/**
 * @dev Interface of the ERC-165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[ERC].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[ERC section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// lib/openzeppelin-contracts/contracts/token/ERC20/IERC20.sol

// OpenZeppelin Contracts (last updated v5.4.0) (token/ERC20/IERC20.sol)

/**
 * @dev Interface of the ERC-20 standard as defined in the ERC.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// lib/openzeppelin-contracts/contracts/utils/ReentrancyGuard.sol

// OpenZeppelin Contracts (last updated v5.1.0) (utils/ReentrancyGuard.sol)

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If EIP-1153 (transient storage) is available on the chain you're deploying at,
 * consider using {ReentrancyGuardTransient} instead.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant NOT_ENTERED = 1;
    uint256 private constant ENTERED = 2;

    uint256 private _status;

    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();

    constructor() {
        _status = NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be NOT_ENTERED
        if (_status == ENTERED) {
            revert ReentrancyGuardReentrantCall();
        }

        // Any calls to nonReentrant after this point will fail
        _status = ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == ENTERED;
    }
}

// lib/openzeppelin-contracts/contracts/interfaces/IERC165.sol

// OpenZeppelin Contracts (last updated v5.4.0) (interfaces/IERC165.sol)

// lib/openzeppelin-contracts/contracts/interfaces/IERC20.sol

// OpenZeppelin Contracts (last updated v5.4.0) (interfaces/IERC20.sol)

// lib/openzeppelin-contracts/contracts/access/Ownable.sol

// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// lib/openzeppelin-contracts/contracts/utils/Pausable.sol

// OpenZeppelin Contracts (last updated v5.3.0) (utils/Pausable.sol)

/**
 * @dev Contract module which allows children to implement an emergency stop
 * mechanism that can be triggered by an authorized account.
 *
 * This module is used through inheritance. It will make available the
 * modifiers `whenNotPaused` and `whenPaused`, which can be applied to
 * the functions of your contract. Note that they will not be pausable by
 * simply including this module, only once the modifiers are put in place.
 */
abstract contract Pausable is Context {
    bool private _paused;

    /**
     * @dev Emitted when the pause is triggered by `account`.
     */
    event Paused(address account);

    /**
     * @dev Emitted when the pause is lifted by `account`.
     */
    event Unpaused(address account);

    /**
     * @dev The operation failed because the contract is paused.
     */
    error EnforcedPause();

    /**
     * @dev The operation failed because the contract is not paused.
     */
    error ExpectedPause();

    /**
     * @dev Modifier to make a function callable only when the contract is not paused.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    modifier whenNotPaused() {
        _requireNotPaused();
        _;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is paused.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    modifier whenPaused() {
        _requirePaused();
        _;
    }

    /**
     * @dev Returns true if the contract is paused, and false otherwise.
     */
    function paused() public view virtual returns (bool) {
        return _paused;
    }

    /**
     * @dev Throws if the contract is paused.
     */
    function _requireNotPaused() internal view virtual {
        if (paused()) {
            revert EnforcedPause();
        }
    }

    /**
     * @dev Throws if the contract is not paused.
     */
    function _requirePaused() internal view virtual {
        if (!paused()) {
            revert ExpectedPause();
        }
    }

    /**
     * @dev Triggers stopped state.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    function _pause() internal virtual whenNotPaused {
        _paused = true;
        emit Paused(_msgSender());
    }

    /**
     * @dev Returns to normal state.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    function _unpause() internal virtual whenPaused {
        _paused = false;
        emit Unpaused(_msgSender());
    }
}

// lib/openzeppelin-contracts/contracts/interfaces/IERC1363.sol

// OpenZeppelin Contracts (last updated v5.4.0) (interfaces/IERC1363.sol)

/**
 * @title IERC1363
 * @dev Interface of the ERC-1363 standard as defined in the https://eips.ethereum.org/EIPS/eip-1363[ERC-1363].
 *
 * Defines an extension interface for ERC-20 tokens that supports executing code on a recipient contract
 * after `transfer` or `transferFrom`, or code on a spender contract after `approve`, in a single transaction.
 */
interface IERC1363 is IERC20, IERC165 {
    /*
     * Note: the ERC-165 identifier for this interface is 0xb0202a11.
     * 0xb0202a11 ===
     *   bytes4(keccak256('transferAndCall(address,uint256)')) ^
     *   bytes4(keccak256('transferAndCall(address,uint256,bytes)')) ^
     *   bytes4(keccak256('transferFromAndCall(address,address,uint256)')) ^
     *   bytes4(keccak256('transferFromAndCall(address,address,uint256,bytes)')) ^
     *   bytes4(keccak256('approveAndCall(address,uint256)')) ^
     *   bytes4(keccak256('approveAndCall(address,uint256,bytes)'))
     */

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferAndCall(address to, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @param data Additional data with no specified format, sent in call to `to`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferAndCall(address to, uint256 value, bytes calldata data) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the allowance mechanism
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param from The address which you want to send tokens from.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferFromAndCall(address from, address to, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the allowance mechanism
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param from The address which you want to send tokens from.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @param data Additional data with no specified format, sent in call to `to`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferFromAndCall(address from, address to, uint256 value, bytes calldata data) external returns (bool);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens and then calls {IERC1363Spender-onApprovalReceived} on `spender`.
     * @param spender The address which will spend the funds.
     * @param value The amount of tokens to be spent.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function approveAndCall(address spender, uint256 value) external returns (bool);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens and then calls {IERC1363Spender-onApprovalReceived} on `spender`.
     * @param spender The address which will spend the funds.
     * @param value The amount of tokens to be spent.
     * @param data Additional data with no specified format, sent in call to `spender`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function approveAndCall(address spender, uint256 value, bytes calldata data) external returns (bool);
}

// lib/openzeppelin-contracts/contracts/token/ERC20/utils/SafeERC20.sol

// OpenZeppelin Contracts (last updated v5.3.0) (token/ERC20/utils/SafeERC20.sol)

/**
 * @title SafeERC20
 * @dev Wrappers around ERC-20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    /**
     * @dev An operation with an ERC-20 token failed.
     */
    error SafeERC20FailedOperation(address token);

    /**
     * @dev Indicates a failed `decreaseAllowance` request.
     */
    error SafeERC20FailedDecreaseAllowance(address spender, uint256 currentAllowance, uint256 requestedDecrease);

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Variant of {safeTransfer} that returns a bool instead of reverting if the operation is not successful.
     */
    function trySafeTransfer(IERC20 token, address to, uint256 value) internal returns (bool) {
        return _callOptionalReturnBool(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Variant of {safeTransferFrom} that returns a bool instead of reverting if the operation is not successful.
     */
    function trySafeTransferFrom(IERC20 token, address from, address to, uint256 value) internal returns (bool) {
        return _callOptionalReturnBool(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     *
     * IMPORTANT: If the token implements ERC-7674 (ERC-20 with temporary allowance), and if the "client"
     * smart contract uses ERC-7674 to set temporary allowances, then the "client" smart contract should avoid using
     * this function. Performing a {safeIncreaseAllowance} or {safeDecreaseAllowance} operation on a token contract
     * that has a non-zero temporary allowance (for that particular owner-spender) will result in unexpected behavior.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        forceApprove(token, spender, oldAllowance + value);
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `requestedDecrease`. If `token` returns no
     * value, non-reverting calls are assumed to be successful.
     *
     * IMPORTANT: If the token implements ERC-7674 (ERC-20 with temporary allowance), and if the "client"
     * smart contract uses ERC-7674 to set temporary allowances, then the "client" smart contract should avoid using
     * this function. Performing a {safeIncreaseAllowance} or {safeDecreaseAllowance} operation on a token contract
     * that has a non-zero temporary allowance (for that particular owner-spender) will result in unexpected behavior.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 requestedDecrease) internal {
        unchecked {
            uint256 currentAllowance = token.allowance(address(this), spender);
            if (currentAllowance < requestedDecrease) {
                revert SafeERC20FailedDecreaseAllowance(spender, currentAllowance, requestedDecrease);
            }
            forceApprove(token, spender, currentAllowance - requestedDecrease);
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     *
     * NOTE: If the token implements ERC-7674, this function will not modify any temporary allowance. This function
     * only sets the "standard" allowance. Any temporary allowance will remain active, in addition to the value being
     * set here.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeCall(token.approve, (spender, value));

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeCall(token.approve, (spender, 0)));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Performs an {ERC1363} transferAndCall, with a fallback to the simple {ERC20} transfer if the target has no
     * code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * Reverts if the returned value is other than `true`.
     */
    function transferAndCallRelaxed(IERC1363 token, address to, uint256 value, bytes memory data) internal {
        if (to.code.length == 0) {
            safeTransfer(token, to, value);
        } else if (!token.transferAndCall(to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Performs an {ERC1363} transferFromAndCall, with a fallback to the simple {ERC20} transferFrom if the target
     * has no code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * Reverts if the returned value is other than `true`.
     */
    function transferFromAndCallRelaxed(
        IERC1363 token,
        address from,
        address to,
        uint256 value,
        bytes memory data
    ) internal {
        if (to.code.length == 0) {
            safeTransferFrom(token, from, to, value);
        } else if (!token.transferFromAndCall(from, to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Performs an {ERC1363} approveAndCall, with a fallback to the simple {ERC20} approve if the target has no
     * code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * NOTE: When the recipient address (`to`) has no code (i.e. is an EOA), this function behaves as {forceApprove}.
     * Opposedly, when the recipient address (`to`) has code, this function only attempts to call {ERC1363-approveAndCall}
     * once without retrying, and relies on the returned value to be true.
     *
     * Reverts if the returned value is other than `true`.
     */
    function approveAndCallRelaxed(IERC1363 token, address to, uint256 value, bytes memory data) internal {
        if (to.code.length == 0) {
            forceApprove(token, to, value);
        } else if (!token.approveAndCall(to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturnBool} that reverts if call fails to meet the requirements.
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        uint256 returnSize;
        uint256 returnValue;
        assembly ("memory-safe") {
            let success := call(gas(), token, 0, add(data, 0x20), mload(data), 0, 0x20)
            // bubble errors
            if iszero(success) {
                let ptr := mload(0x40)
                returndatacopy(ptr, 0, returndatasize())
                revert(ptr, returndatasize())
            }
            returnSize := returndatasize()
            returnValue := mload(0)
        }

        if (returnSize == 0 ? address(token).code.length == 0 : returnValue != 1) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silently catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        bool success;
        uint256 returnSize;
        uint256 returnValue;
        assembly ("memory-safe") {
            success := call(gas(), token, 0, add(data, 0x20), mload(data), 0, 0x20)
            returnSize := returndatasize()
            returnValue := mload(0)
        }
        return success && (returnSize == 0 ? address(token).code.length > 0 : returnValue == 1);
    }
}

// contracts/CommunityRaiseVault.sol

interface IUniswapV2Router02 {
    function addLiquidityETH(
        address token,
        uint256 amountTokenDesired,
        uint256 amountTokenMin,
        uint256 amountETHMin,
        address to,
        uint256 deadline
    ) external payable returns (uint256 amountToken, uint256 amountETH, uint256 liquidity);

    function swapExactETHForTokensSupportingFeeOnTransferTokens(
        uint256 amountOutMin,
        address[] calldata path,
        address to,
        uint256 deadline
    ) external payable;

    function WETH() external pure returns (address);
}

interface IPondManagerMinimal {
    function addToPond(uint256 pepeAmount) external;
}

/// @title PEPEtual Community Raise Vault
/// @notice Collects ETH for 72 hours, seeds liquidity with pre-funded PEPETUAL, burns LP tokens, and lets contributors claim their token allocation.
contract CommunityRaiseVault is Ownable, Pausable, ReentrancyGuard {
    using SafeERC20 for IERC20;

    enum State {
        Collecting,
        Finalized,
        Cancelled
    }

    // Constants
    uint256 public constant RAISE_DURATION = 72 hours;
    uint256 public immutable tokensForContributors; // gross tokens reserved for contributors (before tax)
    uint256 public immutable tokensForLiquidity; // tokens reserved for liquidity pairing
    uint256 public constant TAX_BPS = 969; // 9.69%
    uint256 public constant BPS = 10_000;
    uint256 public constant DISTRIBUTION_TOTAL_BPS = 9690;
    uint256 public constant POND_BPS = 6900; // 6.9%
    uint256 public constant PEPE_BURN_BPS = 690; // 0.69%
    uint256 public constant REWARDS_BPS = 690; // 0.69%
    uint256 public constant DEV_BPS = 690; // 0.69%
    uint256 public constant ART_BPS = 30; // 0.03%
    uint256 public constant CLAIM_GRACE_PERIOD = 30 days;
    address public constant DEAD = 0x000000000000000000000000000000000000dEaD;

    IERC20 public immutable pepetual;
    IERC20 public immutable pepe;
    IUniswapV2Router02 public immutable router;
    IPondManagerMinimal public immutable pondManager;
    address public immutable devWallet;
    address public immutable artWallet;

    uint256 public startTime;
    uint256 public endTime;

    State public state;
    bool public raiseStarted;
    bool public liquidityAdded;
    bool public raiseClosed;

    uint256 public totalRaised;
    uint256 public ethTaxBucket;
    mapping(address => uint256) public contributions;
    mapping(address => bool) public tokensClaimed;

    address[] private contributorList;
    mapping(address => bool) private isContributor;

    uint256 public claimPool; // tokens available for claims (no token tax withheld)
    uint256 public pendingRewardsPepe;
    uint256 public pendingPondPepe;

    event Deposited(address indexed contributor, uint256 amount);
    event Refunded(address indexed contributor, uint256 amount);
    event Finalized(uint256 totalRaised, uint256 tokensUsed, uint256 ethUsed, uint256 lpMinted);
    event TokensClaimed(address indexed contributor, uint256 amount);
    event Cancelled();
    event RaiseClosed(uint256 closedAt);
    event TaxWithheld(uint256 amount);
    event RewardsBuffered(uint256 amount);
    event PondBuffered(uint256 amount);

    constructor(
        address _pepetual,
        address _pepe,
        address _router,
        address _pondManager,
        address _devWallet,
        address _artWallet,
        uint256 _tokensForContributors,
        uint256 _tokensForLiquidity
    ) Ownable(msg.sender) {
        require(_pepetual != address(0), "Invalid token");
        require(_pepe != address(0), "Invalid PEPE token");
        require(_router != address(0), "Invalid router");
        require(_pondManager != address(0), "Invalid pond manager");
        require(_devWallet != address(0), "Invalid dev wallet");
        require(_artWallet != address(0), "Invalid art wallet");
        require(_tokensForContributors > 0, "Invalid contributor amount");
        require(_tokensForLiquidity > 0, "Invalid liquidity amount");
        pepetual = IERC20(_pepetual);
        pepe = IERC20(_pepe);
        router = IUniswapV2Router02(_router);
        pondManager = IPondManagerMinimal(_pondManager);
        devWallet = _devWallet;
        artWallet = _artWallet;
        tokensForContributors = _tokensForContributors;
        tokensForLiquidity = _tokensForLiquidity;
        state = State.Collecting;
    }

    modifier inState(State expected) {
        require(state == expected, "Invalid state");
        _;
    }

    receive() external payable {
        deposit();
    }

    function deposit() public payable whenNotPaused inState(State.Collecting) {
        require(raiseStarted, "Raise not started");
        require(!raiseClosed, "Raise closed");
        require(block.timestamp <= endTime, "Raise ended");
        require(msg.value > 0, "Zero contribution");

        contributions[msg.sender] += msg.value;
        if (!isContributor[msg.sender]) {
            isContributor[msg.sender] = true;
            contributorList.push(msg.sender);
        }
        totalRaised += msg.value;

        emit Deposited(msg.sender, msg.value);
    }

    function startRaise() external onlyOwner inState(State.Collecting) {
        require(!raiseStarted, "Already started");
        raiseStarted = true;
        startTime = block.timestamp;
        endTime = block.timestamp + RAISE_DURATION;
    }

    function finalize(uint256 amountTokenMin, uint256 amountETHMin, uint256 pepeAmountOutMin)
        external
        onlyOwner
        inState(State.Collecting)
    {
        require(raiseStarted, "Raise not started");
        require(raiseClosed || block.timestamp > endTime, "Raise active");

        if (totalRaised == 0) {
            state = State.Cancelled;
            emit Cancelled();
            return;
        }

        uint256 requiredTokens = tokensForContributors + tokensForLiquidity;
        require(
            pepetual.balanceOf(address(this)) >= requiredTokens, "Insufficient PEPETUAL balance"
        );

        // Approve router to spend liquidity tokens
        pepetual.forceApprove(address(router), 0);
        pepetual.forceApprove(address(router), tokensForLiquidity);

        uint256 ethTax = (totalRaised * TAX_BPS) / BPS;
        uint256 ethForLP = totalRaised - ethTax;
        ethTaxBucket = ethTax;

        (uint256 amountToken, uint256 amountETH, uint256 liquidity) = router.addLiquidityETH{
            value: ethForLP
        }(
            address(pepetual),
            tokensForLiquidity,
            amountTokenMin,
            amountETHMin,
            DEAD,
            block.timestamp + 600
        );
        liquidityAdded = true;

        // reset approval to zero for safety
        pepetual.forceApprove(address(router), 0);

        // All contributor tokens flow to the claim pool (token tax handled via trade volume)
        claimPool = tokensForContributors;
        emit TaxWithheld(0);

        // Swap ETH tax to PEPE via router
        if (ethTax > 0) {
            require(pepeAmountOutMin > 0, "Invalid PEPE min");
            address[] memory path = new address[](2);
            path[0] = router.WETH();
            path[1] = address(pepe);

            uint256 pepeBalanceBefore = pepe.balanceOf(address(this));

            router.swapExactETHForTokensSupportingFeeOnTransferTokens{ value: ethTax }(
                pepeAmountOutMin, path, address(this), block.timestamp + 600
            );

            uint256 pepeReceived = pepe.balanceOf(address(this)) - pepeBalanceBefore;
            require(pepeReceived >= pepeAmountOutMin, "Slippage protection");

            uint256 pepeBalance = pepe.balanceOf(address(this));
            if (pepeBalance > 0) {
                uint256 pondShare = (pepeBalance * POND_BPS) / DISTRIBUTION_TOTAL_BPS;
                uint256 burnShare = (pepeBalance * PEPE_BURN_BPS) / DISTRIBUTION_TOTAL_BPS;
                uint256 rewardsShare = (pepeBalance * REWARDS_BPS) / DISTRIBUTION_TOTAL_BPS;
                uint256 devShare = (pepeBalance * DEV_BPS) / DISTRIBUTION_TOTAL_BPS;
                uint256 artShare = (pepeBalance * ART_BPS) / DISTRIBUTION_TOTAL_BPS;

                uint256 distributed = pondShare + burnShare + rewardsShare + devShare + artShare;
                uint256 remainder = pepeBalance > distributed ? pepeBalance - distributed : 0;

                if (pondShare > 0) {
                    pendingPondPepe += pondShare;
                    emit PondBuffered(pondShare);
                }
                if (burnShare > 0) {
                    pepe.safeTransfer(DEAD, burnShare);
                }
                if (devShare > 0) {
                    pepe.safeTransfer(devWallet, devShare);
                }
                if (artShare > 0) {
                    pepe.safeTransfer(artWallet, artShare);
                }

                uint256 rewardsBuffer = rewardsShare + remainder;
                if (rewardsBuffer > 0) {
                    pendingRewardsPepe += rewardsBuffer;
                    emit RewardsBuffered(rewardsBuffer);
                }
            }
        }

        // any unused ETH remains in contract (should be zero for first LP); can be swept later
        state = State.Finalized;

        emit Finalized(totalRaised, amountToken, amountETH, liquidity);
    }

    function cancelRaise() external onlyOwner inState(State.Collecting) {
        state = State.Cancelled;
        emit Cancelled();
    }

    function closeRaise() external onlyOwner inState(State.Collecting) {
        require(raiseStarted, "Raise not started");
        require(!raiseClosed, "Already closed");
        raiseClosed = true;
        emit RaiseClosed(block.timestamp);
    }

    function claimTokens() external nonReentrant inState(State.Finalized) {
        uint256 contribution = contributions[msg.sender];
        require(contribution > 0, "No contribution");
        require(!tokensClaimed[msg.sender], "Already claimed");

        uint256 amount = (claimPool * contribution) / totalRaised;
        tokensClaimed[msg.sender] = true;

        pepetual.safeTransfer(msg.sender, amount);
        emit TokensClaimed(msg.sender, amount);
    }

    function refund() external nonReentrant inState(State.Cancelled) {
        uint256 contribution = contributions[msg.sender];
        require(contribution > 0, "No contribution");
        contributions[msg.sender] = 0;

        (bool success,) = msg.sender.call{ value: contribution }("");
        require(success, "Refund failed");
        emit Refunded(msg.sender, contribution);
    }

    function pendingTokens(address account) external view returns (uint256) {
        if (state != State.Finalized || contributions[account] == 0 || tokensClaimed[account]) {
            return 0;
        }
        return (claimPool * contributions[account]) / totalRaised;
    }

    function timeRemaining() external view returns (uint256) {
        if (!raiseStarted) return RAISE_DURATION;
        if (raiseClosed || block.timestamp >= endTime) return 0;
        return endTime - block.timestamp;
    }

    function getContributors() external view returns (address[] memory) {
        return contributorList;
    }

    function sweep(address token, address to) external onlyOwner nonReentrant {
        require(state != State.Collecting, "Raise active");
        require(to != address(0), "Invalid recipient");

        if (token == address(0)) {
            if (state == State.Finalized) {
                require(block.timestamp > endTime + CLAIM_GRACE_PERIOD, "Claim period active");
            }
            uint256 bal = address(this).balance;
            require(bal > 0, "No ETH");
            (bool success,) = to.call{ value: bal }("");
            require(success, "ETH transfer failed");
        } else {
            if (token == address(pepetual)) {
                require(
                    state == State.Cancelled
                        || (state == State.Finalized && block.timestamp > endTime + CLAIM_GRACE_PERIOD),
                    "Claim period active"
                );
            }
            uint256 bal = IERC20(token).balanceOf(address(this));
            require(bal > 0, "No tokens");
            if (token == address(pepe)) {
                require(
                    pendingRewardsPepe == 0 && pendingPondPepe == 0, "Distribute PEPE buffers first"
                );
            }
            IERC20(token).safeTransfer(to, bal);
        }
    }

    function withdrawRewardsPepe(address to) external onlyOwner {
        require(to != address(0), "Invalid recipient");
        uint256 amount = pendingRewardsPepe;
        require(amount > 0, "Nothing to withdraw");
        pendingRewardsPepe = 0;
        pepe.safeTransfer(to, amount);
    }

    function withdrawPondPepe(address to) external onlyOwner {
        require(to != address(0), "Invalid recipient");
        uint256 amount = pendingPondPepe;
        require(amount > 0, "Nothing to withdraw");
        pendingPondPepe = 0;
        pepe.safeTransfer(to, amount);
    }

    function pause() external onlyOwner {
        _pause();
    }

    function unpause() external onlyOwner {
        _unpause();
    }
}