MorphoLeveragedwstETHwETH

{{
  "language": "Solidity",
  "sources": {
    "@openzeppelin/contracts/token/ERC20/extensions/IERC20Permit.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 *
 * ==== Security Considerations
 *
 * There are two important considerations concerning the use of `permit`. The first is that a valid permit signature
 * expresses an allowance, and it should not be assumed to convey additional meaning. In particular, it should not be
 * considered as an intention to spend the allowance in any specific way. The second is that because permits have
 * built-in replay protection and can be submitted by anyone, they can be frontrun. A protocol that uses permits should
 * take this into consideration and allow a `permit` call to fail. Combining these two aspects, a pattern that may be
 * generally recommended is:
 *
 * ```solidity
 * function doThingWithPermit(..., uint256 value, uint256 deadline, uint8 v, bytes32 r, bytes32 s) public {
 *     try token.permit(msg.sender, address(this), value, deadline, v, r, s) {} catch {}
 *     doThing(..., value);
 * }
 *
 * function doThing(..., uint256 value) public {
 *     token.safeTransferFrom(msg.sender, address(this), value);
 *     ...
 * }
 * ```
 *
 * Observe that: 1) `msg.sender` is used as the owner, leaving no ambiguity as to the signer intent, and 2) the use of
 * `try/catch` allows the permit to fail and makes the code tolerant to frontrunning. (See also
 * {SafeERC20-safeTransferFrom}).
 *
 * Additionally, note that smart contract wallets (such as Argent or Safe) are not able to produce permit signatures, so
 * contracts should have entry points that don't rely on permit.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     *
     * CAUTION: See Security Considerations above.
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}
"
    },
    "@openzeppelin/contracts/token/ERC20/IERC20.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}
"
    },
    "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";
import {IERC20Permit} from "../extensions/IERC20Permit.sol";
import {Address} from "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    /**
     * @dev An operation with an ERC20 token failed.
     */
    error SafeERC20FailedOperation(address token);

    /**
     * @dev Indicates a failed `decreaseAllowance` request.
     */
    error SafeERC20FailedDecreaseAllowance(address spender, uint256 currentAllowance, uint256 requestedDecrease);

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        forceApprove(token, spender, oldAllowance + value);
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `requestedDecrease`. If `token` returns no
     * value, non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 requestedDecrease) internal {
        unchecked {
            uint256 currentAllowance = token.allowance(address(this), spender);
            if (currentAllowance < requestedDecrease) {
                revert SafeERC20FailedDecreaseAllowance(spender, currentAllowance, requestedDecrease);
            }
            forceApprove(token, spender, currentAllowance - requestedDecrease);
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeCall(token.approve, (spender, value));

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeCall(token.approve, (spender, 0)));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data);
        if (returndata.length != 0 && !abi.decode(returndata, (bool))) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return success && (returndata.length == 0 || abi.decode(returndata, (bool))) && address(token).code.length > 0;
    }
}
"
    },
    "@openzeppelin/contracts/utils/Address.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/Address.sol)

pragma solidity ^0.8.20;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev The ETH balance of the account is not enough to perform the operation.
     */
    error AddressInsufficientBalance(address account);

    /**
     * @dev There's no code at `target` (it is not a contract).
     */
    error AddressEmptyCode(address target);

    /**
     * @dev A call to an address target failed. The target may have reverted.
     */
    error FailedInnerCall();

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.20/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        if (address(this).balance < amount) {
            revert AddressInsufficientBalance(address(this));
        }

        (bool success, ) = recipient.call{value: amount}("");
        if (!success) {
            revert FailedInnerCall();
        }
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason or custom error, it is bubbled
     * up by this function (like regular Solidity function calls). However, if
     * the call reverted with no returned reason, this function reverts with a
     * {FailedInnerCall} error.
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        if (address(this).balance < value) {
            revert AddressInsufficientBalance(address(this));
        }
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and reverts if the target
     * was not a contract or bubbling up the revert reason (falling back to {FailedInnerCall}) in case of an
     * unsuccessful call.
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata
    ) internal view returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            // only check if target is a contract if the call was successful and the return data is empty
            // otherwise we already know that it was a contract
            if (returndata.length == 0 && target.code.length == 0) {
                revert AddressEmptyCode(target);
            }
            return returndata;
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and reverts if it wasn't, either by bubbling the
     * revert reason or with a default {FailedInnerCall} error.
     */
    function verifyCallResult(bool success, bytes memory returndata) internal pure returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            return returndata;
        }
    }

    /**
     * @dev Reverts with returndata if present. Otherwise reverts with {FailedInnerCall}.
     */
    function _revert(bytes memory returndata) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert FailedInnerCall();
        }
    }
}
"
    },
    "@shift-defi/core/contracts/defii/execution/Logic.sol": {
      "content": "// SPDX-License-Identifier: SHIFT-1.0
pragma solidity ^0.8.20;

abstract contract Logic {
    error NotImplemented();

    function claimRewards(address recipient) external payable virtual {
        revert NotImplemented();
    }

    function emergencyExit() external payable virtual {
        revert NotImplemented();
    }

    function withdrawLiquidity(
        address recipient,
        uint256 amount
    ) external payable virtual {
        revert NotImplemented();
    }

    function enter() external payable virtual;

    function exit(uint256 liquidity) public payable virtual;

    function accountLiquidity(
        address account
    ) external view virtual returns (uint256);
}
"
    },
    "@shift-defi/core/contracts/libraries/Constants.sol": {
      "content": "// SPDX-License-Identifier: SHIFT-1.0
pragma solidity ^0.8.20;

library Constants {
    uint256 constant BPS = 1e4;
}
"
    },
    "@shitam/defi-product-templates/contracts/Errors.sol": {
      "content": "// SPDX-License-Identifier: SHIFT-1.0
pragma solidity ^0.8.24;

error NotImplemented();
error EnterFailed();
error ExitFailed();
"
    },
    "@shitam/defi-product-templates/contracts/SelfManagedLogic.sol": {
      "content": "// SPDX-License-Identifier: SHIFT-1.0
pragma solidity ^0.8.24;

import {Logic} from "@shift-defi/core/contracts/defii/execution/Logic.sol";
import {UniswapV3Callbacks} from "./UniswapV3Callbacks.sol";

abstract contract SelfManagedLogic is Logic, UniswapV3Callbacks {
    error WrongBuildingBlockId(uint256);

    function enterWithParams(bytes memory params) external payable virtual {
        revert NotImplemented();
    }

    function exitBuildingBlock(
        uint256 buildingBlockId
    ) external payable virtual;

    function allocatedLiquidity(
        address account
    ) external view virtual returns (uint256);

    function exitWithRepay(address lending) external virtual {
        revert NotImplemented();
    }
}
"
    },
    "@shitam/defi-product-templates/contracts/UniswapV3Callbacks.sol": {
      "content": "// SPDX-License-Identifier: SHIFT-1.0
pragma solidity ^0.8.24;

import {NotImplemented} from "./Errors.sol";

abstract contract UniswapV3Callbacks {
    function uniswapV3SwapCallback(
        int256 amount0Delta,
        int256 amount1Delta,
        bytes calldata data
    ) external virtual {
        revert NotImplemented();
    }
    function uniswapV3MintCallback(
        uint256 amount0Owed,
        uint256 amount1Owed,
        bytes calldata data
    ) external virtual {
        revert NotImplemented();
    }
    function uniswapV3FlashCallback(
        uint256 fee0,
        uint256 fee1,
        bytes calldata data
    ) external virtual {
        revert NotImplemented();
    }
}
"
    },
    "contracts/interfaces/ILending.sol": {
      "content": "// SPDX-License-Identifier: SHIFT-1.0
pragma solidity ^0.8.9;

interface ILending {
    function repay(address[] calldata tokens) external;
    function currentDebt(address token) external view returns (uint256);
    function totalDebt() external view returns (uint256);
}
"
    },
    "contracts/logic/ethereum/MorphoLeveragedwstETHwETH.sol": {
      "content": "// SPDX-License-Identifier: SHIFT-1.0

pragma solidity ^0.8.20;

import {IERC20} from "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import {SelfManagedLogicV4WithUtils} from "../templates/SelfManagedLogicV4WithUtils.sol";

contract MorphoLeveragedwstETHwETH is SelfManagedLogicV4WithUtils {
    uint256 public constant loops = 20;
    address public constant morpho = 0xBBBBBbbBBb9cC5e90e3b3Af64bdAF62C37EEFFCb;
    uint256 public constant borrow_ltv = 964;
    uint256 public constant borrow_ltv_denominator = 1000;
    uint256 public constant max_ltv = 941;
    uint256 public constant max_ltv_denominator = 1000;
    uint256 public constant withdraw_ltv = 95900;
    uint256 public constant withdraw_ltv_denominator = 100000;
    bytes32 public constant pool_id = 0xb8fc70e82bc5bb53e773626fcc6a23f7eefa036918d7ef216ecfb1950a94a85e;
    address public constant stETH = 0xae7ab96520DE3A18E5e111B5EaAb095312D7fE84;
    address public constant wstETH = 0x7f39C581F595B53c5cb19bD0b3f8dA6c935E2Ca0;
    address public constant wETH = 0xC02aaA39b223FE8D0A0e5C4F27eAD9083C756Cc2;
    address public constant unstETH = 0x889edC2eDab5f40e902b864aD4d7AdE8E412F9B1;
    uint256 public constant min_amount_to_withdraw = 1000;

    function enter() external payable override {
        uint256 nativeBalance = address(this).balance;
        if (nativeBalance > 0) {
            IstETH(stETH).submit{value:nativeBalance}(address(0));
        }
        uint256 stETHBalance = IstETH(stETH).balanceOf(address(this));
        if (stETHBalance > 0) {
            _approveIfNeeded(stETH, wstETH);
            IwstETH(wstETH).wrap(stETHBalance);
        }
        uint256 wstETHBalance = IwstETH(wstETH).balanceOf(address(this));
        require(wstETHBalance > 0, "wstETH balance is zero");
        _approveIfNeeded(wstETH, morpho);

        IMorpho.MarketParams memory marketParams = IMorpho(morpho).idToMarketParams(pool_id);

        IMorpho(morpho).supplyCollateral(marketParams, wstETHBalance, address(this), "");

        for (uint256 i = 0; i < loops; i++) {
            uint256 ethBalanceToBorrow = IwstETH(wstETH).getStETHByWstETH(wstETHBalance) * borrow_ltv / borrow_ltv_denominator;
            IMorpho(morpho).borrow(marketParams, ethBalanceToBorrow, 0, address(this), address(this));
            IwETH(wETH).withdraw(IwETH(wETH).balanceOf(address(this)));
            IstETH(stETH).submit{value:address(this).balance}(address(0));
            IwstETH(wstETH).wrap(IstETH(stETH).balanceOf(address(this)));
            wstETHBalance = IwstETH(wstETH).balanceOf(address(this));
            IMorpho(morpho).supplyCollateral(marketParams, wstETHBalance, address(this), "");
        }

        IMorpho.Market memory market = IMorpho(morpho).market(pool_id);
        IMorpho.Position memory position = IMorpho(morpho).position(pool_id, address(this));
        uint256 debt_amount = IwstETH(wstETH).getWstETHByStETH(uint256(position.borrowShares) * uint256(market.totalBorrowAssets) / uint256(market.totalBorrowShares));
        uint256 supply_amount = position.collateral;
        uint256 current_ltv = debt_amount * max_ltv_denominator / supply_amount;
        require(current_ltv <= max_ltv, "current ltv is greater than max ltv");
    }

    function exit(uint256 liquidity) public payable override {
        _unstakeIfPossible();
        _repay();

        IMorpho.Market memory market = IMorpho(morpho).market(pool_id);
        IMorpho.Position memory position = IMorpho(morpho).position(pool_id, address(this));
        uint256 debt_amount = IwstETH(wstETH).getWstETHByStETH(uint256(position.borrowShares) * uint256(market.totalBorrowAssets) / uint256(market.totalBorrowShares));
        uint256 supply_amount = position.collateral;

        uint256 amount_to_withdraw = supply_amount - debt_amount * withdraw_ltv_denominator / withdraw_ltv;
        IMorpho(morpho).withdrawCollateral(IMorpho(morpho).idToMarketParams(pool_id), amount_to_withdraw, address(this), address(this));

        IwstETH(wstETH).unwrap(IwstETH(wstETH).balanceOf(address(this)));

        uint256[] memory param = new uint256[](1);
        param[0] = IERC20(stETH).balanceOf(address(this));

        _approveIfNeeded(stETH, unstETH);
        IunstETH(unstETH).requestWithdrawals(
            param,
            address(this)
        );
    }

    function getRequestId() public view returns (uint256) {
        uint256[] memory data = IunstETH(unstETH).getWithdrawalRequests(address(this));
        if (data.length > 0) {
            return data[data.length-1];
        }
        return 0;
    }

    function _unstakeIfPossible() internal {
        uint256 requestId = getRequestId();

        if (requestId != 0) {
            if (IunstETH(unstETH).getLastFinalizedRequestId() >= requestId) {
                IunstETH(unstETH).claimWithdrawal(requestId);
            } else {
                revert("Not ready to claim eth");
            }
        }
    }

    function _repay() internal {
        uint256 balance = address(this).balance;
        if (balance > min_amount_to_withdraw) {
            IwETH(wETH).deposit{value: balance}();
        }

        uint256 amount = IwETH(wETH).balanceOf(address(this));

        if (amount > min_amount_to_withdraw) {
            IMorpho.Market memory market = IMorpho(morpho).market(pool_id);
            IMorpho.Position memory position = IMorpho(morpho).position(pool_id, address(this));
            uint256 paybackAmount = uint256(position.borrowShares) * uint256(market.totalBorrowAssets) / uint256(market.totalBorrowShares);
            _approveIfNeeded(wETH, morpho);

            if (amount < paybackAmount) {
                paybackAmount = amount;
            }
            IMorpho(morpho).repay(IMorpho(morpho).idToMarketParams(pool_id), paybackAmount, 0, address(this), "");
        }
    }

    function claimRewards(address recipient) external payable override {}

    function exitBuildingBlock(
        uint256 buildingBlockId
    ) external payable override {}

    function accountLiquidity(
        address account
    ) public view override returns (uint256) {
        return allocatedLiquidity(account);
    }

    function allocatedLiquidity(
        address account
    ) public view override returns (uint256) {
        IMorpho.Position memory position = IMorpho(morpho).position(pool_id, account);
        return position.collateral;
    }

    receive() external payable {}
}

interface IMorpho {
    struct MarketParams {
        address loanToken;
        address collateralToken;
        address oracle;
        address irm;
        uint256 lltv;
    }
    struct Market {
        uint128 totalSupplyAssets;
        uint128 totalSupplyShares;
        uint128 totalBorrowAssets;
        uint128 totalBorrowShares;
        uint128 lastUpdate;
        uint128 fee;
    }
    struct Position {
        uint256 supplyShares;
        uint128 borrowShares;
        uint128 collateral;
    }
    function idToMarketParams(bytes32 id) external view returns (MarketParams memory);
    function supplyCollateral(MarketParams memory marketParams, uint256 assets, address onBehalf, bytes memory data) external;
    function borrow(
        MarketParams memory marketParams,
        uint256 assets,
        uint256 shares,
        address onBehalf,
        address receiver
    ) external returns (uint256 assetsBorrowed, uint256 sharesBorrowed);
    function market(bytes32 id) external view returns (Market memory m);
    function position(bytes32 id, address user) external view returns (Position memory p);
    function repay(
        MarketParams memory marketParams,
        uint256 assets,
        uint256 shares,
        address onBehalf,
        bytes memory data
    ) external returns (uint256 assetsRepaid, uint256 sharesRepaid);
    function withdrawCollateral(MarketParams memory marketParams, uint256 assets, address onBehalf, address receiver) external;
}

interface IstETH is IERC20 {
    function submit(address _referral) external payable returns (uint256);
}

interface IwstETH is IERC20 {
    function wrap(uint256 _stETHAmount) external returns (uint256);
    function unwrap(uint256 _wstETHAmount) external returns (uint256);
    function getStETHByWstETH(uint256 _wstETHAmount) external view returns (uint256);
    function getWstETHByStETH(uint256 _stETHAmount) external view returns (uint256);
}

interface IwETH is IERC20 {
    function withdraw(uint256 wad) external;
    function deposit() external payable;
}

interface IunstETH is IERC20 {
    function requestWithdrawals(uint256[] calldata _amounts, address _owner) external returns (uint256[] memory requestIds);
    function getLastFinalizedRequestId() external view returns (uint256);
    function claimWithdrawal(uint256 _requestId) external;
    function getWithdrawalRequests(address _owner) external view returns (uint256[] memory requestsIds);
}"
    },
    "contracts/logic/templates/SelfManagedLogicV2WithUtils.sol": {
      "content": "// SPDX-License-Identifier: SHIFT-1.0
pragma solidity ^0.8.9;

import {IERC20} from "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import {SafeERC20} from "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";

import {SelfManagedLogic, UniswapV3Callbacks} from "@shitam/defi-product-templates/contracts/SelfManagedLogic.sol";
import {Constants} from "@shift-defi/core/contracts/libraries/Constants.sol";

import {ILending} from "../../interfaces/ILending.sol";

abstract contract SelfManagedLogicV2WithUtils is SelfManagedLogic {
    using SafeERC20 for IERC20;

    function exit(uint256) public payable override virtual;
    function allocatedLiquidity(address) public view override virtual returns(uint256);

    function _approveIfNeeded(address token, address recipient) internal {
        uint256 allowance = IERC20(token).allowance(address(this), recipient);
        if (allowance < type(uint256).max) {
            IERC20(token).forceApprove(recipient, type(uint256).max);
        }
    }

    function _transferAll(address token, address recipient) internal {
        uint256 balance = IERC20(token).balanceOf(address(this));
        if (balance > 0) {
            IERC20(token).safeTransfer(recipient, balance);
        }
    }

    function _exitWithRepay(address lending, address[] memory tokens) internal virtual {
        require(ILending(lending).totalDebt() > 0);
        if (allocatedLiquidity(address(this)) > 0) {
            exit(allocatedLiquidity(address(this)));
        }
        for (uint i = 0; i < tokens.length; i++) {
            if (IERC20(tokens[i]).balanceOf(address(this)) > 0) {
                _transferAll(tokens[i], lending);
            }
        }
        ILending(lending).repay(tokens);
    }
}
"
    },
    "contracts/logic/templates/SelfManagedLogicV4WithUtils.sol": {
      "content": "// SPDX-License-Identifier: SHIFT-1.0
pragma solidity ^0.8.9;

import {SelfManagedLogicV2WithUtils} from "./SelfManagedLogicV2WithUtils.sol";

abstract contract SelfManagedLogicV4WithUtils is SelfManagedLogicV2WithUtils {
    function rebalance(bytes calldata) external virtual {
        revert NotImplemented();
    }
}
"
    }
  },
  "settings": {
    "optimizer": {
      "enabled": true,
      "runs": 200
    },
    "evmVersion": "paris",
    "outputSelection": {
      "*": {
        "*": [
          "evm.bytecode",
          "evm.deployedBytecode",
          "devdoc",
          "userdoc",
          "metadata",
          "abi"
        ]
      }
    }
  }
}}