Factory

/**
 *Submitted for verification at Etherscan.io on 2025-08-29
 */

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(
        address indexed previousOwner,
        address indexed newOwner
    );

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
        _;
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(
            newOwner != address(0),
            "Ownable: new owner is the zero address"
        );
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(
        address indexed owner,
        address indexed spender,
        uint256 value
    );

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    function updateMetadata(
        string memory name_,
        string memory symbol_
    ) external;

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(
        address owner,
        address spender
    ) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 amount
    ) external returns (bool);
}

/**
 * @dev Interface for the optional metadata functions from the ERC20 standard.
 *
 * _Available since v4.1._
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}

// File: @openzeppelin/contracts@4.8.2/token/ERC20/ERC20.sol

// OpenZeppelin Contracts (last updated v4.8.0) (token/ERC20/ERC20.sol)

pragma solidity 0.8.26;

/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 * For a generic mechanism see {ERC20PresetMinterPauser}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.openzeppelin.com/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * We have followed general OpenZeppelin Contracts guidelines: functions revert
 * instead returning `false` on failure. This behavior is nonetheless
 * conventional and does not conflict with the expectations of ERC20
 * applications.
 *
 * Additionally, an {Approval} event is emitted on calls to {transferFrom}.
 * This allows applications to reconstruct the allowance for all accounts just
 * by listening to said events. Other implementations of the EIP may not emit
 * these events, as it isn't required by the specification.
 *
 * Finally, the non-standard {decreaseAllowance} and {increaseAllowance}
 * functions have been added to mitigate the well-known issues around setting
 * allowances. See {IERC20-approve}.
 */
contract ERC20 is Context, IERC20, IERC20Metadata {
    mapping(address => uint256) private _balances;

    mapping(address => mapping(address => uint256)) private _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;
    address _factory;

    /**
     * @dev Sets the values for {name} and {symbol}.
     *
     * The default value of {decimals} is 18. To select a different value for
     * {decimals} you should overload it.
     *
     * All two of these values are immutable: they can only be set once during
     * construction.
     */
    constructor(string memory name_, string memory symbol_, address factory_) {
        _name = name_;
        _symbol = symbol_;
        _factory = factory_;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view virtual override returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view virtual override returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5.05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the value {ERC20} uses, unless this function is
     * overridden;
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view virtual override returns (uint8) {
        return 18;
    }

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view virtual override returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(
        address account
    ) public view virtual override returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - the caller must have a balance of at least `amount`.
     */
    function updateMetadata(
        string memory name_,
        string memory symbol_
    ) public virtual {
        require(msg.sender == _factory, "only factory can call this function");
        _name = name_;
        _symbol = symbol_;
    }

    function transfer(
        address to,
        uint256 amount
    ) public virtual override returns (bool) {
        address owner = _msgSender();
        _transfer(owner, to, amount);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(
        address owner,
        address spender
    ) public view virtual override returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * NOTE: If `amount` is the maximum `uint256`, the allowance is not updated on
     * `transferFrom`. This is semantically equivalent to an infinite approval.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(
        address spender,
        uint256 amount
    ) public virtual override returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, amount);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Emits an {Approval} event indicating the updated allowance. This is not
     * required by the EIP. See the note at the beginning of {ERC20}.
     *
     * NOTE: Does not update the allowance if the current allowance
     * is the maximum `uint256`.
     *
     * Requirements:
     *
     * - `from` and `to` cannot be the zero address.
     * - `from` must have a balance of at least `amount`.
     * - the caller must have allowance for ``from``'s tokens of at least
     * `amount`.
     */
    function transferFrom(
        address from,
        address to,
        uint256 amount
    ) public virtual override returns (bool) {
        address spender = _msgSender();
        _spendAllowance(from, spender, amount);
        _transfer(from, to, amount);
        return true;
    }

    /**
     * @dev Atomically increases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function increaseAllowance(
        address spender,
        uint256 addedValue
    ) public virtual returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, allowance(owner, spender) + addedValue);
        return true;
    }

    /**
     * @dev Atomically decreases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `spender` must have allowance for the caller of at least
     * `subtractedValue`.
     */
    function decreaseAllowance(
        address spender,
        uint256 subtractedValue
    ) public virtual returns (bool) {
        address owner = _msgSender();
        uint256 currentAllowance = allowance(owner, spender);
        require(
            currentAllowance >= subtractedValue,
            "ERC20: decreased allowance below zero"
        );
        unchecked {
            _approve(owner, spender, currentAllowance - subtractedValue);
        }

        return true;
    }

    /**
     * @dev Moves `amount` of tokens from `from` to `to`.
     *
     * This internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `from` must have a balance of at least `amount`.
     */
    function _transfer(
        address from,
        address to,
        uint256 amount
    ) internal virtual {
        require(from != address(0), "ERC20: transfer from the zero address");
        require(to != address(0), "ERC20: transfer to the zero address");

        _beforeTokenTransfer(from, to, amount);

        uint256 fromBalance = _balances[from];
        require(
            fromBalance >= amount,
            "ERC20: transfer amount exceeds balance"
        );
        unchecked {
            _balances[from] = fromBalance - amount;
            // Overflow not possible: the sum of all balances is capped by totalSupply, and the sum is preserved by
            // decrementing then incrementing.
            _balances[to] += amount;
        }

        emit Transfer(from, to, amount);

        _afterTokenTransfer(from, to, amount);
    }

    /** @dev Creates `amount` tokens and assigns them to `account`, increasing
     * the total supply.
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     */
    function _mint(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: mint to the zero address");

        _beforeTokenTransfer(address(0), account, amount);

        _totalSupply += amount;
        unchecked {
            // Overflow not possible: balance + amount is at most totalSupply + amount, which is checked above.
            _balances[account] += amount;
        }
        emit Transfer(address(0), account, amount);

        _afterTokenTransfer(address(0), account, amount);
    }

    /**
     * @dev Destroys `amount` tokens from `account`, reducing the
     * total supply.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     * - `account` must have at least `amount` tokens.
     */
    function _burn(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: burn from the zero address");

        _beforeTokenTransfer(account, address(0), amount);

        uint256 accountBalance = _balances[account];
        require(accountBalance >= amount, "ERC20: burn amount exceeds balance");
        unchecked {
            _balances[account] = accountBalance - amount;
            // Overflow not possible: amount <= accountBalance <= totalSupply.
            _totalSupply -= amount;
        }

        emit Transfer(account, address(0), amount);

        _afterTokenTransfer(account, address(0), amount);
    }

    /**
     * @dev Sets `amount` as the allowance of `spender` over the `owner` s tokens.
     *
     * This internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     */
    function _approve(
        address owner,
        address spender,
        uint256 amount
    ) internal virtual {
        require(owner != address(0), "ERC20: approve from the zero address");
        require(spender != address(0), "ERC20: approve to the zero address");

        _allowances[owner][spender] = amount;
        emit Approval(owner, spender, amount);
    }

    /**
     * @dev Updates `owner` s allowance for `spender` based on spent `amount`.
     *
     * Does not update the allowance amount in case of infinite allowance.
     * Revert if not enough allowance is available.
     *
     * Might emit an {Approval} event.
     */
    function _spendAllowance(
        address owner,
        address spender,
        uint256 amount
    ) internal virtual {
        uint256 currentAllowance = allowance(owner, spender);
        if (currentAllowance != type(uint256).max) {
            require(
                currentAllowance >= amount,
                "ERC20: insufficient allowance"
            );
            unchecked {
                _approve(owner, spender, currentAllowance - amount);
            }
        }
    }

    /**
     * @dev Hook that is called before any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
     * will be transferred to `to`.
     * - when `from` is zero, `amount` tokens will be minted for `to`.
     * - when `to` is zero, `amount` of ``from``'s tokens will be burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _beforeTokenTransfer(
        address from,
        address to,
        uint256 amount
    ) internal virtual {}

    /**
     * @dev Hook that is called after any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
     * has been transferred to `to`.
     * - when `from` is zero, `amount` tokens have been minted for `to`.
     * - when `to` is zero, `amount` of ``from``'s tokens have been burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _afterTokenTransfer(
        address from,
        address to,
        uint256 amount
    ) internal virtual {}
}

//SPDX-License-Identifier: MIT
pragma solidity 0.8.26;

// contract Token is ERC20, Ownable {
//     constructor(
//         string memory _name,
//         string memory _symbol,
//         uint256 _totalSupply,
//         address _factory
//     ) ERC20(_name, _symbol,_factory) {
//         _mint(msg.sender, _totalSupply);
//     }
// }

interface IUniswapV2Factory {
    function getPair(
        address tokenA,
        address tokenB
    ) external view returns (address);
}

contract GDMToken is ERC20, Ownable {
    address factory;

    constructor(
        string memory _name,
        string memory _symbol,
        uint256 _totalSupply,
        address _factory
    ) ERC20(_name, _symbol, _factory) {
        _mint(msg.sender, _totalSupply);
        factory = _factory;
    }

    function _transfer(
        address sender,
        address recipient,
        uint256 amount
    ) internal override {
        address uniswapFactory = Factory(payable(factory)).v2Factory();
        address weth = Factory(payable(factory)).WETH();

        // address pair = address(0);
        address pair =
        IUniswapV2Factory(uniswapFactory).getPair(
            address(this),
            weth
        );

        if (sender == pair || recipient == pair) {
            address feeRecipient = Factory(payable(factory))
                .tokenFeeRecipient();
            uint256 feeBasisPoints = Factory(payable(factory)).feeBasisPoints();
            uint256 fee = (amount * feeBasisPoints) / 10_000;
            uint256 remaining = amount - fee;

            super._transfer(sender, feeRecipient, fee);
            super._transfer(sender, recipient, remaining);
        } else {
            super._transfer(sender, recipient, amount);
        }
    }
}

contract Factory is Ownable {
    error InvalidMaxSupplyPercentage();
    error TokenDoesNotExist();
    error ZeroTokenAmount();
    error BondingCurveCompleted();
    error ExceedsAllowedTokenPurchase();
    error InsufficientETH();
    error BondingCurveNotCompleted();
    error FeeTooHigh();
    address[] public tokenAddress;
    uint256 tokenCount;

    uint256 public initialVirtualEthReserves1 = 51000000000000000; //W.R.T SOLANA
    uint256 public initialVirtualEthReserves2 = 1900000000000000000; //W.R.T SOLANA
    uint256 public initialRealTokenReserves = 793100000 * 10 ** 18;

    uint256 public feeBasisPoints = 100; // 1%
    uint256 public creatorFees = 250;
    address public feeRecipient;
    address public tokenFeeRecipient;
    address public WETH = 0xC02aaA39b223FE8D0A0e5C4F27eAD9083C756Cc2;
    address public v2Factory = 0x5C69bEe701ef814a2B6a3EDD4B1652CB9cc5aA6f;

    struct BondingCurve {
        uint256 virtualTokenReserves;
        uint256 virtualEthReserves;
        uint256 realTokenReserves;
        uint256 realEthReserves;
        uint256 _totalSupply;
        uint8 maxSupplyPercentage;
        bool isCompleted;
    }
    mapping(address => BondingCurve) public bondingCurve;
    mapping(address => address) public tokenCreator;
    mapping(address => bool) public isToken;

    receive() external payable {}

    constructor(address _feeRecipient, address _tokenFeeRecipient) {
        feeRecipient = _feeRecipient;
        tokenFeeRecipient = _tokenFeeRecipient;
    }

    event TokenCreated(address indexed _creator, address indexed _tokenAddress);
    event TokensPurchased(
        address indexed _buyer,
        address indexed _tokenAddress,
        uint256 indexed _amout
    );
    event TokensSold(
        address indexed _seller,
        address indexed _tokenAddress,
        uint256 indexed _amout
    );
    event Withdraw(
        address indexed _tokenAddress,
        uint256 indexed _ethAmount,
        uint256 indexed _amout,
        uint256 _creatorFee,
        uint256 _adminFee
    );

    function createToken(
        string memory _name,
        string memory _symbol,
        uint8 _maxSupplyPercentage,
        bool _realReserves
    ) external {
        if (_maxSupplyPercentage == 0 || _maxSupplyPercentage > 100) {
            revert InvalidMaxSupplyPercentage();
        }
        GDMToken token = new GDMToken(
            _name,
            _symbol,
            1000000000 ether,
            address(this)
        );
        BondingCurve storage _bondingCurve = bondingCurve[address(token)];
        _bondingCurve._totalSupply = 1000000000 ether;
        _bondingCurve.maxSupplyPercentage = _maxSupplyPercentage;
        _bondingCurve.virtualTokenReserves = 1073000191 * 10 ** 18;
        _bondingCurve.realTokenReserves = initialRealTokenReserves;
        _bondingCurve.virtualEthReserves = _realReserves
            ? initialVirtualEthReserves2
            : initialVirtualEthReserves1;
        isToken[address(token)] = true;
        tokenCreator[address(token)] = msg.sender;
        tokenAddress.push(address(token));
        tokenCount++;
        emit TokenCreated(msg.sender, address(token));
    }

    function updateMetadata(
        string memory _name,
        string memory _symbol,
        address _token
    ) external onlyOwner {
        IERC20(_token).updateMetadata(_name, _symbol);
    }

    function buyTokens(address _token, uint256 _amount) external payable {
        if (!isToken[_token]) revert TokenDoesNotExist();
        if (_amount == 0) revert ZeroTokenAmount();
        if (bondingCurve[_token].isCompleted) revert BondingCurveCompleted();

        uint256 allowedToBuy = (initialRealTokenReserves *
            bondingCurve[_token].maxSupplyPercentage) / 100;

        if (IERC20(_token).balanceOf(msg.sender) + _amount > allowedToBuy)
            revert ExceedsAllowedTokenPurchase();
        uint256 ethToBuy = buyQuote(_token, _amount);
        uint256 fee = (ethToBuy * feeBasisPoints) / 10_000;
        if (msg.value < ethToBuy + fee) revert InsufficientETH();

        bondingCurve[_token].virtualTokenReserves -= _amount;
        bondingCurve[_token].realTokenReserves -= _amount;
        bondingCurve[_token].virtualEthReserves += ethToBuy;
        bondingCurve[_token].realEthReserves += ethToBuy;
        if (bondingCurve[_token].realTokenReserves == 0) {
            bondingCurve[_token].isCompleted = true;
        }
        payable(feeRecipient).transfer(fee);
        IERC20(_token).transfer(msg.sender, _amount);
        emit TokensPurchased(msg.sender, _token, _amount);
    }

    function sellTokens(address _token, uint256 _amount) external {
        if (!isToken[_token]) revert TokenDoesNotExist();
        if (_amount == 0) revert ZeroTokenAmount();
        if (bondingCurve[_token].isCompleted) revert BondingCurveCompleted();
        uint256 ethToReceive = sellQuote(_token, _amount);
        uint256 fee = (ethToReceive * feeBasisPoints) / 10_000;
        IERC20(_token).transferFrom(msg.sender, address(this), _amount);
        bondingCurve[_token].virtualTokenReserves += _amount;
        bondingCurve[_token].realTokenReserves += _amount;
        bondingCurve[_token].virtualEthReserves -= ethToReceive;
        bondingCurve[_token].realEthReserves -= ethToReceive;

        payable(feeRecipient).transfer(fee);
        payable(msg.sender).transfer(ethToReceive - fee);
        emit TokensSold(msg.sender, _token, _amount);
    }

    function withdraw(address _token) external onlyOwner {
        if (!isToken[_token]) revert TokenDoesNotExist();
        if (!bondingCurve[_token].isCompleted)
            revert BondingCurveNotCompleted();

        uint256 fee = (bondingCurve[_token].realEthReserves * creatorFees) /
            10000;
        uint256 ethToTransfer = bondingCurve[_token].realEthReserves -
            (fee * 2);
        uint256 tokensToTransfer = IERC20(_token).balanceOf(address(this));
        bondingCurve[_token].virtualTokenReserves = 0;
        bondingCurve[_token].virtualEthReserves = 0;
        bondingCurve[_token].realEthReserves = 0;

        payable(tokenCreator[_token]).transfer(fee);
        payable(feeRecipient).transfer(fee);
        payable(msg.sender).transfer(ethToTransfer);
        IERC20(_token).transfer(msg.sender, tokensToTransfer);
        emit Withdraw(_token, ethToTransfer, tokensToTransfer, fee, fee);
    }

    function withdrawAdmin(address _receiver, uint _amount) external onlyOwner {
        (bool sent, ) = payable(_receiver).call{value: _amount}("");
        require(sent, "Failed to send Ether");
    }

    function buyQuote(
        address _token,
        uint256 _amount
    ) public view returns (uint256) {
        if (!isToken[_token]) revert TokenDoesNotExist();
        uint256 virtualTokenReserves = bondingCurve[_token]
            .virtualTokenReserves;
        uint256 virtualEthReserves = bondingCurve[_token].virtualEthReserves;
        uint256 k = virtualEthReserves * virtualTokenReserves;

        uint256 ethOutput = (k / (virtualTokenReserves - _amount)) -
            virtualEthReserves;
        return ethOutput;
    }

    function buyQuoteWithFee(
        address _token,
        uint256 _amount
    ) public view returns (uint256) {
        if (!isToken[_token]) revert TokenDoesNotExist();
        uint256 virtualTokenReserves = bondingCurve[_token]
            .virtualTokenReserves;
        uint256 virtualEthReserves = bondingCurve[_token].virtualEthReserves;
        uint256 k = virtualEthReserves * virtualTokenReserves;

        uint256 ethOutput = (k / (virtualTokenReserves - _amount)) -
            virtualEthReserves;

        uint256 fee = (ethOutput * feeBasisPoints) / 10_000;
        return ethOutput + fee;
    }

    function sellQuote(
        address _token,
        uint256 _amount
    ) public view returns (uint256) {
        if (!isToken[_token]) revert TokenDoesNotExist();
        uint256 virtualTokenReserves = bondingCurve[_token]
            .virtualTokenReserves;
        uint256 virtualEthReserves = bondingCurve[_token].virtualEthReserves;
        uint256 k = virtualEthReserves * virtualTokenReserves;

        uint256 ethOutput = virtualEthReserves -
            1 -
            (k / (virtualTokenReserves + _amount));
        return ethOutput;
    }

    function sellQuoteWithFee(
        address _token,
        uint256 _amount
    ) public view returns (uint256) {
        if (!isToken[_token]) revert TokenDoesNotExist();
        uint256 virtualTokenReserves = bondingCurve[_token]
            .virtualTokenReserves;
        uint256 virtualEthReserves = bondingCurve[_token].virtualEthReserves;
        uint256 k = virtualEthReserves * virtualTokenReserves;

        uint256 ethOutput = virtualEthReserves -
            1 -
            (k / (virtualTokenReserves + _amount));

        uint256 fee = (ethOutput * feeBasisPoints) / 10_000;
        return ethOutput + fee;
    }

    function calculateBuyFee(
        address _token,
        uint256 _amount
    ) external view returns (uint256) {
        if (!isToken[_token]) revert TokenDoesNotExist();

        uint256 ethToBuy = buyQuote(_token, _amount);
        uint256 fee = (ethToBuy * feeBasisPoints) / 10_000;
        return fee;
    }

    function changeFeeRecipient(
        address _feeRecipient,
        address _tokenFeeRecipient
    ) external onlyOwner {
        feeRecipient = _feeRecipient;
        tokenFeeRecipient = _tokenFeeRecipient;
    }
    function changeFeeBasisPoints(uint256 _feeBasisPoints) external onlyOwner {
        if (_feeBasisPoints > 500) revert FeeTooHigh();
        feeBasisPoints = _feeBasisPoints;
    }
    function changeCreatorFees(uint256 _creatorFees) external onlyOwner {
        if (_creatorFees > 5000) revert FeeTooHigh();
        creatorFees = _creatorFees;
    }
}