AAVEStrategy

{{
  "language": "Solidity",
  "sources": {
    "lib/openzeppelin-contracts/contracts/security/ReentrancyGuard.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (security/ReentrancyGuard.sol)

pragma solidity ^0.8.0;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    constructor() {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be _NOT_ENTERED
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == _ENTERED;
    }
}
"
    },
    "lib/openzeppelin-contracts/contracts/token/ERC20/IERC20.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 amount) external returns (bool);
}
"
    },
    "lib/openzeppelin-contracts/contracts/token/ERC20/extensions/IERC20Permit.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.4) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 *
 * ==== Security Considerations
 *
 * There are two important considerations concerning the use of `permit`. The first is that a valid permit signature
 * expresses an allowance, and it should not be assumed to convey additional meaning. In particular, it should not be
 * considered as an intention to spend the allowance in any specific way. The second is that because permits have
 * built-in replay protection and can be submitted by anyone, they can be frontrun. A protocol that uses permits should
 * take this into consideration and allow a `permit` call to fail. Combining these two aspects, a pattern that may be
 * generally recommended is:
 *
 * ```solidity
 * function doThingWithPermit(..., uint256 value, uint256 deadline, uint8 v, bytes32 r, bytes32 s) public {
 *     try token.permit(msg.sender, address(this), value, deadline, v, r, s) {} catch {}
 *     doThing(..., value);
 * }
 *
 * function doThing(..., uint256 value) public {
 *     token.safeTransferFrom(msg.sender, address(this), value);
 *     ...
 * }
 * ```
 *
 * Observe that: 1) `msg.sender` is used as the owner, leaving no ambiguity as to the signer intent, and 2) the use of
 * `try/catch` allows the permit to fail and makes the code tolerant to frontrunning. (See also
 * {SafeERC20-safeTransferFrom}).
 *
 * Additionally, note that smart contract wallets (such as Argent or Safe) are not able to produce permit signatures, so
 * contracts should have entry points that don't rely on permit.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     *
     * CAUTION: See Security Considerations above.
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}
"
    },
    "lib/openzeppelin-contracts/contracts/token/ERC20/utils/SafeERC20.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.3) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";
import "../extensions/IERC20Permit.sol";
import "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(IERC20 token, address spender, uint256 value) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        require(
            (value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance + value));
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        unchecked {
            uint256 oldAllowance = token.allowance(address(this), spender);
            require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance - value));
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeWithSelector(token.approve.selector, spender, value);

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, 0));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Use a ERC-2612 signature to set the `owner` approval toward `spender` on `token`.
     * Revert on invalid signature.
     */
    function safePermit(
        IERC20Permit token,
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal {
        uint256 nonceBefore = token.nonces(owner);
        token.permit(owner, spender, value, deadline, v, r, s);
        uint256 nonceAfter = token.nonces(owner);
        require(nonceAfter == nonceBefore + 1, "SafeERC20: permit did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        require(returndata.length == 0 || abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return
            success && (returndata.length == 0 || abi.decode(returndata, (bool))) && Address.isContract(address(token));
    }
}
"
    },
    "lib/openzeppelin-contracts/contracts/utils/Address.sol": {
      "content": "// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     *
     * Furthermore, `isContract` will also return true if the target contract within
     * the same transaction is already scheduled for destruction by `SELFDESTRUCT`,
     * which only has an effect at the end of a transaction.
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.0/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
     * the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
     *
     * _Available since v4.8._
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        if (success) {
            if (returndata.length == 0) {
                // only check isContract if the call was successful and the return data is empty
                // otherwise we already know that it was a contract
                require(isContract(target), "Address: call to non-contract");
            }
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason or using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    function _revert(bytes memory returndata, string memory errorMessage) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert(errorMessage);
        }
    }
}
"
    },
    "src/genesis/interfaces/IGenesisStrategy.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

/**
 * @title IGenesisStrategy
 * @notice Interface for Genesis Vaults yield generation strategies
 * @dev All strategies must implement this interface
 */
interface IGenesisStrategy {
    /**
     * @notice Deposit assets into the strategy
     * @param amount Amount of assets to deposit
     * @return The amount actually deposited
     */
    function deposit(uint256 amount) external returns (uint256);

    /**
     * @notice Withdraw specific amount from strategy
     * @param amount Amount to withdraw
     * @return The amount actually withdrawn
     */
    function withdraw(uint256 amount) external returns (uint256);

    /**
     * @notice Withdraw all assets from strategy
     * @return principal total amount withdrawn
     * @return yield total amount of yield withdrawn
     */
    function withdrawAll() external returns (uint256 principal, uint256 yield);

    /**
     * @notice Get total assets under management
     * @return Total assets in the strategy
     */
    function totalAssets() external view returns (uint256);

    /**
     * @notice Claim rewards from the strategy (yield)
     * @return amount of rewards claimed (returned in liquidity token)
     */
    function claimRewards() external returns (uint256);

    /**
     * @notice Claim rewards from the strategy (non-yield external incentives)
     * @return rewardTokens array of reward token addresses
     * @return amounts array of reward amounts claimed
     */
    function claimIncentiveRewards()
        external
        returns (address[] memory rewardTokens, uint256[] memory amounts);

    /**
     * @notice Get unclaimed incentive rewards balance (non-yield external incentives)
     * @return rewardTokens array of reward token addresses
     * @return amounts array of unclaimed amounts
     */
    function getUnclaimedIncentiveRewards()
        external
        view
        returns (address[] memory rewardTokens, uint256[] memory amounts);

    /**
     * @notice Check if strategy supports given asset
     * @param token Token address to check
     * @return True if asset is supported
     */
    function supportsAsset(address token) external view returns (bool);

    /**
     * @notice Get strategy name
     * @return Strategy name string
     */
    function name() external view returns (string memory);

    /**
     * @notice Get strategy version
     * @return Version string
     */
    function version() external view returns (string memory);

    /**
     * @notice Get the asset this strategy manages
     * @return Asset token address
     */
    function asset() external view returns (address);
}
"
    },
    "src/genesis/interfaces/external/DataTypes.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

/**
 * @title DataTypes
 * @notice Simplified data types for AAVE v3 integration
 * @dev Contains only the structs needed by the AAVE strategy
 */
library DataTypes {
    struct ReserveConfigurationMap {
        uint256 data;
    }

    struct ReserveData {
        ReserveConfigurationMap configuration;
        uint128 liquidityIndex;
        uint128 currentLiquidityRate;
        uint128 variableBorrowIndex;
        uint128 currentVariableBorrowRate;
        uint128 currentStableBorrowRate;
        uint40 lastUpdateTimestamp;
        uint16 id;
        address aTokenAddress;
        address stableDebtTokenAddress;
        address variableDebtTokenAddress;
        address interestRateStrategyAddress;
        uint128 accruedToTreasury;
        uint128 unbacked;
        uint128 isolationModeTotalDebt;
    }
}
"
    },
    "src/genesis/interfaces/external/IPool.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import { DataTypes } from "./DataTypes.sol";

/**
 * @title IPool
 * @notice Simplified interface for AAVE v3 Pool contract
 * @dev Contains only the functions needed by the AAVE strategy
 */
interface IPool {
    /**
     * @notice Supply assets to the pool
     * @param asset The address of the underlying asset to supply
     * @param amount The amount to be supplied
     * @param onBehalfOf The address that will receive the aTokens
     * @param referralCode Code used to register the integrator originating the operation, for potential rewards
     */
    function supply(
        address asset,
        uint256 amount,
        address onBehalfOf,
        uint16 referralCode
    ) external;

    /**
     * @notice Withdraws an `amount` of underlying asset from the reserve, burning the equivalent aTokens owned
     * @param asset The address of the underlying asset to withdraw
     * @param amount The underlying amount to be withdrawn
     * @param to The address that will receive the underlying, same as msg.sender if the user
     * @return The final amount withdrawn
     */
    function withdraw(address asset, uint256 amount, address to) external returns (uint256);

    /**
     * @notice Returns the state and configuration of the reserve
     * @param asset The address of the underlying asset of the reserve
     * @return The state and configuration data of the reserve
     */
    function getReserveData(address asset) external view returns (DataTypes.ReserveData memory);
}
"
    },
    "src/genesis/interfaces/external/IRewardsController.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

/**
 * @title IRewardsController
 * @notice Simplified interface for AAVE v3 Rewards Controller
 * @dev Contains only the functions needed by the AAVE strategy
 */
interface IRewardsController {
    /**
     * @notice Claims all rewards for a user to the desired address, on all the assets specified
     * @param assets The list of assets to check eligible distributions before claiming rewards
     * @param to The address that will be receiving the rewards
     * @return rewardsList List of addresses of the reward tokens
     * @return claimedAmounts List that contains the claimed amount per reward, following same order as "rewardsList"
     */
    function claimAllRewards(
        address[] calldata assets,
        address to
    ) external returns (address[] memory rewardsList, uint256[] memory claimedAmounts);

    /**
     * @notice Claims all rewards for a user to the same address, on all the assets specified
     * @param assets The list of assets to check eligible distributions before claiming rewards
     * @return rewardsList List of addresses of the reward tokens
     * @return claimedAmounts List that contains the claimed amount per reward, following same order as "rewardsList"
     */
    function claimAllRewardsToSelf(
        address[] calldata assets
    ) external returns (address[] memory rewardsList, uint256[] memory claimedAmounts);

    /**
     * @notice Returns the total of rewards of a user, on all the assets specified
     * @param assets The list of assets to check eligible distributions before claiming rewards
     * @param user The address of the user
     * @return rewardsList List of addresses of the reward tokens
     * @return unclaimedAmounts List that contains the unclaimed amount per reward, following same order as "rewardsList"
     */
    function getAllUserRewardsBalance(
        address[] calldata assets,
        address user
    ) external view returns (address[] memory rewardsList, uint256[] memory unclaimedAmounts);
}
"
    },
    "src/genesis/strategies/AAVEStrategy.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import "@openzeppelin/contracts/security/ReentrancyGuard.sol";
import "./BaseGenesisStrategy.sol";
import "../interfaces/external/IPool.sol";
import "../interfaces/external/IRewardsController.sol";
import "../interfaces/external/DataTypes.sol";

/**
 * @title AAVEStrategy
 * @notice Genesis Vault strategy for AAVE v3 lending
 * @dev Multi-chain compatible AAVE strategy with reward claiming
 */
contract AAVEStrategy is BaseGenesisStrategy, ReentrancyGuard {
    using SafeERC20 for IERC20;

    /// @notice AAVE Pool contract
    IPool public immutable aavePool;

    /// @notice AAVE Rewards Controller contract
    IRewardsController public immutable rewardsController;

    /// @notice aToken address for the asset
    address public immutable aToken;

    /// @notice Total principal deposited (used for yield calculation)
    uint256 public totalPrincipalDeposited;

    /// @notice Strategy version
    string private constant VERSION = "1.0.0";

    /// @notice Strategy name
    string private constant NAME = "AAVE Lending Strategy";

    /// @notice Events
    event AssetsSupplied(uint256 amount);
    event AssetsWithdrawn(uint256 amount);
    event RewardsClaimed(address[] rewardTokens, uint256[] amounts);

    /// @notice Custom errors
    error InvalidPoolAddress();
    error InvalidRewardsController();
    error InvalidATokenAddress();

    /**
     * @notice Constructor
     * @param _factory Genesis factory address
     * @param _asset Underlying asset address (e.g., USDC)
     * @param _aavePool AAVE Pool contract address
     * @param _rewardsController AAVE Rewards Controller address
     */
    constructor(
        address _factory,
        address _asset,
        address _aavePool,
        address _rewardsController
    ) BaseGenesisStrategy(_factory, _asset) {
        if (_aavePool == address(0)) revert InvalidPoolAddress();
        if (_rewardsController == address(0)) revert InvalidRewardsController();

        aavePool = IPool(_aavePool);
        rewardsController = IRewardsController(_rewardsController);

        // Get aToken address from AAVE pool
        DataTypes.ReserveData memory reserveData = aavePool.getReserveData(_asset);
        if (reserveData.aTokenAddress == address(0)) revert InvalidATokenAddress();

        aToken = reserveData.aTokenAddress;
    }

    /// @notice Get strategy name
    function name() external pure override returns (string memory) {
        return NAME;
    }

    /// @notice Get strategy version
    function version() external pure override returns (string memory) {
        return VERSION;
    }

    /**
     * @notice Deposit assets into AAVE pool
     * @param amount Amount to deposit
     * @return Amount actually deposited
     */
    function deposit(uint256 amount) external override onlyFactory nonReentrant returns (uint256) {
        if (amount == 0) return 0;

        // Transfer assets from factory
        IERC20(asset).safeTransferFrom(factory, address(this), amount);

        // Approve AAVE pool to spend assets
        IERC20(asset).forceApprove(address(aavePool), amount);

        // Supply to AAVE pool (receives aTokens)
        aavePool.supply(asset, amount, address(this), 0);

        // Track principal deposited
        totalPrincipalDeposited += amount;
        emit AssetsSupplied(amount);
        return amount;
    }

    /**
     * @notice Withdraw specific amount from AAVE pool
     * @param amount Amount to withdraw
     * @return Amount actually withdrawn
     */
    function withdraw(uint256 amount) external override onlyFactory nonReentrant returns (uint256) {
        if (amount == 0) return 0;

        uint256 aTokenBalance = IERC20(aToken).balanceOf(address(this));
        if (aTokenBalance == 0) return 0;

        // Withdraw the minimum of requested amount or available balance
        uint256 withdrawAmount = amount > aTokenBalance ? aTokenBalance : amount;

        // Approve AAVE pool to spend aTokens for withdrawal
        IERC20(aToken).forceApprove(address(aavePool), withdrawAmount);

        uint256 actualWithdrawn = aavePool.withdraw(asset, withdrawAmount, factory);
        // Proportionally reduce principal based on amount withdrawn
        if (totalPrincipalDeposited > 0) {
            // Calculate principal reduction: (actualWithdrawn / totalAssetsBefore) * totalPrincipalDeposited
            uint256 totalAssetsBefore = aTokenBalance;
            uint256 principalReduction = (actualWithdrawn * totalPrincipalDeposited) /
                totalAssetsBefore;

            // Ensure we don't reduce more than total principal
            if (principalReduction > totalPrincipalDeposited) {
                principalReduction = totalPrincipalDeposited;
            }

            totalPrincipalDeposited -= principalReduction;
        }

        emit AssetsWithdrawn(actualWithdrawn);
        return actualWithdrawn;
    }

    /**
     * @notice Withdraw all assets from AAVE pool
     * @return principal The initial principal amount
     * @return yield The yield generated
     */
    function withdrawAll()
        external
        override
        onlyFactory
        nonReentrant
        returns (uint256 principal, uint256 yield)
    {
        uint256 aTokenBalance = IERC20(aToken).balanceOf(address(this));
        if (aTokenBalance == 0) return (0, 0);

        // Approve AAVE pool to spend all aTokens for withdrawal
        IERC20(aToken).forceApprove(address(aavePool), type(uint256).max);

        // Withdraw all from AAVE (use type(uint256).max to withdraw all)
        uint256 withdrawn = aavePool.withdraw(asset, type(uint256).max, factory);
        // Calculate actual principal and yield based on tracking
        principal = totalPrincipalDeposited;

        // Yield is the difference between what we withdrew and the principal we tracked
        if (withdrawn > principal) {
            yield = withdrawn - principal;
        } else {
            // If we somehow withdrew less than principal (shouldn't happen with AAVE),
            // treat everything as principal with no yield
            principal = withdrawn;
            yield = 0;
        }

        // Reset principal tracking since we withdrew everything
        totalPrincipalDeposited = 0;

        emit AssetsWithdrawn(withdrawn);
        return (principal, yield);
    }

    /**
     * @notice Get total assets under management
     * @return Total assets including yield
     */
    function totalAssets() external view override returns (uint256) {
        return IERC20(aToken).balanceOf(address(this));
    }

    /**
     * @notice Claim lending yield from AAVE (aToken appreciation)
     * @dev This harvests the yield for performance fee calculation
     * @return yield Total lending yield claimed (in asset terms)
     */
    function claimRewards() external override onlyFactory nonReentrant returns (uint256 yield) {
        uint256 currentATokenBalance = IERC20(aToken).balanceOf(address(this));

        // Calculate yield as the difference between current aToken balance and tracked principal
        if (currentATokenBalance > totalPrincipalDeposited) {
            yield = currentATokenBalance - totalPrincipalDeposited;
        } else {
            // No yield to harvest
            return 0;
        }

        if (yield > 0) {
            // Approve AAVE pool to spend aTokens for withdrawal
            IERC20(aToken).forceApprove(address(aavePool), yield);

            // Withdraw only the yield portion from AAVE
            uint256 actualWithdrawn = aavePool.withdraw(asset, yield, factory);
            // The principal tracking stays the same since we only withdrew yield
            emit AssetsWithdrawn(actualWithdrawn);
            return actualWithdrawn;
        }

        return 0;
    }

    /**
     * @notice Claim AAVE protocol incentive rewards (stkAAVE, etc.)
     * @dev Separate from lending yield - these are external protocol incentives
     * @return rewardTokens List of reward token addresses
     * @return amounts List of claimed amounts
     */
    function claimIncentiveRewards()
        external
        onlyFactory
        nonReentrant
        returns (address[] memory rewardTokens, uint256[] memory amounts)
    {
        address[] memory assets = new address[](1);
        assets[0] = aToken;

        (address[] memory tokens, uint256[] memory claimedAmounts) = rewardsController
            .claimAllRewards(assets, factory);
        if (tokens.length > 0) {
            emit RewardsClaimed(tokens, claimedAmounts);
            return (tokens, claimedAmounts);
        }
        // Return empty arrays if no rewards
        rewardTokens = new address[](0);
        amounts = new uint256[](0);
    }

    /**
     * @notice Get unclaimed incentive rewards balance
     * @return rewardTokens List of reward token addresses
     * @return amounts List of unclaimed amounts
     */
    function getUnclaimedIncentiveRewards()
        external
        view
        returns (address[] memory rewardTokens, uint256[] memory amounts)
    {
        address[] memory assets = new address[](1);
        assets[0] = aToken;

        (address[] memory tokens, uint256[] memory balances) = rewardsController
            .getAllUserRewardsBalance(assets, address(this));
        return (tokens, balances);
    }

    /**
     * @notice Check if strategy supports the given asset
     * @param token Token address to check
     * @return True if supported
     */
    function supportsAsset(address token) external view override returns (bool) {
        return token == asset;
    }
}
"
    },
    "src/genesis/strategies/BaseGenesisStrategy.sol": {
      "content": "// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import "../interfaces/IGenesisStrategy.sol";

/**
 * @title BaseGenesisStrategy
 * @notice Abstract base contract for Genesis Vault strategies
 * @dev Provides common functionality and access controls
 */
abstract contract BaseGenesisStrategy is IGenesisStrategy {
    /// @notice The Genesis factory contract address
    address public immutable factory;

    /// @notice The asset this strategy manages
    address public immutable override asset;

    /// @notice Only allow factory to call
    modifier onlyFactory() {
        require(msg.sender == factory, "BaseGenesisStrategy: only factory");
        _;
    }

    /**
     * @notice Constructor sets immutable factory and asset
     * @param _factory The Genesis factory address
     * @param _asset The asset token address
     */
    constructor(address _factory, address _asset) {
        require(_factory != address(0), "BaseGenesisStrategy: invalid factory");
        require(_asset != address(0), "BaseGenesisStrategy: invalid asset");

        factory = _factory;
        asset = _asset;
    }

    /// @notice Check if strategy supports given asset
    function supportsAsset(address token) external view virtual override returns (bool) {
        return token == asset;
    }

    /// @notice Get strategy name (must be implemented by child)
    function name() external view virtual override returns (string memory);

    /// @notice Get strategy version (must be implemented by child)
    function version() external view virtual override returns (string memory);

    /// @notice Deposit assets (must be implemented by child)
    function deposit(uint256 amount) external virtual override returns (uint256);

    /// @notice Withdraw specific amount (must be implemented by child)
    function withdraw(uint256 amount) external virtual override returns (uint256);

    /// @notice Withdraw all assets (must be implemented by child)
    function withdrawAll() external virtual override returns (uint256 principal, uint256 yield);

    /// @notice Get total assets under management (must be implemented by child)
    function totalAssets() external view virtual override returns (uint256);
}
"
    }
  },
  "settings": {
    "optimizer": {
      "enabled": true,
      "runs": 200
    },
    "evmVersion": "shanghai",
    "remappings": [
      "@aave/core-v3/=node_modules/@aave/core-v3/",
      "@aave/periphery-v3/=node_modules/@aave/periphery-v3/",
      "@openzeppelin/contracts-upgradeable/=lib/openzeppelin-contracts-upgradeable/contracts/",
      "@openzeppelin/contracts/=lib/openzeppelin-contracts/contracts/",
      "@pendle-sy/=lib/Pendle-SY-Public/",
      "Pendle-SY-Public/=lib/Pendle-SY-Public/contracts/",
      "cannon-std/=lib/cannon-std/src/",
      "ds-test/=lib/openzeppelin-contracts-upgradeable/lib/forge-std/lib/ds-test/src/",
      "erc4626-tests/=lib/openzeppelin-contracts-upgradeable/lib/erc4626-tests/",
      "forge-std/=lib/forge-std/src/",
      "openzeppelin-contracts-upgradeable/=lib/openzeppelin-contracts-upgradeable/",
      "openzeppelin-contracts/=lib/openzeppelin-contracts/",
      "openzeppelin/=lib/openzeppelin-contracts-upgradeable/contracts/"
    ],
    "outputSelection": {
      "*": {
        "*": [
          "evm.bytecode",
          "evm.deployedBytecode",
          "devdoc",
          "userdoc",
          "metadata",
          "abi"
        ]
      }
    }
  }
}}