PresaleFixedV8

{{
  "language": "Solidity",
  "sources": {
    "src/HabePresaleV2.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity ^0.8.28;

import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import "@openzeppelin/contracts/access/Ownable.sol";
import "@openzeppelin/contracts/utils/ReentrancyGuard.sol";

interface Aggregator {
    function latestRoundData() external view returns (uint80, int256, uint256, uint256, uint80);
}

error ZeroAddress();
error InsufficientBalance();
error InsufficientAllowance();
error InsufficientTokenAllocation();
error SlippageTooHigh();

contract PresaleFixedV8 is Ownable, ReentrancyGuard {
    using SafeERC20 for IERC20;

    address public immutable HABE;
    address public immutable USDT;
    address public immutable USDC;
    address public immutable SHIB;
    address public immutable UNI;
    address private offchainSigner;
    Aggregator public immutable ethUSDFeed;
    Aggregator public immutable shibUSDFeed;
    Aggregator public immutable uniUSDFeed;

    bool public claimStatus;
    bool public saleStatus = true;
    bool public userImportCompleted;
    bool public paused;
    bool public migrationCompleted;

    uint256 public constant MAX_TOKENS_PER_BUY = 1_000_000 * 10**18;
    uint256 public tokenToSold = 4_250_000_000 * 10**18;
    uint256 public tokenSold;
    uint256 public USDRaised;

    uint256 public currentRound;
    uint256 public constant saleStartTime = 1748716200;
    uint256 public constant saleEndTime = 1774895400;

    uint256 public airdropDistributed;
    uint256 public rewardDistributed;
    uint256 public rewardPerShare;
    uint256 public constant PRECISION_FACTOR = 10**18;
    uint256 public lastRewardTime = saleStartTime;
    uint256 public constant rewardPerSecond = 14500000000000000000; // 174 * 10^18 / 12 = 14.5 * 10^18
    uint256 public totalStakedTokens; // Track total tokens eligible for rewards
    
    // Precise USD raised accumulator in 18 decimals (includes sub-$1 and migrated amounts)
    uint256 public USDRaised18;
    
    // Migration tracking
    uint256 public totalMigratedUsers;
    uint256 public totalMigratedAmount;
    mapping(address => bool) public migratedUsers;

    uint256[15] public tokenPrice = [
        10 * 10**16,  // $0.10 in wei
        15 * 10**16,  // $0.15 in wei
        20 * 10**16,  // $0.20 in wei
        25 * 10**16,  // $0.25 in wei
        30 * 10**16,  // $0.30 in wei
        35 * 10**16,  // $0.35 in wei
        40 * 10**16,  // $0.40 in wei
        45 * 10**16,  // $0.45 in wei
        50 * 10**16,  // $0.50 in wei
        55 * 10**16,  // $0.55 in wei
        60 * 10**16,  // $0.60 in wei
        65 * 10**16,  // $0.65 in wei
        70 * 10**16,  // $0.70 in wei
        75 * 10**16,  // $0.75 in wei
        80 * 10**16   // $0.80 in wei
    ];
    uint256[15] public tokenRound = [
        1750444200, 1752172200, 1753900200, 1755628200, 1757356200,
        1759084200, 1760812200, 1762540200, 1764268200, 1765996200,
        1767724200, 1769452200, 1771180200, 1772908200, 1774895400
    ];

    struct BuyTokenInfo {
        uint256 USDPaid;
        uint256 tokenFromBuy;
        uint256 tokenFromReward;
        uint256 tokenFromAirdrop;
        uint256 rewardPerShare;
        uint256 tokenClaimed;
    }

    mapping(address => BuyTokenInfo) public mapBuyInfo;

    event TokensBought(address indexed user, uint256 tokens, uint256 amount, uint256 timestamp);
    event TokensClaimed(address indexed user, uint256 amount, uint256 timestamp);
    event SaleStatusUpdated(bool status);
    event ClaimStatusUpdated(bool status);
    event OffChainPurchaseAdded(address indexed user, uint256 amount, uint256 tokens, uint256 timestamp);
    event OffchainSignerUpdated(address indexed newSigner);
    event Paused(bool paused);
    event UserMigrated(address indexed user, uint256 tokenAmount, uint256 usdAmount, uint256 round);
    event MigrationCompleted(uint256 totalUsers, uint256 totalAmount);
    event MigrationReopened();

    constructor(
        address _owner,
        address _offchainSigner,
        address _habe,
        address _usdt,
        address _usdc,
        address _shib,
        address _uni,
        address _ethUSDFeed,
        address _shibUSDFeed,
        address _uniUSDFeed
    ) Ownable(_owner) {
        if (_owner == address(0) || _offchainSigner == address(0)) revert ZeroAddress();
        if (_habe == address(0) || _usdt == address(0) || _usdc == address(0)) revert ZeroAddress();
        if (_shib == address(0) || _uni == address(0)) revert ZeroAddress();
        if (_ethUSDFeed == address(0) || _shibUSDFeed == address(0) || _uniUSDFeed == address(0)) revert ZeroAddress();
        
        HABE = _habe;
        USDT = _usdt;
        USDC = _usdc;
        SHIB = _shib;
        UNI = _uni;
        ethUSDFeed = Aggregator(_ethUSDFeed);
        shibUSDFeed = Aggregator(_shibUSDFeed);
        uniUSDFeed = Aggregator(_uniUSDFeed);
        offchainSigner = _offchainSigner;
        updateRound();
    }

    receive() external payable {}

    modifier notPaused() {
        require(!paused, "Paused");
        _;
    }

    modifier onlyOffchainSigner() {
        require(msg.sender == offchainSigner, "Not authorized signer");
        _;
    }

    function pause(bool _paused) external onlyOwner {
        paused = _paused;
        emit Paused(_paused);
    }

    function validatePrice(int256 price, uint256 updatedAt) internal view {
        require(block.timestamp - updatedAt < 1 hours, "Stale oracle");
        require(price > 0, "Invalid price");
        // Reasonable bounds for crypto assets: $0.00001 to $1,000,000 (1e3 to 1e14)
        // This accommodates ETH prices up to $1M with 8 decimal precision
        require(price >= 1e3 && price <= 1e14, "Price outside reasonable bounds");
    }

    function buyWithToken(address paymentToken, uint256 amount, uint256 minTokensOut) external nonReentrant notPaused {
        require(msg.sender.code.length == 0, "Only EOA");
        require(amount > 0, "Amount must be greater than 0");
        require(saleStatus && block.timestamp >= saleStartTime && block.timestamp <= saleEndTime, "Sale not active");
        require(paymentToken == USDT || paymentToken == USDC || paymentToken == SHIB || paymentToken == UNI, "Unsupported token");
        if (IERC20(paymentToken).balanceOf(msg.sender) < amount) revert InsufficientBalance();
        if (IERC20(paymentToken).allowance(msg.sender, address(this)) < amount) revert InsufficientAllowance();

        updateRound();
        uint256 tokens;
        uint256 usd18; // USD value scaled to 18 decimals
        uint256 price = tokenPrice[currentRound];
        if (paymentToken == SHIB) {
            // Chainlink price assumed 8 decimals; SHIB amount 18 decimals → result 18 decimals
            usd18 = (getSHIBUSDPrice() * amount) / 10**8;
        } else if (paymentToken == UNI) {
            // Chainlink price assumed 8 decimals; UNI amount 18 decimals → result 18 decimals
            usd18 = (getLatestUniPrice() * amount) / 10**8;
        } else {
            // USDT/USDC have 6 decimals; convert to 18 decimals
            usd18 = amount * 10**12;
        }
        tokens = (usd18 * 10**18) / price;
        uint256 usdAmount = usd18 / 10**18; // whole-dollar aggregation if needed
        require(tokens >= minTokensOut, "Slippage too high");
        require(tokens <= MAX_TOKENS_PER_BUY, "Purchase too large");
        if (tokenSold + tokens > tokenToSold) revert InsufficientTokenAllocation();
        
        tokenSold += tokens;
        // Accumulate precise USD (18 decimals) and legacy whole-dollar view
        USDRaised18 += usd18;
        USDRaised += usdAmount;
        // Eligible stake increases by purchased tokens (airdrops excluded from staking)
        totalStakedTokens += tokens;
        BuyTokenInfo storage user = mapBuyInfo[msg.sender];
        // Harvest existing pending rewards if user already has eligible stake
        uint256 eligibleBefore = user.tokenFromBuy + user.tokenFromReward;
        if (eligibleBefore > 0) {
            uint256 p = pendingReward(msg.sender);
            if (p > 0) {
                user.tokenFromReward += p;
                totalStakedTokens += p; // compound into stake
            }
        }
        user.USDPaid += usdAmount;
        user.tokenFromBuy += tokens;
        uint256 eligibleAfter = user.tokenFromBuy + user.tokenFromReward;
        user.rewardPerShare = (eligibleAfter * rewardPerShare) / PRECISION_FACTOR;
        IERC20(paymentToken).safeTransferFrom(msg.sender, address(this), amount);
        emit TokensBought(msg.sender, tokens, usdAmount, block.timestamp);
    }

    function buyWithETH(uint256 minTokensOut) external payable nonReentrant notPaused {
        require(msg.sender.code.length == 0, "Only EOA");
        require(msg.value > 0, "Amount must be greater than 0");
        require(saleStatus && block.timestamp >= saleStartTime && block.timestamp <= saleEndTime, "Sale not active");

        updateRound();
        uint256 price = tokenPrice[currentRound];
        // Convert ETH to USD with 18 decimals (assuming Chainlink 8 decimals)
        uint256 usd18 = (getLatestPrice() * msg.value) / 10**8;
        uint256 tokens = (usd18 * 10**18) / price;
        require(tokens >= minTokensOut, "Slippage too high");
        require(tokens <= MAX_TOKENS_PER_BUY, "Purchase too large");
        if (tokenSold + tokens > tokenToSold) revert InsufficientTokenAllocation();
        
        // Accumulate precise USD (18 decimals) and legacy whole-dollar view
        USDRaised18 += usd18;
        USDRaised += usd18 / 10**18;
        tokenSold += tokens;
        // Eligible stake increases by purchased tokens (airdrops excluded from staking)
        totalStakedTokens += tokens;
        BuyTokenInfo storage user = mapBuyInfo[msg.sender];
        // Harvest existing pending rewards if user already has eligible stake
        uint256 eligibleBefore = user.tokenFromBuy + user.tokenFromReward;
        if (eligibleBefore > 0) {
            uint256 p = pendingReward(msg.sender);
            if (p > 0) {
                user.tokenFromReward += p;
                totalStakedTokens += p; // compound into stake
            }
        }
        user.USDPaid += usd18 / 10**18;
        user.tokenFromBuy += tokens;
        uint256 eligibleAfter = user.tokenFromBuy + user.tokenFromReward;
        user.rewardPerShare = (eligibleAfter * rewardPerShare) / PRECISION_FACTOR;
        emit TokensBought(msg.sender, tokens, usd18 / 10**18, block.timestamp);
    }

    function addOffChainPurchase(
        address[] calldata users,
        uint256[] calldata usdAmount,
        uint256[] calldata tokenAmount
    ) external onlyOffchainSigner nonReentrant notPaused {
        require(users.length == usdAmount.length && users.length == tokenAmount.length, "Length mismatch");
        require(users.length <= 50, "Batch limit 50");
        require(users.length > 0, "Empty batch not allowed");
        updateRound();
        for (uint256 i = 0; i < users.length; i++) {
            require(users[i] != address(0), "Zero address");
            require(tokenAmount[i] <= MAX_TOKENS_PER_BUY, "Purchase too large");
            if (tokenSold + tokenAmount[i] > tokenToSold) revert InsufficientTokenAllocation();
            BuyTokenInfo storage user = mapBuyInfo[users[i]];
            // Harvest existing pending rewards if user already has eligible stake
            uint256 eligibleBefore = user.tokenFromBuy + user.tokenFromReward;
            if (eligibleBefore > 0) {
                uint256 p = pendingReward(users[i]);
                if (p > 0) {
                    user.tokenFromReward += p;
                    totalStakedTokens += p; // compound into stake
                }
            }
            user.USDPaid += usdAmount[i];
            user.tokenFromBuy += tokenAmount[i];
            uint256 eligibleAfter = user.tokenFromBuy + user.tokenFromReward;
            user.rewardPerShare = (eligibleAfter * rewardPerShare) / PRECISION_FACTOR;
            tokenSold += tokenAmount[i];
            totalStakedTokens += tokenAmount[i]; // eligible stake increases by buys only
            USDRaised += usdAmount[i];
            emit OffChainPurchaseAdded(users[i], usdAmount[i], tokenAmount[i], block.timestamp);
        }
    }

    function addAirdropTokens(address[] memory users, uint256[] memory tokens) external onlyOwner nonReentrant notPaused {
        require(users.length == tokens.length, "Mismatched array lengths");
        require(users.length <= 50, "Batch limit 50");
        for (uint256 i = 0; i < users.length; i++) {
            require(tokens[i] > 0, "Tokens must be greater than zero");
            require(users[i] != address(0), "Zero address");
            BuyTokenInfo storage user = mapBuyInfo[users[i]];
            user.tokenFromAirdrop += tokens[i];
            // Airdrops do NOT earn rewards; do not change totalStakedTokens
            // Re-baseline rewardPerShare using only eligible stake
            uint256 eligible = user.tokenFromBuy + user.tokenFromReward;
            user.rewardPerShare = (eligible * rewardPerShare) / PRECISION_FACTOR;
            airdropDistributed += tokens[i];
            emit TokensBought(users[i], tokens[i], 0, block.timestamp);
        }
    }

    function pendingReward(address user) public view returns (uint256) {
        uint256 adjusted = rewardPerShare;
        if (totalStakedTokens > 0) {
            uint256 end = block.timestamp < saleEndTime ? block.timestamp : saleEndTime;
            uint256 add = (end - lastRewardTime) * rewardPerSecond;
            adjusted += (add * PRECISION_FACTOR) / totalStakedTokens;
        }
        BuyTokenInfo memory info = mapBuyInfo[user];
        uint256 eligible = info.tokenFromBuy + info.tokenFromReward; // airdrops excluded
        return (eligible * adjusted / PRECISION_FACTOR) - info.rewardPerShare;
    }

    function updateRound() internal {
        while (currentRound < tokenRound.length - 1 && block.timestamp > tokenRound[currentRound]) {
            currentRound++;
        }
        uint256 end = block.timestamp < saleEndTime ? block.timestamp : saleEndTime;
        if (totalStakedTokens > 0) {
            if (end > lastRewardTime) {
                uint256 amount = (end - lastRewardTime) * rewardPerSecond;
                rewardPerShare += (amount * PRECISION_FACTOR) / totalStakedTokens;
                rewardDistributed += amount;
                lastRewardTime = end;
            }
        } else {
            // No stake: advance the clock to avoid retroactive accrual
            lastRewardTime = end;
        }
    }

    function claimToken() external nonReentrant notPaused {
        require(msg.sender.code.length == 0, "Only EOA");
        require(claimStatus, "Token claim has not started yet");
        BuyTokenInfo storage user = mapBuyInfo[msg.sender];
        uint256 pending = pendingReward(msg.sender);
        pending = pending + user.tokenFromBuy + user.tokenFromReward + user.tokenFromAirdrop - user.tokenClaimed;
        if (pending > 0) {
            user.tokenClaimed += pending;
            IERC20(HABE).safeTransfer(msg.sender, pending);
            // Remove only eligible stake from total staked tokens
            uint256 eligible = user.tokenFromBuy + user.tokenFromReward;
            if (eligible > 0) {
                totalStakedTokens -= eligible;
            }
            user.tokenFromBuy = 0;
            user.tokenFromReward = 0;
            user.tokenFromAirdrop = 0;
            user.rewardPerShare = 0;
            emit TokensClaimed(msg.sender, pending, block.timestamp);
        } else {
            emit TokensClaimed(msg.sender, 0, block.timestamp);
        }
    }

    function updateSaleStatus(bool status) external onlyOwner {
        require(saleStatus != status, "Sale status already set");
        updateRound();
        if (status) {
            require(!claimStatus, "Claim must be stopped before starting presale");
        }
        saleStatus = status;
        emit SaleStatusUpdated(status);
    }
    
    function setOffchainSigner(address _signer) external onlyOwner {
        if (_signer == address(0)) revert ZeroAddress();
        offchainSigner = _signer;
        emit OffchainSignerUpdated(_signer);
    }
    
    function startClaim() external onlyOwner {
        require(!claimStatus, "Claim already started");
        updateRound();
        require(IERC20(HABE).balanceOf(address(this)) >= (tokenSold + totalMigratedAmount + rewardDistributed + airdropDistributed), "Insufficient tokens");
        saleStatus = false;
        claimStatus = true;
        emit ClaimStatusUpdated(true);
    }

    function withdrawToken(address token, address to) external onlyOwner nonReentrant {
        require(to != address(0), "Zero address");
        uint256 balance = IERC20(token).balanceOf(address(this));
        require(balance > 0, "No balance to withdraw");
        IERC20(token).safeTransfer(to, balance);
    }
    
    function withdrawETH(address payable to) external onlyOwner nonReentrant {
        require(to != address(0), "Zero address");
        uint256 balance = address(this).balance;
        require(balance > 0, "No ETH to withdraw");
        (bool sent,) = to.call{value: balance}("");
        require(sent, "ETH transfer failed");
    }

    function getLatestPrice() public view returns (uint256) {
        (, int256 price,, uint256 updatedAt,) = ethUSDFeed.latestRoundData();
        validatePrice(price, updatedAt);
        return uint256(price);
    }

    function getSHIBUSDPrice() public view returns (uint256) {
        (, int256 price,, uint256 updatedAt,) = shibUSDFeed.latestRoundData();
        validatePrice(price, updatedAt);
        return uint256(price);
    }

    function getLatestUniPrice() public view returns (uint256) {
        (, int256 price,, uint256 updatedAt,) = uniUSDFeed.latestRoundData();
        validatePrice(price, updatedAt);
        return uint256(price);
    }

    // ============ MIGRATION FUNCTIONS ============

    /**
     * @notice Migrate a single user from the old contract
     * @param user The address of the user to migrate
     * @param tokenAmount The amount of HABE tokens the user had
     * @param usdAmount The USD amount the user paid (in 6 decimals for USDT/USDC)
     * @param round The round number when the user made the purchase (0-14)
     */
    function migrateUser(
        address user,
        uint256 tokenAmount,
        uint256 usdAmount,
        uint256 round
    ) external onlyOwner nonReentrant notPaused {
        require(!migrationCompleted, "Migration already completed");
        require(user != address(0), "Zero address");
        require(tokenAmount > 0, "Token amount must be greater than 0");
        require(usdAmount > 0, "USD amount must be greater than 0");
        require(round < 15, "Invalid round number");
        require(!migratedUsers[user], "User already migrated");
        require(!saleStatus, "Cannot migrate during active sale");

        // Validate that the user doesn't already have tokens
        BuyTokenInfo storage userInfo = mapBuyInfo[user];
        require(userInfo.tokenFromBuy == 0, "User already has tokens");

        // Update user data
        userInfo.USDPaid = usdAmount;
        userInfo.tokenFromBuy = tokenAmount;
        userInfo.rewardPerShare = (tokenAmount * rewardPerShare) / PRECISION_FACTOR;

        // Update totals (do not inflate presale counters for migration)
        totalStakedTokens += tokenAmount; // eligible stake
        totalMigratedUsers++;
        totalMigratedAmount += tokenAmount;
        migratedUsers[user] = true;

        // Include migrated USD in precise and legacy accumulators (usdAmount has 6 decimals)
        uint256 usd18 = usdAmount * 10**12;
        USDRaised18 += usd18;
        USDRaised += usd18 / 10**18;

        emit UserMigrated(user, tokenAmount, usdAmount, round);
    }

    /**
     * @notice Migrate multiple users in a batch
     * @param users Array of user addresses
     * @param tokenAmounts Array of token amounts for each user
     * @param usdAmounts Array of USD amounts for each user
     * @param rounds Array of round numbers for each user
     */
    function migrateUsersBatch(
        address[] calldata users,
        uint256[] calldata tokenAmounts,
        uint256[] calldata usdAmounts,
        uint256[] calldata rounds
    ) external onlyOwner nonReentrant notPaused {
        require(!migrationCompleted, "Migration already completed");
        require(!saleStatus, "Cannot migrate during active sale");
        require(
            users.length == tokenAmounts.length &&
            users.length == usdAmounts.length &&
            users.length == rounds.length,
            "Array length mismatch"
        );
        require(users.length <= 100, "Batch size too large");

        for (uint256 i = 0; i < users.length; i++) {
            address user = users[i];
            uint256 tokenAmount = tokenAmounts[i];
            uint256 usdAmount = usdAmounts[i];
            uint256 round = rounds[i];

            require(user != address(0), "Zero address");
            require(tokenAmount > 0, "Token amount must be greater than 0");
            require(usdAmount > 0, "USD amount must be greater than 0");
            require(round < 15, "Invalid round number");
            require(!migratedUsers[user], "User already migrated");

            // Validate that the user doesn't already have tokens
            BuyTokenInfo storage userInfo = mapBuyInfo[user];
            require(userInfo.tokenFromBuy == 0, "User already has tokens");

            // Update user data
            userInfo.USDPaid = usdAmount;
            userInfo.tokenFromBuy = tokenAmount;
            userInfo.rewardPerShare = (tokenAmount * rewardPerShare) / PRECISION_FACTOR;

            // Update totals (do not inflate presale counters for migration)
            totalStakedTokens += tokenAmount; // eligible stake
            totalMigratedUsers++;
            totalMigratedAmount += tokenAmount;
            migratedUsers[user] = true;

            // Include migrated USD in precise and legacy accumulators (usdAmount has 6 decimals)
            uint256 usd18 = usdAmount * 10**12;
            USDRaised18 += usd18;
            USDRaised += usd18 / 10**18;

            emit UserMigrated(user, tokenAmount, usdAmount, round);
        }
    }
    
    /**
     * @notice Complete the migration process
     * @dev This function should be called after all users have been migrated
     */
    function completeMigration() external onlyOwner {
        require(!migrationCompleted, "Migration already completed");
        require(totalMigratedUsers > 0, "No users migrated");
        
        migrationCompleted = true;
        emit MigrationCompleted(totalMigratedUsers, totalMigratedAmount);
    }

    /**
     * @notice Reopen migration to allow adding more users after completion
     * @dev Can only be called when sale and claim are not active
     */
    function reopenMigration() external onlyOwner {
        require(migrationCompleted, "Migration not completed");
        require(!saleStatus, "Cannot reopen during active sale");
        require(!claimStatus, "Cannot reopen after claim started");
        migrationCompleted = false;
        emit MigrationReopened();
    }

    /**
     * @notice Check if a user has been migrated
     * @param user The address to check
     * @return True if the user has been migrated
     */
    function isUserMigrated(address user) external view returns (bool) {
        return migratedUsers[user];
    }

    /**
     * @notice Get migration statistics
     * @return totalUsers Total number of migrated users
     * @return totalAmount Total amount of tokens migrated
     * @return completed Whether migration is completed
     */
    function getMigrationStats() external view returns (
        uint256 totalUsers,
        uint256 totalAmount,
        bool completed
    ) {
        return (totalMigratedUsers, totalMigratedAmount, migrationCompleted);
    }

    /**
     * @notice Get exact USD raised in 18 decimals (fair, includes sub-$1 and migrated USD)
     */
    function getUSDRaised18() external view returns (uint256) {
        return USDRaised18;
    }
}"
    },
    "lib/openzeppelin-contracts/contracts/token/ERC20/utils/SafeERC20.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.3.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";
import {IERC1363} from "../../../interfaces/IERC1363.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC-20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    /**
     * @dev An operation with an ERC-20 token failed.
     */
    error SafeERC20FailedOperation(address token);

    /**
     * @dev Indicates a failed `decreaseAllowance` request.
     */
    error SafeERC20FailedDecreaseAllowance(address spender, uint256 currentAllowance, uint256 requestedDecrease);

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Variant of {safeTransfer} that returns a bool instead of reverting if the operation is not successful.
     */
    function trySafeTransfer(IERC20 token, address to, uint256 value) internal returns (bool) {
        return _callOptionalReturnBool(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Variant of {safeTransferFrom} that returns a bool instead of reverting if the operation is not successful.
     */
    function trySafeTransferFrom(IERC20 token, address from, address to, uint256 value) internal returns (bool) {
        return _callOptionalReturnBool(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     *
     * IMPORTANT: If the token implements ERC-7674 (ERC-20 with temporary allowance), and if the "client"
     * smart contract uses ERC-7674 to set temporary allowances, then the "client" smart contract should avoid using
     * this function. Performing a {safeIncreaseAllowance} or {safeDecreaseAllowance} operation on a token contract
     * that has a non-zero temporary allowance (for that particular owner-spender) will result in unexpected behavior.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        forceApprove(token, spender, oldAllowance + value);
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `requestedDecrease`. If `token` returns no
     * value, non-reverting calls are assumed to be successful.
     *
     * IMPORTANT: If the token implements ERC-7674 (ERC-20 with temporary allowance), and if the "client"
     * smart contract uses ERC-7674 to set temporary allowances, then the "client" smart contract should avoid using
     * this function. Performing a {safeIncreaseAllowance} or {safeDecreaseAllowance} operation on a token contract
     * that has a non-zero temporary allowance (for that particular owner-spender) will result in unexpected behavior.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 requestedDecrease) internal {
        unchecked {
            uint256 currentAllowance = token.allowance(address(this), spender);
            if (currentAllowance < requestedDecrease) {
                revert SafeERC20FailedDecreaseAllowance(spender, currentAllowance, requestedDecrease);
            }
            forceApprove(token, spender, currentAllowance - requestedDecrease);
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     *
     * NOTE: If the token implements ERC-7674, this function will not modify any temporary allowance. This function
     * only sets the "standard" allowance. Any temporary allowance will remain active, in addition to the value being
     * set here.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeCall(token.approve, (spender, value));

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeCall(token.approve, (spender, 0)));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Performs an {ERC1363} transferAndCall, with a fallback to the simple {ERC20} transfer if the target has no
     * code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * Reverts if the returned value is other than `true`.
     */
    function transferAndCallRelaxed(IERC1363 token, address to, uint256 value, bytes memory data) internal {
        if (to.code.length == 0) {
            safeTransfer(token, to, value);
        } else if (!token.transferAndCall(to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Performs an {ERC1363} transferFromAndCall, with a fallback to the simple {ERC20} transferFrom if the target
     * has no code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * Reverts if the returned value is other than `true`.
     */
    function transferFromAndCallRelaxed(
        IERC1363 token,
        address from,
        address to,
        uint256 value,
        bytes memory data
    ) internal {
        if (to.code.length == 0) {
            safeTransferFrom(token, from, to, value);
        } else if (!token.transferFromAndCall(from, to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Performs an {ERC1363} approveAndCall, with a fallback to the simple {ERC20} approve if the target has no
     * code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * NOTE: When the recipient address (`to`) has no code (i.e. is an EOA), this function behaves as {forceApprove}.
     * Opposedly, when the recipient address (`to`) has code, this function only attempts to call {ERC1363-approveAndCall}
     * once without retrying, and relies on the returned value to be true.
     *
     * Reverts if the returned value is other than `true`.
     */
    function approveAndCallRelaxed(IERC1363 token, address to, uint256 value, bytes memory data) internal {
        if (to.code.length == 0) {
            forceApprove(token, to, value);
        } else if (!token.approveAndCall(to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturnBool} that reverts if call fails to meet the requirements.
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        uint256 returnSize;
        uint256 returnValue;
        assembly ("memory-safe") {
            let success := call(gas(), token, 0, add(data, 0x20), mload(data), 0, 0x20)
            // bubble errors
            if iszero(success) {
                let ptr := mload(0x40)
                returndatacopy(ptr, 0, returndatasize())
                revert(ptr, returndatasize())
            }
            returnSize := returndatasize()
            returnValue := mload(0)
        }

        if (returnSize == 0 ? address(token).code.length == 0 : returnValue != 1) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silently catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        bool success;
        uint256 returnSize;
        uint256 returnValue;
        assembly ("memory-safe") {
            success := call(gas(), token, 0, add(data, 0x20), mload(data), 0, 0x20)
            returnSize := returndatasize()
            returnValue := mload(0)
        }
        return success && (returnSize == 0 ? address(token).code.length > 0 : returnValue == 1);
    }
}
"
    },
    "lib/openzeppelin-contracts/contracts/access/Ownable.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}
"
    },
    "lib/openzeppelin-contracts/contracts/utils/ReentrancyGuard.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/ReentrancyGuard.sol)

pragma solidity ^0.8.20;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If EIP-1153 (transient storage) is available on the chain you're deploying at,
 * consider using {ReentrancyGuardTransient} instead.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant NOT_ENTERED = 1;
    uint256 private constant ENTERED = 2;

    uint256 private _status;

    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();

    constructor() {
        _status = NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be NOT_ENTERED
        if (_status == ENTERED) {
            revert ReentrancyGuardReentrantCall();
        }

        // Any calls to nonReentrant after this point will fail
        _status = ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == ENTERED;
    }
}
"
    },
    "lib/openzeppelin-contracts/contracts/token/ERC20/IERC20.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (token/ERC20/IERC20.sol)

pragma solidity >=0.4.16;

/**
 * @dev Interface of the ERC-20 standard as defined in the ERC.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}
"
    },
    "lib/openzeppelin-contracts/contracts/interfaces/IERC1363.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (interfaces/IERC1363.sol)

pragma solidity >=0.6.2;

import {IERC20} from "./IERC20.sol";
import {IERC165} from "./IERC165.sol";

/**
 * @title IERC1363
 * @dev Interface of the ERC-1363 standard as defined in the https://eips.ethereum.org/EIPS/eip-1363[ERC-1363].
 *
 * Defines an extension interface for ERC-20 tokens that supports executing code on a recipient contract
 * after `transfer` or `transferFrom`, or code on a spender contract after `approve`, in a single transaction.
 */
interface IERC1363 is IERC20, IERC165 {
    /*
     * Note: the ERC-165 identifier for this interface is 0xb0202a11.
     * 0xb0202a11 ===
     *   bytes4(keccak256('transferAndCall(address,uint256)')) ^
     *   bytes4(keccak256('transferAndCall(address,uint256,bytes)')) ^
     *   bytes4(keccak256('transferFromAndCall(address,address,uint256)')) ^
     *   bytes4(keccak256('transferFromAndCall(address,address,uint256,bytes)')) ^
     *   bytes4(keccak256('approveAndCall(address,uint256)')) ^
     *   bytes4(keccak256('approveAndCall(address,uint256,bytes)'))
     */

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferAndCall(address to, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @param data Additional data with no specified format, sent in call to `to`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferAndCall(address to, uint256 value, bytes calldata data) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the allowance mechanism
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param from The address which you want to send tokens from.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferFromAndCall(address from, address to, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the allowance mechanism
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param from The address which you want to send tokens from.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @param data Additional data with no specified format, sent in call to `to`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferFromAndCall(address from, address to, uint256 value, bytes calldata data) external returns (bool);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens and then calls {IERC1363Spender-onApprovalReceived} on `spender`.
     * @param spender The address which will spend the funds.
     * @param value The amount of tokens to be spent.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function approveAndCall(address spender, uint256 value) external returns (bool);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens and then calls {IERC1363Spender-onApprovalReceived} on `spender`.
     * @param spender The address which will spend the funds.
     * @param value The amount of tokens to be spent.
     * @param data Additional data with no specified format, sent in call to `spender`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function approveAndCall(address spender, uint256 value, bytes calldata data) external returns (bool);
}
"
    },
    "lib/openzeppelin-contracts/contracts/utils/Context.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}
"
    },
    "lib/openzeppelin-contracts/contracts/interfaces/IERC20.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (interfaces/IERC20.sol)

pragma solidity >=0.4.16;

import {IERC20} from "../token/ERC20/IERC20.sol";
"
    },
    "lib/openzeppelin-contracts/contracts/interfaces/IERC165.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (interfaces/IERC165.sol)

pragma solidity >=0.4.16;

import {IERC165} from "../utils/introspection/IERC165.sol";
"
    },
    "lib/openzeppelin-contracts/contracts/utils/introspection/IERC165.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (utils/introspection/IERC165.sol)

pragma solidity >=0.4.16;

/**
 * @dev Interface of the ERC-165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[ERC].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[ERC section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}
"
    }
  },
  "settings": {
    "remappings": [
      "@openzeppelin/contracts/=lib/openzeppelin-contracts/contracts/",
      "erc4626-tests/=lib/openzeppelin-contracts/lib/erc4626-tests/",
      "forge-std/=lib/forge-std/src/",
      "halmos-cheatcodes/=lib/openzeppelin-contracts/lib/halmos-cheatcodes/src/",
      "openzeppelin-contracts/=lib/openzeppelin-contracts/"
    ],
    "optimizer": {
      "enabled": true,
      "runs": 200
    },
    "metadata": {
      "useLiteralContent": false,
      "bytecodeHash": "ipfs",
      "appendCBOR": true
    },
    "outputSelection": {
      "*": {
        "*": [
          "evm.bytecode",
          "evm.deployedBytecode",
          "devdoc",
          "userdoc",
          "metadata",
          "abi"
        ]
      }
    },
    "evmVersion": "prague",
    "viaIR": false
  }
}}