CurveFiEvaluator

{{
  "language": "Solidity",
  "sources": {
    "@openzeppelin/contracts-upgradeable/proxy/utils/Initializable.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (proxy/utils/Initializable.sol)

pragma solidity ^0.8.20;

/**
 * @dev This is a base contract to aid in writing upgradeable contracts, or any kind of contract that will be deployed
 * behind a proxy. Since proxied contracts do not make use of a constructor, it's common to move constructor logic to an
 * external initializer function, usually called `initialize`. It then becomes necessary to protect this initializer
 * function so it can only be called once. The {initializer} modifier provided by this contract will have this effect.
 *
 * The initialization functions use a version number. Once a version number is used, it is consumed and cannot be
 * reused. This mechanism prevents re-execution of each "step" but allows the creation of new initialization steps in
 * case an upgrade adds a module that needs to be initialized.
 *
 * For example:
 *
 * [.hljs-theme-light.nopadding]
 * ```solidity
 * contract MyToken is ERC20Upgradeable {
 *     function initialize() initializer public {
 *         __ERC20_init("MyToken", "MTK");
 *     }
 * }
 *
 * contract MyTokenV2 is MyToken, ERC20PermitUpgradeable {
 *     function initializeV2() reinitializer(2) public {
 *         __ERC20Permit_init("MyToken");
 *     }
 * }
 * ```
 *
 * TIP: To avoid leaving the proxy in an uninitialized state, the initializer function should be called as early as
 * possible by providing the encoded function call as the `_data` argument to {ERC1967Proxy-constructor}.
 *
 * CAUTION: When used with inheritance, manual care must be taken to not invoke a parent initializer twice, or to ensure
 * that all initializers are idempotent. This is not verified automatically as constructors are by Solidity.
 *
 * [CAUTION]
 * ====
 * Avoid leaving a contract uninitialized.
 *
 * An uninitialized contract can be taken over by an attacker. This applies to both a proxy and its implementation
 * contract, which may impact the proxy. To prevent the implementation contract from being used, you should invoke
 * the {_disableInitializers} function in the constructor to automatically lock it when it is deployed:
 *
 * [.hljs-theme-light.nopadding]
 * ```
 * /// @custom:oz-upgrades-unsafe-allow constructor
 * constructor() {
 *     _disableInitializers();
 * }
 * ```
 * ====
 */
abstract contract Initializable {
    /**
     * @dev Storage of the initializable contract.
     *
     * It's implemented on a custom ERC-7201 namespace to reduce the risk of storage collisions
     * when using with upgradeable contracts.
     *
     * @custom:storage-location erc7201:openzeppelin.storage.Initializable
     */
    struct InitializableStorage {
        /**
         * @dev Indicates that the contract has been initialized.
         */
        uint64 _initialized;
        /**
         * @dev Indicates that the contract is in the process of being initialized.
         */
        bool _initializing;
    }

    // keccak256(abi.encode(uint256(keccak256("openzeppelin.storage.Initializable")) - 1)) & ~bytes32(uint256(0xff))
    bytes32 private constant INITIALIZABLE_STORAGE = 0xf0c57e16840df040f15088dc2f81fe391c3923bec73e23a9662efc9c229c6a00;

    /**
     * @dev The contract is already initialized.
     */
    error InvalidInitialization();

    /**
     * @dev The contract is not initializing.
     */
    error NotInitializing();

    /**
     * @dev Triggered when the contract has been initialized or reinitialized.
     */
    event Initialized(uint64 version);

    /**
     * @dev A modifier that defines a protected initializer function that can be invoked at most once. In its scope,
     * `onlyInitializing` functions can be used to initialize parent contracts.
     *
     * Similar to `reinitializer(1)`, except that in the context of a constructor an `initializer` may be invoked any
     * number of times. This behavior in the constructor can be useful during testing and is not expected to be used in
     * production.
     *
     * Emits an {Initialized} event.
     */
    modifier initializer() {
        // solhint-disable-next-line var-name-mixedcase
        InitializableStorage storage $ = _getInitializableStorage();

        // Cache values to avoid duplicated sloads
        bool isTopLevelCall = !$._initializing;
        uint64 initialized = $._initialized;

        // Allowed calls:
        // - initialSetup: the contract is not in the initializing state and no previous version was
        //                 initialized
        // - construction: the contract is initialized at version 1 (no reininitialization) and the
        //                 current contract is just being deployed
        bool initialSetup = initialized == 0 && isTopLevelCall;
        bool construction = initialized == 1 && address(this).code.length == 0;

        if (!initialSetup && !construction) {
            revert InvalidInitialization();
        }
        $._initialized = 1;
        if (isTopLevelCall) {
            $._initializing = true;
        }
        _;
        if (isTopLevelCall) {
            $._initializing = false;
            emit Initialized(1);
        }
    }

    /**
     * @dev A modifier that defines a protected reinitializer function that can be invoked at most once, and only if the
     * contract hasn't been initialized to a greater version before. In its scope, `onlyInitializing` functions can be
     * used to initialize parent contracts.
     *
     * A reinitializer may be used after the original initialization step. This is essential to configure modules that
     * are added through upgrades and that require initialization.
     *
     * When `version` is 1, this modifier is similar to `initializer`, except that functions marked with `reinitializer`
     * cannot be nested. If one is invoked in the context of another, execution will revert.
     *
     * Note that versions can jump in increments greater than 1; this implies that if multiple reinitializers coexist in
     * a contract, executing them in the right order is up to the developer or operator.
     *
     * WARNING: Setting the version to 2**64 - 1 will prevent any future reinitialization.
     *
     * Emits an {Initialized} event.
     */
    modifier reinitializer(uint64 version) {
        // solhint-disable-next-line var-name-mixedcase
        InitializableStorage storage $ = _getInitializableStorage();

        if ($._initializing || $._initialized >= version) {
            revert InvalidInitialization();
        }
        $._initialized = version;
        $._initializing = true;
        _;
        $._initializing = false;
        emit Initialized(version);
    }

    /**
     * @dev Modifier to protect an initialization function so that it can only be invoked by functions with the
     * {initializer} and {reinitializer} modifiers, directly or indirectly.
     */
    modifier onlyInitializing() {
        _checkInitializing();
        _;
    }

    /**
     * @dev Reverts if the contract is not in an initializing state. See {onlyInitializing}.
     */
    function _checkInitializing() internal view virtual {
        if (!_isInitializing()) {
            revert NotInitializing();
        }
    }

    /**
     * @dev Locks the contract, preventing any future reinitialization. This cannot be part of an initializer call.
     * Calling this in the constructor of a contract will prevent that contract from being initialized or reinitialized
     * to any version. It is recommended to use this to lock implementation contracts that are designed to be called
     * through proxies.
     *
     * Emits an {Initialized} event the first time it is successfully executed.
     */
    function _disableInitializers() internal virtual {
        // solhint-disable-next-line var-name-mixedcase
        InitializableStorage storage $ = _getInitializableStorage();

        if ($._initializing) {
            revert InvalidInitialization();
        }
        if ($._initialized != type(uint64).max) {
            $._initialized = type(uint64).max;
            emit Initialized(type(uint64).max);
        }
    }

    /**
     * @dev Returns the highest version that has been initialized. See {reinitializer}.
     */
    function _getInitializedVersion() internal view returns (uint64) {
        return _getInitializableStorage()._initialized;
    }

    /**
     * @dev Returns `true` if the contract is currently initializing. See {onlyInitializing}.
     */
    function _isInitializing() internal view returns (bool) {
        return _getInitializableStorage()._initializing;
    }

    /**
     * @dev Returns a pointer to the storage namespace.
     */
    // solhint-disable-next-line var-name-mixedcase
    function _getInitializableStorage() private pure returns (InitializableStorage storage $) {
        assembly {
            $.slot := INITIALIZABLE_STORAGE
        }
    }
}
"
    },
    "@openzeppelin/contracts-upgradeable/utils/introspection/ERC165Upgradeable.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/introspection/ERC165.sol)

pragma solidity ^0.8.20;

import {IERC165} from "@openzeppelin/contracts/utils/introspection/IERC165.sol";
import {Initializable} from "../../proxy/utils/Initializable.sol";

/**
 * @dev Implementation of the {IERC165} interface.
 *
 * Contracts that want to implement ERC165 should inherit from this contract and override {supportsInterface} to check
 * for the additional interface id that will be supported. For example:
 *
 * ```solidity
 * function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
 *     return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
 * }
 * ```
 */
abstract contract ERC165Upgradeable is Initializable, IERC165 {
    function __ERC165_init() internal onlyInitializing {
    }

    function __ERC165_init_unchained() internal onlyInitializing {
    }
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual returns (bool) {
        return interfaceId == type(IERC165).interfaceId;
    }
}
"
    },
    "@openzeppelin/contracts/token/ERC20/IERC20.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}
"
    },
    "@openzeppelin/contracts/utils/Address.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/Address.sol)

pragma solidity ^0.8.20;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev The ETH balance of the account is not enough to perform the operation.
     */
    error AddressInsufficientBalance(address account);

    /**
     * @dev There's no code at `target` (it is not a contract).
     */
    error AddressEmptyCode(address target);

    /**
     * @dev A call to an address target failed. The target may have reverted.
     */
    error FailedInnerCall();

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.20/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        if (address(this).balance < amount) {
            revert AddressInsufficientBalance(address(this));
        }

        (bool success, ) = recipient.call{value: amount}("");
        if (!success) {
            revert FailedInnerCall();
        }
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason or custom error, it is bubbled
     * up by this function (like regular Solidity function calls). However, if
     * the call reverted with no returned reason, this function reverts with a
     * {FailedInnerCall} error.
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        if (address(this).balance < value) {
            revert AddressInsufficientBalance(address(this));
        }
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and reverts if the target
     * was not a contract or bubbling up the revert reason (falling back to {FailedInnerCall}) in case of an
     * unsuccessful call.
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata
    ) internal view returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            // only check if target is a contract if the call was successful and the return data is empty
            // otherwise we already know that it was a contract
            if (returndata.length == 0 && target.code.length == 0) {
                revert AddressEmptyCode(target);
            }
            return returndata;
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and reverts if it wasn't, either by bubbling the
     * revert reason or with a default {FailedInnerCall} error.
     */
    function verifyCallResult(bool success, bytes memory returndata) internal pure returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            return returndata;
        }
    }

    /**
     * @dev Reverts with returndata if present. Otherwise reverts with {FailedInnerCall}.
     */
    function _revert(bytes memory returndata) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert FailedInnerCall();
        }
    }
}
"
    },
    "@openzeppelin/contracts/utils/introspection/IERC165.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/introspection/IERC165.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}
"
    },
    "contracts/compiler/base/LiquidityPoolsRepository.sol": {
      "content": "// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.22;

import {
    AlreadyUpToDate,
    ILiquidityPoolsRepository,
    PoolIdNotFound,
    PoolIsNotSupported,
    Status
} from "contracts/interfaces/compiler/adapters/index.sol";

abstract contract LiquidityPoolsRepository is ILiquidityPoolsRepository {
    modifier getPoolGuard(uint256 _poolId) {
        Status status = getPoolStatus(_poolId);

        if (status == Status.Undefined) revert PoolIsNotSupported(_poolId);

        _;
    }

    // Interface implementation

    function updatePoolSupport(
        bytes calldata _encodedParams,
        bool _supported
    ) external override returns (uint256 poolId_) {
        poolId_ = getPoolIdFromParams(_encodedParams);
        Status status = getPoolStatus(poolId_);

        if (_supported && status == Status.Undefined) {
            return initializePool(_encodedParams);
        }

        if (_supported && status == Status.Suspended) {
            setPoolStatus(poolId_, Status.Supported);
            return poolId_;
        }

        if (!_supported && status == Status.Supported) {
            setPoolStatus(poolId_, Status.Suspended);
            return poolId_;
        }

        revert AlreadyUpToDate();
    }

    function getPoolId(
        bytes calldata _encodedTokens
    ) external view override returns (uint256 poolId_) {
        if (getPoolStatus(poolId_ = getPoolIdFromTokens(_encodedTokens)) == Status.Undefined) {
            revert PoolIdNotFound(_encodedTokens);
        }
    }

    function getPoolStatus(uint256 _poolId) public view virtual override returns (Status);

    // Internal fixture

    function initializePool(
        bytes calldata _encodedParams
    ) internal virtual returns (uint256 poolId_);

    function setPoolStatus(uint256 _poolId, Status _status) internal virtual;

    function getPoolIdFromParams(
        bytes calldata _encodedParams
    ) internal view virtual returns (uint256 poolId_);

    function getPoolIdFromTokens(
        bytes calldata _encodedTokens
    ) internal view virtual returns (uint256 poolId_);
}
"
    },
    "contracts/compiler/curveFi/actions/CurveFiDecreasePosition.sol": {
      "content": "// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.22;

import {MinAmountOutMustNotBeZero} from "contracts/interfaces/base/CommonErrors.sol";
import {IDecreasePositionEvaluator} from "contracts/interfaces/compiler/adapters/index.sol";
import {CurveFiLiquidityPoolsRepository, CurveFiPool} from "../CurveFiLiquidityPoolsRepository.sol";

abstract contract CurveFiDecreasePosition is CurveFiLiquidityPoolsRepository {
    bytes4 private constant REMOVE_LIQUIDITY_2 =
        bytes4(keccak256("remove_liquidity(uint256,uint256[2])"));
    bytes4 private constant REMOVE_LIQUIDITY_3 =
        bytes4(keccak256("remove_liquidity(uint256,uint256[3])"));
    bytes4 private constant REMOVE_LIQUIDITY_4 =
        bytes4(keccak256("remove_liquidity(uint256,uint256[4])"));
    bytes4 private constant REMOVE_LIQUIDITY_ZAPPER =
        bytes4(keccak256("remove_liquidity(address,uint256,uint256[4])"));

    error InvalidMinOutputLength(uint256 provided, uint256 configured);

    function constructDecreasePosition(
        IDecreasePositionEvaluator.DecreasePositionRequest calldata request
    ) internal view returns (bool needApprove, address lpToken, address target, bytes memory data) {
        uint256 length = request.minOutput.length;
        uint256 i;
        while (i < length) {
            if (request.minOutput[i].amount == 0) revert MinAmountOutMustNotBeZero();
            unchecked {
                ++i;
            }
        }

        CurveFiPool storage pool = getPool(request.descriptor.poolId);
        if (length != pool.nCoins)
            revert InvalidMinOutputLength(request.minOutput.length, pool.nCoins);

        uint256 basePoolId = pool.basePoolId;
        if (basePoolId == 0) {
            target = address(pool.ref);
            data = _construct(pool.nCoins, request);
        } else {
            CurveFiPool storage basePool = getPool(basePoolId);
            needApprove = true;
            target = address(basePool.zapper);
            lpToken = address(pool.gauge.lp_token());
            data = _constructZapper(address(pool.ref), request);
        }
    }

    function _constructZapper(
        address target,
        IDecreasePositionEvaluator.DecreasePositionRequest calldata request
    ) private pure returns (bytes memory payload) {
        uint256[4] memory minOutput;
        uint256 i;
        while (i < request.minOutput.length) {
            minOutput[i] = request.minOutput[i].amount;
            unchecked {
                ++i;
            }
        }
        payload = abi.encodeWithSelector(
            REMOVE_LIQUIDITY_ZAPPER,
            target,
            request.liquidity,
            minOutput
        );
    }

    function _construct(
        uint256 nCoins,
        IDecreasePositionEvaluator.DecreasePositionRequest calldata request
    ) private pure returns (bytes memory payload) {
        if (nCoins == 2) {
            payload = abi.encodeWithSelector(
                REMOVE_LIQUIDITY_2,
                request.liquidity,
                [request.minOutput[0].amount, request.minOutput[1].amount]
            );
        } else if (nCoins == 3) {
            payload = abi.encodeWithSelector(
                REMOVE_LIQUIDITY_3,
                request.liquidity,
                [
                    request.minOutput[0].amount,
                    request.minOutput[1].amount,
                    request.minOutput[2].amount
                ]
            );
        } else {
            payload = abi.encodeWithSelector(
                REMOVE_LIQUIDITY_4,
                request.liquidity,
                [
                    request.minOutput[0].amount,
                    request.minOutput[1].amount,
                    request.minOutput[2].amount,
                    request.minOutput[3].amount
                ]
            );
        }
    }
}
"
    },
    "contracts/compiler/curveFi/actions/CurveFiExchange.sol": {
      "content": "// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.22;

import {Path} from "contracts/compiler/libraries/Path.sol";
import {Address} from "contracts/libraries/Address.sol";

import {
    CurveFiLiquidityPoolsRepository,
    CurveFiPool,
    ICurveFiPool
} from "../CurveFiLiquidityPoolsRepository.sol";
import {CurveFiLib} from "../libraries/CurveFiLib.sol";

abstract contract CurveFiExchange is CurveFiLiquidityPoolsRepository {
    using CurveFiLib for ICurveFiPool;
    using Address for address;
    using Path for bytes;

    bytes4 private constant SELECTOR_EXCHANGE_256_ETH =
        bytes4(keccak256("exchange(uint256,uint256,uint256,uint256,bool)"));
    bytes4 private constant SELECTOR_EXCHANGE_256 =
        bytes4(keccak256("exchange(uint256,uint256,uint256,uint256)"));
    bytes4 private constant SELECTOR_EXCHANGE_128 =
        bytes4(keccak256("exchange(int128,int128,uint256,uint256)"));
    bytes4 private constant SELECTOR_EXCHANGE_UNDERLYING_256 =
        bytes4(keccak256("exchange_underlying(uint256,uint256,uint256,uint256)"));
    bytes4 private constant SELECTOR_EXCHANGE_UNDERLYING_128 =
        bytes4(keccak256("exchange_underlying(int128,int128,uint256,uint256)"));

    /* solhint-disable func-param-name-mixedcase, var-name-mixedcase */
    function constructExchange(
        bytes calldata path,
        uint256 dx,
        uint256 min_dy
    ) internal view returns (address tokenIn, address target, uint256 value, bytes memory data) {
        address tokenOut;
        uint256 poolId;
        (tokenIn, tokenOut, poolId) = path.extractPool(0);
        CurveFiPool storage pool = getPool(poolId);
        CurveFiPool storage basePool = pool.basePoolId != 0 ? getPool(pool.basePoolId) : pool;
        uint256 i = pool.ref.getTokenIndex(pool.nCoins, basePool.ref, basePool.nCoins, tokenIn);
        uint256 j = pool.ref.getTokenIndex(pool.nCoins, basePool.ref, basePool.nCoins, tokenOut);
        target = address(pool.ref);

        if (tokenIn.isEth()) value = dx;
        data = pool.basePoolId == 0
            ? constructExchange(pool.use256, i, j, dx, min_dy, value != 0)
            : constructExchangeUnderlying(pool.use256, i, j, dx, min_dy);
    }

    function constructExchange(
        bool use256,
        uint256 i,
        uint256 j,
        uint256 dx,
        uint256 min_dy,
        bool useEth
    ) private pure returns (bytes memory data) {
        bytes4 selector = use256
            ? (useEth ? SELECTOR_EXCHANGE_256_ETH : SELECTOR_EXCHANGE_256)
            : SELECTOR_EXCHANGE_128;
        data = useEth
            ? abi.encodeWithSelector(selector, i, j, dx, min_dy, true)
            : abi.encodeWithSelector(selector, i, j, dx, min_dy);
    }

    function constructExchangeUnderlying(
        bool use256,
        uint256 i,
        uint256 j,
        uint256 dx,
        uint256 min_dy
    ) private pure returns (bytes memory data) {
        bytes4 selector = use256
            ? SELECTOR_EXCHANGE_UNDERLYING_256
            : SELECTOR_EXCHANGE_UNDERLYING_128;
        data = abi.encodeWithSelector(selector, i, j, dx, min_dy);
    }
    /* solhint-disable func-param-name-mixedcase, var-name-mixedcase */
}
"
    },
    "contracts/compiler/curveFi/CurveFiEvaluator.sol": {
      "content": "// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.22;

import {Address} from "@openzeppelin/contracts/utils/Address.sol";

import {
    IDecreasePositionEvaluator,
    IExchangeEvaluator
} from "contracts/interfaces/compiler/adapters/index.sol";
import {Command} from "contracts/interfaces/compiler/Command.sol";

import {Path} from "../libraries/Path.sol";
import {CurveFiDecreasePosition} from "./actions/CurveFiDecreasePosition.sol";
import {CurveFiExchange} from "./actions/CurveFiExchange.sol";
import {CurveFiLiquidityPoolsRepository} from "./CurveFiLiquidityPoolsRepository.sol";

contract CurveFiEvaluator is
    IDecreasePositionEvaluator,
    IExchangeEvaluator,
    CurveFiLiquidityPoolsRepository,
    CurveFiExchange,
    CurveFiDecreasePosition
{
    using Address for address;
    using Path for bytes;

    error CurveFiV1CantExchangeToDifferentAddress();

    function evaluate(
        address operator,
        ExchangeRequest calldata request
    ) external view override returns (Command[] memory cmds) {
        // TODO: we can specify recipient for V2 pools, but currently this feature is not needed
        if (operator != request.recipient) revert CurveFiV1CantExchangeToDifferentAddress();

        (address tokenIn, address target, uint256 value, bytes memory data) = constructExchange(
            request.path,
            request.amountIn,
            request.minAmountOut
        );
        Command memory cmd = Command({target: target, value: value, payload: data});
        cmds = value == 0 ? cmd.populateWithApprove(tokenIn, request.amountIn) : cmd.asArray();
    }

    function evaluate(
        address,
        DecreasePositionRequest calldata request
    ) external view override returns (Command[] memory cmds) {
        (
            bool needApprove,
            address lpToken,
            address target,
            bytes memory data
        ) = constructDecreasePosition(request);
        Command memory cmd = Command({target: target, value: 0, payload: data});
        cmds = needApprove ? cmd.populateWithApprove(lpToken, request.liquidity) : cmd.asArray();
    }
}
"
    },
    "contracts/compiler/curveFi/CurveFiLiquidityPoolsRepository.sol": {
      "content": "// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.22;

import {
    ICurveFiGauge,
    ICurveFiPool,
    ICurveFiZapper
} from "contracts/interfaces/compliance/internal/curveFi/index.sol";

import {Address} from "contracts/libraries/Address.sol";

import {LiquidityPoolsRepository, Status} from "../base/LiquidityPoolsRepository.sol";
import {CurveFiLib} from "./libraries/CurveFiLib.sol";

struct CurveFiPool {
    ICurveFiPool ref;
    uint80 basePoolId;
    uint8 nCoins;
    bool use256;
    ICurveFiZapper zapper;
    ICurveFiGauge gauge;
    Status status;
}

abstract contract CurveFiLiquidityPoolsRepository is LiquidityPoolsRepository {
    using CurveFiLib for ICurveFiPool;

    struct Storage {
        uint256 currentPoolId;
        mapping(bytes32 poolTokensHash => uint256 poolId) ids;
        mapping(uint256 poolId => CurveFiPool) pools;
    }

    // keccak256("CurveFi Liquidity Pools State V1")
    bytes32 internal constant STORAGE_SLOT =
        0x58ebf467944ec58ecf545c6ac01f80ed366183078a791b197feed2e14cc85f3b;

    function getPoolStatus(uint256 poolId) public view override returns (Status) {
        return _storage().pools[poolId].status;
    }

    function initializePool(
        bytes calldata encodedParams
    ) internal override returns (uint256 poolId_) {
        (address deposit, uint80 basePoolId, , address zapper, address gauge) = abi.decode(
            encodedParams,
            (address, uint80, uint8, address, address)
        );

        // @dev use getPoolGuard modifier to make sure basePool.status isn't Status.Undefined
        if (basePoolId != 0) getPool(basePoolId);

        ICurveFiPool pool = ICurveFiPool(deposit);
        (address[4] memory tokens, uint256 nCoins) = pool.getTokens();
        // Determine whether the pool is V2 (uint256 index) or V1 (int128 index)
        bool use256;
        try pool.mid_fee() returns (uint256) {
            use256 = true;
        } catch {
            use256 = false;
        }

        Storage storage $ = _storage();
        $.ids[hash(tokens)] = ++$.currentPoolId;
        $.pools[poolId_ = $.currentPoolId] = CurveFiPool({
            ref: pool,
            basePoolId: basePoolId,
            nCoins: uint8(nCoins),
            use256: use256,
            zapper: ICurveFiZapper(zapper),
            gauge: ICurveFiGauge(gauge),
            status: Status.Supported
        });
    }

    function setPoolStatus(uint256 poolId, Status status) internal override {
        _storage().pools[poolId].status = status;
    }

    function getPool(
        uint256 poolId
    ) internal view getPoolGuard(poolId) returns (CurveFiPool storage) {
        return _storage().pools[poolId];
    }

    function getPoolIdFromParams(
        bytes calldata encodedParams
    ) internal view override returns (uint256 poolId) {
        (address deposit, , , , ) = abi.decode(
            encodedParams,
            (address, uint80, uint8, address, address)
        );

        (address[4] memory tokens, ) = ICurveFiPool(deposit).getTokens();
        return _storage().ids[hash(tokens)];
    }

    function getPoolIdFromTokens(
        bytes calldata encodedTokens
    ) internal view override returns (uint256 poolId) {
        address[] memory tokens = abi.decode(encodedTokens, (address[]));
        address[4] memory tokensFixed;

        if (tokens.length == 2) tokensFixed = [tokens[0], tokens[1], address(0), address(0)];
        else if (tokens.length == 3) tokensFixed = [tokens[0], tokens[1], tokens[2], address(0)];
        else if (tokens.length == 4) tokensFixed = [tokens[0], tokens[1], tokens[2], tokens[3]];
        else return 0;

        return _storage().ids[hash(tokensFixed)];
    }

    function _storage() private pure returns (Storage storage $) {
        assembly {
            $.slot := STORAGE_SLOT
        }
    }

    function hash(address[4] memory tokens) private pure returns (bytes32) {
        return keccak256(abi.encodePacked(Address.sort(tokens)));
    }
}
"
    },
    "contracts/compiler/curveFi/libraries/CurveFiLib.sol": {
      "content": "// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.22;
import {ICurveFiPool} from "contracts/interfaces/compliance/internal/curveFi/index.sol";

library CurveFiLib {
    error TokenIndexNotFoundInCurveFiPool(address token, address pool);

    function getTokens(
        ICurveFiPool pool
    ) internal view returns (address[4] memory tokens, uint256 nCoins) {
        while (nCoins < 4) {
            try pool.coins(nCoins) returns (address token) {
                tokens[nCoins] = token;
                unchecked {
                    ++nCoins;
                }
            } catch {
                break;
            }
        }
    }

    function getTokenIndex(
        ICurveFiPool pool,
        uint256 nCoinsPool,
        ICurveFiPool basePool,
        uint256 nCoinsBasePool,
        address token
    ) internal view returns (uint256 index) {
        index = pool == basePool ? _getTokenIndex(pool, nCoinsPool, token) : pool.coins(0) == token
            ? 0
            : _getTokenIndex(basePool, nCoinsBasePool, token) + 1;
    }

    function _getTokenIndex(
        ICurveFiPool pool,
        uint256 nCoins,
        address token
    ) private view returns (uint256 index) {
        while (index < nCoins) {
            if (pool.coins(index) == token) return index;
            unchecked {
                ++index;
            }
        }
        revert TokenIndexNotFoundInCurveFiPool(token, address(pool));
    }
}
"
    },
    "contracts/compiler/libraries/Path.sol": {
      "content": "// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.22;

library Path {
    using Path for bytes;

    uint256 internal constant ADDRESS_LEN = 20;
    uint256 internal constant POOL_ID_LEN = 4;
    uint256 internal constant NEXT_OFFSET = ADDRESS_LEN + POOL_ID_LEN;

    error InvalidPathLength(uint256);

    function extractTokenIn(bytes calldata _path) internal pure returns (address tokenIn_) {
        _path.ensureValid();
        tokenIn_ = _path.extractTokenInUnsafe();
    }

    function extractTokenInUnsafe(bytes calldata _path) internal pure returns (address tokenIn_) {
        tokenIn_ = address(bytes20(_path[0:ADDRESS_LEN]));
    }

    function extractTokenOut(bytes calldata _path) internal pure returns (address tokenOut_) {
        _path.ensureValid();
        tokenOut_ = _path.extractTokenOutUnsafe();
    }

    function extractTokenOutUnsafe(bytes calldata _path) internal pure returns (address tokenOut_) {
        uint256 len = _path.length;
        tokenOut_ = address(bytes20(_path[len - ADDRESS_LEN:len]));
    }

    /* solhint-disable var-name-mixedcase */
    function extractPool(
        bytes calldata _path,
        uint256 _poolNumber
    ) internal pure returns (address tokenIn__, address tokenOut_, uint32 poolId_____) {
        /* solhint-enable var-name-mixedcase */
        _path.ensureValid();
        uint256 ptr = _poolNumber * NEXT_OFFSET;

        tokenIn__ = address(bytes20(_path[ptr:(ptr = ptr + ADDRESS_LEN)]));
        poolId_____ = uint32(bytes4(_path[ptr:(ptr = ptr + POOL_ID_LEN)]));
        tokenOut_ = address(bytes20(_path[ptr:(ptr = ptr + ADDRESS_LEN)]));
    }

    function getNumberOfPools(bytes calldata _path) internal pure returns (uint256) {
        _path.ensureValid();
        return (_path.length - ADDRESS_LEN) / NEXT_OFFSET;
    }

    function ensureValid(bytes calldata _path) internal pure {
        if (!isValid(_path)) revert InvalidPathLength(_path.length);
    }

    function isValid(bytes calldata _path) private pure returns (bool) {
        if (_path.length < ADDRESS_LEN) return false;
        return (_path.length - ADDRESS_LEN) % NEXT_OFFSET == 0;
    }
}
"
    },
    "contracts/interfaces/base/CommonErrors.sol": {
      "content": "// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.22;

/**
 * @notice An error indicating that the amount for the specified token is zero.
 * @param token The address of the token with a zero amount.
 */
error AmountMustNotBeZero(address token);

/**
 * @notice An error indicating that an address must not be zero.
 */
error AddressMustNotBeZero();

/**
 * @notice An error indicating that an array must not be empty.
 */
error ArrayMustNotBeEmpty();

/**
 * @notice An error indicating that an string must not be empty.
 */
error StringMustNotBeEmpty();

/**
 * @notice An error indicating storage is already up to date and doesn't need further processing.
 * @dev This error is thrown when attempting to update an entity(s) that is(are) already up to date.
 */
error AlreadyUpToDate();

/**
 * @notice An error indicating that an action is unauthorized for the specified account.
 * @param account The address of the unauthorized account.
 */
error UnauthorizedAccount(address account);

/**
 * @notice An error indicating that the min amount out must not be zero.
 */
error MinAmountOutMustNotBeZero();
"
    },
    "contracts/interfaces/base/IERC165Extended.sol": {
      "content": "// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.22;

/* solhint-disable no-unused-import */
import {
    IERC165
} from "@openzeppelin/contracts-upgradeable/utils/introspection/ERC165Upgradeable.sol";
/* solhint-enable no-unused-import */

/**
 * @notice An error indicating that an address does not support the expected interface
 * @param implementation The address that does not implement the required interface
 */
error UnsupportedInterface(address implementation);

/**
 * @dev Extended interface of the ERC165 standard to ensure compatibility
 * with Diamond facets as defined in EIP-2535.
 *
 * This interface extends the basic ERC165 mechanism to provide additional
 * flexibility for querying supported interfaces, which can then be
 * dynamically resolved by one of facets in a Diamond.
 */
interface IERC165Extended {
    /**
     * @notice Checks if the given interface ID is supported by the contract.
     * @param interfaceId The ID of the interface to query.
     * @return isSupported Boolean value indicating whether the interface is supported.
     */
    function supportsInterfaceExtended(bytes4 interfaceId) external pure returns (bool isSupported);
}
"
    },
    "contracts/interfaces/compiler/adapters/IDecreasePositionEvaluator.sol": {
      "content": "// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.22;

import {Asset} from "contracts/libraries/AssetLibrary.sol";
import {Command} from "../Command.sol";
import {PositionDescriptor} from "./PositionDescriptor.sol";

interface IDecreasePositionEvaluator {
    /**
     * @notice Request structure for decreasing a position.
     * @dev `descriptor`: The [`PositionDescriptor`](/interfaces/compiler/adapters/PositionDescriptor.sol/struct.PositionDescriptor.html)
     *  struct.
     * @dev `liquidity`: Abstract amount that can be interpreted differently in different protocols (e.g., amount of LP tokens to burn).
     * @dev `minOutput`: [`Asset`](/interfaces/compliance/Asset.sol/struct.Asset.html) array with minimum amounts that must be retrieved from the position.
     */
    struct DecreasePositionRequest {
        PositionDescriptor descriptor;
        uint256 liquidity;
        Asset[] minOutput;
    }

    /**
     * @notice Evaluate a decrease position request.
     * @param _operator Address which initiated the request
     * @param _request The [`DecreasePositionRequest`](#decreasepositionrequest) struct containing decrease position details.
     * @return cmds_ An array of [`Command`](../../Command.sol/struct.Command.html) to execute the request.
     */
    function evaluate(
        address _operator,
        DecreasePositionRequest calldata _request
    ) external returns (Command[] memory cmds_);
}
"
    },
    "contracts/interfaces/compiler/adapters/IExchangeEvaluator.sol": {
      "content": "// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.22;

import {Command} from "../Command.sol";

/**
 * @title IExchangeEvaluator
 * @notice Interface for compiling commands for token exchanges for different protocols.
 */
interface IExchangeEvaluator {
    /**
     * @notice Structure for an exchange token request.
     * @dev `path`: Encoded path of tokens to follow in the exchange, including pool identifiers.
     * 20 bytes(tokenA) + 4 byte(poolId_A_B) + 20 bytes(tokenB) + ...
     * ... + 4 byte(poolId_N-1_N) + 20 bytes(tokenN).
     * @dev `extraData`: Additional data specific to a particular protocol, such as the response from a 1Inch Exchange API.
     * @dev `amountIn`: The amount of tokenA to spend.
     * @dev `minAmountOut`: The minimum amount of tokenN to receive.
     * @dev `recipient`: The recipient of tokenN.
     */
    struct ExchangeRequest {
        bytes path;
        bytes extraData;
        uint256 amountIn;
        uint256 minAmountOut;
        address recipient;
    }

    /**
     * @notice Constructs an exchange token request.
     * @param _operator Address which initiated the request
     * @param _request The [`ExchangeRequest`](#exchangerequest) struct containing exchange token details.
     * @return cmds_ An array of [`Command`](../../Command.sol/struct.Command.html) to execute the request.
     */
    function evaluate(
        address _operator,
        ExchangeRequest calldata _request
    ) external view returns (Command[] memory cmds_);
}
"
    },
    "contracts/interfaces/compiler/adapters/IIncreasePositionEvaluator.sol": {
      "content": "// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.22;

import {Asset} from "contracts/libraries/AssetLibrary.sol";
import {Command} from "../Command.sol";
import {PositionDescriptor} from "./PositionDescriptor.sol";

interface IIncreasePositionEvaluator {
    /**
     * @notice Structure for an increase position request.
     * @dev `descriptor`: The [`PositionDescriptor`](/interfaces/compiler/adapters/PositionDescriptor.sol/struct.PositionDescriptor.html)
     *  struct.
     * @dev `input`: An array of [`Asset`](/interfaces/compliance/Asset.sol/struct.Asset.html) representing the token-amounts that will be added to the position.
     * @dev `minLiquidityOut`: An abstract amount that can be interpreted differently in different protocols (e.g., minimum amount of LP tokens to receive).
     */
    struct IncreasePositionRequest {
        PositionDescriptor descriptor;
        Asset[] input;
        uint256 minLiquidityOut;
    }

    /**
     * @notice Evaluate a increase position request.
     * @param _operator Address which initiated the request
     * @param _request The [`IncreasePositionRequest`](#increasepositionrequest) struct containing increase position details.
     * @return cmds_ An array of [`Command`](../../Command.sol/struct.Command.html) to execute the request.
     */
    function evaluate(
        address _operator,
        IncreasePositionRequest calldata _request
    ) external returns (Command[] memory cmds_);
}
"
    },
    "contracts/interfaces/compiler/adapters/ILiquidityPoolsRepository.sol": {
      "content": "// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.22;

/* solhint-disable no-unused-import */
import {AlreadyUpToDate} from "contracts/interfaces/base/CommonErrors.sol";
import {
    Status,
    TokenIsNotSupported
} from "contracts/interfaces/compliance/IWhitelistingController.sol";
/* solhint-enable no-unused-import */

/**
 * @notice Error indicating that the pool ID was not found.
 * @param encodedPool The encoded pool data that was searched for.
 */
error PoolIdNotFound(bytes encodedPool);

/**
 * @notice Error indicating that the pool does not exist.
 * @param poolId The unique identifier of the pool that was searched for.
 */
error PoolIsNotSupported(uint256 poolId);

/**
 * @notice Error indicating that the pool is suspended.
 * @param poolId The unique identifier of the pool that is suspended.
 */
error PoolIsSuspended(uint256 poolId);

/**
 * @title ILiquidityPoolsRepository
 * @notice Interface for managing liquidity pools and their support status.
 */
interface ILiquidityPoolsRepository {
    /**
     * @notice Update the support status of a liquidity pool.
     * @param _encodedPool The encoded pool data.
     * @param _supported Whether the pool is supported or not.
     * @return poolId_ The unique identifier of the pool.
     * @dev Reverts with a [`PoolIdNotFound()`](/interfaces/compiler/adapters/ILiquidityPoolsRepository.sol/error.PoolIdNotFound.html)
     *  error if the pool does not exist.
     */
    function updatePoolSupport(
        bytes calldata _encodedPool,
        bool _supported
    ) external returns (uint256 poolId_);

    /**
     * @notice Get the status of a specific pool.
     * @param _poolId The unique identifier of the pool.
     * @return status The status of the pool.
     * @dev Reverts with a [`PoolIsNotSupported()`](/interfaces/compiler/adapters/ILiquidityPoolsRepository.sol/error.PoolIsNotSupported.html)
     *  error if the pool does not exist.
     */
    function getPoolStatus(uint256 _poolId) external returns (Status status);

    /**
     * @notice Get the unique identifier (pool ID) of a specific pool.
     * @param _encodedPool The encoded pool data.
     * @return poolId_ The unique identifier of the pool.
     * @dev Reverts with a [`PoolIsNotSupported()`](/interfaces/compiler/adapters/ILiquidityPoolsRepository.sol/error.PoolIsNotSupported.html)
     *  error if the pool does not exist.
     */
    function getPoolId(bytes calldata _encodedPool) external view returns (uint256 poolId_);
}
"
    },
    "contracts/interfaces/compiler/adapters/index.sol": {
      "content": "// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.22;

import {
    IDecreasePositionEvaluator
} from "contracts/interfaces/compiler/adapters/IDecreasePositionEvaluator.sol";
import {IExchangeEvaluator} from "contracts/interfaces/compiler/adapters/IExchangeEvaluator.sol";
import {
    IIncreasePositionEvaluator
} from "contracts/interfaces/compiler/adapters/IIncreasePositionEvaluator.sol";
import {
    AlreadyUpToDate,
    ILiquidityPoolsRepository,
    PoolIdNotFound,
    PoolIsNotSupported,
    PoolIsSuspended,
    Status,
    TokenIsNotSupported
} from "contracts/interfaces/compiler/adapters/ILiquidityPoolsRepository.sol";
import {PositionDescriptor} from "contracts/interfaces/compiler/adapters/PositionDescriptor.sol";
"
    },
    "contracts/interfaces/compiler/adapters/PositionDescriptor.sol": {
      "content": "// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.22;

// TODO CRYPTO-145: Possibly move into appropriate interface?
/**
 * @notice Used to determine the required position for an operation.
 * @dev `poolId`: An identifier that is unique within a single protocol.
 * @dev `extraData`: Additional data used to specify the position, for example
 * this is used in OneInchV5Evaluator to pass swap tx generated via 1inch API.
 */
struct PositionDescriptor {
    uint256 poolId;
    bytes extraData;
}
"
    },
    "contracts/interfaces/compiler/Command.sol": {
      "content": "// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.22;

import {CommandLibrary} from "contracts/libraries/CommandLibrary.sol";

/**
 * @title Command
 * @notice Contains arguments for a low-level call.
 * @dev This struct allows deferring the call's execution, suspending it by passing it to another function or contract.
 * @dev `target` The address to be called.
 * @dev `value` Value to send in the call.
 * @dev `payload` Encoded call with function selector and arguments.
 */
struct Command {
    address target;
    uint256 value;
    bytes payload;
}

using CommandLibrary for Command global;
"
    },
    "contracts/interfaces/compliance/Asset.sol": {
      "content": "// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.22;

import {AssetLibrary} from "contracts/libraries/AssetLibrary.sol";

/**
 * @title Asset
 * @dev Represents an asset with its token address and the amount.
 * @param token The address of the asset's token.
 * @param amount The amount of the asset.
 */
struct Asset {
    address token;
    uint256 amount;
}

using AssetLibrary for Asset global;
"
    },
    "contracts/interfaces/compliance/internal/curveFi/ICurveFiGauge.sol": {
      "content": "// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.22;

/* solhint-disable func-name-mixedcase, var-name-mixedcase, func-param-name-mixedcase */
interface ICurveFiGauge {
    /// @param _value Amount to stake
    /// @dev Stakes _value lp tokens to the gauge
    function deposit(uint256 _value) external;

    /// @param _value Amount to unstake
    /// @dev Unstakes _value lp tokens from the gauge
    function withdraw(uint256 _value) external;

    /// @return Address of the lp token which you can stake to this gauge
    function lp_token() external view returns (address);

    /// @return _account's lp balance on the gauge
    function balanceOf(address _account) external view returns (uint256);
}
/* solhint-enable func-name-mixedcase, var-name-mixedcase, func-param-name-mixedcase */
"
    },
    "contracts/interfaces/compliance/internal/curveFi/ICurveFiMinter.sol": {
      "content": "// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.22;

interface ICurveFiMinter {
    /// @param _gauge Address of the gauge in which tokens was staked
    /// @dev Claims all rewards from gauge staking
    function mint(address _gauge) external;
}
"
    },
    "contracts/interfaces/compliance/internal/curveFi/ICurveFiPool.sol": {
      "content": "// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.22;

/* solhint-disable func-name-mixedcase, var-name-mixedcase, func-param-name-mixedcase */
interface ICurveFiPool {
    /**
     *
     *
     * Liquidity
     *
     *
     **/

    /**
     * @param _deposit_amounts List of amounts of underlying coins to deposit. Amounts correspond to the tokens at the same index locations within Factory.get_underlying_coins.
     * @param _min_mint_amount Minimum amount of LP tokens to mint from the deposit.
     **/
    function add_liquidity(uint256[4] calldata _deposit_amounts, uint256 _min_mint_amount) external;

    /**
     * @param _deposit_amounts List of amounts of underlying coins to deposit. Amounts correspond to the tokens at the same index locations within Factory.get_underlying_coins.
     * @param _min_mint_amount Minimum amount of LP tokens to mint from the deposit.
     **/
    function add_liquidity(uint256[3] calldata _deposit_amounts, uint256 _min_mint_amount) external;

    /**
     * @param _deposit_amounts List of amounts of underlying coins to deposit. Amounts correspond to the tokens at the same index locations within Factory.get_underlying_coins.
     * @param _min_mint_amount Minimum amount of LP tokens to mint from the deposit.
     **/
    function add_liquidity(uint256[2] calldata _deposit_amounts, uint256 _min_mint_amount) external;

    /**
     * @param _burn_amount Quantity of LP tokens to burn in the withdrawal. Amounts correspond to the tokens at the same index locations within Factory.get_underlying_coins.
     * @param _min_amounts Minimum amounts of underlying coins to receive.
     **/
    function remove_liquidity(uint256 _burn_amount, uint256[4] calldata _min_amounts) external;

    /**
     * @param _burn_amount Quantity of LP tokens to burn in the withdrawal. Amounts correspond to the tokens at the same index locations within Factory.get_underlying_coins.
     * @param _min_amounts Minimum amounts of underlying coins to receive.
     **/
    function remove_liquidity(uint256 _burn_amount, uint256[3] calldata _min_amounts) external;

    /**
     * @param _burn_amount Quantity of LP tokens to burn in the withdrawal. Amounts correspond to the tokens at the same index locations within Factory.get_underlying_coins.
     * @param _min_amounts Minimum amounts of underlying coins to receive.
     **/
    function remove_liquidity(uint256 _burn_amount, uint256[2] calldata _min_amounts) external;

    /**
     * @param _burn_amount Amount of LP tokens to burn in the withdrawal.
     * @param i Index value of the coin to withdraw. Can be found using the coins getter method.
     * @param _min_received Minimum amount of the coin to receive
     **/
    function remove_liquidity_one_coin(
        uint256 _burn_amount,
        int128 i,
        uint256 _min_received
    ) external;

    /**
     * @param _burn_amount Amount of LP tokens to burn in the withdrawal.
     * @param i Index value of the coin to withdraw. Can be found using the coins getter method.
     * @param _min_received Minimum amount of the coin to receive
     **/
    function remove_liquidity_one_coin(
        uint256 _burn_amount,
        uint256 i,
        uint256 _min_received
    ) external;

    /// @notice Withdraw coins from the pool in an imbalanced amount
    /// @param _amounts List of amounts of underlying coins to withdraw
    /// @param _max_burn_amount Maximum amount of LP token to burn in the withdrawal
    function remove_liquidity_imbalance(
        uint256[4] calldata _amounts,
        uint256 _max_burn_amount
    ) external;

    /// @notice Withdraw coins from the pool in an imbalanced amount
    /// @param _amounts List of amounts of underlying coins to withdraw
    /// @param _max_burn_amount Maximum amount of LP token to burn in the withdrawal
    function remove_liquidity_imbalance(
        uint256[3] calldata _amounts,
        uint256 _max_burn_amount
    ) external;

    /// @notice Withdraw coins from the pool in an imbalanced amount
    /// @param _amounts List of amounts of underlying coins to withdraw
    /// @param _max_burn_amount Maximum amount of LP token to burn in the withdrawal
    function remove_liquidity_imbalance(
        uint256[2] calldata _amounts,
        uint256 _max_burn_amount
    ) external;

    /**
     *
     *
     * Swaps
     *
     *
     **/

    /**
     * Perform an exchange between two coins.
     * @param _i Index value for the coin to send
     * @param _j Index value of the coin to receive
     * @param _dx Amount of i being exchanged
     * @param _min_dy Minimum amount of j to receive
     **/
    function exchange(int128 _i, int128 _j, uint256 _dx, uint256 _min_dy) external payable;

    /**
     * Perform an exchange between two coins.
     * @param _i Index value for the coin to send
     * @param _j Index value of the coin to receive
     * @param _dx Amount of i being exchanged
     * @param _min_dy Minimum amount of j to receive
     * @param _use_eth Do use eth instead of weth
     **/
    function exchange(
        uint256 _i,
        uint256 _j,
        uint256 _dx,
        uint256 _min_dy,
        bool _use_eth
    ) external payable;

    /**
     * Perform an exchange between two coins.
     * @param _i Index value for the coin to send
     * @param _j Index value of the coin to receive
     * @param _dx Amount of i being exchanged
     * @param _min_dy Minimum amount of j to receive
     * @param _use_eth Do use eth instead of weth
     * @param _recipient An address that will receive the `_j` coin
     * @return dy_ The amount of `_j` received in the exchange.
     **/
    function exchange(
        uint256 _i,
        uint256 _j,
        uint256 _dx,
        uint256 _min_dy,
        bool _use_eth,
        address _recipient
    ) external payable returns (uint256 dy_);

    /**
     * Perform an exchange between two underlying coins.
     * @param _i: Index value of the underlying token to send.
     * @param _j: Index value of the underlying token to receive.
     * @param _dx: The amount of i being exchanged.
     * @param _min_dy: The minimum amount of j to receive. If the swap would result in less, the transaction will revert.
     * @param _receiver: An optional address that will receive j. If not given, defaults to the caller.
     * @return dy_ The amount of j received in the exchange.
     **/
    function exchange_underlying(
        int128 _i,
        int128 _j,
        uint256 _dx,
        uint256 _min_dy,
        address _receiver
    ) external returns (uint256 dy_);

    /**
     *
     *
     * Getters
     *
     *
     **/

    /**
     * Get the amount of coin j one would receive for swapping _dx of coin i
     * @param _i Index value for the coin to send
     * @param _j Index value of the coin to receive
     * @param _dx Amount of i being exchanged
     **/
    function get_dy(int128 _i, int128 _j, uint256 _dx) external view returns (uint256 dy_);

    /**
     * Get the amount of coin j one would receive for swapping _dx of coin i
     * @param _i Index value for the coin to send
     * @param _j Index value of the coin to receive
     * @param _dx Amount of i being exchanged
     **/
    function get_dy(uint256 _i, uint256 _j, uint256 _dx) external view returns (uint256 dy_);

    /**
     * Get the amount received (“dy”) when swapping between two underlying assets within the pool.
     * @param _i Index value for the coin to send
     * @param _j Index value of the coin to receive
     * @param _dx The amount of j received.
     **/
    function get_dy_underlying(
        int128 _i,
        int128 _j,
        uint256 _dx
    ) external view returns (uint256 dy_);

    /**
     * Get the amount received (“dy”) when swapping between two underlying assets within the pool.
     * @param _i Index value for the coin to send
     * @param _j Index value of the coin to receive
     * @param _dx The amount of j received.
     **/
    function get_dy_underlying(
        uint256 _i,
        uint256 _j,
        uint256 _dx
    ) external view returns (uint256 dy_);

    /**
     * @param _amounts Amount of each coin being deposited. Amounts correspond to the tokens at the same index locations within coins.
     * @param _is_deposit set True for deposits, False for withdrawals.
     * @return The expected amount of LP tokens minted or burned.
     **/
    function calc_token_amount(
        uint256[4] calldata _amounts,
        bool _is_deposit
    ) external view returns (uint256);

    /**
     * @param _amounts Amount of each coin being deposited. Amounts correspond to the tokens at the same index locations within coins.
     * @param _is_deposit set True for deposits, False for withdrawals.
     * @return The expected amount of LP tokens minted or burned.
     **/
    function calc_token_amount(
        uint256[3] calldata _amounts,
        bool _is_deposit
    ) external view returns (uint256);

    /**
     * @param _amounts Amount of each coin being deposited. Amounts correspond to the tokens at the same index locations within coins.
     * @return The expected amount of LP tokens minted or burned.
     **/
    function calc_token_amount(uint256[2] calldata _amounts) external view returns (uint256);

    /**
     * @param _amounts Amount of each coin being deposited. Amounts correspond to the tokens at the same index locations within coins.
     * @param _is_deposit set True for deposits, False for withdrawals.
     * @return The expected amount of LP tokens minted or burned.
     **/
    function calc_token_amount(
        uint256[2] calldata _amounts,
        bool _is_deposit
    ) external view returns (uint256);

    /**
     * @param _burn_amount Amount of LP tokens to burn in the withdrawal.
     * @param i Index value of the underlying coin to withdraw. Can be found using the coins getter method.
     * @return The expected amount of coin received.
     **/
    function calc_withdraw_one_coin(
        uint